code.delx.au - gnu-emacs-elpa/blob - packages/ada-mode/gpr-mode.el

   1 ;;; gpr-mode --- major-mode for editing GNAT project files
   2
   3 ;; Copyright (C) 2004, 2007, 2008, 2012-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Stephen Leake <stephen_leake@member.fsf.org>
   6 ;; Maintainer: Stephen Leake <stephen_leake@member.fsf.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; gpr-mode is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; gpr-mode is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;;; History:
  28 ;;
  29 ;; The first gpr-mode was written by Rolf Ebert
  30 ;; <rolf.ebert_nosp...@gmx.net> in 2004.
  31 ;;
  32 ;; Stephen Leake <stephen_leake@member.fsf.org> rewrote it in 2013 to
  33 ;; use the wisi indentation engine.
  34 ;;
  35 ;;;;; Code:
  36
  37 ;; we reuse several ada-mode functions
  38 (require 'ada-mode)
  39
  40 (defvar gpr-mode-map
  41   (let ((map (make-sparse-keymap)))
  42     ;; C-c <letter> are reserved for users
  43
  44     ;; global-map has C-x ` 'next-error
  45     (define-key map [return]   'ada-indent-newline-indent)
  46     (define-key map "\C-c`"    'ada-show-secondary-error)
  47     ;; comment-dwim is in global map on M-;
  48     (define-key map "\C-c\C-c" 'compile)
  49     (define-key map "\C-c\C-e" 'gpr-expand)
  50     (define-key map "\C-c\C-f" 'gpr-show-parse-error)
  51     (define-key map "\C-c\C-i" 'gpr-indent-statement)
  52             ;; FIXME (later): implement?
  53     ;; (define-key map "\C-c\C-n" 'ada-next-statement-keyword)
  54     ;; (define-key map "\C-c\C-p" 'ada-prev-statement-keyword)
  55     (define-key map "\C-c\C-o"   'ff-find-other-file)
  56     (define-key map "\C-c\C-P" 'gpr-set-as-project)
  57     (define-key map "\C-c\C-t" 'ada-case-read-all-exceptions)
  58     (define-key map "\C-c\C-w" 'ada-case-adjust-at-point)
  59     (define-key map "\C-c\C-y" 'ada-case-create-exception)
  60     (define-key map "\C-c\C-\M-y" (lambda () (ada-case-create-exception nil nil t)))
  61     (define-key map "\M-n" 'skeleton-next-placeholder)
  62     (define-key map "\M-p" 'skeleton-prev-placeholder)
  63     map
  64   )  "Local keymap used for GPR mode.")
  65
  66 (defvar gpr-mode-menu (make-sparse-keymap "gpr"))
  67 (easy-menu-define gpr-mode-menu gpr-mode-map "Menu keymap for gpr mode"
  68   '("gpr"
  69     ("Help"
  70      ["gpr Mode"              (info "gpr-mode") t]
  71      ["GNAT Reference Manual" (info "gnat_rm") t]
  72      ["GNAT User Guide"       (info "gnat_ugn") t]
  73      ["Key bindings"          describe-bindings t]
  74      )
  75
  76     ["Customize"     (customize-group 'ada)];; we reuse the Ada indentation options
  77     ["------"        nil nil]
  78     ["Find and select project ..." ada-build-prompt-select-prj-file t]
  79     ["Select project ..."          ada-prj-select                   t]
  80     ["Set as current project"      gpr-set-as-project               t]
  81     ["Show current project"        ada-prj-show                     t]
  82     ["Next compilation error"      next-error                       t]
  83     ["Show secondary error"        ada-show-secondary-error         t]
  84     ["Show last parse error"       gpr-show-parse-error             t]
  85     ["Other file"                  ff-find-other-file               t]
  86     ("Edit"
  87      ["Indent Line or selection"      indent-for-tab-command         t]
  88      ["Indent current statement"      gpr-indent-statement           t]
  89      ["Indent Lines in File"          (indent-region (point-min) (point-max))  t]
  90      ["Expand skeleton"               gpr-expand                     t]
  91      ["Next skeleton placeholder"     skeleton-next-placeholder      t]
  92      ["Previous skeleton placeholder" skeleton-prev-placeholder      t]
  93      ["Comment/uncomment selection"   comment-dwim                   t]
  94      ["Fill Comment Paragraph"        fill-paragraph                 t]
  95
  96      ["Fill Comment Paragraph Justify" ada-fill-comment-paragraph-justify t]
  97      ["Fill Comment Paragraph Postfix" ada-fill-comment-paragraph-postfix t]
  98      )
  99     ))
 100
 101 (defvar gpr-show-parse-error nil
 102   ;; Supplied by indentation engine parser
 103   "Function to show last error reported by indentation parser."
 104   )
 105
 106 (defun gpr-show-parse-error ()
 107   (interactive)
 108   (when gpr-show-parse-error
 109     (funcall gpr-show-parse-error)))
 110
 111 (defvar gpr-expand nil
 112   ;; skeleton function
 113   "Function to call to expand tokens (ie insert skeletons).")
 114
 115 (defun gpr-expand ()
 116   "Expand previous word into a statement skeleton."
 117   (interactive)
 118   (when gpr-expand
 119     (funcall gpr-expand)))
 120
 121 (defvar gpr-indent-statement nil
 122   ;; indentation function
 123   "Function to indent the statement/declaration point is in or after.
 124 Function is called with no arguments.")
 125
 126 (defun gpr-indent-statement ()
 127   "Indent current statement."
 128   (interactive)
 129   (when gpr-indent-statement
 130     (funcall gpr-indent-statement)))
 131
 132 (defvar gpr-font-lock-keywords
 133   (progn
 134     (list
 135      ;;
 136      ;; keyword plus name.
 137      (list (concat
 138             "\\<\\("
 139             "package\\|"
 140             "project\\|"
 141             "for"
 142             "\\)\\>[ \t]*"
 143             "\\(\\sw+\\(\\.\\sw*\\)*\\)?")
 144            '(1 font-lock-keyword-face) '(2 font-lock-function-name-face nil t))
 145      ;;
 146      ;; Main keywords
 147      (list (concat "\\<"
 148                    (regexp-opt
 149                     '("abstract" "aggregate" "case" "configuration" "external" "is" "library" "null" "others"
 150                       "renames" "standard" "type" "use" "when" "with") t)
 151                    "\\>")
 152            '(1 font-lock-keyword-face))
 153      ;;
 154      ;; Anything following end and not already fontified is a body name.
 155      '("\\<\\(end\\)\\>\\([ \t]+\\)?\\(\\(\\sw\\|[_.]\\)+\\)?"
 156        (1 font-lock-keyword-face) (3 font-lock-function-name-face nil t))
 157      ;;
 158      ))
 159   "Expressions to highlight in gpr mode.")
 160
 161 (defun gpr-ff-special-with ()
 162   (ada-require-project-file)
 163   (let ((project-path (match-string 1)))
 164     ;; project-path may be any of "foo", "foo.gpr", "../foo.gpr"
 165     ;;
 166     ;; The result of ff-special-constructs is used by
 167     ;; ff-find-the-other-file with ff-search-directories and nil
 168     ;; suffix list, so it must contain the relative path and the
 169     ;; suffix
 170     (if (file-name-extension project-path)
 171         project-path
 172       (concat project-path ".gpr"))
 173     ))
 174
 175 (defun gpr-set-ff-special-constructs ()
 176   "Add gpr-specific pairs to `ff-special-constructs'."
 177   (set (make-local-variable 'ff-special-constructs) nil)
 178   (mapc (lambda (pair) (add-to-list 'ff-special-constructs pair))
 179         ;; Each car is a regexp; if it matches at point, the cdr is
 180         ;; invoked.  Each cdr should return the absolute file name to
 181         ;; go to.
 182         (list
 183          ;; A "with" clause; allow "foo_bar.gpr" and "../foo"
 184          (cons "^with[ \t]+\"\\(\\(?:\\(?:\\sw\\|\\s.\\)\\|\\s_\\)+\\)\";"
 185                'gpr-ff-special-with)
 186          )))
 187
 188 (defvar gpr-which-function nil
 189   ;; supplied by the indentation engine
 190   "Function called with no parameters; it should return the name
 191 of the package or project point is in or just after, or nil.")
 192
 193 (defun gpr-which-function ()
 194   "See `gpr-which-function' variable."
 195   (when gpr-which-function
 196     (funcall gpr-which-function)))
 197
 198 (defun gpr-add-log-current-function ()
 199   "For `add-log-current-defun-function'. Returns enclosing package or project name."
 200   ;; add-log-current-defun is typically called with point at the start
 201   ;; of an ediff change section, which is before the start of the
 202   ;; declaration of a new item. So go to the end of the current line
 203   ;; first
 204   (save-excursion
 205     (end-of-line 1)
 206     (gpr-which-function)))
 207
 208 (defun gpr-set-as-project (&optional file)
 209   "Set FILE (default current buffer file) as Emacs project file."
 210   (interactive)
 211   (ada-parse-prj-file (or file (buffer-file-name)))
 212   (ada-select-prj-file (or file (buffer-file-name))))
 213
 214 ;;;;
 215 ;;;###autoload
 216 (defun gpr-mode ()
 217   "The major mode for editing GNAT project files."
 218
 219   (interactive)
 220   (kill-all-local-variables)
 221   (setq major-mode 'gpr-mode)
 222   (setq mode-name "GNAT Project")
 223   (use-local-map gpr-mode-map)
 224   (set-syntax-table ada-mode-syntax-table)
 225   (set (make-local-variable 'syntax-begin-function) nil)
 226   (set 'case-fold-search t); gpr is case insensitive; the syntax parsing requires this setting
 227   (set (make-local-variable 'comment-start) "--")
 228   (set (make-local-variable 'comment-end) "")
 229   (set (make-local-variable 'comment-start-skip) "---*[ \t]*")
 230   (set (make-local-variable 'comment-multi-line) nil)
 231
 232   (set (make-local-variable 'require-final-newline) t)
 233
 234   (set (make-local-variable 'font-lock-defaults)
 235        '(gpr-font-lock-keywords
 236          nil t
 237          ((?\_ . "w"))))
 238
 239   (gpr-set-ff-special-constructs)
 240   (setq ff-search-directories 'ada-project-search-path)
 241
 242   (set (make-local-variable 'add-log-current-defun-function)
 243        'gpr-add-log-current-function)
 244
 245   (run-hooks 'gpr-mode-hook)
 246
 247   )
 248
 249 ;;;###autoload
 250 (add-to-list 'auto-mode-alist '("\\.gpr\\'" . gpr-mode))  ; GNAT project files
 251
 252 (provide 'gpr-mode)
 253
 254 (unless (featurep 'gpr-indent-engine)
 255   (require 'gpr-wisi))
 256
 257 (unless (featurep 'gpr-skeletons)
 258   (require 'gpr-skel))
 259
 260 ;;; end of file