Windows
*******

This chapter describes the functions and variables related to Emacs windows.  See Frames, for how windows are assigned an area of screen available for Emacs to use.  See Display, for information on how text is displayed in windows.

Basic Concepts of Emacs Windows
===============================

A window is a area of the screen which is used to display a buffer (see Buffers).  In Emacs Lisp, windows are represented by a special Lisp object type.

Windows are grouped into frames (see Frames).  Each frame contains at least one window; the user can subdivide it into multiple, non-overlapping windows to view several buffers at once.  Lisp programs can use multiple windows for a variety of purposes.  In Rmail, for example, you can view a summary of message titles in one window, and the contents of the selected message in another window.

Emacs uses the word ``window'' with a different meaning than in graphical desktop environments and window systems, such as the X Window System.  When Emacs is run on X, each of its graphical X windows is an Emacs frame (containing one or more Emacs windows). When Emacs is run on a text terminal, the frame fills the entire terminal screen.

Unlike X windows, Emacs windows are tiled; they never overlap within the area of the frame.  When a window is created, resized, or deleted, the change in window space is taken from or given to the adjacent windows, so that the total area of the frame is unchanged.

A live window is one that is actually displaying a buffer in a frame.  Such a window can be deleted, i.e. removed from the frame (see Deleting Windows); then it is no longer live, but the Lisp object representing it might be still referenced from other Lisp objects.  A deleted window may be brought back to life by restoring a saved window configuration (see Window Configurations).

 -- Function: windowp object
     This function returns t if OBJECT is a window (whether or not it is live).  Otherwise, it returns nil.

 -- Function: window-live-p object
     This function returns t if OBJECT is a live window and nil otherwise.  A live window is one that displays a buffer.

The windows in each frame are organized into a window tree. See Windows and Frames.  The leaf nodes of each window tree are live windows---the ones actually displaying buffers.  The internal nodes of the window tree are internal windows, which are not live. You can distinguish internal windows from deleted windows with window-valid-p.

 -- Function: window-valid-p object
     This function returns t if OBJECT is a live window, or an internal window in a window tree.  Otherwise, it returns nil, including for the case where OBJECT is a deleted window.

In each frame, at any time, exactly one Emacs window is designated as selected within the frame.  For the selected frame, that window is called the selected window---the one in which most editing takes place, and in which the cursor for selected windows appears (see Cursor Parameters).  The selected window's buffer is usually also the current buffer, except when set-buffer has been used (see Current Buffer).  As for non-selected frames, the window selected within the frame becomes the selected window if the frame is ever selected.  See Selecting Windows.

 -- Function: selected-window
     This function returns the selected window (which is always a live window).

Windows and Frames
==================

Each window belongs to exactly one frame (see Frames).

 -- Function: window-frame window
     This function returns the frame that the window WINDOW belongs to.  If WINDOW is nil, it defaults to the selected window.

 -- Function: window-list &optional frame minibuffer window
     This function returns a list of live windows belonging to the frame FRAME.  If FRAME is omitted or nil, it defaults to the selected frame.

     The optional argument MINIBUFFER specifies whether to include the minibuffer window in the returned list.  If MINIBUFFER is t, the minibuffer window is included.  If MINIBUFFER is nil or omitted, the minibuffer window is included only if it is active.  If MINIBUFFER is neither nil nor t, the minibuffer window is never included.

     The optional argument WINDOW, if non-nil, should be a live window on the specified frame; then WINDOW will be the first element in the returned list.  If WINDOW is omitted or nil, the window selected within the frame is the first element.

Windows in the same frame are organized into a window tree, whose leaf nodes are the live windows.  The internal nodes of a window tree are not live; they exist for the purpose of organizing the relationships between live windows.  The root node of a window tree is called the root window.  It can be either a live window (if the frame has just one window), or an internal window.

A minibuffer window (see Minibuffer Windows) is not part of its frame's window tree unless the frame is a minibuffer-only frame. Nonetheless, most of the functions in this section accept the minibuffer window as an argument.  Also, the function window-tree described at the end of this section lists the minibuffer window alongside the actual window tree.

 -- Function: frame-root-window &optional frame-or-window
     This function returns the root window for FRAME-OR-WINDOW.  The argument FRAME-OR-WINDOW should be either a window or a frame; if omitted or nil, it defaults to the selected frame.  If FRAME-OR-WINDOW is a window, the return value is the root window of that window's frame.

When a window is split, there are two live windows where previously there was one.  One of these is represented by the same Lisp window object as the original window, and the other is represented by a newly-created Lisp window object.  Both of these live windows become leaf nodes of the window tree, as child windows of a single internal window.  If necessary, Emacs automatically creates this internal window, which is also called the parent window, and assigns it to the appropriate position in the window tree.  A set of windows that share the same parent are called siblings.

 -- Function: window-parent &optional window
     This function returns the parent window of WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window.  The return value is nil if WINDOW has no parent (i.e. it is a minibuffer window or the root window of its frame).

Each internal window always has at least two child windows.  If this number falls to one as a result of window deletion, Emacs automatically deletes the internal window, and its sole remaining child window takes its place in the window tree.

Each child window can be either a live window, or an internal window (which in turn would have its own child windows).  Therefore, each internal window can be thought of as occupying a certain rectangular screen area---the union of the areas occupied by the live windows that are ultimately descended from it.

For each internal window, the screen areas of the immediate children are arranged either vertically or horizontally (never both).  If the child windows are arranged one above the other, they are said to form a vertical combination; if they are arranged side by side, they are said to form a horizontal combination.  Consider the following example:

          ______________________________________
         | ______  ____________________________ |
         ||      || __________________________ ||
         ||      |||                          |||
         ||      |||                          |||
         ||      |||                          |||
         ||      |||____________W4____________|||
         ||      || __________________________ ||
         ||      |||                          |||
         ||      |||                          |||
         ||      |||____________W5____________|||
         ||__W2__||_____________W3_____________ |
         |__________________W1__________________|

The root window of this frame is an internal window, W1.  Its child windows form a horizontal combination, consisting of the live window W2 and the internal window W3.  The child windows of W3 form a vertical combination, consisting of the live windows W4 and W5.  Hence, the live windows in this window tree are W2 W4, and W5.

The following functions can be used to retrieve a child window of an internal window, and the siblings of a child window.

 -- Function: window-top-child window
     This function returns the topmost child window of WINDOW, if WINDOW is an internal window whose children form a vertical combination.  For any other type of window, the return value is nil.

 -- Function: window-left-child window
     This function returns the leftmost child window of WINDOW, if WINDOW is an internal window whose children form a horizontal combination.  For any other type of window, the return value is nil.

 -- Function: window-child window
     This function returns the first child window of the internal window WINDOW---the topmost child window for a vertical combination, or the leftmost child window for a horizontal combination.  If WINDOW is a live window, the return value is nil.

 -- Function: window-combined-p &optional window horizontal
     This function returns a non-nil value if and only if WINDOW is part of a vertical combination.  If WINDOW is omitted or nil, it defaults to the selected one.

     If the optional argument HORIZONTAL is non-nil, this means to return non-nil if and only if WINDOW is part of a horizontal combination.

 -- Function: window-next-sibling &optional window
     This function returns the next sibling of the window WINDOW.  If omitted or nil, WINDOW defaults to the selected window. The return value is nil if WINDOW is the last child of its parent.

 -- Function: window-prev-sibling &optional window
     This function returns the previous sibling of the window WINDOW. If omitted or nil, WINDOW defaults to the selected window.  The return value is nil if WINDOW is the first child of its parent.

The functions window-next-sibling and window-prev-sibling should not be confused with the functions next-window and previous-window which respectively return the next and previous window in the cyclic ordering of windows (see Cyclic Window Ordering).

You can use the following functions to find the first live window on a frame, and to retrieve the entire window tree of a frame:

 -- Function: frame-first-window &optional frame-or-window
     This function returns the live window at the upper left corner of the frame specified by FRAME-OR-WINDOW.  The argument FRAME-OR-WINDOW must denote a window or a live frame and defaults to the selected frame.  If FRAME-OR-WINDOW specifies a window, this function returns the first window on that window's frame.  Under the assumption that the frame from our canonical example is selected (frame-first-window) returns W2.

 -- Function: window-tree &optional frame
     This function returns a list representing the window tree for frame FRAME.  If FRAME is omitted or nil, it defaults to the selected frame.

     The return value is a list of the form (ROOT MINI), where ROOT represents the window tree of the frame's root window, and MINI is the frame's minibuffer window.

     If the root window is live, ROOT is that window itself. Otherwise, ROOT is a list (DIR EDGES W1 W2 ...) where DIR is nil for a horizontal combination and t for a vertical combination, EDGES gives the size and position of the combination, and the remaining elements are the child windows.  Each child window may again be a window object (for a live window) or a list with the same format as above (for an internal window).  The EDGES element is a list (LEFT TOP RIGHT BOTTOM), similar to the value returned by window-edges (see Coordinates and Windows).

Window Sizes
============

The following schematic shows the structure of a live window:

              _________________________________________
           ^ |______________ Header Line_______________|
           | |LS|LF|LM|                       |RM|RF|RS| ^
           | |  |  |  |                       |  |  |  | |
      Window |  |  |  |       Text Area       |  |  |  | Window
      Total  |  |  |  |     (Window Body)     |  |  |  | Body
      Height |  |  |  |                       |  |  |  | Height
           | |  |  |  |<- Window Body Width ->|  |  |  | |
           | |__|__|__|_______________________|__|__|__| v
           v |_______________ Mode Line _______________|

              <----------- Window Total Width -------->

At the center of the window is the text area, or body, where the buffer text is displayed.  On each side of the text area is a series of vertical areas; from innermost to outermost, these are the left and right margins, denoted by LM and RM in the schematic (see Display Margins); the left and right fringes, denoted by LF and RF (see Fringes); and the left or right scroll bar, only one of which is present at any time, denoted by LS and RS (see Scroll Bars).  At the top of the window is an optional header line (see Header Lines), and at the bottom of the window is the mode line (see Mode Line Format).

Emacs provides several functions for finding the height and width of a window.  Except where noted, Emacs reports window heights and widths as integer numbers of lines and columns respectively.  On a graphical display, each ``line'' and ``column'' actually corresponds to the height and width of a ``default'' character specified by the frame's default font.  Thus, if a window is displaying text with a different font or size, the reported height and width for that window may differ from the actual number of text lines or columns displayed within it.

The total height of a window is the distance between the top and bottom of the window, including the header line (if one exists) and the mode line.  The total width of a window is the distance between the left and right edges of the mode line.  Note that the height of a frame is not the same as the height of its windows, since a frame may also contain an echo area, menu bar, and tool bar (see Size and Position).

 -- Function: window-total-height &optional window
     This function returns the total height, in lines, of the window WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window.  If WINDOW is an internal window, the return value is the total height occupied by its descendant windows.

 -- Function: window-total-width &optional window
     This function returns the total width, in columns, of the window WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window.  If WINDOW is internal, the return value is the total width occupied by its descendant windows.

 -- Function: window-total-size &optional window horizontal
     This function returns either the total height or width of the window WINDOW.  If HORIZONTAL is omitted or nil, this is equivalent to calling window-total-height for WINDOW; otherwise it is equivalent to calling window-total-width for WINDOW.

The following functions can be used to determine whether a given window has any adjacent windows.

 -- Function: window-full-height-p &optional window
     This function returns non-nil if WINDOW has no other window above or below it in its frame, i.e. its total height equals the total height of the root window on that frame.  If WINDOW is omitted or nil, it defaults to the selected window.

 -- Function: window-full-width-p &optional window
     This function returns non-nil if WINDOW has no other window to the left or right in its frame, i.e. its total width equals that of the root window on that frame.  If WINDOW is omitted or nil, it defaults to the selected window.

The body height of a window is the height of its text area, which does not include the mode or header line.  Similarly, the body width is the width of the text area, which does not include the scroll bar, fringes, or margins.

 -- Function: window-body-height &optional window
     This function returns the body height, in lines, of the window WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window; otherwise it must be a live window.

     If there is a partially-visible line at the bottom of the text area, that counts as a whole line; to exclude such a partially-visible line, use window-text-height, below.

 -- Function: window-body-width &optional window
     This function returns the body width, in columns, of the window WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window; otherwise it must be a live window.

 -- Function: window-body-size &optional window horizontal
     This function returns the body height or body width of WINDOW. If HORIZONTAL is omitted or nil, it is equivalent to calling window-body-height for WINDOW; otherwise it is equivalent to calling window-body-width.

 -- Function: window-text-height &optional window
     This function is like window-body-height, except that any partially-visible line at the bottom of the text area is not counted.

