code.delx.au - gnu-emacs-elpa/blob - admin/archive-contents.el

   1 ;;; archive-contents.el --- Auto-generate an Emacs Lisp package archive.
   2
   3 ;; Copyright (C) 2011, 2012  Free Software Foundation, Inc
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6
   7 ;; This program is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;;; Code:
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'lisp-mnt)
  26 (require 'package)
  27
  28 (defconst archive-contents-subdirectory-regexp
  29   "\\([^.].*?\\)-\\([0-9]+\\(?:[.][0-9]+\\|\\(?:pre\\|beta\\|alpha\\)[0-9]+\\)*\\)")
  30
  31 (defconst archive-re-no-dot "\\`\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*"
  32   "Regular expression matching all files except \".\" and \"..\".")
  33
  34 (defun archive--convert-require (elt)
  35   (list (car elt)
  36         (version-to-list (car (cdr elt)))))
  37
  38 (defun archive--strip-rcs-id (str)
  39   "Strip RCS version ID from the version string STR.
  40 If the result looks like a dotted numeric version, return it.
  41 Otherwise return nil."
  42   (when str
  43     (when (string-match "\\`[ \t]*[$]Revision:[ \t]+" str)
  44       (setq str (substring str (match-end 0))))
  45     (condition-case nil
  46         (if (version-to-list str)
  47             str)
  48       (error nil))))
  49
  50 (defun archive--delete-elc-files (dir &optional only-orphans)
  51   "Recursively delete all .elc files in DIR.
  52 Delete backup files also."
  53   (dolist (f (directory-files dir t archive-re-no-dot))
  54     (cond ((file-directory-p f)
  55            (archive--delete-elc-files f))
  56           ((or (and (string-match "\\.elc\\'" f)
  57                     (not (and only-orphans
  58                               (file-readable-p (replace-match ".el" t t f)))))
  59                (backup-file-name-p f))
  60            (delete-file f)))))
  61
  62 (defun batch-make-archive ()
  63   "Process package content directories and generate the archive-contents file."
  64   (let ((packages '(1))) ; format-version.
  65     (dolist (dir (directory-files default-directory nil archive-re-no-dot))
  66       (condition-case v
  67           (if (not (file-directory-p dir))
  68               (error "Skipping non-package file %s" dir)
  69             (let* ((pkg (file-name-nondirectory dir))
  70                    (autoloads-file (expand-file-name (concat pkg "-autoloads.el") dir))
  71                    simple-p)
  72               ;; Omit autoloads and .elc files from the package.
  73               (if (file-exists-p autoloads-file)
  74                   (delete-file autoloads-file))
  75               (archive--delete-elc-files dir)
  76               ;; Test whether this is a simple or multi-file package.
  77               (setq simple-p (archive--simple-package-p dir pkg))
  78               (push (if simple-p
  79                         (apply #'archive--process-simple-package
  80                                dir pkg simple-p)
  81                       (archive--process-multi-file-package dir pkg))
  82                     packages)))
  83         ;; Error handler
  84         (error (message "%s" (cadr v)))))
  85     (with-temp-buffer
  86       (pp (nreverse packages) (current-buffer))
  87       (write-region nil nil "archive-contents"))))
  88
  89 (defun batch-prepare-packages ()
  90   "Prepare the `packages' directory inside the Bzr checkout.
  91 Expects to be called from within the `packages' directory.
  92 \"Prepare\" here is for subsequent construction of the packages and archive,
  93 so it is meant to refresh any generated files we may need.
  94 Currently only refreshes the ChangeLog files."
  95   (let* ((wit ".changelog-witness")
  96          (prevno (or (with-temp-buffer
  97                        (ignore-errors (insert-file-contents wit))
  98                        (when (looking-at "[1-9][0-9]*\\'")
  99                          (string-to-number (match-string 0))))
 100                      1))
 101          (new-revno
 102           (or (with-temp-buffer
 103                 (call-process "bzr" nil '(t) nil "revno")
 104                 (goto-char (point-min))
 105                 (when (looking-at "[1-9][0-9]*$")
 106                   (string-to-number (match-string 0))))
 107               (error "bzr revno did not return a number as expected")))
 108          (pkgs '()))
 109     (unless (= prevno new-revno)
 110       (with-temp-buffer
 111         (unless (zerop (call-process "bzr" nil '(t) nil "log" "-v"
 112                                      (format "-r%d.." (1+ prevno))))
 113           (error "Error signaled by bzr log -v -r%d.." (1+ prevno)))
 114         (goto-char (point-min))
 115         (while (re-search-forward "^  packages/\\([-[:alnum:]]+\\)/" nil t)
 116           (cl-pushnew (match-string 1) pkgs :test #'equal))))
 117     (dolist (pkg pkgs)
 118       (condition-case v
 119           (if (file-directory-p pkg)
 120               (archive--make-changelog pkg))
 121         (error (message "%s" (cadr v)))))
 122     (write-region (number-to-string new-revno) nil wit nil 'quiet)))
 123
 124 (defun archive--simple-package-p (dir pkg)
 125   "Test whether DIR contains a simple package named PKG.
 126 If so, return a list (VERSION DESCRIPTION REQ COMMENTARY), where
 127 VERSION is the version string of the simple package, DESCRIPTION
 128 is the brief description of the package, REQ is a list of
 129 requirements, and COMMENTARY is the package commentary.
 130 Otherwise, return nil."
 131   (let* ((pkg-file (expand-file-name (concat pkg "-pkg.el") dir))
 132          (mainfile (expand-file-name (concat pkg ".el") dir))
 133          (files (directory-files dir nil archive-re-no-dot))
 134          version description req commentary)
 135     (dolist (file (prog1 files (setq files ())))
 136       (unless (string-match "\\.elc\\'" file)
 137         (push file files)))
 138     (setq files (delete (concat pkg "-pkg.el") files))
 139     (setq files (delete (concat pkg "-autoloads.el") files))
 140     (setq files (delete "ChangeLog" files))
 141     (cond
 142      ((and (or (not (file-exists-p pkg-file))
 143                (= (length files) 1))
 144            (file-exists-p mainfile))
 145       (with-temp-buffer
 146         (insert-file-contents mainfile)
 147         (goto-char (point-min))
 148         (if (not (looking-at ";;;.*---[ \t]*\\(.*?\\)[ \t]*\\(-\\*-.*-\\*-[ \t]*\\)?$"))
 149             (error "Can't parse first line of %s" mainfile)
 150           (setq description (match-string 1))
 151           (setq version
 152                 (or (archive--strip-rcs-id (lm-header "package-version"))
 153                     (archive--strip-rcs-id (lm-header "version"))
 154                     (error "Missing `version' header")))
 155           ;; Grab the other fields, which are not mandatory.
 156           (let ((requires-str (lm-header "package-requires")))
 157             (if requires-str
 158                 (setq req (mapcar 'archive--convert-require
 159                                   (car (read-from-string requires-str))))))
 160           (setq commentary (lm-commentary))
 161           (list version description req commentary))))
 162      ((not (file-exists-p pkg-file))
 163       (error "Can find single file nor package desc file in %s" dir)))))
 164
 165 (defun archive--process-simple-package (dir pkg vers desc req commentary)
 166   "Deploy the contents of DIR into the archive as a simple package.
 167 Rename DIR/PKG.el to PKG-VERS.el, delete DIR, and write the
 168 package commentary to PKG-readme.txt.  Return the descriptor."
 169   ;; Write the readme file.
 170   (with-temp-buffer
 171     (erase-buffer)
 172     (emacs-lisp-mode)
 173     (insert (or commentary
 174                 (prog1 "No description"
 175                   (message "Missing commentary in package %s" pkg))))
 176     (goto-char (point-min))
 177     (while (looking-at ";*[ \t]*\\(commentary[: \t]*\\)?\n")
 178       (delete-region (match-beginning 0)
 179                      (match-end 0)))
 180     (uncomment-region (point-min) (point-max))
 181     (goto-char (point-max))
 182     (while (progn (forward-line -1)
 183                   (looking-at "[ \t]*\n"))
 184       (delete-region (match-beginning 0)
 185                      (match-end 0)))
 186     (write-region nil nil (concat pkg "-readme.txt")))
 187   ;; Write DIR/foo.el to foo-VERS.el and delete DIR
 188   (rename-file (expand-file-name (concat pkg ".el") dir)
 189                (concat pkg "-" vers ".el"))
 190   ;; Add the content of the ChangeLog.
 191   (let ((cl (expand-file-name "ChangeLog" dir)))
 192     (with-current-buffer (find-file-noselect (concat pkg "-" vers ".el"))
 193       (goto-char (point-max))
 194       (re-search-backward "^;;;.*ends here")
 195       (re-search-backward "^(provide")
 196       (skip-chars-backward " \t\n")
 197       (insert "\n")
 198       (let ((start (point)))
 199         (insert-file-contents cl)
 200         (unless (bolp) (insert "\n"))
 201         (comment-region start (point)))
 202       (save-buffer)
 203       (kill-buffer)))
 204   (delete-directory dir t)
 205   (cons (intern pkg) (vector (version-to-list vers) req desc 'single)))
 206
 207 (defun archive--make-changelog (dir)
 208   "Export Bzr log info of DIR into a ChangeLog file."
 209   (message "Refreshing ChangeLog in %S" dir)
 210   (let ((default-directory (file-name-as-directory (expand-file-name dir))))
 211     (with-temp-buffer
 212       (set-buffer-multibyte nil)
 213       (let ((coding-system-for-read 'binary)
 214             (coding-system-for-write 'binary))
 215         (if (file-readable-p "ChangeLog") (insert-file-contents "ChangeLog"))
 216         (let ((old-md5 (md5 (current-buffer))))
 217           (erase-buffer)
 218           (call-process "bzr" nil (current-buffer) nil
 219                         "log" "--gnu-changelog" ".")
 220           (if (equal old-md5 (md5 (current-buffer)))
 221               (message "ChangeLog's md5 unchanged for %S" dir)
 222             (write-region (point-min) (point-max) "ChangeLog" nil 'quiet)))))))
 223
 224 (defun archive--process-multi-file-package (dir pkg)
 225   "Deploy the contents of DIR into the archive as a multi-file package.
 226 Rename DIR/ to PKG-VERS/, and write the package commentary to
 227 PKG-readme.txt.  Return the descriptor."
 228   (let* ((exp (archive--multi-file-package-def dir pkg))
 229          (vers (nth 2 exp))
 230          (req (mapcar 'archive--convert-require (nth 4 exp)))
 231          (readme (expand-file-name "README" dir)))
 232     (unless (equal (nth 1 exp) pkg)
 233       (error (format "Package name %s doesn't match file name %s"
 234                      (nth 1 exp) pkg)))
 235     ;; Write the readme file.
 236     (when (file-exists-p readme)
 237       (copy-file readme (concat pkg "-readme.txt") 'ok-if-already-exists))
 238     (rename-file dir (concat pkg "-" vers))
 239     (cons (intern pkg) (vector (version-to-list vers) req (nth 3 exp) 'tar))))
 240
 241 (defun archive--multi-file-package-def (dir pkg)
 242   "Reurn the `define-package' form in the file DIR/PKG-pkg.el."
 243   (let ((pkg-file (expand-file-name (concat pkg "-pkg.el") dir)))
 244     (with-temp-buffer
 245       (unless (file-exists-p pkg-file)
 246         (error "File not found: %s" pkg-file))
 247       (insert-file-contents pkg-file)
 248       (goto-char (point-min))
 249       (read (current-buffer)))))
 250
 251 (defun batch-make-site-dir (package-dir site-dir)
 252   (require 'package)
 253   (setq package-dir (expand-file-name package-dir default-directory))
 254   (setq site-dir (expand-file-name site-dir default-directory))
 255   (dolist (dir (directory-files package-dir t archive-re-no-dot))
 256     (condition-case v
 257         (if (not (file-directory-p dir))
 258             (error "Skipping non-package file %s" dir)
 259           (let* ((pkg (file-name-nondirectory dir))
 260                  (autoloads-file (expand-file-name
 261                                   (concat pkg "-autoloads.el") dir))
 262                  simple-p version)
 263             ;; Omit autoloads and .elc files from the package.
 264             (if (file-exists-p autoloads-file)
 265                 (delete-file autoloads-file))
 266             (archive--delete-elc-files dir 'only-orphans)
 267             ;; Test whether this is a simple or multi-file package.
 268             (setq simple-p (archive--simple-package-p dir pkg))
 269             (if simple-p
 270                 (progn
 271                   (apply 'archive--write-pkg-file dir pkg simple-p)
 272                   (setq version (car simple-p)))
 273               (setq version
 274                     (nth 2 (archive--multi-file-package-def dir pkg))))
 275             (make-symbolic-link (expand-file-name dir package-dir)
 276                                 (expand-file-name (concat pkg "-" version)
 277                                                   site-dir)
 278                                 t)
 279             (let ((make-backup-files nil))
 280               (package-generate-autoloads pkg dir))
 281             (let ((load-path (cons dir load-path)))
 282               ;; FIXME: Don't compile the -pkg.el files!
 283               (byte-recompile-directory dir 0))))
 284      ;; Error handler
 285      (error (message "%s" (cadr v))))))
 286
 287 (defun batch-make-site-package (sdir)
 288   (let* ((dest (car (file-attributes sdir)))
 289          (pkg (file-name-nondirectory (directory-file-name (or dest sdir))))
 290          (dir (or dest sdir)))
 291     (let ((make-backup-files nil))
 292       (package-generate-autoloads pkg dir))
 293     (let ((load-path (cons dir load-path)))
 294       ;; FIXME: Don't compile the -pkg.el files!
 295       (byte-recompile-directory dir 0))))
 296
 297 (defun archive--write-pkg-file (pkg-dir name version desc requires &rest ignored)
 298   (let ((pkg-file (expand-file-name (concat name "-pkg.el") pkg-dir))
 299         (print-level nil)
 300         (print-length nil))
 301     (write-region
 302      (concat (format ";; Generated package description from %s.el\n"
 303                      name)
 304              (prin1-to-string
 305               (list 'define-package
 306                     name
 307                     version
 308                     desc
 309                     (list 'quote
 310                           ;; Turn version lists into string form.
 311                           (mapcar
 312                            (lambda (elt)
 313                              (list (car elt)
 314                                    (package-version-join (cadr elt))))
 315                            requires))))
 316              "\n")
 317      nil
 318      pkg-file)))
 319
 320 ;;; Make the HTML pages for online browsing.
 321
 322 (defun archive--html-header (title)
 323   (format "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2 Final//EN\">
 324 <html>
 325 <head>
 326   <title>%s</title>
 327   <meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\">
 328 </head>
 329 <body>
 330 <h1 align=\"center\">%s</h1>"
 331           title title))
 332
 333 (defun archive--html-bytes-format (bytes) ;Aka memory-usage-format.
 334   (setq bytes (/ bytes 1024.0))
 335   (let ((units '(;; "B"
 336                  "kB" "MB" "GB" "TB")))
 337     (while (>= bytes 1024)
 338       (setq bytes (/ bytes 1024.0))
 339       (setq units (cdr units)))
 340     (cond
 341      ;; ((integerp bytes) (format "%4d%s" bytes (car units)))
 342      ((>= bytes 100) (format "%4.0f%s" bytes (car units)))
 343      ((>= bytes 10) (format "%4.1f%s" bytes (car units)))
 344      (t (format "%4.2f%s" bytes (car units))))))
 345
 346 (defun archive--html-make-pkg (pkg files)
 347   (let ((name (symbol-name (car pkg)))
 348         (latest (package-version-join (aref (cdr pkg) 0)))
 349         (desc (aref (cdr pkg) 2)))
 350     ;; FIXME: Add maintainer info.
 351     (with-temp-buffer
 352       (insert (archive--html-header (format "GNU ELPA - %s" name)))
 353       (insert (format "<p>Description: %s</p>\n" desc))
 354       (let* ((file (cdr (assoc latest files)))
 355              (attrs (file-attributes file)))
 356         (insert (format "<p>Latest: <a href=%S>%s</a>, %s, %s</p>\n"
 357                         file file
 358                         (format-time-string "%Y-%b-%d" (nth 5 attrs))
 359                         (archive--html-bytes-format (nth 7 attrs)))))
 360       ;; FIXME: This URL is wrong for Org.
 361       (let ((repurl (concat "http://bzr.sv.gnu.org/lh/emacs/elpa/files/head:/packages/" name)))
 362         (insert (format "<p>Repository: <a href=%S>%s</a></p>" repurl repurl)))
 363       (let ((readme (concat name "-readme.txt"))
 364             (end (copy-marker (point) t)))
 365         (when (file-readable-p readme)
 366           (insert "<p>Full description:<pre>\n")
 367           (insert-file-contents readme)
 368           (goto-char end)
 369           (insert "\n</pre></p>")))
 370       (unless (< (length files) 2)
 371         (insert (format "<p>Old versions:<table cellpadding=\"3\" border=\"1\">\n"))
 372         (dolist (file files)
 373           (unless (equal (pop file) latest)
 374             (let ((attrs (file-attributes file)))
 375               (insert (format "<tr><td><a href=%S>%s</a></td><td>%s</td><td>%s</td>\n"
 376                               file file
 377                               (format-time-string "%Y-%b-%d" (nth 5 attrs))
 378                               (archive--html-bytes-format (nth 7 attrs)))))))
 379         (insert "</table></body>\n"))
 380       (write-region (point-min) (point-max) (concat name ".html")))))
 381
 382 (defun archive--html-make-index (pkgs)
 383   (with-temp-buffer
 384     (insert (archive--html-header "GNU ELPA Packages"))
 385     (insert "<table cellpadding=\"3\" border=\"1\">\n")
 386     (insert "<tr><th>Package</th><th>Version</th><th>Description</th></tr>\n")
 387     (dolist (pkg pkgs)
 388       (insert (format "<tr><td><a href=\"%s.html\">%s</a></td><td>%s</td><td>%s</td></tr>\n"
 389                       (car pkg) (car pkg)
 390                       (package-version-join (aref (cdr pkg) 0))
 391                       (aref (cdr pkg) 2))))
 392     (insert "</table></body>\n")
 393     (write-region (point-min) (point-max) "index.html")))
 394
 395 (defun batch-html-make-index ()
 396   (let ((packages (make-hash-table :test #'equal))
 397         (archive-contents
 398          (with-temp-buffer
 399            (insert-file-contents "archive-contents")
 400            (goto-char (point-min))
 401            ;; Skip the first element which is a version number.
 402            (cdr (read (current-buffer))))))
 403     (dolist (file (directory-files default-directory nil))
 404       (cond
 405        ((member file '("." ".." "elpa.rss" "index.html" "archive-contents")))
 406        ((string-match "\\.html\\'" file))
 407        ((string-match "-readme\\.txt\\'" file)
 408         (let ((name (substring file 0 (match-beginning 0))))
 409           (puthash name (gethash name packages) packages)))
 410        ((string-match "-\\([0-9][^-]*\\)\\.\\(tar\\|el\\)\\'" file)
 411         (let ((name (substring file 0 (match-beginning 0)))
 412               (version (match-string 1 file)))
 413           (push (cons version file) (gethash name packages))))
 414        (t (message "Unknown file %S" file))))
 415     (dolist (pkg archive-contents)
 416       (archive--html-make-pkg pkg (gethash (symbol-name (car pkg)) packages)))
 417     ;; FIXME: Add (old?) packages that are in `packages' but not in
 418     ;; archive-contents.
 419     (archive--html-make-index archive-contents)))
 420
 421
 422 ;; Local Variables:
 423 ;; lexical-binding: t
 424 ;; End:
 425
 426 (provide 'archive-contents)
 427 ;;; archive-contents.el ends here