code.delx.au - gnu-emacs/blob - lisp/gnus/mm-bodies.el

   1 ;;; mm-bodies.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (or (fboundp  'base64-decode-region)
  31       (require 'base64)))
  32
  33 (eval-when-compile
  34   (defvar mm-uu-decode-function)
  35   (defvar mm-uu-binhex-decode-function))
  36
  37 (require 'mm-util)
  38 (require 'rfc2047)
  39 (require 'mm-encode)
  40
  41 ;; 8bit treatment gets any char except: 0x32 - 0x7f, CR, LF, TAB, BEL,
  42 ;; BS, vertical TAB, form feed, and ^_
  43 (defvar mm-7bit-chars "\x20-\x7f\r\n\t\x7\x8\xb\xc\x1f")
  44
  45 (defcustom mm-body-charset-encoding-alist
  46   '((iso-2022-jp . 7bit)
  47     (iso-2022-jp-2 . 7bit)
  48     ;; We MUST encode UTF-16 because it can contain \0's which is
  49     ;; known to break servers.
  50     ;; Note: UTF-16 variants are invalid for text parts [RFC 2781],
  51     ;; so this can't happen :-/.
  52     (utf-16 . base64)
  53     (utf-16be . base64)
  54     (utf-16le . base64))
  55   "Alist of MIME charsets to encodings.
  56 Valid encodings are `7bit', `8bit', `quoted-printable' and `base64'."
  57   :type '(repeat (cons (symbol :tag "charset")
  58                        (choice :tag "encoding"
  59                                (const 7bit)
  60                                (const 8bit)
  61                                (const quoted-printable)
  62                                (const base64))))
  63   :group 'mime)
  64
  65 (defun mm-encode-body (&optional charset)
  66   "Encode a body.
  67 Should be called narrowed to the body that is to be encoded.
  68 If there is more than one non-ASCII MULE charset in the body, then the
  69 list of MULE charsets found is returned.
  70 If CHARSET is non-nil, it is used as the MIME charset to encode the body.
  71 If successful, the MIME charset is returned.
  72 If no encoding was done, nil is returned."
  73   (if (not (mm-multibyte-p))
  74       ;; In the non-Mule case, we search for non-ASCII chars and
  75       ;; return the value of `mail-parse-charset' if any are found.
  76       (or charset
  77           (save-excursion
  78             (goto-char (point-min))
  79             (if (re-search-forward "[^\x0-\x7f]" nil t)
  80                 (or mail-parse-charset
  81                     (message-options-get 'mm-encody-body-charset)
  82                     (message-options-set
  83                      'mm-encody-body-charset
  84                      (mm-read-coding-system "Charset used in the article: ")))
  85               ;; The logic in `mml-generate-mime-1' confirms that it's OK
  86               ;; to return nil here.
  87               nil)))
  88     (save-excursion
  89       (if charset
  90           (progn
  91             (mm-encode-coding-region (point-min) (point-max) charset)
  92             charset)
  93         (goto-char (point-min))
  94         (let ((charsets (mm-find-mime-charset-region (point-min) (point-max)
  95                                                      mm-hack-charsets)))
  96           (cond
  97            ;; No encoding.
  98            ((null charsets)
  99             nil)
 100            ;; Too many charsets.
 101            ((> (length charsets) 1)
 102             charsets)
 103            ;; We encode.
 104            (t
 105             (prog1
 106                 (setq charset (car charsets))
 107               (mm-encode-coding-region (point-min) (point-max)
 108                                        (mm-charset-to-coding-system charset))))
 109            ))))))
 110
 111 (defun mm-long-lines-p (length)
 112   "Say whether any of the lines in the buffer is longer than LENGTH."
 113   (save-excursion
 114     (goto-char (point-min))
 115     (end-of-line)
 116     (while (and (not (eobp))
 117                 (not (> (current-column) length)))
 118       (forward-line 1)
 119       (end-of-line))
 120     (and (> (current-column) length)
 121          (current-column))))
 122
 123 (defvar message-posting-charset)
 124
 125 (defun mm-body-encoding (charset &optional encoding)
 126   "Do Content-Transfer-Encoding and return the encoding of the current buffer."
 127   (when (stringp encoding)
 128     (setq encoding (intern (downcase encoding))))
 129   (let ((bits (mm-body-7-or-8))
 130         (longp (mm-long-lines-p 1000)))
 131     (require 'message)
 132     (cond
 133      ((and (not longp)
 134            (not (and mm-use-ultra-safe-encoding
 135                      (save-excursion (re-search-forward "^From " nil t))))
 136            (eq bits '7bit))
 137       bits)
 138      ((and (not mm-use-ultra-safe-encoding)
 139            (not longp)
 140            (not (cdr (assq charset mm-body-charset-encoding-alist)))
 141            (or (eq t (cdr message-posting-charset))
 142                (memq charset (cdr message-posting-charset))
 143                (eq charset mail-parse-charset)))
 144       bits)
 145      (t
 146       (let ((encoding (or encoding
 147                           (cdr (assq charset mm-body-charset-encoding-alist))
 148                           (mm-qp-or-base64))))
 149         (when mm-use-ultra-safe-encoding
 150           (setq encoding (mm-safer-encoding encoding)))
 151         (mm-encode-content-transfer-encoding encoding "text/plain")
 152         encoding)))))
 153
 154 (defun mm-body-7-or-8 ()
 155   "Say whether the body is 7bit or 8bit."
 156   (if (save-excursion
 157         (goto-char (point-min))
 158         (skip-chars-forward mm-7bit-chars)
 159         (eobp))
 160       '7bit
 161     '8bit))
 162
 163 ;;;
 164 ;;; Functions for decoding
 165 ;;;
 166
 167 (eval-when-compile (defvar mm-uu-yenc-decode-function))
 168
 169 (defun mm-decode-content-transfer-encoding (encoding &optional type)
 170   "Decodes buffer encoded with ENCODING, returning success status.
 171 If TYPE is `text/plain' CRLF->LF translation may occur."
 172   (prog1
 173       (condition-case error
 174           (cond
 175            ((eq encoding 'quoted-printable)
 176             (quoted-printable-decode-region (point-min) (point-max))
 177             t)
 178            ((eq encoding 'base64)
 179             (base64-decode-region
 180              (point-min)
 181              ;; Some mailers insert whitespace
 182              ;; junk at the end which
 183              ;; base64-decode-region dislikes.
 184              ;; Also remove possible junk which could
 185              ;; have been added by mailing list software.
 186              (save-excursion
 187                (goto-char (point-min))
 188                (while (re-search-forward "^[\t ]*\r?\n" nil t)
 189                  (delete-region (match-beginning 0) (match-end 0)))
 190                (goto-char (point-max))
 191                (when (re-search-backward "^[A-Za-z0-9+/]+=*[\t ]*$" nil t)
 192                  (forward-line))
 193                (point))))
 194            ((memq encoding '(7bit 8bit binary))
 195             ;; Do nothing.
 196             t)
 197            ((null encoding)
 198             ;; Do nothing.
 199             t)
 200            ((memq encoding '(x-uuencode x-uue))
 201             (require 'mm-uu)
 202             (funcall mm-uu-decode-function (point-min) (point-max))
 203             t)
 204            ((eq encoding 'x-binhex)
 205             (require 'mm-uu)
 206             (funcall mm-uu-binhex-decode-function (point-min) (point-max))
 207             t)
 208            ((eq encoding 'x-yenc)
 209             (require 'mm-uu)
 210             (funcall mm-uu-yenc-decode-function (point-min) (point-max))
 211             )
 212            ((functionp encoding)
 213             (funcall encoding (point-min) (point-max))
 214             t)
 215            (t
 216             (message "Unknown encoding %s; defaulting to 8bit" encoding)))
 217         (error
 218          (message "Error while decoding: %s" error)
 219          nil))
 220     (when (and
 221            (memq encoding '(base64 x-uuencode x-uue x-binhex x-yenc))
 222            (equal type "text/plain"))
 223       (goto-char (point-min))
 224       (while (search-forward "\r\n" nil t)
 225         (replace-match "\n" t t)))))
 226
 227 (defun mm-decode-body (charset &optional encoding type)
 228   "Decode the current article that has been encoded with ENCODING to CHARSET.
 229 ENCODING is a MIME content transfer encoding.
 230 CHARSET is the MIME charset with which to decode the data after transfer
 231 decoding.  If it is nil, default to `mail-parse-charset'."
 232   (when (stringp charset)
 233     (setq charset (intern (downcase charset))))
 234   (when (or (not charset)
 235             (eq 'gnus-all mail-parse-ignored-charsets)
 236             (memq 'gnus-all mail-parse-ignored-charsets)
 237             (memq charset mail-parse-ignored-charsets))
 238     (setq charset mail-parse-charset))
 239   (save-excursion
 240     (when encoding
 241       (mm-decode-content-transfer-encoding encoding type))
 242     (when (featurep 'mule)  ; Fixme: Wrong test for unibyte session.
 243       (let ((coding-system (mm-charset-to-coding-system charset)))
 244         (if (and (not coding-system)
 245                  (listp mail-parse-ignored-charsets)
 246                  (memq 'gnus-unknown mail-parse-ignored-charsets))
 247             (setq coding-system
 248                   (mm-charset-to-coding-system mail-parse-charset)))
 249         (when (and charset coding-system
 250                    ;; buffer-file-coding-system
 251                    ;;Article buffer is nil coding system
 252                    ;;in XEmacs
 253                    (mm-multibyte-p)
 254                    (or (not (eq coding-system 'ascii))
 255                        (setq coding-system mail-parse-charset))
 256                    (not (eq coding-system 'gnus-decoded)))
 257           (mm-decode-coding-region (point-min) (point-max)
 258                                    coding-system))
 259         (setq buffer-file-coding-system
 260               (if (boundp 'last-coding-system-used)
 261                   (symbol-value 'last-coding-system-used)
 262                 coding-system))))))
 263
 264 (defun mm-decode-string (string charset)
 265   "Decode STRING with CHARSET."
 266   (when (stringp charset)
 267     (setq charset (intern (downcase charset))))
 268   (when (or (not charset)
 269             (eq 'gnus-all mail-parse-ignored-charsets)
 270             (memq 'gnus-all mail-parse-ignored-charsets)
 271             (memq charset mail-parse-ignored-charsets))
 272     (setq charset mail-parse-charset))
 273   (or
 274    (when (featurep 'mule)
 275      (let ((coding-system (mm-charset-to-coding-system charset)))
 276        (if (and (not coding-system)
 277                 (listp mail-parse-ignored-charsets)
 278                 (memq 'gnus-unknown mail-parse-ignored-charsets))
 279            (setq coding-system
 280                  (mm-charset-to-coding-system mail-parse-charset)))
 281        (when (and charset coding-system
 282                   (mm-multibyte-p)
 283                   (or (not (eq coding-system 'ascii))
 284                       (setq coding-system mail-parse-charset)))
 285          (mm-decode-coding-string string coding-system))))
 286    string))
 287
 288 (provide 'mm-bodies)
 289
 290 ;;; arch-tag: 41104bb6-4443-4ca9-8d5c-ff87ecf27d8d
 291 ;;; mm-bodies.el ends here