For compatibility with previous versions of Emacs, window-height is an alias for window-total-height, and window-width is an alias for window-body-width.  These aliases are considered obsolete and will be removed in the future.

Commands that change the size of windows (see Resizing Windows), or split them (see Splitting Windows), obey the variables window-min-height and window-min-width, which specify the smallest allowable window height and width.  See Deleting and Rearranging Windows (The GNU Emacs Manual).  They also obey the variable window-size-fixed, with which a window can be fixed in size:

 -- Variable: window-size-fixed
     If this buffer-local variable is non-nil, the size of any window displaying the buffer cannot normally be changed.  Deleting a window or changing the frame's size may still change its size, if there is no choice.

     If the value is height, then only the window's height is fixed; if the value is width, then only the window's width is fixed. Any other non-nil value fixes both the width and the height.

 -- Function: window-size-fixed-p &optional window horizontal
     This function returns a non-nil value if WINDOW's height is fixed.  If WINDOW is omitted or nil, it defaults to the selected window.  If the optional argument HORIZONTAL is non-nil, the return value is non-nil if WINDOW's width is fixed.

     A nil return value does not necessarily mean that WINDOW can be resized in the desired direction.  To determine that, use the function window-resizable.  See Resizing Windows.

See Coordinates and Windows, for more functions that report the positions of various parts of a window relative to the frame, from which you can calculate its size.  In particular, you can use the functions window-pixel-edges and window-inside-pixel-edges to find the size in pixels, for graphical displays.

Resizing Windows
================

This section describes functions for resizing a window without changing the size of its frame.  Because live windows do not overlap, these functions are meaningful only on frames that contain two or more windows: resizing a window also changes the size of a neighboring window.  If there is just one window on a frame, its size cannot be changed except by resizing the frame (see Size and Position).

Except where noted, these functions also accept internal windows as arguments.  Resizing an internal window causes its child windows to be resized to fit the same space.

 -- Function: window-resizable window delta &optional horizontal ignore
     This function returns DELTA if the size of WINDOW can be changed vertically by DELTA lines.  If the optional argument HORIZONTAL is non-nil, it instead returns DELTA if WINDOW can be resized horizontally by DELTA columns.  It does not actually change the window size.

     If WINDOW is nil, it defaults to the selected window.

     A positive value of DELTA means to check whether the window can be enlarged by that number of lines or columns; a negative value of DELTA means to check whether the window can be shrunk by that many lines or columns.  If DELTA is non-zero, a return value of 0 means that the window cannot be resized.

     Normally, the variables window-min-height and window-min-width specify the smallest allowable window size. See Deleting and Rearranging Windows (The GNU Emacs Manual).  However, if the optional argument IGNORE is non-nil, this function ignores window-min-height and window-min-width, as well as window-size-fixed. Instead, it considers the minimum-height window to be one consisting of a header (if any), a mode line, plus a text area one line tall; and a minimum-width window as one consisting of fringes, margins, and scroll bar (if any), plus a text area two columns wide.

 -- Function: window-resize window delta &optional horizontal ignore
     This function resizes WINDOW by DELTA increments.  If HORIZONTAL is nil, it changes the height by DELTA lines; otherwise, it changes the width by DELTA columns.  A positive DELTA means to enlarge the window, and a negative DELTA means to shrink it.

     If WINDOW is nil, it defaults to the selected window.  If the window cannot be resized as demanded, an error is signaled.

     The optional argument IGNORE has the same meaning as for the function window-resizable above.

     The choice of which window edges this function alters depends on the values of the option window-combination-resize and the combination limits of the involved windows; in some cases, it may alter both edges.  See Splitting Windows.  To resize by moving only the bottom or right edge of a window, use the function adjust-window-trailing-edge, below.

 -- Function: adjust-window-trailing-edge window delta &optional horizontal
     This function moves WINDOW's bottom edge by DELTA lines. If optional argument HORIZONTAL is non-nil, it instead moves the right edge by DELTA columns.  If WINDOW is nil, it defaults to the selected window.

     A positive DELTA moves the edge downwards or to the right; a negative DELTA moves it upwards or to the left.  If the edge cannot be moved as far as specified by DELTA, this function moves it as far as possible but does not signal a error.

     This function tries to resize windows adjacent to the edge that is moved.  If this is not possible for some reason (e.g. if that adjacent window is fixed-size), it may resize other windows.

The following commands resize windows in more specific ways.  When called interactively, they act on the selected window.

 -- Command: fit-window-to-buffer &optional window max-height min-height override
     This command adjusts the height of WINDOW to fit the text in it. It returns non-nil if it was able to resize WINDOW, and nil otherwise.  If WINDOW is omitted or nil, it defaults to the selected window.  Otherwise, it should be a live window.

     The optional argument MAX-HEIGHT, if non-nil, specifies the maximum total height that this function can give WINDOW. The optional argument MIN-HEIGHT, if no-nil, specifies the minimum total height that it can give, which overrides the variable window-min-height.

     If the optional argument OVERRIDE is non-nil, this function ignores any size restrictions imposed by window-min-height and window-min-width.

 -- Command: shrink-window-if-larger-than-buffer &optional window
     This command attempts to reduce WINDOW's height as much as possible while still showing its full buffer, but no less than window-min-height lines.  The return value is non-nil if the window was resized, and nil otherwise.  If WINDOW is omitted or nil, it defaults to the selected window.  Otherwise, it should be a live window.

     This command does nothing if the window is already too short to display all of its buffer, or if any of the buffer is scrolled off-screen, or if the window is the only live window in its frame.

 -- Command: balance-windows &optional window-or-frame
     This function balances windows in a way that gives more space to full-width and/or full-height windows.  If WINDOW-OR-FRAME specifies a frame, it balances all windows on that frame.  If WINDOW-OR-FRAME specifies a window, it balances only that window and its siblings (see Windows and Frames).

 -- Command: balance-windows-area
     This function attempts to give all windows on the selected frame approximately the same share of the screen area.  Full-width or full-height windows are not given more space than other windows.

 -- Command: maximize-window &optional window
     This function attempts to make WINDOW as large as possible, in both dimensions, without resizing its frame or deleting other windows. If WINDOW is omitted or nil, it defaults to the selected window.

 -- Command: minimize-window &optional window
     This function attempts to make WINDOW as small as possible, in both dimensions, without deleting it or resizing its frame.  If WINDOW is omitted or nil, it defaults to the selected window.

Splitting Windows
=================

This section describes functions for creating a new window by splitting an existing one.

 -- Command: split-window &optional window size side
     This function creates a new live window next to the window WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window.  That window is ``split'', and reduced in size.  The space is taken up by the new window, which is returned.

     The optional second argument SIZE determines the sizes of WINDOW and/or the new window.  If it is omitted or nil, both windows are given equal sizes; if there is an odd line, it is allocated to the new window.  If SIZE is a positive number, WINDOW is given SIZE lines (or columns, depending on the value of SIDE).  If SIZE is a negative number, the new window is given -SIZE lines (or columns).

     If SIZE is nil, this function obeys the variables window-min-height and window-min-width.  See Deleting and Rearranging Windows (The GNU Emacs Manual).  Thus, it signals an error if splitting would result in making a window smaller than those variables specify.  However, a non-nil value for SIZE causes those variables to be ignored; in that case, the smallest allowable window is considered to be one that has space for a text area one line tall and/or two columns wide.

     The optional third argument SIDE determines the position of the new window relative to WINDOW.  If it is nil or below, the new window is placed below WINDOW.  If it is above, the new window is placed above WINDOW.  In both these cases, SIZE specifies a total window height, in lines.

     If SIDE is t or right, the new window is placed on the right of WINDOW.  If SIDE is left, the new window is placed on the left of WINDOW.  In both these cases, SIZE specifies a total window width, in columns.

     If WINDOW is a live window, the new window inherits various properties from it, including margins and scroll bars.  If WINDOW is an internal window, the new window inherits the properties of the window selected within WINDOW's frame.

     The behavior of this function may be altered by the window parameters of WINDOW, so long as the variable ignore-window-parameters is non-nil.  If the value of the split-window window parameter is t, this function ignores all other window parameters.  Otherwise, if the value of the split-window window parameter is a function, that function is called with the arguments WINDOW, SIZE, and SIDE, in lieu of the usual action of split-window.  Otherwise, this function obeys the window-atom or window-side window parameter, if any.  See Window Parameters.

As an example, here is a sequence of split-window calls that yields the window configuration discussed in Windows and Frames. This example demonstrates splitting a live window as well as splitting an internal window.  We begin with a frame containing a single window (a live root window), which we denote by W4.  Calling (split-window W4) yields this window configuration:

          ______________________________________
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||_________________W4_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||_________________W5_________________||
         |__________________W3__________________|

The split-window call has created a new live window, denoted by W5.  It has also created a new internal window, denoted by W3, which becomes the root window and the parent of both W4 and W5.

