code.delx.au - gnu-emacs-elpa/blob - packages/ada-mode/ada-gnat-xref.el

   1 ;; Ada mode cross-reference functionality provided by the 'gnat xref'
   2 ;; tool. Includes related functions, such as gnatprep support.
   3 ;;
   4 ;; These tools are all Ada-specific; see gnat-inspect for
   5 ;; multi-language GNAT cross-reference tools.
   6 ;;
   7 ;; GNAT is provided by AdaCore; see http://libre.adacore.com/
   8 ;;
   9 ;;; Copyright (C) 2012 - 2014  Free Software Foundation, Inc.
  10 ;;
  11 ;; Author: Stephen Leake <stephen_leake@member.fsf.org>
  12 ;; Maintainer: Stephen Leake <stephen_leake@member.fsf.org>
  13 ;;
  14 ;; This file is part of GNU Emacs.
  15 ;;
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20 ;;
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25 ;;
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28 ;;
  29 ;;; Usage:
  30 ;;
  31 ;; Emacs should enter Ada mode automatically when you load an Ada
  32 ;; file, based on the file extension.
  33 ;;
  34 ;; By default, ada-mode is configured to load this file, so nothing
  35 ;; special needs to done to use it.
  36
  37 (require 'ada-fix-error)
  38 (require 'compile)
  39 (require 'gnat-core)
  40
  41 ;;;;; code
  42
  43 ;;;; uses of gnat tools
  44
  45 (defconst ada-gnat-file-line-col-regexp "\\(.*\\):\\([0-9]+\\):\\([0-9]+\\)")
  46
  47 (defun ada-gnat-xref-other (identifier file line col)
  48   "For `ada-xref-other-function', using 'gnat find', which is Ada-specific."
  49
  50   (when (eq ?\" (aref identifier 0))
  51     ;; gnat find wants the quotes on operators, but the column is after the first quote.
  52     (setq col (+ 1 col))
  53     )
  54
  55   (let* ((arg (format "%s:%s:%d:%d" identifier file line col))
  56          (switches (concat
  57                     "-a"
  58                     (when (ada-prj-get 'gpr_ext) (concat "--ext=" (ada-prj-get 'gpr_ext)))))
  59          status
  60          (result nil))
  61     (with-current-buffer (gnat-run-buffer)
  62       (gnat-run-gnat "find" (list switches arg))
  63
  64       (goto-char (point-min))
  65       (forward-line 2); skip ADA_PROJECT_PATH, 'gnat find'
  66
  67       ;; gnat find returns two items; the starting point, and the 'other' point
  68       (unless (looking-at (concat ada-gnat-file-line-col-regexp ":"))
  69         ;; no results
  70         (error "'%s' not found in cross-reference files; recompile?" identifier))
  71
  72       (while (not result)
  73         (looking-at (concat ada-gnat-file-line-col-regexp "\\(: warning:\\)?"))
  74         (if (match-string 4)
  75             ;; error in *.gpr; ignore here.
  76             (forward-line 1)
  77           ;; else process line
  78           (let ((found-file (match-string 1))
  79                 (found-line (string-to-number (match-string 2)))
  80                 (found-col  (string-to-number (match-string 3))))
  81             (if (not
  82                  (and
  83                   (equal file found-file)
  84                   (= line found-line)
  85                   (= col found-col)))
  86                 ;; found other item
  87                 (setq result (list found-file found-line (1- found-col)))
  88               (forward-line 1))
  89             ))
  90
  91         (when (eobp)
  92           (pop-to-buffer (current-buffer))
  93           (error "gnat find did not return other item"))
  94         ))
  95     result))
  96
  97 (defun ada-gnat-xref-parents (identifier file line col)
  98   "For `ada-xref-parents-function', using 'gnat find', which is Ada-specific."
  99
 100   (let* ((arg (format "%s:%s:%d:%d" identifier file line col))
 101          (switches (list
 102                     "-a"
 103                     "-d"
 104                     (when (ada-prj-get 'gpr_ext) (concat "--ext=" (ada-prj-get 'gpr_ext)))
 105                     ))
 106          (result nil))
 107     (with-current-buffer (gnat-run-buffer)
 108       (gnat-run-gnat "find" (append switches (list arg)))
 109
 110       (goto-char (point-min))
 111       (forward-line 2); skip GPR_PROJECT_PATH, 'gnat find'
 112
 113       ;; gnat find returns two items; the starting point, and the 'other' point
 114       (unless (looking-at (concat ada-gnat-file-line-col-regexp ":"))
 115         ;; no results
 116         (error "'%s' not found in cross-reference files; recompile?" identifier))
 117
 118       (while (not result)
 119         (looking-at (concat ada-gnat-file-line-col-regexp "\\(: warning:\\)?"))
 120         (if (match-string 4)
 121             ;; error in *.gpr; ignore here.
 122             (forward-line 1)
 123           ;; else process line
 124           (let ((found-file (match-string 1))
 125                 (found-line (string-to-number (match-string 2)))
 126                 (found-col  (string-to-number (match-string 3))))
 127
 128             (skip-syntax-forward "^ ")
 129             (skip-syntax-forward " ")
 130             (if (looking-at (concat "derived from .* (" ada-gnat-file-line-col-regexp ")"))
 131                 ;; found other item
 132                 (setq result (list (match-string 1)
 133                                    (string-to-number (match-string 2))
 134                                    (1- (string-to-number (match-string 3)))))
 135               (forward-line 1)))
 136           )
 137         (when (eobp)
 138           (pop-to-buffer (current-buffer))
 139           (error "gnat find did not return parent types"))
 140         ))
 141
 142     (ada-goto-source (nth 0 result)
 143                      (nth 1 result)
 144                      (nth 2 result)
 145                      nil ;; other-window
 146                      )
 147     ))
 148
 149 (defun ada-gnat-xref-all (identifier file line col)
 150   "For `ada-xref-all-function'."
 151   ;; we use `compilation-start' to run gnat, not `gnat-run', so it
 152   ;; is asynchronous, and automatically runs the compilation error
 153   ;; filter.
 154
 155   (let* ((cmd (format "gnat find -a -r %s:%s:%d:%d" identifier file line col)))
 156
 157     (with-current-buffer (gnat-run-buffer); for default-directory
 158       (let ((compilation-environment (ada-prj-get 'proc_env))
 159             (compilation-error "reference")
 160             ;; gnat find uses standard gnu format for output, so don't
 161             ;; need to set compilation-error-regexp-alist
 162             )
 163         (when (ada-prj-get 'gpr_file)
 164           (setq cmd (concat cmd " -P" (file-name-nondirectory (ada-prj-get 'gpr_file)))))
 165
 166         (compilation-start cmd
 167                            'compilation-mode
 168                            (lambda (mode-name) (concat mode-name "-gnatfind")))
 169     ))))
 170
 171 ;;;;; setup
 172
 173 (defun ada-gnat-xref-select-prj ()
 174   (setq ada-file-name-from-ada-name 'ada-gnat-file-name-from-ada-name)
 175   (setq ada-ada-name-from-file-name 'ada-gnat-ada-name-from-file-name)
 176   (setq ada-make-package-body       'ada-gnat-make-package-body)
 177
 178   (add-hook 'ada-syntax-propertize-hook 'gnatprep-syntax-propertize)
 179
 180   ;; must be after indentation engine setup, because that resets the
 181   ;; indent function list.
 182   (add-hook 'ada-mode-hook 'ada-gnat-xref-setup t)
 183
 184   (setq ada-xref-other-function  'ada-gnat-xref-other)
 185   (setq ada-xref-parent-function 'ada-gnat-xref-parents)
 186   (setq ada-xref-all-function    'ada-gnat-xref-all)
 187
 188   ;; gnatmake -gnatD generates files with .dg extensions. But we don't
 189   ;; need to navigate between them.
 190   ;;
 191   ;; There is no common convention for a file extension for gnatprep files.
 192
 193   (add-to-list 'completion-ignored-extensions ".ali") ;; gnat library files, used for cross reference
 194   (add-to-list 'compilation-error-regexp-alist 'gnat)
 195   )
 196
 197 (defun ada-gnat-xref-deselect-prj ()
 198   (setq ada-file-name-from-ada-name nil)
 199   (setq ada-ada-name-from-file-name nil)
 200   (setq ada-make-package-body       nil)
 201
 202   (setq ada-syntax-propertize-hook (delq 'gnatprep-syntax-propertize ada-syntax-propertize-hook))
 203   (setq ada-mode-hook (delq 'ada-gnat-xref-setup ada-mode-hook))
 204
 205   (setq ada-xref-other-function  nil)
 206   (setq ada-xref-parent-function nil)
 207   (setq ada-xref-all-function    nil)
 208
 209   (setq completion-ignored-extensions (delete ".ali" completion-ignored-extensions))
 210   (setq compilation-error-regexp-alist (delete 'gnat compilation-error-regexp-alist))
 211   )
 212
 213 (defun ada-gnat-xref-setup ()
 214   (when (boundp 'wisi-indent-calculate-functions)
 215     (add-to-list 'wisi-indent-calculate-functions 'gnatprep-indent))
 216   )
 217
 218 (defun ada-gnat-xref ()
 219   "Set Ada mode global vars to use 'gnat xref'"
 220   (add-to-list 'ada-prj-file-ext-extra     "gpr")
 221   (add-to-list 'ada-prj-parser-alist       '("gpr" . gnat-parse-gpr))
 222   (add-to-list 'ada-select-prj-xref-tool   '(gnat  . ada-gnat-xref-select-prj))
 223   (add-to-list 'ada-deselect-prj-xref-tool '(gnat  . ada-gnat-xref-deselect-prj))
 224
 225   ;; no parse-*-xref yet
 226
 227   (font-lock-add-keywords 'ada-mode
 228    ;; gnatprep preprocessor line
 229    (list (list "^[ \t]*\\(#.*\n\\)"  '(1 font-lock-type-face t))))
 230
 231   (add-hook 'ada-gnat-fix-error-hook 'ada-gnat-fix-error))
 232
 233 (ada-gnat-xref)
 234
 235 (provide 'ada-gnat-xref)
 236 (provide 'ada-xref-tool)
 237
 238 (unless (default-value 'ada-xref-tool)
 239   (set-default 'ada-xref-tool 'gnat))
 240
 241 ;; end of file