code.delx.au - gnu-emacs/blob - lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994, 1998, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defgroup hexl nil
  57   "Edit a file in a hex dump format using the hexl filter."
  58   :group 'data)
  59
  60
  61 (defcustom hexl-program "hexl"
  62   "The program that will hexlify and dehexlify its stdin.
  63 `hexl-program' will always be concatenated with `hexl-options'
  64 and \"-de\" when dehexlifying a buffer."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-iso ""
  69   "If your emacs can handle ISO characters, this should be set to
  70 \"-iso\" otherwise it should be \"\"."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-options (format "-hex %s" hexl-iso)
  75   "Options to hexl-program that suit your needs."
  76   :type 'string
  77   :group 'hexl)
  78
  79 (defcustom hexlify-command
  80   (format "%s %s"
  81           (shell-quote-argument
  82            (expand-file-name hexl-program exec-directory))
  83           hexl-options)
  84   "The command to use to hexlify a buffer."
  85   :type 'string
  86   :group 'hexl)
  87
  88 (defcustom dehexlify-command
  89   (format "%s -de %s"
  90           (shell-quote-argument
  91            (expand-file-name hexl-program exec-directory))
  92           hexl-options)
  93   "The command to use to unhexlify a buffer."
  94   :type 'string
  95   :group 'hexl)
  96
  97 (defcustom hexl-follow-ascii t
  98   "If non-nil then highlight the ASCII character corresponding to point."
  99   :type 'boolean
 100   :group 'hexl
 101   :version "20.3")
 102
 103 (defvar hexl-max-address 0
 104   "Maximum offset into hexl buffer.")
 105
 106 (defvar hexl-mode-map nil)
 107
 108 (defvar hexl-mode-old-local-map)
 109 (defvar hexl-mode-old-mode-name)
 110 (defvar hexl-mode-old-major-mode)
 111 (defvar hexl-mode-old-write-contents-hooks)
 112 (defvar hexl-mode-old-require-final-newline)
 113 (defvar hexl-mode-old-syntax-table)
 114
 115 (defvar hexl-ascii-overlay nil
 116   "Overlay used to highlight ASCII element corresponding to current point.")
 117 (make-variable-buffer-local 'hexl-ascii-overlay)
 118
 119 ;; routines
 120
 121 (put 'hexl-mode 'mode-class 'special)
 122
 123 ;;;###autoload
 124 (defun hexl-mode (&optional arg)
 125   "\\<hexl-mode-map>A mode for editing binary files in hex dump format.
 126 This is not an ordinary major mode; it alters some aspects
 127 if the current mode's behavior, but not all; also, you can exit
 128 Hexl mode and return to the previous mode using `hexl-mode-exit'.
 129
 130 This function automatically converts a buffer into the hexl format
 131 using the function `hexlify-buffer'.
 132
 133 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 134 representing the offset into the file that the characters on this line
 135 are at and 16 characters from the file (displayed as hexadecimal
 136 values grouped every 16 bits) and as their ASCII values.
 137
 138 If any of the characters (displayed as ASCII characters) are
 139 unprintable (control or meta characters) they will be replaced as
 140 periods.
 141
 142 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 143 in hexl format.
 144
 145 A sample format:
 146
 147   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 148   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 149   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 150   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 151   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 152   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 153   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 154   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 155   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 156   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 157   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 158   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 159   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 160   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 161   000000c0: 7265 6769 6f6e 2e0a                      region..
 162
 163 Movement is as simple as movement in a normal emacs text buffer.  Most
 164 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 165 to move the cursor left, right, down, and up).
 166
 167 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 168 also supported.
 169
 170 There are several ways to change text in hexl mode:
 171
 172 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 173 bound to self-insert so you can simply type the character and it will
 174 insert itself (actually overstrike) into the buffer.
 175
 176 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 177 it isn't bound to self-insert.  An octal number can be supplied in place
 178 of another key to insert the octal number's ASCII representation.
 179
 180 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 181 into the buffer at the current point.
 182
 183 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 184 into the buffer at the current point.
 185
 186 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 187 into the buffer at the current point.
 188
 189 \\[hexl-mode-exit] will exit hexl-mode.
 190
 191 Note: saving the file with any of the usual Emacs commands
 192 will actually convert it back to binary format while saving.
 193
 194 You can use \\[hexl-find-file] to visit a file in Hexl mode.
 195
 196 \\[describe-bindings] for advanced commands."
 197   (interactive "p")
 198   (unless (eq major-mode 'hexl-mode)
 199     (let ((modified (buffer-modified-p))
 200           (inhibit-read-only t)
 201           (original-point (1- (point)))
 202           max-address)
 203       (and (eobp) (not (bobp))
 204            (setq original-point (1- original-point)))
 205       (if (not (or (eq arg 1) (not arg)))
 206           ;; if no argument then we guess at hexl-max-address
 207           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 208         (setq max-address (1- (buffer-size)))
 209         (hexlify-buffer)
 210         (set-buffer-modified-p modified))
 211       (make-local-variable 'hexl-max-address)
 212       (setq hexl-max-address max-address)
 213       (hexl-goto-address original-point))
 214
 215     ;; We do not turn off the old major mode; instead we just
 216     ;; override most of it.  That way, we can restore it perfectly.
 217     (make-local-variable 'hexl-mode-old-local-map)
 218     (setq hexl-mode-old-local-map (current-local-map))
 219     (use-local-map hexl-mode-map)
 220
 221     (make-local-variable 'hexl-mode-old-mode-name)
 222     (setq hexl-mode-old-mode-name mode-name)
 223     (setq mode-name "Hexl")
 224
 225     (make-local-variable 'hexl-mode-old-major-mode)
 226     (setq hexl-mode-old-major-mode major-mode)
 227     (setq major-mode 'hexl-mode)
 228
 229     (make-local-variable 'hexl-mode-old-syntax-table)
 230     (setq hexl-mode-old-syntax-table (syntax-table))
 231     (set-syntax-table (standard-syntax-table))
 232
 233     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 234     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 235     (make-local-variable 'write-contents-hooks)
 236     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 237
 238     (make-local-variable 'hexl-mode-old-require-final-newline)
 239     (setq hexl-mode-old-require-final-newline require-final-newline)
 240     (make-local-variable 'require-final-newline)
 241     (setq require-final-newline nil)
 242
 243     ;; Add hooks to rehexlify or dehexlify on various events.
 244     (make-local-hook 'after-revert-hook)
 245     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 246
 247     (make-local-hook 'change-major-mode-hook)
 248     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 249
 250     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 251   (run-hooks 'hexl-mode-hook))
 252
 253 (defun hexl-after-revert-hook ()
 254   (setq hexl-max-address (1- (buffer-size)))
 255   (hexlify-buffer)
 256   (set-buffer-modified-p nil))
 257
 258 (defvar hexl-in-save-buffer nil)
 259
 260 (defun hexl-save-buffer ()
 261   "Save a hexl format buffer as binary in visited file if modified."
 262   (interactive)
 263   (if hexl-in-save-buffer nil
 264     (set-buffer-modified-p (if (buffer-modified-p)
 265                                (save-excursion
 266                                  (let ((buf (generate-new-buffer " hexl"))
 267                                        (name (buffer-name))
 268                                        (file-name (buffer-file-name))
 269                                        (start (point-min))
 270                                        (end (point-max))
 271                                        modified)
 272                                    (set-buffer buf)
 273                                    (insert-buffer-substring name start end)
 274                                    (set-buffer name)
 275                                    (dehexlify-buffer)
 276                                    ;; Prevent infinite recursion.
 277                                    (let ((hexl-in-save-buffer t))
 278                                      (save-buffer))
 279                                    (setq modified (buffer-modified-p))
 280                                    (delete-region (point-min) (point-max))
 281                                    (insert-buffer-substring buf start end)
 282                                    (kill-buffer buf)
 283                                    modified))
 284                              (message "(No changes need to be saved)")
 285                              nil))
 286     ;; Return t to indicate we have saved t
 287     t))
 288
 289 ;;;###autoload
 290 (defun hexl-find-file (filename)
 291   "Edit file FILENAME in hexl-mode.
 292 Switch to a buffer visiting file FILENAME, creating one in none exists."
 293   (interactive "fFilename: ")
 294   (find-file-literally filename)
 295   (if (not (eq major-mode 'hexl-mode))
 296       (hexl-mode)))
 297
 298 (defun hexl-mode-exit (&optional arg)
 299   "Exit Hexl mode, returning to previous mode.
 300 With arg, don't unhexlify buffer."
 301   (interactive "p")
 302   (if (or (eq arg 1) (not arg))
 303       (let ((modified (buffer-modified-p))
 304             (inhibit-read-only t)
 305             (original-point (1+ (hexl-current-address))))
 306         (dehexlify-buffer)
 307         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 308         (set-buffer-modified-p modified)
 309         (goto-char original-point)))
 310
 311   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 312   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 313   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 314   (setq hexl-ascii-overlay nil)
 315
 316   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 317   (setq require-final-newline hexl-mode-old-require-final-newline)
 318   (setq mode-name hexl-mode-old-mode-name)
 319   (use-local-map hexl-mode-old-local-map)
 320   (set-syntax-table hexl-mode-old-syntax-table)
 321   (setq major-mode hexl-mode-old-major-mode)
 322   (force-mode-line-update))
 323
 324 (defun hexl-maybe-dehexlify-buffer ()
 325   "Convert a hexl format buffer to binary.
 326 Ask the user for confirmation."
 327   (if (y-or-n-p "Convert contents back to binary format? ")
 328       (let ((modified (buffer-modified-p))
 329             (inhibit-read-only t)
 330             (original-point (1+ (hexl-current-address))))
 331         (dehexlify-buffer)
 332         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 333         (set-buffer-modified-p modified)
 334         (goto-char original-point))))
 335
 336 (defun hexl-current-address (&optional validate)
 337   "Return current hexl-address."
 338   (interactive)
 339   (let ((current-column (- (% (point) 68) 11))
 340         (hexl-address 0))
 341     (if (< current-column 0)
 342         (if validate
 343             (error "Point is not on a character in the file")
 344           (setq current-column 0)))
 345     (setq hexl-address
 346           (+ (* (/ (point) 68) 16)
 347              (if (>= current-column 41)
 348                  (- current-column 41)
 349                (/ (- current-column  (/ current-column 5)) 2))))
 350     (when (interactive-p)
 351       (message "Current address is %d" hexl-address))
 352     hexl-address))
 353
 354 (defun hexl-address-to-marker (address)
 355   "Return buffer position for ADDRESS."
 356   (interactive "nAddress: ")
 357   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 358
 359 (defun hexl-goto-address (address)
 360   "Goto hexl-mode (decimal) address ADDRESS.
 361 Signal error if ADDRESS out of range."
 362   (interactive "nAddress: ")
 363   (if (or (< address 0) (> address hexl-max-address))
 364           (error "Out of hexl region"))
 365   (goto-char (hexl-address-to-marker address)))
 366
 367 (defun hexl-goto-hex-address (hex-address)
 368   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 369 Signal error if HEX-ADDRESS is out of range."
 370   (interactive "sHex Address: ")
 371   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 372
 373 (defun hexl-hex-string-to-integer (hex-string)
 374   "Return decimal integer for HEX-STRING."
 375   (interactive "sHex number: ")
 376   (let ((hex-num 0))
 377     (while (not (equal hex-string ""))
 378       (setq hex-num (+ (* hex-num 16)
 379                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 380       (setq hex-string (substring hex-string 1)))
 381     hex-num))
 382
 383 (defun hexl-octal-string-to-integer (octal-string)
 384   "Return decimal integer for OCTAL-STRING."
 385   (interactive "sOctal number: ")
 386   (let ((oct-num 0))
 387     (while (not (equal octal-string ""))
 388       (setq oct-num (+ (* oct-num 8)
 389                        (hexl-oct-char-to-integer
 390                         (string-to-char octal-string))))
 391       (setq octal-string (substring octal-string 1)))
 392     oct-num))
 393
 394 ;; move point functions
 395
 396 (defun hexl-backward-char (arg)
 397   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 398   (interactive "p")
 399   (hexl-goto-address (- (hexl-current-address) arg)))
 400
 401 (defun hexl-forward-char (arg)
 402   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 403   (interactive "p")
 404   (hexl-goto-address (+ (hexl-current-address) arg)))
 405
 406 (defun hexl-backward-short (arg)
 407   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 408   (interactive "p")
 409   (hexl-goto-address (let ((address (hexl-current-address)))
 410                        (if (< arg 0)
 411                            (progn
 412                              (setq arg (- arg))
 413                              (while (> arg 0)
 414                                (if (not (equal address (logior address 3)))
 415                                    (if (> address hexl-max-address)
 416                                        (progn
 417                                          (message "End of buffer.")
 418                                          (setq address hexl-max-address))
 419                                      (setq address (logior address 3)))
 420                                  (if (> address hexl-max-address)
 421                                      (progn
 422                                        (message "End of buffer.")
 423                                        (setq address hexl-max-address))
 424                                    (setq address (+ address 4))))
 425                                (setq arg (1- arg)))
 426                              (if (> address hexl-max-address)
 427                                  (progn
 428                                    (message "End of buffer.")
 429                                    (setq address hexl-max-address))
 430                                (setq address (logior address 3))))
 431                          (while (> arg 0)
 432                            (if (not (equal address (logand address -4)))
 433                                (setq address (logand address -4))
 434                              (if (not (equal address 0))
 435                                  (setq address (- address 4))
 436                                (message "Beginning of buffer.")))
 437                            (setq arg (1- arg))))
 438                        address)))
 439
 440 (defun hexl-forward-short (arg)
 441   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 442   (interactive "p")
 443   (hexl-backward-short (- arg)))
 444
 445 (defun hexl-backward-word (arg)
 446   "Move to left ARG words (right if ARG negative) in hexl-mode."
 447   (interactive "p")
 448   (hexl-goto-address (let ((address (hexl-current-address)))
 449                        (if (< arg 0)
 450                            (progn
 451                              (setq arg (- arg))
 452                              (while (> arg 0)
 453                                (if (not (equal address (logior address 7)))
 454                                    (if (> address hexl-max-address)
 455                                        (progn
 456                                          (message "End of buffer.")
 457                                          (setq address hexl-max-address))
 458                                      (setq address (logior address 7)))
 459                                  (if (> address hexl-max-address)
 460                                      (progn
 461                                        (message "End of buffer.")
 462                                        (setq address hexl-max-address))
 463                                    (setq address (+ address 8))))
 464                                (setq arg (1- arg)))
 465                              (if (> address hexl-max-address)
 466                                  (progn
 467                                    (message "End of buffer.")
 468                                    (setq address hexl-max-address))
 469                                (setq address (logior address 7))))
 470                          (while (> arg 0)
 471                            (if (not (equal address (logand address -8)))
 472                                (setq address (logand address -8))
 473                              (if (not (equal address 0))
 474                                  (setq address (- address 8))
 475                                (message "Beginning of buffer.")))
 476                            (setq arg (1- arg))))
 477                        address)))
 478
 479 (defun hexl-forward-word (arg)
 480   "Move right ARG words (left if ARG negative) in hexl-mode."
 481   (interactive "p")
 482   (hexl-backward-word (- arg)))
 483
 484 (defun hexl-previous-line (arg)
 485   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 486 If there is byte at the target address move to the last byte in that line."
 487   (interactive "p")
 488   (hexl-next-line (- arg)))
 489
 490 (defun hexl-next-line (arg)
 491   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 492 If there is no byte at the target address move to the last byte in that line."
 493   (interactive "p")
 494   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 495                        (if (and (< arg 0) (< address 0))
 496                                 (progn (message "Out of hexl region.")
 497                                        (setq address
 498                                              (% (hexl-current-address) 16)))
 499                          (if (and (> address hexl-max-address)
 500                                   (< (% hexl-max-address 16) (% address 16)))
 501                              (setq address hexl-max-address)
 502                            (if (> address hexl-max-address)
 503                                (progn (message "Out of hexl region.")
 504                                       (setq
 505                                        address
 506                                        (+ (logand hexl-max-address -16)
 507                                           (% (hexl-current-address) 16)))))))
 508                        address)))
 509
 510 (defun hexl-beginning-of-buffer (arg)
 511   "Move to the beginning of the hexl buffer.
 512 Leaves `hexl-mark' at previous position.
 513 With prefix arg N, puts point N bytes of the way from the true beginning."
 514   (interactive "p")
 515   (push-mark (point))
 516   (hexl-goto-address (+ 0 (1- arg))))
 517
 518 (defun hexl-end-of-buffer (arg)
 519   "Go to `hexl-max-address' minus ARG."
 520   (interactive "p")
 521   (push-mark (point))
 522   (hexl-goto-address (- hexl-max-address (1- arg))))
 523
 524 (defun hexl-beginning-of-line ()
 525   "Goto beginning of line in hexl mode."
 526   (interactive)
 527   (goto-char (+ (* (/ (point) 68) 68) 11)))
 528
 529 (defun hexl-end-of-line ()
 530   "Goto end of line in hexl mode."
 531   (interactive)
 532   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 533                        (if (> address hexl-max-address)
 534                            (setq address hexl-max-address))
 535                        address)))
 536
 537 (defun hexl-scroll-down (arg)
 538   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 539   (interactive "P")
 540   (if (null arg)
 541       (setq arg (1- (window-height)))
 542     (setq arg (prefix-numeric-value arg)))
 543   (hexl-scroll-up (- arg)))
 544
 545 (defun hexl-scroll-up (arg)
 546   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG.
 547 If there's no byte at the target address, move to the first or last line."
 548   (interactive "P")
 549   (if (null arg)
 550       (setq arg (1- (window-height)))
 551     (setq arg (prefix-numeric-value arg)))
 552   (let* ((movement (* arg 16))
 553          (address (hexl-current-address))
 554          (dest (+ address movement)))
 555     (cond
 556      ;; If possible, try to stay at the same offset from the beginning
 557      ;; of the 16-byte group, even if we move to the first or last
 558      ;; group.
 559      ((and (> dest hexl-max-address)
 560            (>= (% hexl-max-address 16) (% address 16)))
 561       (setq dest (+ (logand hexl-max-address -16) (% address 16))))
 562      ((> dest hexl-max-address)
 563       (setq dest hexl-max-address))
 564      ((< dest 0)
 565       (setq dest (% address 16))))
 566     (if (/= dest (+ address movement))
 567         (message "Out of hexl region."))
 568     (hexl-goto-address dest)
 569     (recenter 0)))
 570
 571 (defun hexl-beginning-of-1k-page ()
 572   "Go to beginning of 1k boundary."
 573   (interactive)
 574   (hexl-goto-address (logand (hexl-current-address) -1024)))
 575
 576 (defun hexl-end-of-1k-page ()
 577   "Go to end of 1k boundary."
 578   (interactive)
 579   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 580                        (if (> address hexl-max-address)
 581                            (setq address hexl-max-address))
 582                        address)))
 583
 584 (defun hexl-beginning-of-512b-page ()
 585   "Go to beginning of 512 byte boundary."
 586   (interactive)
 587   (hexl-goto-address (logand (hexl-current-address) -512)))
 588
 589 (defun hexl-end-of-512b-page ()
 590   "Go to end of 512 byte boundary."
 591   (interactive)
 592   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 593                        (if (> address hexl-max-address)
 594                            (setq address hexl-max-address))
 595                        address)))
 596
 597 (defun hexl-quoted-insert (arg)
 598   "Read next input character and insert it.
 599 Useful for inserting control characters.
 600 You may also type up to 3 octal digits, to insert a character with that code"
 601   (interactive "p")
 602   (hexl-insert-char (read-quoted-char) arg))
 603
 604 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 605
 606 ;;;###autoload
 607 (defun hexlify-buffer ()
 608   "Convert a binary buffer to hexl format.
 609 This discards the buffer's undo information."
 610   (interactive)
 611   (and buffer-undo-list
 612        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 613            (error "Aborted")))
 614   (setq buffer-undo-list nil)
 615   ;; Don't decode text in the ASCII part of `hexl' program output.
 616   (let ((coding-system-for-read 'raw-text)
 617         (coding-system-for-write buffer-file-coding-system)
 618         (buffer-undo-list t))
 619     (shell-command-on-region (point-min) (point-max) hexlify-command t)
 620     (if (> (point) (hexl-address-to-marker hexl-max-address))
 621         (hexl-goto-address hexl-max-address))))
 622
 623 (defun dehexlify-buffer ()
 624   "Convert a hexl format buffer to binary.
 625 This discards the buffer's undo information."
 626   (interactive)
 627   (and buffer-undo-list
 628        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 629            (error "Aborted")))
 630   (setq buffer-undo-list nil)
 631   (let ((coding-system-for-write 'raw-text)
 632         (coding-system-for-read buffer-file-coding-system)
 633         (buffer-undo-list t))
 634     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 635
 636 (defun hexl-char-after-point ()
 637   "Return char for ASCII hex digits at point."
 638   (hexl-htoi (char-after (point))
 639              (char-after (1+ (point)))))
 640
 641 (defun hexl-htoi (lh rh)
 642   "Hex (char) LH (char) RH to integer."
 643     (+ (* (hexl-hex-char-to-integer lh) 16)
 644        (hexl-hex-char-to-integer rh)))
 645
 646 (defun hexl-hex-char-to-integer (character)
 647   "Take a char and return its value as if it was a hex digit."
 648   (if (and (>= character ?0) (<= character ?9))
 649       (- character ?0)
 650     (let ((ch (logior character 32)))
 651       (if (and (>= ch ?a) (<= ch ?f))
 652           (- ch (- ?a 10))
 653         (error "Invalid hex digit `%c'" ch)))))
 654
 655 (defun hexl-oct-char-to-integer (character)
 656   "Take a char and return its value as if it was a octal digit."
 657   (if (and (>= character ?0) (<= character ?7))
 658       (- character ?0)
 659     (error "Invalid octal digit `%c'" character)))
 660
 661 (defun hexl-printable-character (ch)
 662   "Return a displayable string for character CH."
 663   (format "%c" (if hexl-iso
 664                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 665                        46
 666                      ch)
 667                  (if (or (< ch 32) (>= ch 127))
 668                      46
 669                    ch))))
 670
 671 (defun hexl-self-insert-command (arg)
 672   "Insert this character."
 673   (interactive "p")
 674   (hexl-insert-char last-command-char arg))
 675
 676 (defun hexl-insert-char (ch num)
 677   "Insert a character in a hexl buffer."
 678   (let ((address (hexl-current-address t)))
 679     (while (> num 0)
 680       (let ((hex-position
 681              (+ (* (/ address 16) 68)
 682                 11
 683                 (* 2 (% address 16))
 684                 (/ (% address 16) 2)))
 685             (ascii-position
 686              (+ (* (/ address 16) 68) 52 (% address 16)))
 687             at-ascii-position)
 688         (if (= (point) ascii-position)
 689             (setq at-ascii-position t))
 690         (goto-char hex-position)
 691         (delete-char 2)
 692         (insert (format "%02x" ch))
 693         (goto-char ascii-position)
 694         (delete-char 1)
 695         (insert (hexl-printable-character ch))
 696         (or (eq address hexl-max-address)
 697             (setq address (1+ address)))
 698         (hexl-goto-address address)
 699         (if at-ascii-position
 700             (progn
 701               (beginning-of-line)
 702               (forward-char 51)
 703               (forward-char (% address 16)))))
 704       (setq num (1- num)))))
 705
 706 ;; hex conversion
 707
 708 (defun hexl-insert-hex-char (arg)
 709   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 710   (interactive "p")
 711   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 712     (if (or (> num 255) (< num 0))
 713         (error "Hex number out of range")
 714       (hexl-insert-char num arg))))
 715
 716 (defun hexl-insert-hex-string (str arg)
 717   "Insert hexadecimal string STR at point ARG times.
 718 Embedded whitespace, dashes, and periods in the string are ignored."
 719   (interactive "sHex string: \np")
 720   (setq str (replace-regexp-in-string "[- \t.]" "" str))
 721   (let ((chars '()))
 722     (let ((len (length str))
 723           (idx 0))
 724       (if (eq (logand len 1) 1)
 725           (let ((num (hexl-hex-string-to-integer (substring str 0 1))))
 726             (setq chars (cons num chars))
 727             (setq idx 1)))
 728       (while (< idx len)
 729         (let* ((nidx (+ idx 2))
 730                (num (hexl-hex-string-to-integer (substring str idx nidx))))
 731           (setq chars (cons num chars))
 732           (setq idx nidx))))
 733     (setq chars (nreverse chars))
 734     (while (> arg 0)
 735       (let ((chars chars))
 736         (while chars
 737           (hexl-insert-char (car chars) 1)
 738           (setq chars (cdr chars))))
 739       (setq arg (- arg 1)))))
 740
 741 (defun hexl-insert-decimal-char (arg)
 742   "Insert a ASCII char ARG times at point for a given decimal number."
 743   (interactive "p")
 744   (let ((num (string-to-int (read-string "Decimal Number: "))))
 745     (if (or (> num 255) (< num 0))
 746         (error "Decimal number out of range")
 747       (hexl-insert-char num arg))))
 748
 749 (defun hexl-insert-octal-char (arg)
 750   "Insert a ASCII char ARG times at point for a given octal number."
 751   (interactive "p")
 752   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 753     (if (or (> num 255) (< num 0))
 754         (error "Decimal number out of range")
 755       (hexl-insert-char num arg))))
 756
 757 (defun hexl-follow-ascii (&optional arg)
 758   "Toggle following ASCII in Hexl buffers.
 759 With prefix ARG, turn on following if and only if ARG is positive.
 760 When following is enabled, the ASCII character corresponding to the
 761 element under the point is highlighted.
 762 Customize the variable `hexl-follow-ascii' to disable this feature."
 763   (interactive "P")
 764   (let ((on-p (if arg
 765                   (> (prefix-numeric-value arg) 0)
 766                (not hexl-ascii-overlay))))
 767
 768     (make-local-hook 'post-command-hook)
 769
 770     (if on-p
 771       ;; turn it on
 772       (if (not hexl-ascii-overlay)
 773           (progn
 774             (setq hexl-ascii-overlay (make-overlay 1 1)
 775                   hexl-follow-ascii t)
 776             (overlay-put hexl-ascii-overlay 'face 'highlight)
 777             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 778       ;; turn it off
 779       (if hexl-ascii-overlay
 780           (progn
 781             (delete-overlay hexl-ascii-overlay)
 782             (setq hexl-ascii-overlay nil
 783                   hexl-follow-ascii nil)
 784             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 785             )))))
 786
 787 (defun hexl-follow-ascii-find ()
 788   "Find and highlight the ASCII element corresponding to current point."
 789   (let ((pos (+ 51
 790                 (- (point) (current-column))
 791                 (mod (hexl-current-address) 16))))
 792     (move-overlay hexl-ascii-overlay pos (1+ pos))
 793     ))
 794
 795 ;; startup stuff.
 796
 797 (if hexl-mode-map
 798     nil
 799   (setq hexl-mode-map (make-sparse-keymap))
 800
 801   (define-key hexl-mode-map [left] 'hexl-backward-char)
 802   (define-key hexl-mode-map [right] 'hexl-forward-char)
 803   (define-key hexl-mode-map [up] 'hexl-previous-line)
 804   (define-key hexl-mode-map [down] 'hexl-next-line)
 805   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 806   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 807   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 808   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 809   (define-key hexl-mode-map [home] 'hexl-beginning-of-line)
 810   (define-key hexl-mode-map [end] 'hexl-end-of-line)
 811   (define-key hexl-mode-map [C-home] 'hexl-beginning-of-buffer)
 812   (define-key hexl-mode-map [C-end] 'hexl-end-of-buffer)
 813   (define-key hexl-mode-map [deletechar] 'undefined)
 814   (define-key hexl-mode-map [deleteline] 'undefined)
 815   (define-key hexl-mode-map [insertline] 'undefined)
 816   (define-key hexl-mode-map [S-delete] 'undefined)
 817   (define-key hexl-mode-map "\177" 'undefined)
 818
 819   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 820   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 821   (define-key hexl-mode-map "\C-d" 'undefined)
 822   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 823   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 824
 825   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 826       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 827
 828   (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 829   (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 830   (define-key hexl-mode-map "\C-k" 'undefined)
 831   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 832   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 833   (define-key hexl-mode-map "\C-o" 'undefined)
 834   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 835   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 836   (define-key hexl-mode-map "\C-t" 'undefined)
 837   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 838   (define-key hexl-mode-map "\C-w" 'undefined)
 839   (define-key hexl-mode-map "\C-y" 'undefined)
 840
 841   (let ((ch 32))
 842     (while (< ch 127)
 843       (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 844       (setq ch (1+ ch))))
 845
 846   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 847   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 848   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 849   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 850   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 851   (define-key hexl-mode-map "\e\C-i" 'undefined)
 852   (define-key hexl-mode-map "\e\C-j" 'undefined)
 853   (define-key hexl-mode-map "\e\C-k" 'undefined)
 854   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 855   (define-key hexl-mode-map "\e\C-q" 'undefined)
 856   (define-key hexl-mode-map "\e\C-t" 'undefined)
 857   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 858   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 859   (define-key hexl-mode-map "\ec" 'undefined)
 860   (define-key hexl-mode-map "\ed" 'undefined)
 861   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 862   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 863   (define-key hexl-mode-map "\ei" 'undefined)
 864   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 865   (define-key hexl-mode-map "\ek" 'undefined)
 866   (define-key hexl-mode-map "\el" 'undefined)
 867   (define-key hexl-mode-map "\eq" 'undefined)
 868   (define-key hexl-mode-map "\es" 'undefined)
 869   (define-key hexl-mode-map "\et" 'undefined)
 870   (define-key hexl-mode-map "\eu" 'undefined)
 871   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 872   (define-key hexl-mode-map "\ey" 'undefined)
 873   (define-key hexl-mode-map "\ez" 'undefined)
 874   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 875   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 876
 877   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 878
 879   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 880   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 881   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 882   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 883   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 884
 885 (provide 'hexl)
 886
 887 ;;; hexl.el ends here