Next, we call (split-window W3 nil 'left), passing the internal window W3 as the argument.  The result:

          ______________________________________
         | ______  ____________________________ |
         ||      || __________________________ ||
         ||      |||                          |||
         ||      |||                          |||
         ||      |||                          |||
         ||      |||____________W4____________|||
         ||      || __________________________ ||
         ||      |||                          |||
         ||      |||                          |||
         ||      |||____________W5____________|||
         ||__W2__||_____________W3_____________ |
         |__________________W1__________________|

A new live window W2 is created, to the left of the internal window W3.  A new internal window W1 is created, becoming the new root window.

 -- User Option: window-combination-resize
     If this variable is nil, split-window can only split a window (denoted by WINDOW) if WINDOW's screen area is large enough to accommodate both itself and the new window.

     If this variable is t, split-window tries to resize all windows that are part of the same combination as WINDOW, in order to accommodate the new window.  In particular, this may allow split-window to succeed even if WINDOW is a fixed-size window or too small to ordinarily split.  Furthermore, subsequently resizing or deleting WINDOW may resize all other windows in its combination.

     The default is nil.  Other values are reserved for future use. The value of this variable is ignored when window-combination-limit is non-nil (see below).

To illustrate the effect of window-combination-resize, consider the following window configuration:

          ______________________________________
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||_________________W2_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||_________________W3_________________||
         |__________________W1__________________|

If window-combination-resize is nil, splitting window W3 leaves the size of W2 unchanged:

          ______________________________________
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||_________________W2_________________||
         | ____________________________________ |
         ||                                    ||
         ||_________________W3_________________||
         | ____________________________________ |
         ||                                    ||
         ||_________________W4_________________||
         |__________________W1__________________|

If window-combination-resize is t, splitting W3 instead leaves all three live windows with approximately the same height:

          ______________________________________
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W2_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W3_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W4_________________||
         |__________________W1__________________|

 -- User Option: window-combination-limit
     If the value of this variable is t, the split-window function always creates a new internal window.  If the value is nil, the new live window is allowed to share the existing parent window, if one exists, provided the split occurs in the same direction as the existing window combination (otherwise, a new internal window is created anyway).  The default is nil.  Other values are reserved for future use.

     Thus, if the value of this variable is at all times t, then at all times every window tree is a binary tree (a tree where each window except the root window has exactly one sibling).

     Furthermore, split-window calls set-window-combination-limit on the newly-created internal window, recording the current value of this variable.  This affects how the window tree is rearranged when the child windows are deleted (see below).

 -- Function: set-window-combination-limit window limit
     This functions sets the combination limit of the window WINDOW to LIMIT.  This value can be retrieved via the function window-combination-limit.  See below for its effects; note that it is only meaningful for internal windows.  The split-window function automatically calls this function, passing the value of the variable window-combination-limit as LIMIT.

 -- Function: window-combination-limit window
     This function returns the combination limit for WINDOW.

     The combination limit is meaningful only for an internal window.  If it is nil, then Emacs is allowed to automatically delete WINDOW, in response to a window deletion, in order to group the child windows of WINDOW with its sibling windows to form a new window combination.  If the combination limit is t, the child windows of WINDOW are never automatically re-combined with its siblings.

To illustrate the effect of window-combination-limit, consider the following configuration (throughout this example, we will assume that window-combination-resize is nil):

          ______________________________________
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||                                    ||
         ||_________________W2_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W3_________________||
         |__________________W1__________________|

If window-combination-limit is nil, splitting W2 into two windows, one above the other, yields

          ______________________________________
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W2_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W4_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W3_________________||
         |__________________W1__________________|

The newly-created window, W4, shares the same internal window W1.  If W4 is resized, it is allowed to resize the other live window, W3.

If window-combination-limit is t, splitting W2 in the initial configuration would instead have produced this:

          ______________________________________
         | ____________________________________ |
         || __________________________________ ||
         |||                                  |||
         |||________________W2________________|||
         || __________________________________ ||
         |||                                  |||
         |||________________W4________________|||
         ||_________________W5_________________||
         | ____________________________________ |
         ||                                    ||
         ||                                    ||
         ||_________________W3_________________||
         |__________________W1__________________|

A new internal window W5 has been created; its children are W2 and the new live window W4.  Now, W2 is the only sibling of W4, so resizing W4 will resize W2, leaving W3 unaffected.

For interactive use, Emacs provides two commands which always split the selected window.  These call split-window internally.

 -- Command: split-window-right &optional size
     This function splits the selected window into two side-by-side windows, putting the selected window on the left.  If SIZE is positive, the left window gets SIZE columns; if SIZE is negative, the right window gets -SIZE columns.

 -- Command: split-window-below &optional size
     This function splits the selected window into two windows, one above the other, leaving the upper window selected.  If SIZE is positive, the upper window gets SIZE lines; if SIZE is negative, the lower window gets -SIZE lines.

 -- User Option: split-window-keep-point
     If the value of this variable is non-nil (the default), split-window-below behaves as described above.

     If it is nil, split-window-below adjusts point in each of the two windows to minimize redisplay.  (This is useful on slow terminals.)  It selects whichever window contains the screen line that point was previously on.  Note that this only affects split-window-below, not the lower-level split-window function.

Deleting Windows
================

Deleting a window removes it from the frame's window tree.  If the window is a live window, it disappears from the screen.  If the window is an internal window, its child windows are deleted too.

Even after a window is deleted, it continues to exist as a Lisp object, until there are no more references to it.  Window deletion can be reversed, by restoring a saved window configuration (see Window Configurations).

 -- Command: delete-window &optional window
     This function removes WINDOW from display and returns nil.  If WINDOW is omitted or nil, it defaults to the selected window.  If deleting the window would leave no more windows in the window tree (e.g. if it is the only live window in the frame), an error is signaled.

     By default, the space taken up by WINDOW is given to one of its adjacent sibling windows, if any.  However, if the variable window-combination-resize is non-nil, the space is proportionally distributed among any remaining windows in the window combination.  See Splitting Windows.

     The behavior of this function may be altered by the window parameters of WINDOW, so long as the variable ignore-window-parameters is non-nil.  If the value of the delete-window window parameter is t, this function ignores all other window parameters.  Otherwise, if the value of the delete-window window parameter is a function, that function is called with the argument WINDOW, in lieu of the usual action of delete-window.  Otherwise, this function obeys the window-atom or window-side window parameter, if any. See Window Parameters.

 -- Command: delete-other-windows &optional window
     This function makes WINDOW fill its frame, by deleting other windows as necessary.  If WINDOW is omitted or nil, it defaults to the selected window.  The return value is nil.

     The behavior of this function may be altered by the window parameters of WINDOW, so long as the variable ignore-window-parameters is non-nil.  If the value of the delete-other-windows window parameter is t, this function ignores all other window parameters.  Otherwise, if the value of the delete-other-windows window parameter is a function, that function is called with the argument WINDOW, in lieu of the usual action of delete-other-windows.  Otherwise, this function obeys the window-atom or window-side window parameter, if any.  See Window Parameters.

 -- Command: delete-windows-on &optional buffer-or-name frame
     This function deletes all windows showing BUFFER-OR-NAME, by calling delete-window on those windows.  BUFFER-OR-NAME should be a buffer, or the name of a buffer; if omitted or nil, it defaults to the current buffer.  If there are no windows showing the specified buffer, this function does nothing.  If the specified buffer is a minibuffer, an error is signaled.

     If there is a dedicated window showing the buffer, and that window is the only one on its frame, this function also deletes that frame if it is not the only frame on the terminal.

     The optional argument FRAME specifies which frames to operate on:

       * nil means operate on all frames.

       * t means operate on the selected frame.

       * visible means operate on all visible frames.

       * 0 means operate on all visible or iconified frames.

       * A frame means operate on that frame.

     Note that this argument does not have the same meaning as in other functions which scan all live windows (see Cyclic Window Ordering).  Specifically, the values t and nil have the opposite of their meanings in those other functions.

Selecting Windows
=================

 -- Function: select-window window &optional norecord
     This function makes WINDOW the selected window, as well as the window selected within its frame (see Basic Windows). WINDOW must be a live window.  Unless WINDOW already is the selected window, its buffer becomes the current buffer (see Buffers and Windows).  The return value is WINDOW.

     By default, this function also moves WINDOW's selected buffer to the front of the buffer list (see The Buffer List), and makes WINDOW the most recently selected window.  However, if the optional argument NORECORD is non-nil, these additional actions are omitted.

The sequence of calls to select-window with a non-nil NORECORD argument determines an ordering of windows by their selection time.  The function get-lru-window can be used to retrieve the least recently selected live window (see Cyclic Window Ordering).

 -- Macro: save-selected-window forms...
     This macro records the selected frame, as well as the selected window of each frame, executes FORMS in sequence, then restores the earlier selected frame and windows.  It also saves and restores the current buffer.  It returns the value of the last form in FORMS.

     This macro does not save or restore anything about the sizes, arrangement or contents of windows; therefore, if FORMS change them, the change persists.  If the previously selected window of some frame is no longer live at the time of exit from FORMS, that frame's selected window is left alone.  If the previously selected window is no longer live, then whatever window is selected at the end of FORMS remains selected.  The current buffer is restored if and only if it is still live when exiting FORMS.

     This macro changes neither the ordering of recently selected windows nor the buffer list.

 -- Macro: with-selected-window window forms...
     This macro selects WINDOW, executes FORMS in sequence, then restores the previously selected window and current buffer.  The ordering of recently selected windows and the buffer list remain unchanged unless you deliberately change them within FORMS, for example, by calling select-window with argument NORECORD nil.

     The order of recently selected windows and the buffer list are not changed by this macro.

 -- Function: frame-selected-window &optional frame
     This function returns the window on FRAME that is selected within that frame.  FRAME should be a live frame; if omitted or nil, it defaults to the selected frame.

 -- Function: set-frame-selected-window frame window &optional norecord
     This function makes window the window selected within the frame FRAME.  FRAME should be a live frame; if omitted or nil, it defaults to the selected frame.  WINDOW should be a live window; if omitted or nil, it defaults to the selected window.

     If FRAME is the selected frame, this makes WINDOW the selected window.

     If the optional argument NORECORD is non-nil, this function does not alter the list of most recently selected windows, nor the buffer list.

Cyclic Ordering of Windows
==========================

When you use the command C-x o (other-window) to select some other window, it moves through live windows in a specific order. For any given configuration of windows, this order never varies.  It is called the cyclic ordering of windows.

The ordering is determined by a depth-first traversal of the frame's window tree, retrieving the live windows which are the leaf nodes of the tree (see Windows and Frames).  If the minibuffer is active, the minibuffer window is included too.  The ordering is cyclic, so the last window in the sequence is followed by the first one.

 -- Function: next-window &optional window minibuf all-frames
     This function returns a live window, the one following WINDOW in the cyclic ordering of windows.  WINDOW should be a live window; if omitted or nil, it defaults to the selected window.

     The optional argument MINIBUF specifies whether minibuffer windows shall be included in the cyclic ordering.  Normally, when MINIBUF is nil, a minibuffer window is included only if it is currently ``active''; this matches the behavior of C-x o.  (Note that a minibuffer window is active as long as its minibuffer is in use; see Minibuffers).

     If MINIBUF is t, the cyclic ordering includes all minibuffer windows.  If MINIBUF is neither t nor nil, minibuffer windows are not included even if they are active.

     The optional argument ALL-FRAMES specifies which frames to consider:

       * nil means to consider windows on WINDOW's frame.  If the minibuffer window is considered (as specified by the MINIBUF argument), then frames that share the minibuffer window are considered too.

       * t means to consider windows on all existing frames.

       * visible means to consider windows on all visible frames.

       * 0 means to consider windows on all visible or iconified frames.

       * A frame means to consider windows on that specific frame.

       * Anything else means to consider windows on WINDOW's frame, and no others.

     If more than one frame is considered, the cyclic ordering is obtained by appending the orderings for those frames, in the same order as the list of all live frames (see Finding All Frames).

 -- Function: previous-window &optional window minibuf all-frames
     This function returns a live window, the one preceding WINDOW in the cyclic ordering of windows.  The other arguments are handled like in next-window.

 -- Command: other-window count &optional all-frames
     This function selects a live window, one COUNT places from the selected window in the cyclic ordering of windows.  If COUNT is a positive number, it skips COUNT windows forwards; if COUNT is negative, it skips -COUNT windows backwards; if COUNT is zero, that simply re-selects the selected window.  When called interactively, COUNT is the numeric prefix argument.

     The optional argument ALL-FRAMES has the same meaning as in next-window, like a nil MINIBUF argument to next-window.

     This function does not select a window that has a non-nil no-other-window window parameter (see Window Parameters).

 -- Function: walk-windows fun &optional minibuf all-frames
     This function calls the function FUN once for each live window, with the window as the argument.

     It follows the cyclic ordering of windows.  The optional arguments MINIBUF and ALL-FRAMES specify the set of windows included; these have the same arguments as in next-window.  If ALL-FRAMES specifies a frame, the first window walked is the first window on that frame (the one returned by frame-first-window), not necessarily the selected window.

     If FUN changes the window configuration by splitting or deleting windows, that does not alter the set of windows walked, which is determined prior to calling FUN for the first time.

 -- Function: one-window-p &optional no-mini all-frames
     This function returns t if the selected window is the only live window, and nil otherwise.

     If the minibuffer window is active, it is normally considered (so that this function returns nil).  However, if the optional argument NO-MINI is non-nil, the minibuffer window is ignored even if active.  The optional argument ALL-FRAMES has the same meaning as for next-window.

The following functions return a window which satisfies some criterion, without selecting it:

 -- Function: get-lru-window &optional all-frames dedicated
     This function returns a live window which is heuristically the ``least recently used'' window.  The optional argument ALL-FRAMES has the same meaning as in next-window.

     If any full-width windows are present, only those windows are considered.  The selected window is never returned, unless it is the only candidate.  A minibuffer window is never a candidate.  A dedicated window (see Dedicated Windows) is never a candidate unless the optional argument DEDICATED is non-nil.

 -- Function: get-largest-window &optional all-frames dedicated
     This function returns the window with the largest area (height times width).  A minibuffer window is never a candidate.  A dedicated window (see Dedicated Windows) is never a candidate unless the optional argument DEDICATED is non-nil.

     If there are two candidate windows of the same size, this function prefers the one that comes first in the cyclic ordering of windows, starting from the selected window.

     The optional argument ALL-FRAMES specifies the windows to search, and has the same meaning as in next-window.

 -- Function: get-window-with-predicate predicate &optional minibuf all-frames default
     This function calls the function PREDICATE for each of the windows in the cyclic order of windows in turn, passing it the window as an argument.  If the predicate returns non-nil for any window, this function stops and returns that window.  If no such window is found, the return value is DEFAULT (which defaults to nil).

     The optional arguments MINIBUF and ALL-FRAMES specify the windows to search, and have the same meanings as in next-window.

Buffers and Windows
===================

This section describes low-level functions for examining and setting the contents of windows.  See Switching Buffers, for higher-level functions for displaying a specific buffer in a window.

 -- Function: window-buffer &optional window
     This function returns the buffer that WINDOW is displaying.  If WINDOW is omitted or nil it defaults to the selected window.  If WINDOW is an internal window, this function returns nil.

 -- Function: set-window-buffer window buffer-or-name &optional keep-margins
     This function makes WINDOW display BUFFER-OR-NAME. WINDOW should be a live window; if nil, it defaults to the selected window.  BUFFER-OR-NAME should be a buffer, or the name of an existing buffer.  This function does not change which window is selected, nor does it directly change which buffer is current (see Current Buffer).  Its return value is nil.

     If WINDOW is strongly dedicated to a buffer and BUFFER-OR-NAME does not specify that buffer, this function signals an error.  See Dedicated Windows.

     By default, this function resets WINDOW's position, display margins, fringe widths, and scroll bar settings, based on the local variables in the specified buffer.  However, if the optional argument KEEP-MARGINS is non-nil, it leaves the display margins and fringe widths unchanged.

     When writing an application, you should normally use the higher-level functions described in Switching Buffers, instead of calling set-window-buffer directly.

     This function runs window-scroll-functions, followed by window-configuration-change-hook.  See Window Hooks.

 -- Variable: buffer-display-count
     This buffer-local variable records the number of times a buffer has been displayed in a window.  It is incremented each time set-window-buffer is called for the buffer.

 -- Variable: buffer-display-time
     This buffer-local variable records the time at which a buffer was last displayed in a window.  The value is nil if the buffer has never been displayed.  It is updated each time set-window-buffer is called for the buffer, with the value returned by current-time (see Time of Day).

 -- Function: get-buffer-window &optional buffer-or-name all-frames
     This function returns the first window displaying BUFFER-OR-NAME in the cyclic ordering of windows, starting from the selected window (see Cyclic Window Ordering).  If no such window exists, the return value is nil.

     BUFFER-OR-NAME should be a buffer or the name of a buffer; if omitted or nil, it defaults to the current buffer.  The optional argument ALL-FRAMES specifies which windows to consider:

       * t means consider windows on all existing frames.

       * visible means consider windows on all visible frames.

       * 0 means consider windows on all visible or iconified frames.

       * A frame means consider windows on that frame only.

       * Any other value means consider windows on the selected frame.

     Note that these meanings differ slightly from those of the ALL-FRAMES argument to next-window (see Cyclic Window Ordering).  This function may be changed in a future version of Emacs to eliminate this discrepancy.

 -- Function: get-buffer-window-list &optional buffer-or-name minibuf all-frames
     This function returns a list of all windows currently displaying BUFFER-OR-NAME.  BUFFER-OR-NAME should be a buffer or the name of an existing buffer.  If omitted or nil, it defaults to the current buffer.

     The arguments MINIBUF and ALL-FRAMES have the same meanings as in the function next-window (see Cyclic Window Ordering).  Note that the ALL-FRAMES argument does not behave exactly like in get-buffer-window.

 -- Command: replace-buffer-in-windows &optional buffer-or-name
     This command replaces BUFFER-OR-NAME with some other buffer, in all windows displaying it.  BUFFER-OR-NAME should be a buffer, or the name of an existing buffer; if omitted or nil, it defaults to the current buffer.

     The replacement buffer in each window is chosen via switch-to-prev-buffer (see Window History).  Any dedicated window displaying BUFFER-OR-NAME is deleted (see Dedicated Windows), unless it is the only window on its frame---if it is the only window, and that frame is not the only frame on its terminal, the frame is ``dismissed'' by calling the function specified by frame-auto-hide-function (see Quitting Windows).  If the dedicated window is the only window on the only frame on its terminal, the buffer is replaced anyway.

Switching to a Buffer in a Window
=================================

This section describes high-level functions for switching to a specified buffer in some window.

Do not use these functions to make a buffer temporarily current just so a Lisp program can access or modify it.  They have side-effects, such as changing window histories (see Window History), which will surprise the user if used that way.  If you want to make a buffer current to modify it in Lisp, use with-current-buffer, save-current-buffer, or set-buffer.  See Current Buffer.

 -- Command: switch-to-buffer buffer-or-name &optional norecord force-same-window
     This function displays BUFFER-OR-NAME in the selected window, and makes it the current buffer.  (In contrast, set-buffer makes the buffer current but does not display it; see Current Buffer).  It is often used interactively (as the binding of C-x b), as well as in Lisp programs.  The return value is the buffer switched to.

     If BUFFER-OR-NAME is nil, it defaults to the buffer returned by other-buffer (see The Buffer List).  If BUFFER-OR-NAME is a string that is not the name of any existing buffer, this function creates a new buffer with that name; the new buffer's major mode is determined by the variable major-mode (see Major Modes).

     Normally the specified buffer is put at the front of the buffer list---both the global buffer list and the selected frame's buffer list (see The Buffer List).  However, this is not done if the optional argument NORECORD is non-nil.

     If this function is unable to display the buffer in the selected window---usually because the selected window is a minibuffer window or is strongly dedicated to its buffer (see Dedicated Windows)---then it normally tries to display the buffer in some other window, in the manner of pop-to-buffer (see below).  However, if the optional argument FORCE-SAME-WINDOW is non-nil, it signals an error instead.

The next two functions are similar to switch-to-buffer, except for the described features.

 -- Command: switch-to-buffer-other-window buffer-or-name &optional norecord
     This function makes the buffer specified by BUFFER-OR-NAME current and displays it in some window other than the selected window. It uses the function pop-to-buffer internally (see below).

     If the selected window already displays the specified buffer, it continues to do so, but another window is nonetheless found to display it as well.

     The BUFFER-OR-NAME and NORECORD arguments have the same meanings as in switch-to-buffer.

 -- Command: switch-to-buffer-other-frame buffer-or-name &optional norecord
     This function makes the buffer specified by BUFFER-OR-NAME current and displays it, usually in a new frame.  It uses the function pop-to-buffer (see below).

     If the specified buffer is already displayed in another window, in any frame on the current terminal, this switches to that window instead of creating a new frame.  However, the selected window is never used for this.

     The BUFFER-OR-NAME and NORECORD arguments have the same meanings as in switch-to-buffer.

The above commands use the function pop-to-buffer, which flexibly displays a buffer in some window and selects that window for editing.  In turn, pop-to-buffer uses display-buffer for displaying the buffer.  Hence, all the variables affecting display-buffer will affect it as well.  See Choosing Window, for the documentation of display-buffer.

 -- Function: pop-to-buffer buffer-or-name &optional action norecord
     This function makes BUFFER-OR-NAME the current buffer and displays it in some window, preferably not the window previously selected.  It then selects the displaying window.  If that window is on a different graphical frame, that frame is given input focus if possible (see Input Focus).  The return value is the buffer that was switched to.

     If BUFFER-OR-NAME is nil, it defaults to the buffer returned by other-buffer (see The Buffer List).  If BUFFER-OR-NAME is a string that is not the name of any existing buffer, this function creates a new buffer with that name; the new buffer's major mode is determined by the variable major-mode (see Major Modes).

     If ACTION is non-nil, it should be a display action to pass to display-buffer (see Choosing Window). Alternatively, a non-nil, non-list value means to pop to a window other than the selected one---even if the buffer is already displayed in the selected window.

     Like switch-to-buffer, this function updates the buffer list unless NORECORD is non-nil.

Choosing a Window for Display
=============================

The command display-buffer flexibly chooses a window for display, and displays a specified buffer in that window.  It can be called interactively, via the key binding C-x 4 C-o.  It is also used as a subroutine by many functions and commands, including switch-to-buffer and pop-to-buffer (see Switching Buffers).

This command performs several complex steps to find a window to display in.  These steps are described by means of display actions, which have the form (FUNCTION . ALIST). Here, FUNCTION is either a function or a list of functions, which we refer to as action functions; ALIST is an association list, which we refer to as action alists.

An action function accepts two arguments: the buffer to display and an action alist.  It attempts to display the buffer in some window, picking or creating a window according to its own criteria.  If successful, it returns the window; otherwise, it returns nil. See Display Action Functions, for a list of predefined action functions.

display-buffer works by combining display actions from several sources, and calling the action functions in turn, until one of them manages to display the buffer and returns a non-nil value.

 -- Command: display-buffer buffer-or-name &optional action frame
     This command makes BUFFER-OR-NAME appear in some window, without selecting the window or making the buffer current.  The argument BUFFER-OR-NAME must be a buffer or the name of an existing buffer.  The return value is the window chosen to display the buffer.

     The optional argument ACTION, if non-nil, should normally be a display action (described above).  display-buffer builds a list of action functions and an action alist, by consolidating display actions from the following sources (in order):

       * The variable display-buffer-overriding-action.

       * The user option display-buffer-alist.

       * A special action for handling special-display-buffer-names and special-display-regexps, if either of those variables is non-nil.  See Choosing Window Options.

       * The ACTION argument.

       * The user option display-buffer-base-action.

       * The constant display-buffer-fallback-action.

     Each action function is called in turn, passing the buffer as the first argument and the combined action alist as the second argument, until one of the functions returns non-nil.

     The argument ACTION can also have a non-nil, non-list value.  This has the special meaning that the buffer should be displayed in a window other than the selected one, even if the selected window is already displaying it.  If called interactively with a prefix argument, ACTION is t.

     The optional argument FRAME, if non-nil, specifies which frames to check when deciding whether the buffer is already displayed. It is equivalent to adding an element (reusable-frames . FRAME) to the action alist of ACTION.  See Display Action Functions.

 -- Variable: display-buffer-overriding-action
     The value of this variable should be a display action, which is treated with the highest priority by display-buffer.  The default value is empty, i.e. (nil . nil).

 -- User Option: display-buffer-alist
     The value of this option is an alist mapping regular expressions to display actions.  If the name of the buffer passed to display-buffer matches a regular expression in this alist, then display-buffer uses the corresponding display action.

 -- User Option: display-buffer-base-action
     The value of this option should be a display action.  This option can be used to define a ``standard'' display action for calls to display-buffer.

 -- Constant: display-buffer-fallback-action
     This display action specifies the fallback behavior for display-buffer if no other display actions are given.

Action Functions for display-buffer
===================================

The following basic action functions are defined in Emacs.  Each of these functions takes two arguments: BUFFER, the buffer to display, and ALIST, an action alist.  Each action function returns the window if it succeeds, and nil if it fails.

 -- Function: display-buffer-same-window buffer alist
     This function tries to display BUFFER in the selected window. It fails if the selected window is a minibuffer window or is dedicated to another buffer (see Dedicated Windows).  It also fails if ALIST has a non-nil inhibit-same-window entry.

 -- Function: display-buffer-reuse-window buffer alist
     This function tries to ``display'' BUFFER by finding a window that is already displaying it.

     If ALIST has a non-nil inhibit-same-window entry, the selected window is not eligible for reuse.  If ALIST contains a reusable-frames entry, its value determines which frames to search for a reusable window:

       * nil means consider windows on the selected frame. (Actually, the last non-minibuffer frame.)

       * t means consider windows on all frames.

       * visible means consider windows on all visible frames.

       * 0 means consider windows on all visible or iconified frames.

       * A frame means consider windows on that frame only.

     If ALIST contains no reusable-frames entry, this function normally searches just the selected frame; however, if either the variable display-buffer-reuse-frames or the variable pop-up-frames is non-nil, it searches all frames on the current terminal.  See Choosing Window Options.

     If this function chooses a window on another frame, it makes that frame visible and raises it if necessary.

 -- Function: display-buffer-pop-up-frame buffer alist
     This function creates a new frame, and displays the buffer in that frame's window.  It actually performs the frame creation by calling the function specified in pop-up-frame-function (see Choosing Window Options).

 -- Function: display-buffer-pop-up-window buffer alist
     This function tries to display BUFFER by splitting the largest or least recently-used window (typically one on the selected frame). It actually performs the split by calling the function specified in split-window-preferred-function (see Choosing Window Options).

     It can fail if no window splitting can be performed for some reason (e.g. if there is just one frame and it has an unsplittable frame parameter; see Buffer Parameters).

 -- Function: display-buffer-use-some-window buffer alist
     This function tries to display BUFFER by choosing an existing window and displaying the buffer in that window.  It can fail if all windows are dedicated to another buffer (see Dedicated Windows).

Additional Options for Displaying Buffers
=========================================

The behavior of the standard display actions of display-buffer (see Choosing Window) can be modified by a variety of user options.

 -- User Option: display-buffer-reuse-frames
     If the value of this variable is non-nil, display-buffer may search all frames on the current terminal when looking for a window already displaying the specified buffer.  The default is nil.  This variable is consulted by the action function display-buffer-reuse-window (see Display Action Functions).

 -- User Option: pop-up-windows
     If the value of this variable is non-nil, display-buffer is allowed to split an existing window to make a new window for displaying in.  This is the default.

     This variable is provided mainly for backward compatibility.  It is obeyed by display-buffer via a special mechanism in display-buffer-fallback-action, which only calls the action function display-buffer-pop-up-window (see Display Action Functions) when the value is nil.  It is not consulted by display-buffer-pop-up-window itself, which the user may specify directly in display-buffer-alist etc.

 -- User Option: split-window-preferred-function
     This variable specifies a function for splitting a window, in order to make a new window for displaying a buffer.  It is used by the display-buffer-pop-up-window action function to actually split the window (see Display Action Functions).

     The default value is split-window-sensibly, which is documented below.  The value must be a function that takes one argument, a window, and return either a new window (which is used to display the desired buffer) or nil (which means the splitting failed).

 -- Function: split-window-sensibly window
     This function tries to split window, and return the newly created window.  If window cannot be split, it returns nil.

     This function obeys the usual rules that determine when a window may be split (see Splitting Windows).  It first tries to split by placing the new window below, subject to the restriction imposed by split-height-threshold (see below) in addition to any other restrictions.  If that fails, it tries to split by placing the new window to the right, subject to split-width-threshold (see below).  If that fails, and the window is the only window on its frame, this function again tries to split and place the new window below, disregarding split-height-threshold.  If this fails as well, this function gives up and returns nil.

 -- User Option: split-height-threshold
     This variable, used by split-window-sensibly, specifies whether to split the window placing the new window below.  If it is an integer, that means to split only if the original window has at least that many lines.  If it is nil, that means not to split this way.

 -- User Option: split-width-threshold
     This variable, used by split-window-sensibly, specifies whether to split the window placing the new window to the right.  If the value is an integer, that means to split only if the original window has at least that many columns.  If the value is nil, that means not to split this way.

 -- User Option: pop-up-frames
     If the value of this variable is non-nil, that means display-buffer may display buffers by making new frames.  The default is nil.

     A non-nil value also means that when display-buffer is looking for a window already displaying BUFFER-OR-NAME, it can search any visible or iconified frame, not just the selected frame.

     This variable is provided mainly for backward compatibility.  It is obeyed by display-buffer via a special mechanism in display-buffer-fallback-action, which calls the action function display-buffer-pop-up-frame (see Display Action Functions) if the value is non-nil.  (This is done before attempting to split a window.)  This variable is not consulted by display-buffer-pop-up-frame itself, which the user may specify directly in display-buffer-alist etc.

 -- User Option: pop-up-frame-function
     This variable specifies a function for creating a new frame, in order to make a new window for displaying a buffer.  It is used by the display-buffer-pop-up-frame action function (see Display Action Functions).

     The value should be a function that takes no arguments and returns a frame, or nil if no frame could be created.  The default value is a function that creates a frame using the parameters specified by pop-up-frame-alist (see below).

 -- User Option: pop-up-frame-alist
     This variable holds an alist of frame parameters (see Frame Parameters), which is used by the default function in pop-up-frame-function to make a new frame.  The default is nil.

 -- User Option: special-display-buffer-names
     A list of buffer names identifying buffers that should be displayed specially.  If the name of BUFFER-OR-NAME is in this list, display-buffer handles the buffer specially.  By default, special display means to give the buffer a dedicated frame.

     If an element is a list, instead of a string, then the CAR of that list is the buffer name, and the rest of that list says how to create the frame.  There are two possibilities for the rest of that list (its CDR): It can be an alist, specifying frame parameters, or it can contain a function and arguments to give to it.  (The function's first argument is always the buffer to be displayed; the arguments from the list come after that.)

     For example:

          (("myfile" (minibuffer) (menu-bar-lines . 0)))

     specifies to display a buffer named myfile in a dedicated frame with specified minibuffer and menu-bar-lines parameters.

     The list of frame parameters can also use the phony frame parameters same-frame and same-window.  If the specified frame parameters include (same-window . VALUE) and VALUE is non-nil, that means to display the buffer in the current selected window.  Otherwise, if they include (same-frame . VALUE) and VALUE is non-nil, that means to display the buffer in a new window in the currently selected frame.

 -- User Option: special-display-regexps
     A list of regular expressions specifying buffers that should be displayed specially.  If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer specially.  By default, special display means to give the buffer a dedicated frame.

     If an element is a list, instead of a string, then the CAR of the list is the regular expression, and the rest of the list says how to create the frame.  See special-display-buffer-names above.

 -- Function: special-display-p buffer-name
     This function returns non-nil if displaying a buffer named BUFFER-NAME with display-buffer would create a special frame.  The value is t if it would use the default frame parameters, or else the specified list of frame parameters.

 -- User Option: special-display-function
     This variable holds the function to call to display a buffer specially. It receives the buffer as an argument, and should return the window in which it is displayed.  The default value of this variable is special-display-popup-frame, see below.

 -- Function: special-display-popup-frame buffer &optional args
     This function tries to make BUFFER visible in a frame of its own. If BUFFER is already displayed in some window, it makes that window's frame visible and raises it.  Otherwise, it creates a frame that is dedicated to BUFFER.  The return value is the window used to display BUFFER.

     If ARGS is an alist, it specifies frame parameters for the new frame.  If ARGS is a list whose CAR is a symbol, then (car ARGS) is called as a function to actually create and set up the frame; it is called with BUFFER as first argument, and (cdr ARGS) as additional arguments.

     This function always uses an existing window displaying BUFFER, whether or not it is in a frame of its own; but if you set up the above variables in your init file, before BUFFER was created, then presumably the window was previously made by this function.

 -- User Option: special-display-frame-alist
     This variable holds frame parameters for special-display-popup-frame to use when it creates a frame.

 -- User Option: same-window-buffer-names
     A list of buffer names for buffers that should be displayed in the selected window.  If the buffer's name is in this list, display-buffer handles the buffer by switching to it in the selected window.

 -- User Option: same-window-regexps
     A list of regular expressions that specify buffers that should be displayed in the selected window.  If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer by switching to it in the selected window.

 -- Function: same-window-p buffer-name
     This function returns t if displaying a buffer named BUFFER-NAME with display-buffer would put it in the selected window.

 -- User Option: display-buffer-function
     This variable is the most flexible way to customize the behavior of display-buffer.  If it is non-nil, it should be a function that display-buffer calls to do the work.  The function should accept two arguments, the first two arguments that display-buffer received.  It should choose or create a window, display the specified buffer in it, and then return the window.

     This variable takes precedence over all the other options described above.

Window History
==============

Each window remembers the buffers it has displayed earlier and the order in which these buffers have been removed from it.  This history is used, for example, by replace-buffer-in-windows (see Buffers and Windows).  This list is automatically maintained by Emacs, but you can use the following functions to explicitly inspect or alter it:

 -- Function: window-prev-buffers &optional window
     This function returns a list specifying the previous contents of WINDOW, which should be a live window and defaults to the selected window.

     Each list element has the form (BUFFER WINDOW-START WINDOW-POS), where BUFFER is a buffer previously shown in the window, WINDOW-START is the window start position when that buffer was last shown, and WINDOW-POS is the point position when that buffer was last shown.

     The list is ordered so that earlier elements correspond to more recently-shown buffers, and the first element usually corresponds to the buffer most recently removed from the window.

 -- Function: set-window-prev-buffers window prev-buffers
     This function sets WINDOW's previous buffers to the value of PREV-BUFFERS.  The argument WINDOW must be a live window and defaults to the selected one.  The argument PREV-BUFFERS should be a list of the same form as that returned by window-prev-buffers.

In addition, each buffer maintains a list of next buffers, which is a list of buffers re-shown by switch-to-prev-buffer (see below).  This list is mainly used by switch-to-prev-buffer and switch-to-next-buffer for choosing buffers to switch to.

 -- Function: window-next-buffers &optional window
     This function returns the list of buffers recently re-shown in WINDOW via switch-to-prev-buffer.  The WINDOW argument must denote a live window or nil (meaning the selected window).

 -- Function: set-window-next-buffers window next-buffers
     This function sets the next buffer list of WINDOW to NEXT-BUFFERS.  The WINDOW argument should be a live window or nil (meaning the selected window).  The argument NEXT-BUFFERS should be a list of buffers.

The following commands can be used to cycle through the global buffer list, much like bury-buffer and unbury-buffer.  However, they cycle according to the specified window's history list, rather than the global buffer list.  In addition, they restore window-specific window start and point positions, and may show a buffer even if it is already shown in another window.  The switch-to-prev-buffer command, in particular, is used by replace-buffer-in-windows, bury-buffer and quit-window to find a replacement buffer for a window.

 -- Command: switch-to-prev-buffer &optional window bury-or-kill
     This command displays the previous buffer in WINDOW.  The argument WINDOW should be a live window or nil (meaning the selected window).  If the optional argument BURY-OR-KILL is non-nil, this means that the buffer currently shown in WINDOW is about to be buried or killed and consequently shall not be switched to in future invocations of this command.

     The previous buffer is usually the buffer shown before the buffer currently shown in WINDOW.  However, a buffer that has been buried or killed or has been already shown by a recent invocation of switch-to-prev-buffer does not qualify as previous buffer.

     If repeated invocations of this command have already shown all buffers previously shown in WINDOW, further invocations will show buffers from the buffer list of the frame WINDOW appears on (see The Buffer List) trying to skip buffers that are already shown in another window on that frame.

 -- Command: switch-to-next-buffer &optional window
     This command switches to the next buffer in WINDOW thus undoing the effect of the last switch-to-prev-buffer command in WINDOW.  The argument WINDOW must be a live window and defaults to the selected one.

     If there is no recent invocation of a switch-to-prev-buffer that can be undone, this function tries to show a buffer from the buffer list of the frame WINDOW appears on (see The Buffer List).

By default switch-to-prev-buffer and switch-to-next-buffer can switch to a buffer that is already shown in another window on the same frame.  The following option can be used to override that behavior.

 -- User Option: switch-to-visible-buffer
     If this variable is non-nil, switch-to-prev-buffer and switch-to-next-buffer may switch to a buffer that is already visible on the same frame, provided the buffer was shown in the argument window before.  If it's nil, switch-to-prev-buffer and switch-to-next-buffer always try to avoid switching to a buffer that is already visible in another window on the same frame.

Dedicated Windows
=================

Functions for displaying a buffer can be told to not use specific windows by marking these windows as dedicated to their buffers. display-buffer (see Choosing Window) never uses a dedicated window for displaying another buffer in it.  get-lru-window and get-largest-window (see Selecting Windows) do not consider dedicated windows as candidates when their DEDICATED argument is non-nil.  The behavior of set-window-buffer (see Buffers and Windows) with respect to dedicated windows is slightly different, see below.

When delete-windows-on (see Deleting Windows) wants to delete a dedicated window and that window is the only window on its frame, it deletes the window's frame too, provided there are other frames left.  replace-buffer-in-windows (see Switching Buffers) tries to delete all dedicated windows showing its buffer argument.  When such a window is the only window on its frame, that frame is deleted, provided there are other frames left.  If there are no more frames left, some other buffer is displayed in the window, and the window is marked as non-dedicated.

When you kill a buffer (see Killing Buffers) displayed in a dedicated window, any such window usually gets deleted too, since kill-buffer calls replace-buffer-in-windows for cleaning up windows.  Burying a buffer (see The Buffer List) deletes the selected window if it is dedicated to that buffer.  If, however, that window is the only window on its frame, bury-buffer displays another buffer in it and iconifies the frame.

 -- Function: window-dedicated-p &optional window
     This function returns non-nil if WINDOW is dedicated to its buffer and nil otherwise.  More precisely, the return value is the value assigned by the last call of set-window-dedicated-p for WINDOW or nil if that function was never called with WINDOW as its argument.  The default for WINDOW is the selected window.

 -- Function: set-window-dedicated-p window flag
     This function marks WINDOW as dedicated to its buffer if FLAG is non-nil, and non-dedicated otherwise.

     As a special case, if FLAG is t, WINDOW becomes strongly dedicated to its buffer.  set-window-buffer signals an error when the window it acts upon is strongly dedicated to its buffer and does not already display the buffer it is asked to display.  Other functions do not treat t differently from any non-nil value.

Quitting Windows
================

When you want to get rid of a window used for displaying a buffer you can call delete-window or delete-windows-on (see Deleting Windows) to remove that window from its frame.  If the buffer is shown on a separate frame, you might want to call delete-frame (see Deleting Frames) instead.  If, on the other hand, a window has been reused for displaying the buffer, you might prefer showing the buffer previously shown in that window by calling the function switch-to-prev-buffer (see Window History). Finally, you might want to either bury (see The Buffer List) or kill (see Killing Buffers) the window's buffer.

The following function uses information on how the window for displaying the buffer was obtained in the first place thus attempting to automatize the above decisions for you.

 -- Command: quit-window &optional kill window
     This command quits WINDOW and buries its buffer.  The argument WINDOW must be a live window and defaults to the selected one. With prefix argument KILL non-nil, it kills the buffer instead of burying it.

     Quitting WINDOW means to proceed as follows: If WINDOW was created specially for displaying its current buffer, delete WINDOW provided its frame contains at least one other live window.  If WINDOW is the only window on its frame and there are other frames on the frame's terminal, the value of KILL determines how to proceed with the window.  If KILL is nil, the fate of the frame is determined by calling frame-auto-hide-function (see below) with that frame as sole argument.  If KILL is non-nil, the frame is deleted unconditionally.

     If WINDOW was reused for displaying its buffer, this command tries to display the buffer previously shown in it.  It also tries to restore the window start (see Window Start and End) and point (see Window Point) positions of the previously shown buffer.  If, in addition, the current buffer was temporarily resized, this command will also try to restore the original height of WINDOW.

     The three cases described so far require that the buffer shown in WINDOW is still the buffer displayed by the last buffer display function for this window.  If another buffer has been shown in the meantime or the buffer previously shown no longer exists, this command calls switch-to-prev-buffer (see Window History) to show some other buffer instead.

The function quit-window bases its decisions on information stored in WINDOW's quit-restore window parameter (see Window Parameters) and resets that parameter to nil after it's done.

The following option specifies how to deal with a frame containing just one window that shall be either quit or whose buffer shall be buried.

 -- User Option: frame-auto-hide-function
     The function specified by this option is called to automatically hide frames.  This function is called with one argument - a frame.

     The function specified here is called by bury-buffer (see The Buffer List) when the selected window is dedicated and shows the buffer that shall be buried.  It is also called by quit-window (see above) when the frame of the window that shall be quit has been specially created for displaying that window's buffer and the buffer shall be buried.

     The default is to call iconify-frame (see Visibility of Frames).  Alternatively, you may either specify delete-frame (see Deleting Frames) to remove the frame from its display, ignore to leave the frame unchanged, or any other function that can take a frame as its sole argument.

     Note that the function specified by this option is called if and only if there's at least one other frame on the terminal of the frame it's supposed to handle and that frame contains only one live window.

Windows and Point
=================

Each window has its own value of point (see Point), independent of the value of point in other windows displaying the same buffer.  This makes it useful to have multiple windows showing one buffer.

  * The window point is established when a window is first created; it is initialized from the buffer's point, or from the window point of another window opened on the buffer if such a window exists.

  * Selecting a window sets the value of point in its buffer from the window's value of point.  Conversely, deselecting a window sets the window's value of point from that of the buffer.  Thus, when you switch between windows that display a given buffer, the point value for the selected window is in effect in the buffer, while the point values for the other windows are stored in those windows.

  * As long as the selected window displays the current buffer, the window's point and the buffer's point always move together; they remain equal.

As far as the user is concerned, point is where the cursor is, and when the user switches to another buffer, the cursor jumps to the position of point in that buffer.

 -- Function: window-point &optional window
     This function returns the current position of point in WINDOW. For a nonselected window, this is the value point would have (in that window's buffer) if that window were selected.  The default for WINDOW is the selected window.

     When WINDOW is the selected window and its buffer is also the current buffer, the value returned is the same as point in that buffer. Strictly speaking, it would be more correct to return the ``top-level'' value of point, outside of any save-excursion forms.  But that value is hard to find.

 -- Function: set-window-point window position
     This function positions point in WINDOW at position POSITION in WINDOW's buffer.  It returns POSITION.

     If WINDOW is selected, and its buffer is current, this simply does goto-char.

 -- Variable: window-point-insertion-type
     This variable specifies the marker insertion type (see Marker Insertion Types) of window-point.  The default is nil, so window-point will stay behind text inserted there.

The Window Start and End Positions
==================================

Each window maintains a marker used to keep track of a buffer position that specifies where in the buffer display should start.  This position is called the display-start position of the window (or just the start).  The character after this position is the one that appears at the upper left corner of the window.  It is usually, but not inevitably, at the beginning of a text line.

After switching windows or buffers, and in some other cases, if the window start is in the middle of a line, Emacs adjusts the window start to the start of a line.  This prevents certain operations from leaving the window start at a meaningless point within a line.  This feature may interfere with testing some Lisp code by executing it using the commands of Lisp mode, because they trigger this readjustment.  To test such code, put it into a command and bind the command to a key.

 -- Function: window-start &optional window
     This function returns the display-start position of window WINDOW.  If WINDOW is nil, the selected window is used.  For example,

          (window-start)
               => 7058

     When you create a window, or display a different buffer in it, the display-start position is set to a display-start position recently used for the same buffer, or to point-min if the buffer doesn't have any.

     Redisplay updates the window-start position (if you have not specified it explicitly since the previous redisplay)---to make sure point appears on the screen.  Nothing except redisplay automatically changes the window-start position; if you move point, do not expect the window-start position to change in response until after the next redisplay.

     For a realistic example of using window-start, see the description of count-lines.  See Definition of count-lines.

 -- Function: window-end &optional window update
     This function returns the position where display of its buffer ends in WINDOW.  The default for WINDOW is the selected window.

     Simply changing the buffer text or moving point does not update the value that window-end returns.  The value is updated only when Emacs redisplays and redisplay completes without being preempted.

     If the last redisplay of WINDOW was preempted, and did not finish, Emacs does not know the position of the end of display in that window. In that case, this function returns nil.

     If UPDATE is non-nil, window-end always returns an up-to-date value for where display ends, based on the current window-start value.  If a previously saved value of that position is still valid, window-end returns that value; otherwise it computes the correct value by scanning the buffer text.

     Even if UPDATE is non-nil, window-end does not attempt to scroll the display if point has moved off the screen, the way real redisplay would do.  It does not alter the window-start value.  In effect, it reports where the displayed text will end if scrolling is not required.

 -- Function: set-window-start window position &optional noforce
     This function sets the display-start position of WINDOW to POSITION in WINDOW's buffer.  It returns POSITION.

     The display routines insist that the position of point be visible when a buffer is displayed.  Normally, they change the display-start position (that is, scroll the window) whenever necessary to make point visible. However, if you specify the start position with this function using nil for NOFORCE, it means you want display to start at POSITION even if that would put the location of point off the screen.  If this does place point off screen, the display routines move point to the left margin on the middle line in the window.

     For example, if point is 1 and you set the start of the window to 37, the start of the next line, point will be ``above'' the top of the window.  The display routines will automatically move point if it is still 1 when redisplay occurs.  Here is an example:

          ;; Here is what foo looks like before executing
          ;;   the set-window-start expression.

          ---------- Buffer: foo ----------
          -!-This is the contents of buffer foo.
          2
          3
          4
          5
          6
          ---------- Buffer: foo ----------

          (set-window-start
           (selected-window)
           (save-excursion
             (goto-char 1)
             (forward-line 1)
             (point)))
          => 37

          ;; Here is what foo looks like after executing
          ;;   the set-window-start expression.
          ---------- Buffer: foo ----------
          2
          3
          -!-4
          5
          6
          ---------- Buffer: foo ----------

     If NOFORCE is non-nil, and POSITION would place point off screen at the next redisplay, then redisplay computes a new window-start position that works well with point, and thus POSITION is not used.

 -- Function: pos-visible-in-window-p &optional position window partially
     This function returns non-nil if POSITION is within the range of text currently visible on the screen in WINDOW.  It returns nil if POSITION is scrolled vertically out of view. Locations that are partially obscured are not considered visible unless PARTIALLY is non-nil.  The argument POSITION defaults to the current position of point in WINDOW; WINDOW, to the selected window.  If POSITION is t, that means to check the last visible position in WINDOW.

     This function considers only vertical scrolling.  If POSITION is out of view only because WINDOW has been scrolled horizontally, pos-visible-in-window-p returns non-nil anyway. See Horizontal Scrolling.

     If POSITION is visible, pos-visible-in-window-p returns t if PARTIALLY is nil; if PARTIALLY is non-nil, and the character following POSITION is fully visible, it returns a list of the form (X Y), where X and Y are the pixel coordinates relative to the top left corner of the window; otherwise it returns an extended list of the form (X Y RTOP RBOT ROWH VPOS), where RTOP and RBOT specify the number of off-window pixels at the top and bottom of the row at POSITION, ROWH specifies the visible height of that row, and VPOS specifies the vertical position (zero-based row number) of that row.

     Here is an example:

          ;; If point is off the screen now, recenter it now.
          (or (pos-visible-in-window-p
               (point) (selected-window))
              (recenter 0))

 -- Function: window-line-height &optional line window
     This function returns the height of text line LINE in WINDOW.  If LINE is one of header-line or mode-line, window-line-height returns information about the corresponding line of the window.  Otherwise, LINE is a text line number starting from 0.  A negative number counts from the end of the window.  The default for LINE is the current line in WINDOW; the default for WINDOW is the selected window.

     If the display is not up to date, window-line-height returns nil.  In that case, pos-visible-in-window-p may be used to obtain related information.

     If there is no line corresponding to the specified LINE, window-line-height returns nil.  Otherwise, it returns a list (HEIGHT VPOS YPOS OFFBOT), where HEIGHT is the height in pixels of the visible part of the line, VPOS and YPOS are the vertical position in lines and pixels of the line relative to the top of the first text line, and OFFBOT is the number of off-window pixels at the bottom of the text line.  If there are off-window pixels at the top of the (first) text line, YPOS is negative.

Textual Scrolling
=================

Textual scrolling means moving the text up or down through a window.  It works by changing the window's display-start location.  It may also change the value of window-point to keep point on the screen (see Window Point).

The basic textual scrolling functions are scroll-up (which scrolls forward) and scroll-down (which scrolls backward).  In these function names, ``up'' and ``down'' refer to the direction of motion of the buffer text relative to the window.  Imagine that the text is written on a long roll of paper and that the scrolling commands move the paper up and down.  Thus, if you are looking at the middle of a buffer and repeatedly call scroll-down, you will eventually see the beginning of the buffer.

Some people have urged that the opposite convention be used: they imagine the window moving over text that remains in place, so that ``down'' commands take you to the end of the buffer.  This convention is consistent with fact that such a command is bound to a key named PageDown on modern keyboards.  We have not switched to this convention as that is likely to break existing Emacs Lisp code.

Textual scrolling functions (aside from scroll-other-window) have unpredictable results if the current buffer is not the one displayed in the selected window.  See Current Buffer.

If the window contains a row taller than the height of the window (for example in the presence of a large image), the scroll functions will adjust the window's vertical scroll position to scroll the partially visible row.  Lisp callers can disable this feature by binding the variable auto-window-vscroll to nil (see Vertical Scrolling).

 -- Command: scroll-up &optional count
     This function scrolls forward by COUNT lines in the selected window.

     If COUNT is negative, it scrolls backward instead.  If COUNT is nil (or omitted), the distance scrolled is next-screen-context-lines lines less than the height of the window's text area.

     If the selected window cannot be scrolled any further, this function signals an error.  Otherwise, it returns nil.

 -- Command: scroll-down &optional count
     This function scrolls backward by COUNT lines in the selected window.

     If COUNT is negative, it scrolls forward instead.  If COUNT is omitted or nil, the distance scrolled is next-screen-context-lines lines less than the height of the window's text area.

     If the selected window cannot be scrolled any further, this function signals an error.  Otherwise, it returns nil.

 -- Command: scroll-up-command &optional count
     This behaves like scroll-up, except that if the selected window cannot be scrolled any further and the value of the variable scroll-error-top-bottom is t, it tries to move to the end of the buffer instead.  If point is already there, it signals an error.

 -- Command: scroll-down-command &optional count
     This behaves like scroll-down, except that if the selected window cannot be scrolled any further and the value of the variable scroll-error-top-bottom is t, it tries to move to the beginning of the buffer instead.  If point is already there, it signals an error.

 -- Command: scroll-other-window &optional count
     This function scrolls the text in another window upward COUNT lines.  Negative values of COUNT, or nil, are handled as in scroll-up.

     You can specify which buffer to scroll by setting the variable other-window-scroll-buffer to a buffer.  If that buffer isn't already displayed, scroll-other-window displays it in some window.

     When the selected window is the minibuffer, the next window is normally the one at the top left corner.  You can specify a different window to scroll, when the minibuffer is selected, by setting the variable minibuffer-scroll-window.  This variable has no effect when any other window is selected.  When it is non-nil and the minibuffer is selected, it takes precedence over other-window-scroll-buffer.  See Definition of minibuffer-scroll-window.

     When the minibuffer is active, it is the next window if the selected window is the one at the bottom right corner.  In this case, scroll-other-window attempts to scroll the minibuffer.  If the minibuffer contains just one line, it has nowhere to scroll to, so the line reappears after the echo area momentarily displays the message Beginning of buffer.

 -- Variable: other-window-scroll-buffer
     If this variable is non-nil, it tells scroll-other-window which buffer's window to scroll.

 -- User Option: scroll-margin
     This option specifies the size of the scroll margin---a minimum number of lines between point and the top or bottom of a window.  Whenever point gets within this many lines of the top or bottom of the window, redisplay scrolls the text automatically (if possible) to move point out of the margin, closer to the center of the window.

 -- User Option: scroll-conservatively
     This variable controls how scrolling is done automatically when point moves off the screen (or into the scroll margin).  If the value is a positive integer N, then redisplay scrolls the text up to N lines in either direction, if that will bring point back into proper view.  This behavior is called conservative scrolling. Otherwise, scrolling happens in the usual way, under the control of other variables such as scroll-up-aggressively and scroll-down-aggressively.

     The default value is zero, which means that conservative scrolling never happens.

 -- User Option: scroll-down-aggressively
     The value of this variable should be either nil or a fraction F between 0 and 1.  If it is a fraction, that specifies where on the screen to put point when scrolling down.  More precisely, when a window scrolls down because point is above the window start, the new start position is chosen to put point F part of the window height from the top.  The larger F, the more aggressive the scrolling.

     A value of nil is equivalent to .5, since its effect is to center point.  This variable automatically becomes buffer-local when set in any fashion.

 -- User Option: scroll-up-aggressively
     Likewise, for scrolling up.  The value, F, specifies how far point should be placed from the bottom of the window; thus, as with scroll-up-aggressively, a larger value scrolls more aggressively.

 -- User Option: scroll-step
     This variable is an older variant of scroll-conservatively. The difference is that if its value is N, that permits scrolling only by precisely N lines, not a smaller number.  This feature does not work with scroll-margin.  The default value is zero.

 -- User Option: scroll-preserve-screen-position
     If this option is t, whenever a scrolling command moves point off-window, Emacs tries to adjust point to keep the cursor at its old vertical position in the window, rather than the window edge.

     If the value is non-nil and not t, Emacs adjusts point to keep the cursor at the same vertical position, even if the scrolling command didn't move point off-window.

     This option affects all scroll commands that have a non-nil scroll-command symbol property.

 -- User Option: next-screen-context-lines
     The value of this variable is the number of lines of continuity to retain when scrolling by full screens.  For example, scroll-up with an argument of nil scrolls so that this many lines at the bottom of the window appear instead at the top.  The default value is 2.

 -- User Option: scroll-error-top-bottom
     If this option is nil (the default), scroll-up-command and scroll-down-command simply signal an error when no more scrolling is possible.

     If the value is t, these commands instead move point to the beginning or end of the buffer (depending on scrolling direction); only if point is already on that position do they signal an error.

 -- Command: recenter &optional count
     This function scrolls the text in the selected window so that point is displayed at a specified vertical position within the window.  It does not ``move point'' with respect to the text.

     If COUNT is a non-negative number, that puts the line containing point COUNT lines down from the top of the window.  If COUNT is a negative number, then it counts upward from the bottom of the window, so that -1 stands for the last usable line in the window.  If COUNT is a non-nil list, then it stands for the line in the middle of the window.

     If COUNT is nil, recenter puts the line containing point in the middle of the window, then clears and redisplays the entire selected frame.

     When recenter is called interactively, COUNT is the raw prefix argument.  Thus, typing C-u as the prefix sets the COUNT to a non-nil list, while typing C-u 4 sets COUNT to 4, which positions the current line four lines from the top.

     With an argument of zero, recenter positions the current line at the top of the window.  This action is so handy that some people make a separate key binding to do this.  For example,

          (defun line-to-top-of-window ()
            "Scroll current line to top of window.
          Replaces three keystroke sequence C-u 0 C-l."
            (interactive)
            (recenter 0))

          (global-set-key [kp-multiply] 'line-to-top-of-window)

Vertical Fractional Scrolling
=============================

Vertical fractional scrolling means shifting text in a window up or down by a specified multiple or fraction of a line.  Each window has a vertical scroll position, which is a number, never less than zero.  It specifies how far to raise the contents of the window. Raising the window contents generally makes all or part of some lines disappear off the top, and all or part of some other lines appear at the bottom.  The usual value is zero.

The vertical scroll position is measured in units of the normal line height, which is the height of the default font.  Thus, if the value is .5, that means the window contents are scrolled up half the normal line height.  If it is 3.3, that means the window contents are scrolled up somewhat over three times the normal line height.

What fraction of a line the vertical scrolling covers, or how many lines, depends on what the lines contain.  A value of .5 could scroll a line whose height is very short off the screen, while a value of 3.3 could scroll just part of the way through a tall line or an image.

 -- Function: window-vscroll &optional window pixels-p
     This function returns the current vertical scroll position of WINDOW.  The default for WINDOW is the selected window. If PIXELS-P is non-nil, the return value is measured in pixels, rather than in units of the normal line height.

          (window-vscroll)
               => 0

 -- Function: set-window-vscroll window lines &optional pixels-p
     This function sets WINDOW's vertical scroll position to LINES.  If WINDOW is nil, the selected window is used.  The argument LINES should be zero or positive; if not, it is taken as zero.

     The actual vertical scroll position must always correspond to an integral number of pixels, so the value you specify is rounded accordingly.

     The return value is the result of this rounding.

          (set-window-vscroll (selected-window) 1.2)
               => 1.13

     If PIXELS-P is non-nil, LINES specifies a number of pixels.  In this case, the return value is LINES.

 -- Variable: auto-window-vscroll
     If this variable is non-nil, the line-move, scroll-up, and scroll-down functions will automatically modify the vertical scroll position to scroll through display rows that are taller than the height of the window, for example in the presence of large images.

Horizontal Scrolling
====================

Horizontal scrolling means shifting the image in the window left or right by a specified multiple of the normal character width.  Each window has a horizontal scroll position, which is a number, never less than zero.  It specifies how far to shift the contents left. Shifting the window contents left generally makes all or part of some characters disappear off the left, and all or part of some other characters appear at the right.  The usual value is zero.

The horizontal scroll position is measured in units of the normal character width, which is the width of space in the default font.  Thus, if the value is 5, that means the window contents are scrolled left by 5 times the normal character width.  How many characters actually disappear off to the left depends on their width, and could vary from line to line.

Because we read from side to side in the ``inner loop,'' and from top to bottom in the ``outer loop,'' the effect of horizontal scrolling is not like that of textual or vertical scrolling.  Textual scrolling involves selection of a portion of text to display, and vertical scrolling moves the window contents contiguously; but horizontal scrolling causes part of each line to go off screen.

Usually, no horizontal scrolling is in effect; then the leftmost column is at the left edge of the window.  In this state, scrolling to the right is meaningless, since there is no data to the left of the edge to be revealed by it; so this is not allowed.  Scrolling to the left is allowed; it scrolls the first columns of text off the edge of the window and can reveal additional columns on the right that were truncated before.  Once a window has a nonzero amount of leftward horizontal scrolling, you can scroll it back to the right, but only so far as to reduce the net horizontal scroll to zero.  There is no limit to how far left you can scroll, but eventually all the text will disappear off the left edge.

If auto-hscroll-mode is set, redisplay automatically alters the horizontal scrolling of a window as necessary to ensure that point is always visible.  However, you can still set the horizontal scrolling value explicitly.  The value you specify serves as a lower bound for automatic scrolling, i.e. automatic scrolling will not scroll a window to a column less than the specified one.

 -- Command: scroll-left &optional count set-minimum
     This function scrolls the selected window COUNT columns to the left (or to the right if COUNT is negative).  The default for COUNT is the window width, minus 2.

     The return value is the total amount of leftward horizontal scrolling in effect after the change---just like the value returned by window-hscroll (below).

     Once you scroll a window as far right as it can go, back to its normal position where the total leftward scrolling is zero, attempts to scroll any farther right have no effect.

     If SET-MINIMUM is non-nil, the new scroll amount becomes the lower bound for automatic scrolling; that is, automatic scrolling will not scroll a window to a column less than the value returned by this function.  Interactive calls pass non-nil for SET-MINIMUM.

 -- Command: scroll-right &optional count set-minimum
     This function scrolls the selected window COUNT columns to the right (or to the left if COUNT is negative).  The default for COUNT is the window width, minus 2.  Aside from the direction of scrolling, this works just like scroll-left.

 -- Function: window-hscroll &optional window
     This function returns the total leftward horizontal scrolling of WINDOW---the number of columns by which the text in WINDOW is scrolled left past the left margin.  The default for WINDOW is the selected window.

     The return value is never negative.  It is zero when no horizontal scrolling has been done in WINDOW (which is usually the case).

          (window-hscroll)
               => 0

          (scroll-left 5)
               => 5

          (window-hscroll)
               => 5

 -- Function: set-window-hscroll window columns
     This function sets horizontal scrolling of WINDOW.  The value of COLUMNS specifies the amount of scrolling, in terms of columns from the left margin.  The argument COLUMNS should be zero or positive; if not, it is taken as zero.  Fractional values of COLUMNS are not supported at present.

     Note that set-window-hscroll may appear not to work if you test it by evaluating a call with M-: in a simple way.  What happens is that the function sets the horizontal scroll value and returns, but then redisplay adjusts the horizontal scrolling to make point visible, and this overrides what the function did.  You can observe the function's effect if you call it while point is sufficiently far from the left margin that it will remain visible.

     The value returned is COLUMNS.

          (set-window-hscroll (selected-window) 10)
               => 10

Here is how you can determine whether a given position POSITION is off the screen due to horizontal scrolling:

     (defun hscroll-on-screen (window position)
       (save-excursion
         (goto-char position)
         (and
          (>= (- (current-column) (window-hscroll window)) 0)
          (< (- (current-column) (window-hscroll window))
             (window-width window)))))

Coordinates and Windows
=======================

This section describes functions that report the position of a window.  Most of these functions report positions relative to the window's frame.  In this case, the coordinate origin (0,0) lies near the upper left corner of the frame.  For technical reasons, on graphical displays the origin is not located at the exact corner of the graphical window as it appears on the screen.  If Emacs is built with the GTK+ toolkit, the origin is at the upper left corner of the frame area used for displaying Emacs windows, below the title-bar, GTK+ menu bar, and tool bar (since these are drawn by the window manager and/or GTK+, not by Emacs).  But if Emacs is not built with GTK+, the origin is at the upper left corner of the tool bar (since in this case Emacs itself draws the tool bar).  In both cases, the X and Y coordinates increase rightward and downward respectively.

Except where noted, X and Y coordinates are reported in integer character units, i.e. numbers of lines and columns respectively.  On a graphical display, each ``line'' and ``column'' corresponds to the height and width of a default character specified by the frame's default font.

 -- Function: window-edges &optional window
     This function returns a list of the edge coordinates of WINDOW. If WINDOW is omitted or nil, it defaults to the selected window.

     The return value has the form (LEFT TOP RIGHT BOTTOM).  These list elements are, respectively, the X coordinate of the leftmost column occupied by the window, the Y coordinate of the topmost row, the X coordinate one column to the right of the rightmost column, and the Y coordinate one row down from the bottommost row.

     Note that these are the actual outer edges of the window, including any header line, mode line, scroll bar, fringes, and display margins. On a text terminal, if the window has a neighbor on its right, its right edge includes the separator line between the window and its neighbor.

 -- Function: window-inside-edges &optional window
     This function is similar to window-edges, but the returned edge values are for the text area of the window.  They exclude any header line, mode line, scroll bar, fringes, display margins, and vertical separator.

 -- Function: window-top-line &optional window
     This function returns the Y coordinate of the topmost row of WINDOW, equivalent to the TOP entry in the list returned by window-edges.

 -- Function: window-left-column &optional window
     This function returns the X coordinate of the leftmost column of WINDOW, equivalent to the LEFT entry in the list returned by window-edges.

The following functions can be used to relate a set of frame-relative coordinates to a window:

 -- Function: window-at x y &optional frame
     This function returns the live window at the frame-relative coordinates X and Y, on frame FRAME.  If there is no window at that position, the return value is nil.  If FRAME is omitted or nil, it defaults to the selected frame.

 -- Function: coordinates-in-window-p coordinates window
     This function checks whether a window WINDOW occupies the frame-relative coordinates COORDINATES, and if so which part of the window that is.  WINDOW should be a live window. COORDINATES should be a cons cell of the form (X . Y), where X and Y are frame-relative coordinates.

     If there is no window at the specified position, the return value is nil .  Otherwise, the return value is one of the following:

     (RELX . RELY)
          The coordinates are inside WINDOW.  The numbers RELX and RELY are the equivalent window-relative coordinates for the specified position, counting from 0 at the top left corner of the window.

     mode-line
          The coordinates are in the mode line of WINDOW.

     header-line
          The coordinates are in the header line of WINDOW.

     vertical-line
          The coordinates are in the vertical line between WINDOW and its neighbor to the right.  This value occurs only if the window doesn't have a scroll bar; positions in a scroll bar are considered outside the window for these purposes.

     left-fringe
     right-fringe
          The coordinates are in the left or right fringe of the window.

     left-margin
     right-margin
          The coordinates are in the left or right margin of the window.

     nil
          The coordinates are not in any part of WINDOW.

     The function coordinates-in-window-p does not require a frame as argument because it always uses the frame that WINDOW is on.

The following functions return window positions in pixels, rather than character units.  Though mostly useful on graphical displays, they can also be called on text terminals, where the screen area of each text character is taken to be ``one pixel''.

 -- Function: window-pixel-edges &optional window
     This function returns a list of pixel coordinates for the edges of WINDOW.  If WINDOW is omitted or nil, it defaults to the selected window.

     The return value has the form (LEFT TOP RIGHT BOTTOM).  The list elements are, respectively, the X pixel coordinate of the left window edge, the Y pixel coordinate of the top edge, one more than the X pixel coordinate of the right edge, and one more than the Y pixel coordinate of the bottom edge.

 -- Function: window-inside-pixel-edges &optional window
     This function is like window-pixel-edges, except that it returns the pixel coordinates for the edges of the window's text area, rather than the pixel coordinates for the edges of the window itself. WINDOW must specify a live window.

The following functions return window positions in pixels, relative to the display screen rather than the frame:

 -- Function: window-absolute-pixel-edges &optional window
     This function is like window-pixel-edges, except that it returns the edge pixel coordinates relative to the top left corner of the display screen.

 -- Function: window-inside-absolute-pixel-edges &optional window
     This function is like window-inside-pixel-edges, except that it returns the edge pixel coordinates relative to the top left corner of the display screen.  WINDOW must specify a live window.

Window Configurations
=====================

A window configuration records the entire layout of one frame---all windows, their sizes, which buffers they contain, how those buffers are scrolled, and their values of point and the mark; also their fringes, margins, and scroll bar settings.  It also includes the value of minibuffer-scroll-window.  As a special exception, the window configuration does not record the value of point in the selected window for the current buffer.

You can bring back an entire frame layout by restoring a previously saved window configuration.  If you want to record the layout of all frames instead of just one, use a frame configuration instead of a window configuration; see Frame Configurations.

 -- Function: current-window-configuration &optional frame
     This function returns a new object representing FRAME's current window configuration.  The default for FRAME is the selected frame.  The variable window-persistent-parameters specifies whether and which window parameters are saved by this function, see Window Parameters for details.

 -- Function: set-window-configuration configuration
     This function restores the configuration of windows and buffers as specified by CONFIGURATION, for the frame that CONFIGURATION was created for.

     The argument CONFIGURATION must be a value that was previously returned by current-window-configuration.  The configuration is restored in the frame from which CONFIGURATION was made, whether that frame is selected or not.  This always counts as a window size change and triggers execution of the window-size-change-functions (see Window Hooks), because set-window-configuration doesn't know how to tell whether the new configuration actually differs from the old one.

     If the frame which CONFIGURATION was saved from is dead, all this function does is restore the three variables window-min-height, window-min-width and minibuffer-scroll-window. In this case, the function returns nil.  Otherwise, it returns t.

     Here is a way of using this function to get the same effect as save-window-excursion:

          (let ((config (current-window-configuration)))
            (unwind-protect
                (progn (split-window-below nil)
                       ...)
              (set-window-configuration config)))

 -- Macro: save-window-excursion forms...
     This special form records the window configuration, executes FORMS in sequence, then restores the earlier window configuration.  The window configuration includes, for each window, the value of point and the portion of the buffer that is visible.  It also includes the choice of selected window.  However, it does not include the value of point in the current buffer; use save-excursion also, if you wish to preserve that.

     Don't use this construct when save-selected-window is sufficient.

     Exit from save-window-excursion always triggers execution of window-size-change-functions.  (It doesn't know how to tell whether the restored configuration actually differs from the one in effect at the end of the FORMS.)

     The return value is the value of the final form in FORMS. For example:

          (split-window)
               => #<window 25 on control.texi>

          (setq w (selected-window))
               => #<window 19 on control.texi>

          (save-window-excursion
            (delete-other-windows w)
            (switch-to-buffer "foo")
            'do-something)
               => do-something
               ;; The screen is now split again.

 -- Function: window-configuration-p object
     This function returns t if OBJECT is a window configuration.

 -- Function: compare-window-configurations config1 config2
     This function compares two window configurations as regards the structure of windows, but ignores the values of point and mark and the saved scrolling positions---it can return t even if those aspects differ.

     The function equal can also compare two window configurations; it regards configurations as unequal if they differ in any respect, even a saved point or mark.

 -- Function: window-configuration-frame config
     This function returns the frame for which the window configuration CONFIG was made.

Other primitives to look inside of window configurations would make sense, but are not implemented because we did not need them.  See the file winner.el for some more operations on windows configurations.

The objects returned by current-window-configuration die together with the Emacs process.  In order to store a window configuration on disk and read it back in another Emacs session, the functions described next can be used.  These functions are also useful to clone the state of a frame into an arbitrary live window (set-window-configuration effectively clones the windows of a frame into the root window of that very frame only).

 -- Function: window-state-get &optional window writable
     This function returns the state of WINDOW as a Lisp object.  The argument WINDOW can be any window and defaults to the root window of the selected frame.

     If the optional argument WRITABLE is non-nil, this means to not use markers for sampling positions like window-point or window-start.  This argument should be non-nil when the state shall be written to disk and read back in another session.

     Together, the argument WRITABLE and the variable window-persistent-parameters specify which window parameters are saved by this function, see Window Parameters for details.

The value returned by window-state-get can be used in the same session to make a clone of a window in another window.  It can be also written to disk and read back in another session.  In either case, use the function described next to restore the state of the window.

 -- Function: window-state-put state &optional window ignore
     This function puts the window state STATE into WINDOW.  The argument STATE should be the state of a window returned by an earlier invocation of window-state-get, see above.  The optional argument WINDOW must specify a live window and defaults to the selected one.

     The optional argument IGNORE non-nil means to ignore minimum window sizes and fixed size restrictions.  If IGNORE equals safe, this means windows can get as small as one line and/or two columns.

Window Parameters
=================

This section describes how window parameters can be used to associate additional information with windows.

 -- Function: window-parameter window parameter
     This function returns WINDOW's value for PARAMETER.  The default for WINDOW is the selected window.  If WINDOW has no setting for PARAMETER, this function returns nil.

 -- Function: window-parameters &optional window
     This function returns all parameters of WINDOW and their values. The default for WINDOW is the selected window.  The return value, if non-nil is an association list whose elements have the form (PARAMETER . VALUE).

 -- Function: set-window-parameter window parameter value
     This function sets WINDOW's value of PARAMETER to VALUE and returns VALUE.  The default for WINDOW is the selected window.

By default, functions saving and restoring window configurations or the states of windows (see Window Configurations) do not care about window parameters.  This means, that when you change the value of a parameter within the body of a save-window-excursion, the previous value is not restored upon exit of that macro.  It also means that when you restore via window-state-put a window state saved earlier by window-state-get, all cloned windows have their parameters reset to nil.  The following variable allows to override the standard behavior.

 -- Variable: window-persistent-parameters
     This variable is an alist specifying which parameters get saved by current-window-configuration and window-state-get and subsequently restored by set-window-configuration and window-state-put, see Window Configurations.

     The CAR of each entry of this alist is the symbol specifying the parameter.  The CDR should be one of the following:

     nil
          This value means the parameter is neither saved by window-state-get nor by current-window-configuration.

     t
          This value specifies that the parameter is saved by current-window-configuration and, provided its WRITABLE argument is nil, by window-state-get.

     writable
          This means that the parameter is saved unconditionally by both current-window-configuration and window-state-get.  This value should not be used for parameters whose values do not have a read syntax.  Otherwise, invoking window-state-put in another session may fail with an invalid-read-syntax error.

Some functions, notably delete-window, delete-other-windows and split-window may behave specially when their WINDOW argument has a parameter set.  You can override such special behavior by binding the following variable to a non-nil value:

 -- Variable: ignore-window-parameters
     If this variable is non-nil, some standard functions do not process window parameters.  The functions currently affected by this are split-window, delete-window, delete-other-windows and other-window.

     An application can bind this variable to a non-nil value around calls to these functions.  If it does so, the application is fully responsible for correctly assigning the parameters of all involved windows when exiting that function.

The following parameters are currently used by the window management code:

delete-window
     This parameter affects the execution of delete-window (see Deleting Windows).

delete-other-windows
     This parameter affects the execution of delete-other-windows (see Deleting Windows).

split-window
     This parameter affects the execution of split-window (see Splitting Windows).

other-window
     This parameter affects the execution of other-window (see Cyclic Window Ordering).

no-other-window
     This parameter marks the window as not selectable by other-window (see Cyclic Window Ordering).

clone-of
     This parameter specifies the window this one has been cloned from and is installed by window-state-get, see Window Configurations.

quit-restore
     This parameter tells how to proceed with a window when the buffer it shows is no more needed.  It is installed by the buffer display functions (see Choosing Window) and consulted by the function quit-window (see Quitting Windows).

In addition, the parameters window-atom and window-side are reserved and should not be used by applications.

Hooks for Window Scrolling and Changes
======================================

This section describes how a Lisp program can take action whenever a window displays a different part of its buffer or a different buffer. There are three actions that can change this: scrolling the window, switching buffers in the window, and changing the size of the window. The first two actions run window-scroll-functions; the last runs window-size-change-functions.

 -- Variable: window-scroll-functions
     This variable holds a list of functions that Emacs should call before redisplaying a window with scrolling.  Displaying a different buffer in the window also runs these functions.

     This variable is not a normal hook, because each function is called with two arguments: the window, and its new display-start position.

     These functions must be careful in using window-end (see Window Start and End); if you need an up-to-date value, you must use the UPDATE argument to ensure you get it.

     Warning: don't use this feature to alter the way the window is scrolled.  It's not designed for that, and such use probably won't work.

 -- Variable: window-size-change-functions
     This variable holds a list of functions to be called if the size of any window changes for any reason.  The functions are called just once per redisplay, and just once for each frame on which size changes have occurred.

     Each function receives the frame as its sole argument.  There is no direct way to find out which windows on that frame have changed size, or precisely how.  However, if a size-change function records, at each call, the existing windows and their sizes, it can also compare the present sizes and the previous sizes.

     Creating or deleting windows counts as a size change, and therefore causes these functions to be called.  Changing the frame size also counts, because it changes the sizes of the existing windows.

     It is not a good idea to use save-window-excursion (see Window Configurations) in these functions, because that always counts as a size change, and it would cause these functions to be called over and over.  In most cases, save-selected-window (see Selecting Windows) is what you need here.

 -- Variable: window-configuration-change-hook
     A normal hook that is run every time you change the window configuration of an existing frame.  This includes splitting or deleting windows, changing the sizes of windows, or displaying a different buffer in a window.

     The buffer-local part of this hook is run once per each window on the affected frame, with the relevant window selected and its buffer current.  The global part is run once for the modified frame, with that frame selected.

In addition, you can use jit-lock-register to register a Font Lock fontification function, which will be called whenever parts of a buffer are (re)fontified because a window was scrolled or its size changed.  See Other Font Lock Variables.