code.delx.au - gnu-emacs/blob - lisp/image-mode.el

   1 ;;; image-mode.el --- support for visiting image files
   2 ;;
   3 ;; Copyright (C) 2005 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Richard Stallman <rms@gnu.org>
   6 ;; Keywords: multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines a major mode for visiting image files
  28 ;; that allows conversion between viewing the text of the file
  29 ;; and viewing the file as an image.  Viewing the image
  30 ;; works by putting a `display' text-property on the
  31 ;; image data, with the image-data still present underneath; if the
  32 ;; resulting buffer file is saved to another name it will correctly save
  33 ;; the image data to the new file.
  34
  35 ;;; Code:
  36
  37 (require 'image)
  38
  39 ;;;###autoload (push '("\\.jpe?g\\'"    . image-mode) auto-mode-alist)
  40 ;;;###autoload (push '("\\.png\\'"      . image-mode) auto-mode-alist)
  41 ;;;###autoload (push '("\\.gif\\'"      . image-mode) auto-mode-alist)
  42 ;;;###autoload (push '("\\.tiff?\\'"    . image-mode) auto-mode-alist)
  43 ;;;###autoload (push '("\\.p[bpgn]m\\'" . image-mode) auto-mode-alist)
  44 ;;;###autoload (push '("\\.x[bp]m\\'"   . image-mode-maybe) auto-mode-alist)
  45
  46 (defvar image-mode-map
  47   (let ((map (make-sparse-keymap)))
  48     (define-key map "\C-c\C-c" 'image-toggle-display)
  49     map)
  50   "Major mode keymap for Image mode.")
  51
  52 ;;;###autoload
  53 (defun image-mode ()
  54   "Major mode for image files.
  55 You can use \\<image-mode-map>\\[image-toggle-display]
  56 to toggle between display as an image and display as text."
  57   (interactive)
  58   (kill-all-local-variables)
  59   (setq mode-name "Image")
  60   (setq major-mode 'image-mode)
  61   (use-local-map image-mode-map)
  62   (add-hook 'change-major-mode-hook 'image-toggle-display-text nil t)
  63   (if (not (get-text-property (point-min) 'display))
  64       (image-toggle-display)
  65     ;; Set next vars when image is already displayed but local
  66     ;; variables were cleared by kill-all-local-variables
  67     (setq cursor-type nil truncate-lines t))
  68   (run-mode-hooks 'image-mode-hook)
  69   (message (concat (substitute-command-keys
  70                     "Type \\[image-toggle-display] to view the image as ")
  71                    (if (get-text-property (point-min) 'display)
  72                        "text" "an image") ".")))
  73
  74 ;;;###autoload
  75 (define-minor-mode image-minor-mode
  76   "Toggle Image minor mode.
  77 With arg, turn Image minor mode on if arg is positive, off otherwise.
  78 See the command `image-mode' for more information on this mode."
  79   nil " Image" image-mode-map
  80   :group 'image
  81   :version "22.1"
  82   (unless (or (eq major-mode 'image-mode) image-minor-mode)
  83     (use-local-map image-mode-map)))
  84
  85 ;;;###autoload
  86 (defun image-mode-maybe ()
  87   "Set major or minor mode for image files.
  88 Set Image major mode only when there are no other major modes
  89 associated with a filename in `auto-mode-alist'.  When an image
  90 filename matches another major mode in `auto-mode-alist' then
  91 set that major mode and Image minor mode.
  92
  93 See commands `image-mode' and `image-minor-mode' for more
  94 information on these modes."
  95   (interactive)
  96   (let* ((mode-alist
  97           (delq nil (mapcar
  98                      (lambda (elt)
  99                        (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 100                                      '(image-mode image-mode-maybe))
 101                          elt))
 102                      auto-mode-alist))))
 103     (if (assoc-default buffer-file-name mode-alist 'string-match)
 104         (let ((auto-mode-alist mode-alist))
 105           (set-auto-mode)
 106           (image-minor-mode t))
 107       (image-mode))))
 108
 109 (defun image-toggle-display-text ()
 110   "Showing the text of the image file."
 111   (if (get-text-property (point-min) 'display)
 112       (image-toggle-display)))
 113
 114 (defun image-toggle-display ()
 115   "Start or stop displaying an image file as the actual image.
 116 This command toggles between showing the text of the image file
 117 and showing the image as an image."
 118   (interactive)
 119   (if (get-text-property (point-min) 'display)
 120       (let ((inhibit-read-only t)
 121             (buffer-undo-list t)
 122             (modified (buffer-modified-p)))
 123         (remove-list-of-text-properties (point-min) (point-max)
 124                                         '(display intangible read-nonsticky
 125                                                   read-only front-sticky))
 126         (set-buffer-modified-p modified)
 127         (kill-local-variable 'cursor-type)
 128         (kill-local-variable 'truncate-lines)
 129         (if (called-interactively-p)
 130             (message "Repeat this command to go back to displaying the image")))
 131     ;; Turn the image data into a real image, but only if the whole file
 132     ;; was inserted
 133     (let* ((data
 134             (string-make-unibyte
 135              (buffer-substring-no-properties (point-min) (point-max))))
 136            (image
 137             (create-image data nil t))
 138            (props
 139             `(display ,image
 140                       intangible ,image
 141                       rear-nonsticky (display intangible)
 142                       ;; This a cheap attempt to make the whole buffer
 143                       ;; read-only when we're visiting the file (as
 144                       ;; opposed to just inserting it).
 145                       read-only t front-sticky (read-only)))
 146            (inhibit-read-only t)
 147            (buffer-undo-list t)
 148            (modified (buffer-modified-p)))
 149       (add-text-properties (point-min) (point-max) props)
 150       (set-buffer-modified-p modified)
 151       ;; Inhibit the cursor when the buffer contains only an image,
 152       ;; because cursors look very strange on top of images.
 153       (setq cursor-type nil)
 154       ;; This just makes the arrow displayed in the right fringe
 155       ;; area look correct when the image is wider than the window.
 156       (setq truncate-lines t)
 157       (if (called-interactively-p)
 158           (message "Repeat this command to go back to displaying the file as text")))))
 159
 160 (provide 'image-mode)
 161
 162 ;; arch-tag: b5b2b7e6-26a7-4b79-96e3-1546b5c4c6cb
 163 ;;; image-mode.el ends here