code.delx.au - gnu-emacs/blob - test/automated/seq-tests.el

   1 ;;; seq-tests.el --- Tests for sequences.el
   2
   3 ;; Copyright (C) 2014-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Petton <nicolas@petton.fr>
   6 ;; Maintainer: emacs-devel@gnu.org
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Tests for sequences.el
  26
  27 ;;; Code:
  28
  29 (require 'ert)
  30 (require 'seq)
  31
  32 (defmacro with-test-sequences (spec &rest body)
  33   "Successively bind VAR to a list, vector, and string built from SEQ.
  34 Evaluate BODY for each created sequence.
  35
  36 \(fn (var seq) body)"
  37   (declare (indent 1) (debug ((symbolp form) body)))
  38   (let ((initial-seq (make-symbol "initial-seq")))
  39     `(let ((,initial-seq ,(cadr spec)))
  40        ,@(mapcar (lambda (s)
  41                    `(let ((,(car spec) (apply (function ,s) ,initial-seq)))
  42                       ,@body))
  43                  '(list vector string)))))
  44
  45 (defun same-contents-p (seq1 seq2)
  46   "Return t if SEQ1 and SEQ2 have the same contents, nil otherwise."
  47   (equal (append seq1 '()) (append seq2 '())))
  48
  49 (defun test-sequences-evenp (integer)
  50   "Return t if INTEGER is even."
  51   (eq (logand integer 1) 0))
  52
  53 (defun test-sequences-oddp (integer)
  54   "Return t if INTEGER is odd."
  55   (not (test-sequences-evenp integer)))
  56
  57 (ert-deftest test-setf-seq-elt ()
  58   (with-test-sequences (seq '(1 2 3))
  59     (setf (seq-elt seq 1) 4)
  60     (should (= 4 (seq-elt seq 1)))))
  61
  62 (ert-deftest test-seq-drop ()
  63   (with-test-sequences (seq '(1 2 3 4))
  64     (should (equal (seq-drop seq 0) seq))
  65     (should (equal (seq-drop seq 1) (seq-subseq seq 1)))
  66     (should (equal (seq-drop seq 2) (seq-subseq seq 2)))
  67     (should (seq-empty-p (seq-drop seq 4)))
  68     (should (seq-empty-p (seq-drop seq 10))))
  69   (with-test-sequences (seq '())
  70     (should (seq-empty-p (seq-drop seq 0)))
  71     (should (seq-empty-p (seq-drop seq 1)))))
  72
  73 (ert-deftest test-seq-take ()
  74   (with-test-sequences (seq '(2 3 4 5))
  75     (should (seq-empty-p (seq-take seq 0)))
  76     (should (= (seq-length (seq-take seq 1)) 1))
  77     (should (= (seq-elt (seq-take seq 1) 0) 2))
  78     (should (same-contents-p (seq-take seq 3) '(2 3 4)))
  79     (should (equal (seq-take seq 10) seq))))
  80
  81 (ert-deftest test-seq-drop-while ()
  82   (with-test-sequences (seq '(1 3 2 4))
  83     (should (equal (seq-drop-while #'test-sequences-oddp seq)
  84                    (seq-drop seq 2)))
  85     (should (equal (seq-drop-while #'test-sequences-evenp seq)
  86                    seq))
  87     (should (seq-empty-p (seq-drop-while #'numberp seq))))
  88   (with-test-sequences (seq '())
  89     (should (seq-empty-p (seq-drop-while #'test-sequences-oddp seq)))))
  90
  91 (ert-deftest test-seq-take-while ()
  92   (with-test-sequences (seq '(1 3 2 4))
  93     (should (equal (seq-take-while #'test-sequences-oddp seq)
  94                    (seq-take seq 2)))
  95     (should (seq-empty-p (seq-take-while #'test-sequences-evenp seq)))
  96     (should (equal (seq-take-while #'numberp seq) seq)))
  97   (with-test-sequences (seq '())
  98     (should (seq-empty-p (seq-take-while #'test-sequences-oddp seq)))))
  99
 100 (ert-deftest test-seq-filter ()
 101   (with-test-sequences (seq '(6 7 8 9 10))
 102     (should (equal (seq-filter #'test-sequences-evenp seq) '(6 8 10)))
 103     (should (equal (seq-filter #'test-sequences-oddp seq) '(7 9)))
 104     (should (equal (seq-filter (lambda (elt) nil) seq) '())))
 105   (with-test-sequences (seq '())
 106     (should (equal (seq-filter #'test-sequences-evenp seq) '()))))
 107
 108 (ert-deftest test-seq-remove ()
 109   (with-test-sequences (seq '(6 7 8 9 10))
 110     (should (equal (seq-remove #'test-sequences-evenp seq) '(7 9)))
 111     (should (equal (seq-remove #'test-sequences-oddp seq) '(6 8 10)))
 112     (should (same-contents-p (seq-remove (lambda (elt) nil) seq) seq)))
 113   (with-test-sequences (seq '())
 114     (should (equal (seq-remove #'test-sequences-evenp seq) '()))))
 115
 116 (ert-deftest test-seq-count ()
 117   (with-test-sequences (seq '(6 7 8 9 10))
 118     (should (equal (seq-count #'test-sequences-evenp seq) 3))
 119     (should (equal (seq-count #'test-sequences-oddp seq) 2))
 120     (should (equal (seq-count (lambda (elt) nil) seq) 0)))
 121   (with-test-sequences (seq '())
 122     (should (equal (seq-count #'test-sequences-evenp seq) 0))))
 123
 124 (ert-deftest test-seq-reduce ()
 125   (with-test-sequences (seq '(1 2 3 4))
 126     (should (= (seq-reduce #'+ seq 0) 10))
 127     (should (= (seq-reduce #'+ seq 5) 15)))
 128   (with-test-sequences (seq '())
 129     (should (eq (seq-reduce #'+ seq 0) 0))
 130     (should (eq (seq-reduce #'+ seq 7) 7))))
 131
 132 (ert-deftest test-seq-some ()
 133   (with-test-sequences (seq '(4 3 2 1))
 134     (should (seq-some #'test-sequences-evenp seq))
 135     (should (seq-some #'test-sequences-oddp seq))
 136     (should-not (seq-some (lambda (elt) (> elt 10)) seq)))
 137   (with-test-sequences (seq '())
 138     (should-not (seq-some #'test-sequences-oddp seq)))
 139   (should (seq-some #'null '(1 nil 2))))
 140
 141 (ert-deftest test-seq-contains ()
 142   (with-test-sequences (seq '(3 4 5 6))
 143     (should (seq-contains seq 3))
 144     (should-not (seq-contains seq 7)))
 145   (with-test-sequences (seq '())
 146     (should-not (seq-contains seq 3))
 147     (should-not (seq-contains seq nil))))
 148
 149 (ert-deftest test-seq-every-p ()
 150   (with-test-sequences (seq '(43 54 22 1))
 151     (should (seq-every-p (lambda (elt) t) seq))
 152     (should-not (seq-every-p #'test-sequences-oddp seq))
 153     (should-not (seq-every-p #'test-sequences-evenp seq)))
 154   (with-test-sequences (seq '(42 54 22 2))
 155     (should (seq-every-p #'test-sequences-evenp seq))
 156     (should-not (seq-every-p #'test-sequences-oddp seq)))
 157   (with-test-sequences (seq '())
 158     (should (seq-every-p #'identity seq))
 159     (should (seq-every-p #'test-sequences-evenp seq))))
 160
 161 (ert-deftest test-seq-empty-p ()
 162   (with-test-sequences (seq '(0))
 163     (should-not (seq-empty-p seq)))
 164   (with-test-sequences (seq '(0 1 2))
 165     (should-not (seq-empty-p seq)))
 166   (with-test-sequences (seq '())
 167     (should (seq-empty-p seq))))
 168
 169 (ert-deftest test-seq-sort ()
 170   (should (equal (seq-sort #'< "cbaf") "abcf"))
 171   (should (equal (seq-sort #'< '(2 1 9 4)) '(1 2 4 9)))
 172   (should (equal (seq-sort #'< [2 1 9 4]) [1 2 4 9]))
 173   (should (equal (seq-sort #'< "") "")))
 174
 175 (ert-deftest test-seq-uniq ()
 176   (with-test-sequences (seq '(2 4 6 8 6 4 3))
 177     (should (equal (seq-uniq seq) '(2 4 6 8 3))))
 178   (with-test-sequences (seq '(3 3 3 3 3))
 179     (should (equal (seq-uniq seq) '(3))))
 180   (with-test-sequences (seq '())
 181     (should (equal (seq-uniq seq) '()))))
 182
 183 (ert-deftest test-seq-subseq ()
 184   (with-test-sequences (seq '(2 3 4 5))
 185     (should (equal (seq-subseq seq 0 4) seq))
 186     (should (same-contents-p (seq-subseq seq 2 4) '(4 5)))
 187     (should (same-contents-p (seq-subseq seq 1 3) '(3 4)))
 188     (should (same-contents-p (seq-subseq seq 1 -1) '(3 4))))
 189   (should (vectorp (seq-subseq [2 3 4 5] 2)))
 190   (should (stringp (seq-subseq "foo" 2 3)))
 191   (should (listp (seq-subseq '(2 3 4 4) 2 3)))
 192   (should-error (seq-subseq '(1 2 3) 4))
 193   (should-not   (seq-subseq '(1 2 3) 3))
 194   (should       (seq-subseq '(1 2 3) -3))
 195   (should-error (seq-subseq '(1 2 3) 1 4))
 196   (should       (seq-subseq '(1 2 3) 1 3))
 197   (should-error (seq-subseq '() -1))
 198   (should-error (seq-subseq [] -1))
 199   (should-error (seq-subseq "" -1))
 200   (should-not (seq-subseq '() 0))
 201   (should-error (seq-subseq '() 0 -1)))
 202
 203 (ert-deftest test-seq-concatenate ()
 204   (with-test-sequences (seq '(2 4 6))
 205     (should (equal (seq-concatenate 'string seq [8]) (string 2 4 6 8)))
 206     (should (equal (seq-concatenate 'list seq '(8 10)) '(2 4 6 8 10)))
 207     (should (equal (seq-concatenate 'vector seq '(8 10)) [2 4 6 8 10]))
 208     (should (equal (seq-concatenate 'vector nil '(8 10)) [8 10]))
 209     (should (equal (seq-concatenate 'vector seq nil) [2 4 6]))))
 210
 211 (ert-deftest test-seq-mapcat ()
 212   (should (equal (seq-mapcat #'seq-reverse '((3 2 1) (6 5 4)))
 213                  '(1 2 3 4 5 6)))
 214   (should (equal (seq-mapcat #'seq-reverse '[(3 2 1) (6 5 4)])
 215                  '(1 2 3 4 5 6)))
 216   (should (equal (seq-mapcat #'seq-reverse '((3 2 1) (6 5 4)) 'vector)
 217                  '[1 2 3 4 5 6])))
 218
 219 (ert-deftest test-seq-partition ()
 220   (should (same-contents-p (seq-partition '(0 1 2 3 4 5 6 7) 3)
 221                            '((0 1 2) (3 4 5) (6 7))))
 222   (should (same-contents-p (seq-partition '[0 1 2 3 4 5 6 7] 3)
 223                            '([0 1 2] [3 4 5] [6 7])))
 224   (should (same-contents-p (seq-partition "Hello world" 2)
 225                            '("He" "ll" "o " "wo" "rl" "d")))
 226   (should (equal (seq-partition '() 2) '()))
 227   (should (equal (seq-partition '(1 2 3) -1) '())))
 228
 229 (ert-deftest test-seq-group-by ()
 230   (with-test-sequences (seq '(1 2 3 4))
 231    (should (equal (seq-group-by #'test-sequences-oddp seq)
 232                   '((t 1 3) (nil 2 4)))))
 233   (should (equal (seq-group-by #'car '((a 1) (b 3) (c 4) (a 2)))
 234                  '((b (b 3)) (c (c 4)) (a (a 1) (a 2))))))
 235
 236 (ert-deftest test-seq-reverse ()
 237   (with-test-sequences (seq '(1 2 3 4))
 238     (should (same-contents-p (seq-reverse seq) '(4 3 2 1)))
 239     (should (equal (type-of (seq-reverse seq))
 240                    (type-of seq)))))
 241
 242 (ert-deftest test-seq-into ()
 243   (let* ((vector [1 2 3])
 244          (list (seq-into vector 'list)))
 245     (should (same-contents-p vector list))
 246     (should (listp list)))
 247   (let* ((list '(hello world))
 248          (vector (seq-into list 'vector)))
 249     (should (same-contents-p vector list))
 250     (should (vectorp vector)))
 251   (let* ((string "hello")
 252          (list (seq-into string 'list)))
 253     (should (same-contents-p string list))
 254     (should (stringp string)))
 255   (let* ((string "hello")
 256          (vector (seq-into string 'vector)))
 257     (should (same-contents-p string vector))
 258     (should (stringp string)))
 259   (let* ((list nil)
 260          (vector (seq-into list 'vector)))
 261     (should (same-contents-p list vector))
 262     (should (vectorp vector))))
 263
 264 (ert-deftest test-seq-intersection ()
 265   (let ((v1 [2 3 4 5])
 266         (v2 [1 3 5 6 7]))
 267     (should (same-contents-p (seq-intersection v1 v2)
 268                              '(3 5))))
 269   (let ((l1 '(2 3 4 5))
 270         (l2 '(1 3 5 6 7)))
 271     (should (same-contents-p (seq-intersection l1 l2)
 272                              '(3 5))))
 273   (let ((v1 [2 4 6])
 274         (v2 [1 3 5]))
 275     (should (seq-empty-p (seq-intersection v1 v2)))))
 276
 277 (ert-deftest test-seq-difference ()
 278   (let ((v1 [2 3 4 5])
 279         (v2 [1 3 5 6 7]))
 280     (should (same-contents-p (seq-difference v1 v2)
 281                              '(2 4))))
 282   (let ((l1 '(2 3 4 5))
 283         (l2 '(1 3 5 6 7)))
 284     (should (same-contents-p (seq-difference l1 l2)
 285                              '(2 4))))
 286   (let ((v1 [2 4 6])
 287         (v2 [2 4 6]))
 288     (should (seq-empty-p (seq-difference v1 v2)))))
 289
 290 (ert-deftest test-seq-let ()
 291   (with-test-sequences (seq '(1 2 3 4))
 292     (seq-let (a b c d e) seq
 293       (should (= a 1))
 294       (should (= b 2))
 295       (should (= c 3))
 296       (should (= d 4))
 297       (should (null e)))
 298     (seq-let (a b &rest others) seq
 299       (should (= a 1))
 300       (should (= b 2))
 301       (should (same-contents-p others (seq-drop seq 2)))))
 302   (let ((seq '(1 (2 (3 (4))))))
 303     (seq-let (_ (_ (_ (a)))) seq
 304       (should (= a 4))))
 305   (let (seq)
 306     (seq-let (a b c) seq
 307       (should (null a))
 308       (should (null b))
 309       (should (null c)))))
 310
 311 (ert-deftest test-seq-min-max ()
 312   (with-test-sequences (seq '(4 5 3 2 0 4))
 313     (should (= (seq-min seq) 0))
 314     (should (= (seq-max seq) 5))))
 315
 316 (ert-deftest test-seq-into-sequence ()
 317   (with-test-sequences (seq '(1 2 3))
 318     (should (eq seq (seq-into-sequence seq)))
 319     (should-error (seq-into-sequence 2))))
 320
 321 (provide 'seq-tests)
 322 ;;; seq-tests.el ends here