Operating System Interface
**************************

This chapter is about starting and getting out of Emacs, access to values in the operating system environment, and terminal input, output.

See Building Emacs, for related information.  See Display, for additional operating system status information pertaining to the terminal and the screen.

Starting Up Emacs
=================

This section describes what Emacs does when it is started, and how you can customize these actions.

Summary: Sequence of Actions at Startup
---------------------------------------

When Emacs is started up, it performs the following operations (see normal-top-level in startup.el):

 1. It adds subdirectories to load-path, by running the file named subdirs.el in each directory in the list.  Normally, this file adds the directory's subdirectories to the list, and those are scanned in their turn.  The files subdirs.el are normally generated automatically when Emacs is installed.

 2. It loads any leim-list.el that it finds in the load-path directories.  This file is intended for registering input methods. The search is only for any personal leim-list.el files that you may have created; it skips the directories containing the standard Emacs libraries (these should contain only a single leim-list.el file, which is compiled into the Emacs executable).

 3. It sets the variable before-init-time to the value of current-time (see Time of Day).  It also sets after-init-time to nil, which signals to Lisp programs that Emacs is being initialized.

 4. It sets the language environment and the terminal coding system, if requested by environment variables such as LANG.

 5. It does some basic parsing of the command-line arguments.

 6. If not running in batch mode, it initializes the window system that the variable initial-window-system specifies (see initial-window-system).  The initialization function for each supported window system is specified by window-system-initialization-alist.  If the value of initial-window-system is WINDOWSYSTEM, then the appropriate initialization function is defined in the file term/WINDOWSYSTEM-win.el.  This file should have been compiled into the Emacs executable when it was built.

 7. It runs the normal hook before-init-hook.

 8. If appropriate, it creates a graphical frame.  This is not done if the options --batch or --daemon were specified.

 9. It initializes the initial frame's faces, and sets up the menu bar and tool bar if needed.  If graphical frames are supported, it sets up the tool bar even if the current frame is not a graphical one, since a graphical frame may be created later on.

 10. It use custom-reevaluate-setting to re-initialize the members of the list custom-delayed-init-variables.  These are any pre-loaded user options whose default value depends on the run-time, rather than build-time, context. See custom-initialize-delay.

 11. It loads the library site-start, if it exists.  This is not done if the options -Q or --no-site-file were specified.

 12. It loads your init file (see Init File).  This is not done if the options -q, -Q, or --batch were specified.  If the -u option was specified, Emacs looks for the init file in that user's home directory instead.

 13. It loads the library default, if it exists.  This is not done if inhibit-default-init is non-nil, nor if the options -q, -Q, or --batch were specified.

 14. It loads your abbrevs from the file specified by abbrev-file-name, if that file exists and can be read (see abbrev-file-name).  This is not done if the option --batch was specified.

 15. If package-enable-at-startup is non-nil, it calls the function package-initialize to activate any optional Emacs Lisp package that has been installed.  See Packaging Basics.

 16. It sets the variable after-init-time to the value of current-time.  This variable was set to nil earlier; setting it to the current time signals that the initialization phase is over, and, together with before-init-time, provides the measurement of how long it took.

 17. It runs the normal hook after-init-hook.

 18. If the buffer *scratch* exists and is still in Fundamental mode (as it should be by default), it sets its major mode according to initial-major-mode.

 19. If started on a text terminal, it loads the terminal-specific Lisp library (see Terminal-Specific), and runs the hook tty-setup-hook.  This is not done in --batch mode, nor if term-file-prefix is nil.

 20. It displays the initial echo area message, unless you have suppressed that with inhibit-startup-echo-area-message.

 21. It processes any command-line options that were not handled earlier.

 22. It now exits if the option --batch was specified.

 23. If initial-buffer-choice is a string, it visits the file (or directory) with that name.  If it is a function, it calls the function with no arguments and selects the buffer that it returns. If the *scratch* buffer exists and is empty, it inserts initial-scratch-message into that buffer.

 24. It runs emacs-startup-hook.

 25. It calls frame-notice-user-settings, which modifies the parameters of the selected frame according to whatever the init files specify.

 26. It runs window-setup-hook.  The only difference between this hook and emacs-startup-hook is that this one runs after the previously mentioned modifications to the frame parameters.

 27. It displays the startup screen, which is a special buffer that contains information about copyleft and basic Emacs usage.  This is not done if inhibit-startup-screen or initial-buffer-choice are non-nil, or if the --no-splash or -Q command-line options were specified.

 28. If the option --daemon was specified, it calls server-start and detaches from the controlling terminal. See Emacs Server (The GNU Emacs Manual).

 29. If started by the X session manager, it calls emacs-session-restore passing it as argument the ID of the previous session.  See Session Management.

The following options affect some aspects of the startup sequence.

 -- User Option: inhibit-startup-screen
     This variable, if non-nil, inhibits the startup screen.  In that case, Emacs typically displays the *scratch* buffer; but see initial-buffer-choice, below.

     Do not set this variable in the init file of a new user, or in a way that affects more than one user, as that would prevent new users from receiving information about copyleft and basic Emacs usage.

     inhibit-startup-message and inhibit-splash-screen are aliases for this variable.

 -- User Option: initial-buffer-choice
     If non-nil, this variable is a string that specifies a file or directory for Emacs to display after starting up, instead of the startup screen. If its value is a function, Emacs calls that function which must return a buffer which is then displayed. If its value is t, Emacs displays the *scratch* buffer.

 -- User Option: inhibit-startup-echo-area-message
     This variable controls the display of the startup echo area message. You can suppress the startup echo area message by adding text with this form to your init file:

          (setq inhibit-startup-echo-area-message
                "YOUR-LOGIN-NAME")

     Emacs explicitly checks for an expression as shown above in your init file; your login name must appear in the expression as a Lisp string constant.  You can also use the Customize interface.  Other methods of setting inhibit-startup-echo-area-message to the same value do not inhibit the startup message.  This way, you can easily inhibit the message for yourself if you wish, but thoughtless copying of your init file will not inhibit the message for someone else.

 -- User Option: initial-scratch-message
     This variable, if non-nil, should be a string, which is inserted into the *scratch* buffer when Emacs starts up.  If it is nil, the *scratch* buffer is empty.

The following command-line options affect some aspects of the startup sequence.  See Initial Options (The GNU Emacs Manual).

--no-splash
     Do not display a splash screen.

--batch
     Run without an interactive terminal.  See Batch Mode.

--daemon
     Do not initialize any display; just start a server in the background.

--no-init-file
-q
     Do not load either the init file, or the default library.

--no-site-file
     Do not load the site-start library.

--quick
-Q
     Equivalent to -q --no-site-file --no-splash.

The Init File
-------------

When you start Emacs, it normally attempts to load your init file.  This is either a file named .emacs or .emacs.el in your home directory, or a file named init.el in a subdirectory named .emacs.d in your home directory.

The command-line switches -q, -Q, and -u control whether and where to find the init file; -q (and the stronger -Q) says not to load an init file, while -u USER says to load USER's init file instead of yours. See Entering Emacs (The GNU Emacs Manual).  If neither option is specified, Emacs uses the LOGNAME environment variable, or the USER (most systems) or USERNAME (MS systems) variable, to find your home directory and thus your init file; this way, even if you have su'd, Emacs still loads your own init file.  If those environment variables are absent, though, Emacs uses your user-id to find your home directory.

An Emacs installation may have a default init file, which is a Lisp library named default.el.  Emacs finds this file through the standard search path for libraries (see How Programs Do Loading).  The Emacs distribution does not come with this file; it is intended for local customizations.  If the default init file exists, it is loaded whenever you start Emacs.  But your own personal init file, if any, is loaded first; if it sets inhibit-default-init to a non-nil value, then Emacs does not subsequently load the default.el file.  In batch mode, or if you specify -q (or -Q), Emacs loads neither your personal init file nor the default init file.

Another file for site-customization is site-start.el.  Emacs loads this before the user's init file.  You can inhibit the loading of this file with the option --no-site-file.

 -- User Option: site-run-file
     This variable specifies the site-customization file to load before the user's init file.  Its normal value is "site-start".  The only way you can change it with real effect is to do so before dumping Emacs.

See Init File Examples (The GNU Emacs Manual), for examples of how to make various commonly desired customizations in your .emacs file.

 -- User Option: inhibit-default-init
     If this variable is non-nil, it prevents Emacs from loading the default initialization library file.  The default value is nil.

 -- Variable: before-init-hook
     This normal hook is run, once, just before loading all the init files (site-start.el, your init file, and default.el). (The only way to change it with real effect is before dumping Emacs.)

 -- Variable: after-init-hook
     This normal hook is run, once, just after loading all the init files (site-start.el, your init file, and default.el), before loading the terminal-specific library (if started on a text terminal) and processing the command-line action arguments.

 -- Variable: emacs-startup-hook
     This normal hook is run, once, just after handling the command line arguments.  In batch mode, Emacs does not run this hook.

 -- Variable: window-setup-hook
     This normal hook is very similar to emacs-startup-hook. The only difference is that it runs slightly later, after setting of the frame parameters.  See window-setup-hook.

 -- Variable: user-init-file
     This variable holds the absolute file name of the user's init file.  If the actual init file loaded is a compiled file, such as .emacs.elc, the value refers to the corresponding source file.

 -- Variable: user-emacs-directory
     This variable holds the name of the .emacs.d directory.  It is ~/.emacs.d on all platforms but MS-DOS.

Terminal-Specific Initialization
--------------------------------

Each terminal type can have its own Lisp library that Emacs loads when run on that type of terminal.  The library's name is constructed by concatenating the value of the variable term-file-prefix and the terminal type (specified by the environment variable TERM). Normally, term-file-prefix has the value "term/"; changing this is not recommended.  Emacs finds the file in the normal manner, by searching the load-path directories, and trying the .elc and .el suffixes.

The usual role of a terminal-specific library is to enable special keys to send sequences that Emacs can recognize.  It may also need to set or add to input-decode-map if the Termcap or Terminfo entry does not specify all the terminal's function keys.  See Terminal Input.

When the name of the terminal type contains a hyphen or underscore, and no library is found whose name is identical to the terminal's name, Emacs strips from the terminal's name the last hyphen or underscore and everything that follows it, and tries again.  This process is repeated until Emacs finds a matching library, or until there are no more hyphens or underscores in the name (i.e., there is no terminal-specific library).  For example, if the terminal name is xterm-256color and there is no term/xterm-256color.el library, Emacs tries to load term/xterm.el.  If necessary, the terminal library can evaluate (getenv "TERM") to find the full name of the terminal type.

Your init file can prevent the loading of the terminal-specific library by setting the variable term-file-prefix to nil.

You can also arrange to override some of the actions of the terminal-specific library by using tty-setup-hook.  This is a normal hook that Emacs runs after initializing a new text terminal. You could use this hook to define initializations for terminals that do not have their own libraries.  See Hooks.

 -- Variable: term-file-prefix
     If the value of this variable is non-nil, Emacs loads a terminal-specific initialization file as follows:

          (load (concat term-file-prefix (getenv "TERM")))

     You may set the term-file-prefix variable to nil in your init file if you do not wish to load the terminal-initialization file.

     On MS-DOS, Emacs sets the TERM environment variable to internal.

 -- Variable: tty-setup-hook
     This variable is a normal hook that Emacs runs after initializing a new text terminal.  (This applies when Emacs starts up in non-windowed mode, and when making a tty emacsclient connection.)  The hook runs after loading your init file (if applicable) and the terminal-specific Lisp file, so you can use it to adjust the definitions made by that file.

     For a related feature, see window-setup-hook.

Command-Line Arguments
----------------------

You can use command-line arguments to request various actions when you start Emacs.  Note that the recommended way of using Emacs is to start it just once, after logging in, and then do all editing in the same Emacs session (see Entering Emacs (The GNU Emacs Manual)). For this reason, you might not use command-line arguments very often; nonetheless, they can be useful when invoking Emacs from session scripts or debugging Emacs.  This section describes how Emacs processes command-line arguments.

 -- Function: command-line
     This function parses the command line that Emacs was called with, processes it, and (amongst other things) loads the user's init file and displays the startup messages.

 -- Variable: command-line-processed
     The value of this variable is t once the command line has been processed.

     If you redump Emacs by calling dump-emacs (see Building Emacs), you may wish to set this variable to nil first in order to cause the new dumped Emacs to process its new command-line arguments.

 -- Variable: command-switch-alist
     This variable is an alist of user-defined command-line options and associated handler functions.  By default it is empty, but you can add elements if you wish.

     A command-line option is an argument on the command line, which has the form:

          -OPTION

     The elements of the command-switch-alist look like this:

          (OPTION . HANDLER-FUNCTION)

     The CAR, OPTION, is a string, the name of a command-line option (not including the initial hyphen).  The HANDLER-FUNCTION is called to handle OPTION, and receives the option name as its sole argument.

     In some cases, the option is followed in the command line by an argument.  In these cases, the HANDLER-FUNCTION can find all the remaining command-line arguments in the variable command-line-args-left (see below).  (The entire list of command-line arguments is in command-line-args.)

     The command-line arguments are parsed by the command-line-1 function in the startup.el file.  See also Command Line Arguments for Emacs Invocation (The GNU Emacs Manual).

 -- Variable: command-line-args
     The value of this variable is the list of command-line arguments passed to Emacs.

 -- Variable: command-line-args-left
     The value of this variable is the list of command-line arguments that have not yet been processed.

 -- Variable: command-line-functions
     This variable's value is a list of functions for handling an unrecognized command-line argument.  Each time the next argument to be processed has no special meaning, the functions in this list are called, in order of appearance, until one of them returns a non-nil value.

     These functions are called with no arguments.  They can access the command-line argument under consideration through the variable argi, which is bound temporarily at this point.  The remaining arguments (not including the current one) are in the variable command-line-args-left.

     When a function recognizes and processes the argument in argi, it should return a non-nil value to say it has dealt with that argument.  If it has also dealt with some of the following arguments, it can indicate that by deleting them from command-line-args-left.

     If all of these functions return nil, then the argument is treated as a file name to visit.

Getting Out of Emacs
====================

There are two ways to get out of Emacs: you can kill the Emacs job, which exits permanently, or you can suspend it, which permits you to reenter the Emacs process later.  (In a graphical environment, you can of course simply switch to another application without doing anything special to Emacs, then switch back to Emacs when you want.)

Killing Emacs
-------------

Killing Emacs means ending the execution of the Emacs process. If you started Emacs from a terminal, the parent process normally resumes control.  The low-level primitive for killing Emacs is kill-emacs.

 -- Command: kill-emacs &optional exit-data
     This command calls the hook kill-emacs-hook, then exits the Emacs process and kills it.

     If EXIT-DATA is an integer, that is used as the exit status of the Emacs process.  (This is useful primarily in batch operation; see Batch Mode.)

     If EXIT-DATA is a string, its contents are stuffed into the terminal input buffer so that the shell (or whatever program next reads input) can read them.

The kill-emacs function is normally called via the higher-level command C-x C-c (save-buffers-kill-terminal).  See Exiting (The GNU Emacs Manual).  It is also called automatically if Emacs receives a SIGTERM or SIGHUP operating system signal (e.g., when the controlling terminal is disconnected), or if it receives a SIGINT signal while running in batch mode (see Batch Mode).

 -- Variable: kill-emacs-hook
     This normal hook is run by kill-emacs, before it kills Emacs.

     Because kill-emacs can be called in situations where user interaction is impossible (e.g., when the terminal is disconnected), functions on this hook should not attempt to interact with the user. If you want to interact with the user when Emacs is shutting down, use kill-emacs-query-functions, described below.

When Emacs is killed, all the information in the Emacs process, aside from files that have been saved, is lost.  Because killing Emacs inadvertently can lose a lot of work, the save-buffers-kill-terminal command queries for confirmation if you have buffers that need saving or subprocesses that are running. It also runs the abnormal hook kill-emacs-query-functions:

 -- Variable: kill-emacs-query-functions
     When save-buffers-kill-terminal is killing Emacs, it calls the functions in this hook, after asking the standard questions and before calling kill-emacs.  The functions are called in order of appearance, with no arguments.  Each function can ask for additional confirmation from the user.  If any of them returns nil, save-buffers-kill-emacs does not kill Emacs, and does not run the remaining functions in this hook.  Calling kill-emacs directly does not run this hook.

Suspending Emacs
----------------

On text terminals, it is possible to suspend Emacs, which means stopping Emacs temporarily and returning control to its superior process, which is usually the shell.  This allows you to resume editing later in the same Emacs process, with the same buffers, the same kill ring, the same undo history, and so on.  To resume Emacs, use the appropriate command in the parent shell---most likely fg.

Suspending works only on a terminal device from which the Emacs session was started.  We call that device the controlling terminal of the session.  Suspending is not allowed if the controlling terminal is a graphical terminal.  Suspending is usually not relevant in graphical environments, since you can simply switch to another application without doing anything special to Emacs.

Some operating systems (those without SIGTSTP, or MS-DOS) do not support suspension of jobs; on these systems, ``suspension'' actually creates a new shell temporarily as a subprocess of Emacs. Then you would exit the shell to return to Emacs.

 -- Command: suspend-emacs &optional string
     This function stops Emacs and returns control to the superior process. If and when the superior process resumes Emacs, suspend-emacs returns nil to its caller in Lisp.

     This function works only on the controlling terminal of the Emacs session; to relinquish control of other tty devices, use suspend-tty (see below).  If the Emacs session uses more than one terminal, you must delete the frames on all the other terminals before suspending Emacs, or this function signals an error. See Multiple Terminals.

     If STRING is non-nil, its characters are sent to Emacs's superior shell, to be read as terminal input. The characters in STRING are not echoed by the superior shell; only the results appear.

     Before suspending, suspend-emacs runs the normal hook suspend-hook.  After the user resumes Emacs, suspend-emacs runs the normal hook suspend-resume-hook. See Hooks.

     The next redisplay after resumption will redraw the entire screen, unless the variable no-redraw-on-reenter is non-nil. See Refresh Screen.

     Here is an example of how you could use these hooks:

          (add-hook 'suspend-hook
                    (lambda () (or (y-or-n-p "Really suspend? ")
                                   (error "Suspend canceled"))))

          (add-hook 'suspend-resume-hook (lambda () (message "Resumed!")
                                           (sit-for 2)))

     Here is what you would see upon evaluating (suspend-emacs "pwd"):

          ---------- Buffer: Minibuffer ----------
          Really suspend? y
          ---------- Buffer: Minibuffer ----------

          ---------- Parent Shell ----------
          bash$ /home/username
          bash$ fg

          ---------- Echo Area ----------
          Resumed!

     Note that pwd is not echoed after Emacs is suspended.  But it is read and executed by the shell.

 -- Variable: suspend-hook
     This variable is a normal hook that Emacs runs before suspending.

 -- Variable: suspend-resume-hook
     This variable is a normal hook that Emacs runs on resuming after a suspension.

 -- Function: suspend-tty &optional tty
     If TTY specifies a terminal device used by Emacs, this function relinquishes the device and restores it to its prior state.  Frames that used the device continue to exist, but are not updated and Emacs doesn't read input from them.  TTY can be a terminal object, a frame (meaning the terminal for that frame), or nil (meaning the terminal for the selected frame).  See Multiple Terminals.

     If TTY is already suspended, this function does nothing.

     This function runs the hook suspend-tty-functions, passing the terminal object as an argument to each function.

 -- Function: resume-tty &optional tty
     This function resumes the previously suspended terminal device TTY; where TTY has the same possible values as it does for suspend-tty.

     This function reopens the terminal device, re-initializes it, and redraws it with that terminal's selected frame.  It then runs the hook resume-tty-functions, passing the terminal object as an argument to each function.

     If the same device is already used by another Emacs terminal, this function signals an error.  If TTY is not suspended, this function does nothing.

 -- Function: controlling-tty-p &optional tty
     This function returns non-nil if TTY is the controlling terminal of the Emacs session; TTY can be a terminal object, a frame (meaning the terminal for that frame), or nil (meaning the terminal for the selected frame).

 -- Command: suspend-frame
     This command suspends a frame.  For GUI frames, it calls iconify-frame (see Visibility of Frames); for frames on text terminals, it calls either suspend-emacs or suspend-tty, depending on whether the frame is displayed on the controlling terminal device or not.

Operating System Environment
============================

Emacs provides access to variables in the operating system environment through various functions.  These variables include the name of the system, the user's UID, and so on.

 -- Variable: system-configuration
     This variable holds the standard GNU configuration name for the hardware/software configuration of your system, as a string.  For example, a typical value for a 64-bit GNU/Linux system is "x86_64-unknown-linux-gnu".

 -- Variable: system-type
     The value of this variable is a symbol indicating the type of operating system Emacs is running on.  The possible values are:

     aix
          IBM's AIX.

     berkeley-unix
          Berkeley BSD and its variants.

     cygwin
          Cygwin, a Posix layer on top of MS-Windows.

     darwin
          Darwin (Mac OS X).

     gnu
          The GNU system (using the GNU kernel, which consists of the HURD and Mach).

     gnu/linux
          A GNU/Linux system---that is, a variant GNU system, using the Linux kernel.  (These systems are the ones people often call ``Linux'', but actually Linux is just the kernel, not the whole system.)

     gnu/kfreebsd
          A GNU (glibc-based) system with a FreeBSD kernel.

     hpux
          Hewlett-Packard HPUX operating system.

     irix
          Silicon Graphics Irix system.

     ms-dos
          Microsoft's DOS.  Emacs compiled with DJGPP for MS-DOS binds system-type to ms-dos even when you run it on MS-Windows.

     usg-unix-v
          AT&T Unix System V.

     windows-nt
          Microsoft Windows NT, 9X and later.  The value of system-type is always windows-nt, e.g., even on Windows 7.

     We do not wish to add new symbols to make finer distinctions unless it is absolutely necessary!  In fact, we hope to eliminate some of these alternatives in the future.  If you need to make a finer distinction than system-type allows for, you can test system-configuration, e.g., against a regexp.

 -- Function: system-name
     This function returns the name of the machine you are running on, as a string.

The symbol system-name is a variable as well as a function.  In fact, the function returns whatever value the variable system-name currently holds.  Thus, you can set the variable system-name in case Emacs is confused about the name of your system.  The variable is also useful for constructing frame titles (see Frame Titles).

 -- User Option: mail-host-address
     If this variable is non-nil, it is used instead of system-name for purposes of generating email addresses.  For example, it is used when constructing the default value of user-mail-address.  See User Identification.  (Since this is done when Emacs starts up, the value actually used is the one saved when Emacs was dumped.  See Building Emacs.)

 -- Command: getenv var &optional frame
     This function returns the value of the environment variable VAR, as a string.  VAR should be a string.  If VAR is undefined in the environment, getenv returns nil.  It returns "" if VAR is set but null.  Within Emacs, a list of environment variables and their values is kept in the variable process-environment.

          (getenv "USER")
               => "lewis"

     The shell command printenv prints all or part of the environment:

          bash$ printenv
          PATH=/usr/local/bin:/usr/bin:/bin
          USER=lewis

          TERM=xterm
          SHELL=/bin/bash
          HOME=/home/lewis

          ...

 -- Command: setenv variable &optional value substitute
     This command sets the value of the environment variable named VARIABLE to VALUE.  VARIABLE should be a string. Internally, Emacs Lisp can handle any string.  However, normally VARIABLE should be a valid shell identifier, that is, a sequence of letters, digits and underscores, starting with a letter or underscore.  Otherwise, errors may occur if subprocesses of Emacs try to access the value of VARIABLE.  If VALUE is omitted or nil (or, interactively, with a prefix argument), setenv removes VARIABLE from the environment.  Otherwise, VALUE should be a string.

     If the optional argument SUBSTITUTE is non-nil, Emacs calls the function substitute-env-vars to expand any environment variables in VALUE.

     setenv works by modifying process-environment; binding that variable with let is also reasonable practice.

     setenv returns the new value of VARIABLE, or nil if it removed VARIABLE from the environment.

 -- Variable: process-environment
     This variable is a list of strings, each describing one environment variable.  The functions getenv and setenv work by means of this variable.

          process-environment
          => ("PATH=/usr/local/bin:/usr/bin:/bin"
              "USER=lewis"

              "TERM=xterm"
              "SHELL=/bin/bash"
              "HOME=/home/lewis"
              ...)

     If process-environment contains ``duplicate'' elements that specify the same environment variable, the first of these elements specifies the variable, and the other ``duplicates'' are ignored.

 -- Variable: initial-environment
     This variable holds the list of environment variables Emacs inherited from its parent process when Emacs started.

 -- Variable: path-separator
     This variable holds a string that says which character separates directories in a search path (as found in an environment variable).  Its value is ":" for Unix and GNU systems, and ";" for MS systems.

 -- Function: parse-colon-path path
     This function takes a search path string such as the value of the PATH environment variable, and splits it at the separators, returning a list of directory names.  nil in this list means the current directory.  Although the function's name says ``colon'', it actually uses the value of path-separator.

          (parse-colon-path ":/foo:/bar")
               => (nil "/foo/" "/bar/")

 -- Variable: invocation-name
     This variable holds the program name under which Emacs was invoked.  The value is a string, and does not include a directory name.

 -- Variable: invocation-directory
     This variable holds the directory from which the Emacs executable was invoked, or nil if that directory cannot be determined.

 -- Variable: installation-directory
     If non-nil, this is a directory within which to look for the lib-src and etc subdirectories.  In an installed Emacs, it is normally nil.  It is non-nil when Emacs can't find those directories in their standard installed locations, but can find them in a directory related somehow to the one containing the Emacs executable (i.e., invocation-directory).

 -- Function: load-average &optional use-float
     This function returns the current 1-minute, 5-minute, and 15-minute system load averages, in a list.  The load average indicates the number of processes trying to run on the system.

     By default, the values are integers that are 100 times the system load averages, but if USE-FLOAT is non-nil, then they are returned as floating-point numbers without multiplying by 100.

     If it is impossible to obtain the load average, this function signals an error.  On some platforms, access to load averages requires installing Emacs as setuid or setgid so that it can read kernel information, and that usually isn't advisable.

     If the 1-minute load average is available, but the 5- or 15-minute averages are not, this function returns a shortened list containing the available averages.

          (load-average)
               => (169 48 36)

          (load-average t)
               => (1.69 0.48 0.36)

     The shell command uptime returns similar information.

 -- Function: emacs-pid
     This function returns the process ID of the Emacs process, as an integer.

 -- Variable: tty-erase-char
     This variable holds the erase character that was selected in the system's terminal driver, before Emacs was started.

User Identification
===================

 -- Variable: init-file-user
     This variable says which user's init files should be used by Emacs---or nil if none.  "" stands for the user who originally logged in.  The value reflects command-line options such as -q or -u USER.

     Lisp packages that load files of customizations, or any other sort of user profile, should obey this variable in deciding where to find it. They should load the profile of the user name found in this variable. If init-file-user is nil, meaning that the -q, -Q, or -batch option was used, then Lisp packages should not load any customization files or user profile.

 -- User Option: user-mail-address
     This holds the nominal email address of the user who is using Emacs. Emacs normally sets this variable to a default value after reading your init files, but not if you have already set it.  So you can set the variable to some other value in your init file if you do not want to use the default value.

 -- Function: user-login-name &optional uid
     This function returns the name under which the user is logged in. It uses the environment variables LOGNAME or USER if either is set.  Otherwise, the value is based on the effective UID, not the real UID.

     If you specify UID (a number), the result is the user name that corresponds to UID, or nil if there is no such user.

 -- Function: user-real-login-name
     This function returns the user name corresponding to Emacs's real UID.  This ignores the effective UID, and the environment variables LOGNAME and USER.

 -- Function: user-full-name &optional uid
     This function returns the full name of the logged-in user---or the value of the environment variable NAME, if that is set.

     If the Emacs process's user-id does not correspond to any known user (and provided NAME is not set), the result is "unknown".

     If UID is non-nil, then it should be a number (a user-id) or a string (a login name).  Then user-full-name returns the full name corresponding to that user-id or login name.  If you specify a user-id or login name that isn't defined, it returns nil.

The symbols user-login-name, user-real-login-name and user-full-name are variables as well as functions.  The functions return the same values that the variables hold.  These variables allow you to ``fake out'' Emacs by telling the functions what to return.  The variables are also useful for constructing frame titles (see Frame Titles).

 -- Function: user-real-uid
     This function returns the real UID of the user. The value may be floating point, in the (unlikely) event that the UID is too large to fit in a Lisp integer.

 -- Function: user-uid
     This function returns the effective UID of the user. The value may be floating point.

 -- Function: group-gid
     This function returns the effective GID of the Emacs process. The value may be floating point.

 -- Function: group-real-gid
     This function returns the real GID of the Emacs process. The value may be floating point.

 -- Function: system-users
     This function returns a list of strings, listing the user names on the system.  If Emacs cannot retrieve this information, the return value is a list containing just the value of user-real-login-name.

 -- Function: system-groups
     This function returns a list of strings, listing the names of user groups on the system.  If Emacs cannot retrieve this information, the return value is nil.

Time of Day
===========

This section explains how to determine the current time and time zone.

Most of these functions represent time as a list of either four integers, (SEC-HIGH SEC-LOW MICROSEC PICOSEC), or of three integers, (SEC-HIGH SEC-LOW MICROSEC), or of two integers, (SEC-HIGH SEC-LOW).  The integers SEC-HIGH and SEC-LOW give the high and low bits of an integer number of seconds.  This integer, HIGH * 2**16 + LOW, is the number of seconds from the epoch (0:00 January 1, 1970 UTC) to the specified time.  The third list element MICROSEC, if present, gives the number of microseconds from the start of that second to the specified time. Similarly, the fourth list element PICOSEC, if present, gives the number of picoseconds from the start of that microsecond to the specified time.

The return value of current-time represents time using four integers, as do the timestamps in the return value of file-attributes (see Definition of file-attributes).  In function arguments, e.g., the TIME-VALUE argument to current-time-string, two-, three-, and four-integer lists are accepted.  You can convert times from the list representation into standard human-readable strings using current-time-string, or to other forms using the decode-time and format-time-string functions documented in the following sections.

 -- Function: current-time-string &optional time-value
     This function returns the current time and date as a human-readable string.  The format does not vary for the initial part of the string, which contains the day of week, month, day of month, and time of day in that order: the number of characters used for these fields is always the same, so you can reliably use substring to extract them.  You should count characters from the beginning of the string rather than from the end, as the year might not have exactly four digits, and additional information may some day be added at the end.

     The argument TIME-VALUE, if given, specifies a time to format (represented as a list of integers), instead of the current time.

          (current-time-string)
               => "Wed Oct 14 22:21:05 1987"

 -- Function: current-time
     This function returns the current time, represented as a list of four integers (SEC-HIGH SEC-LOW MICROSEC PICOSEC). These integers have trailing zeros on systems that return time with lower resolutions.  On all current machines PICOSEC is a multiple of 1000, but this may change as higher-resolution clocks become available.

 -- Function: float-time &optional time-value
     This function returns the current time as a floating-point number of seconds since the epoch.  The optional argument TIME-VALUE, if given, specifies a time (represented as a list of integers) to convert instead of the current time.

     Warning: Since the result is floating point, it may not be exact.  Do not use this function if precise time stamps are required.

 -- Function: current-time-zone &optional time-value
     This function returns a list describing the time zone that the user is in.

     The value has the form (OFFSET NAME).  Here OFFSET is an integer giving the number of seconds ahead of UTC (east of Greenwich).  A negative value means west of Greenwich.  The second element, NAME, is a string giving the name of the time zone.  Both elements change when daylight saving time begins or ends; if the user has specified a time zone that does not use a seasonal time adjustment, then the value is constant through time.

     If the operating system doesn't supply all the information necessary to compute the value, the unknown elements of the list are nil.

     The argument TIME-VALUE, if given, specifies a time (represented as a list of integers) to analyze instead of the current time.

The current time zone is determined by the TZ environment variable.  See System Environment.  For example, you can tell Emacs to use universal time with (setenv "TZ" "UTC0").  If TZ is not in the environment, Emacs uses a platform-dependent default time zone.

Time Conversion
===============

These functions convert time values (lists of two to four integers, as explained in the previous section) into calendrical information and vice versa.

Many 32-bit operating systems are limited to time values containing 32 bits of information; these systems typically handle only the times from 1901-12-13 20:45:52 UTC through 2038-01-19 03:14:07 UTC. However, 64-bit and some 32-bit operating systems have larger time values, and can represent times far in the past or future.

Time conversion functions always use the Gregorian calendar, even for dates before the Gregorian calendar was introduced.  Year numbers count the number of years since the year 1 B.C., and do not skip zero as traditional Gregorian years do; for example, the year number -37 represents the Gregorian year 38 B.C.

 -- Function: decode-time &optional time
     This function converts a time value into calendrical information.  If you don't specify TIME, it decodes the current time.  The return value is a list of nine elements, as follows:

          (SECONDS MINUTES HOUR DAY MONTH YEAR DOW DST ZONE)

     Here is what the elements mean:

     seconds
          The number of seconds past the minute, as an integer between 0 and 59. On some operating systems, this is 60 for leap seconds.

     minutes
          The number of minutes past the hour, as an integer between 0 and 59.

     hour
          The hour of the day, as an integer between 0 and 23.

     day
          The day of the month, as an integer between 1 and 31.

     month
          The month of the year, as an integer between 1 and 12.

     year
          The year, an integer typically greater than 1900.

     dow
          The day of week, as an integer between 0 and 6, where 0 stands for Sunday.

     dst
          t if daylight saving time is effect, otherwise nil.

     zone
          An integer indicating the time zone, as the number of seconds east of Greenwich.

     Common Lisp Note: Common Lisp has different meanings for DOW and ZONE.

 -- Function: encode-time seconds minutes hour day month year &optional zone
     This function is the inverse of decode-time.  It converts seven items of calendrical data into a time value.  For the meanings of the arguments, see the table above under decode-time.

     Year numbers less than 100 are not treated specially.  If you want them to stand for years above 1900, or years above 2000, you must alter them yourself before you call encode-time.

     The optional argument ZONE defaults to the current time zone and its daylight saving time rules.  If specified, it can be either a list (as you would get from current-time-zone), a string as in the TZ environment variable, t for Universal Time, or an integer (as you would get from decode-time).  The specified zone is used without any further alteration for daylight saving time.

     If you pass more than seven arguments to encode-time, the first six are used as SECONDS through YEAR, the last argument is used as ZONE, and the arguments in between are ignored.  This feature makes it possible to use the elements of a list returned by decode-time as the arguments to encode-time, like this:

          (apply 'encode-time (decode-time ...))

     You can perform simple date arithmetic by using out-of-range values for the SECONDS, MINUTES, HOUR, DAY, and MONTH arguments; for example, day 0 means the day preceding the given month.

     The operating system puts limits on the range of possible time values; if you try to encode a time that is out of range, an error results. For instance, years before 1970 do not work on some systems; on others, years as early as 1901 do work.

Parsing and Formatting Times
============================

These functions convert time values to text in a string, and vice versa. Time values are lists of two to four integers (see Time of Day).

 -- Function: date-to-time string
     This function parses the time-string STRING and returns the corresponding time value.

 -- Function: format-time-string format-string &optional time universal
     This function converts TIME (or the current time, if TIME is omitted) to a string according to FORMAT-STRING.  The argument FORMAT-STRING may contain %-sequences which say to substitute parts of the time.  Here is a table of what the %-sequences mean:

     %a
          This stands for the abbreviated name of the day of week.

     %A
          This stands for the full name of the day of week.

     %b
          This stands for the abbreviated name of the month.

     %B
          This stands for the full name of the month.

     %c
          This is a synonym for %x %X.

     %C
          This has a locale-specific meaning.  In the default locale (named C), it is equivalent to %A, %B %e, %Y.

     %d
          This stands for the day of month, zero-padded.

     %D
          This is a synonym for %m/%d/%y.

     %e
          This stands for the day of month, blank-padded.

     %h
          This is a synonym for %b.

     %H
          This stands for the hour (00--23).

     %I
          This stands for the hour (01--12).

     %j
          This stands for the day of the year (001--366).

     %k
          This stands for the hour (0--23), blank padded.

     %l
          This stands for the hour (1--12), blank padded.

     %m
          This stands for the month (01--12).

     %M
          This stands for the minute (00--59).

     %n
          This stands for a newline.

     %N
          This stands for the nanoseconds (000000000--999999999).  To ask for fewer digits, use %3N for milliseconds, %6N for microseconds, etc.  Any excess digits are discarded, without rounding.

     %p
          This stands for AM or PM, as appropriate.

     %r
          This is a synonym for %I:%M:%S %p.

     %R
          This is a synonym for %H:%M.

     %S
          This stands for the seconds (00--59).

     %t
          This stands for a tab character.

     %T
          This is a synonym for %H:%M:%S.

     %U
          This stands for the week of the year (01--52), assuming that weeks start on Sunday.

     %w
          This stands for the numeric day of week (0--6).  Sunday is day 0.

     %W
          This stands for the week of the year (01--52), assuming that weeks start on Monday.

     %x
          This has a locale-specific meaning.  In the default locale (named C), it is equivalent to %D.

     %X
          This has a locale-specific meaning.  In the default locale (named C), it is equivalent to %T.

     %y
          This stands for the year without century (00--99).

     %Y
          This stands for the year with century.

     %Z
          This stands for the time zone abbreviation (e.g., EST).

     %z
          This stands for the time zone numerical offset (e.g., -0500).

     You can also specify the field width and type of padding for any of these %-sequences.  This works as in printf: you write the field width as digits in the middle of a %-sequences.  If you start the field width with 0, it means to pad with zeros.  If you start the field width with _, it means to pad with spaces.

     For example, %S specifies the number of seconds since the minute; %03S means to pad this with zeros to 3 positions, %_3S to pad with spaces to 3 positions.  Plain %3S pads with zeros, because that is how %S normally pads to two positions.

     The characters E and O act as modifiers when used between % and one of the letters in the table above.  E specifies using the current locale's ``alternative'' version of the date and time. In a Japanese locale, for example, %Ex might yield a date format based on the Japanese Emperors' reigns.  E is allowed in %Ec, %EC, %Ex, %EX, %Ey, and %EY.

     O means to use the current locale's ``alternative'' representation of numbers, instead of the ordinary decimal digits.  This is allowed with most letters, all the ones that output numbers.

     If UNIVERSAL is non-nil, that means to describe the time as Universal Time; nil means describe it using what Emacs believes is the local time zone (see current-time-zone).

     This function uses the C library function strftime (see Formatting Calendar Time (The GNU C Library Reference Manual)) to do most of the work.  In order to communicate with that function, it first encodes its argument using the coding system specified by locale-coding-system (see Locales); after strftime returns the resulting string, format-time-string decodes the string using that same coding system.

 -- Function: seconds-to-time seconds
     This function converts SECONDS, the number of seconds since the epoch, to a time value and returns that.  To convert back, use float-time (see Time of Day).

 -- Function: format-seconds format-string seconds
     This function converts its argument SECONDS into a string of years, days, hours, etc., according to FORMAT-STRING.  The argument FORMAT-STRING may contain %-sequences which control the conversion.  Here is a table of what the %-sequences mean:

     %y
     %Y
          The integer number of 365-day years.

     %d
     %D
          The integer number of days.

     %h
     %H
          The integer number of hours.

     %m
     %M
          The integer number of minutes.

     %s
     %S
          The integer number of seconds.

     %z
          Non-printing control flag.  When it is used, other specifiers must be given in the order of decreasing size, i.e., years before days, hours before minutes, etc.  Nothing will be produced in the result string to the left of %z until the first non-zero conversion is encountered.  For example, the default format used by emacs-uptime (see emacs-uptime) "%Y, %D, %H, %M, %z%S" means that the number of seconds will always be produced, but years, days, hours, and minutes will only be shown if they are non-zero.

     %%
          Produces a literal %.

     Upper-case format sequences produce the units in addition to the numbers, lower-case formats produce only the numbers.

     You can also specify the field width by following the % with a number; shorter numbers will be padded with blanks.  An optional period before the width requests zero-padding instead.  For example, "%.3Y" might produce "004 years".

     Warning: This function works only with values of SECONDS that don't exceed most-positive-fixnum (see most-positive-fixnum).

Processor Run time
==================

Emacs provides several functions and primitives that return time, both elapsed and processor time, used by the Emacs process.

 -- Command: emacs-uptime &optional format
     This function returns a string representing the Emacs uptime---the elapsed wall-clock time this instance of Emacs is running.  The string is formatted by format-seconds according to the optional argument FORMAT.  For the available format descriptors, see format-seconds.  If FORMAT is nil or omitted, it defaults to "%Y, %D, %H, %M, %z%S".

     When called interactively, it prints the uptime in the echo area.

 -- Function: get-internal-run-time
     This function returns the processor run time used by Emacs as a list of four integers: (HIGH LOW MICROSEC PICOSEC), using the same format as current-time (see Time of Day).

     Note that the time returned by this function excludes the time Emacs was not using the processor, and if the Emacs process has several threads, the returned value is the sum of the processor times used up by all Emacs threads.

     If the system doesn't provide a way to determine the processor run time, get-internal-run-time returns the same time as current-time.

 -- Command: emacs-init-time
     This function returns the duration of the Emacs initialization (see Startup Summary) in seconds, as a string.  When called interactively, it prints the duration in the echo area.

Time Calculations
=================

These functions perform calendrical computations using time values (the kind of list that current-time returns).

 -- Function: time-less-p t1 t2
     This returns t if time value T1 is less than time value T2.

 -- Function: time-subtract t1 t2
     This returns the time difference T1 - T2 between two time values, in the same format as a time value.

 -- Function: time-add t1 t2
     This returns the sum of two time values, one of which ought to represent a time difference rather than a point in time. Here is how to add a number of seconds to a time value:

          (time-add TIME (seconds-to-time SECONDS))

 -- Function: time-to-days time
     This function returns the number of days between the beginning of year 1 and TIME.

 -- Function: time-to-day-in-year time
     This returns the day number within the year corresponding to TIME.

 -- Function: date-leap-year-p year
     This function returns t if YEAR is a leap year.

Timers for Delayed Execution
============================

You can set up a timer to call a function at a specified future time or after a certain length of idleness.

Emacs cannot run timers at any arbitrary point in a Lisp program; it can run them only when Emacs could accept output from a subprocess: namely, while waiting or inside certain primitive functions such as sit-for or read-event which can wait.  Therefore, a timer's execution may be delayed if Emacs is busy.  However, the time of execution is very precise if Emacs is idle.

Emacs binds inhibit-quit to t before calling the timer function, because quitting out of many timer functions can leave things in an inconsistent state.  This is normally unproblematical because most timer functions don't do a lot of work.  Indeed, for a timer to call a function that takes substantial time to run is likely to be annoying.  If a timer function needs to allow quitting, it should use with-local-quit (see Quitting).  For example, if a timer function calls accept-process-output to receive output from an external process, that call should be wrapped inside with-local-quit, to ensure that C-g works if the external process hangs.

It is usually a bad idea for timer functions to alter buffer contents.  When they do, they usually should call undo-boundary both before and after changing the buffer, to separate the timer's changes from user commands' changes and prevent a single undo entry from growing to be quite large.

Timer functions should also avoid calling functions that cause Emacs to wait, such as sit-for (see Waiting).  This can lead to unpredictable effects, since other timers (or even the same timer) can run while waiting.  If a timer function needs to perform an action after a certain time has elapsed, it can do this by scheduling a new timer.

If a timer function calls functions that can change the match data, it should save and restore the match data.  See Saving Match Data.

 -- Command: run-at-time time repeat function &rest args
     This sets up a timer that calls the function FUNCTION with arguments ARGS at time TIME.  If REPEAT is a number (integer or floating point), the timer is scheduled to run again every REPEAT seconds after TIME.  If REPEAT is nil, the timer runs only once.

     TIME may specify an absolute or a relative time.

     Absolute times may be specified using a string with a limited variety of formats, and are taken to be times today, even if already in the past.  The recognized forms are XXXX, X:XX, or XX:XX (military time), and XXam, XXAM, XXpm, XXPM, XX:XXam, XX:XXAM, XX:XXpm, or XX:XXPM.  A period can be used instead of a colon to separate the hour and minute parts.

     To specify a relative time as a string, use numbers followed by units. For example:

     1 min
          denotes 1 minute from now.

     1 min 5 sec
          denotes 65 seconds from now.

     1 min 2 sec 3 hour 4 day 5 week 6 fortnight 7 month 8 year
          denotes exactly 103 months, 123 days, and 10862 seconds from now.

     For relative time values, Emacs considers a month to be exactly thirty days, and a year to be exactly 365.25 days.

     Not all convenient formats are strings.  If TIME is a number (integer or floating point), that specifies a relative time measured in seconds.  The result of encode-time can also be used to specify an absolute value for TIME.

     In most cases, REPEAT has no effect on when first call takes place---TIME alone specifies that.  There is one exception: if TIME is t, then the timer runs whenever the time is a multiple of REPEAT seconds after the epoch.  This is useful for functions like display-time.

     The function run-at-time returns a timer value that identifies the particular scheduled future action.  You can use this value to call cancel-timer (see below).

A repeating timer nominally ought to run every REPEAT seconds, but remember that any invocation of a timer can be late.  Lateness of one repetition has no effect on the scheduled time of the next repetition.  For instance, if Emacs is busy computing for long enough to cover three scheduled repetitions of the timer, and then starts to wait, it will immediately call the timer function three times in immediate succession (presuming no other timers trigger before or between them).  If you want a timer to run again no less than N seconds after the last invocation, don't use the REPEAT argument. Instead, the timer function should explicitly reschedule the timer.

 -- User Option: timer-max-repeats
     This variable's value specifies the maximum number of times to repeat calling a timer function in a row, when many previously scheduled calls were unavoidably delayed.

 -- Macro: with-timeout (seconds timeout-forms...) body...
     Execute BODY, but give up after SECONDS seconds.  If BODY finishes before the time is up, with-timeout returns the value of the last form in BODY.  If, however, the execution of BODY is cut short by the timeout, then with-timeout executes all the TIMEOUT-FORMS and returns the value of the last of them.

     This macro works by setting a timer to run after SECONDS seconds.  If BODY finishes before that time, it cancels the timer.  If the timer actually runs, it terminates execution of BODY, then executes TIMEOUT-FORMS.

     Since timers can run within a Lisp program only when the program calls a primitive that can wait, with-timeout cannot stop executing BODY while it is in the midst of a computation---only when it calls one of those primitives.  So use with-timeout only with a BODY that waits for input, not one that does a long computation.

The function y-or-n-p-with-timeout provides a simple way to use a timer to avoid waiting too long for an answer.  See Yes-or-No Queries.

 -- Function: cancel-timer timer
     This cancels the requested action for TIMER, which should be a timer---usually, one previously returned by run-at-time or run-with-idle-timer.  This cancels the effect of that call to one of these functions; the arrival of the specified time will not cause anything special to happen.

Idle Timers
===========

Here is how to set up a timer that runs when Emacs is idle for a certain length of time.  Aside from how to set them up, idle timers work just like ordinary timers.

 -- Command: run-with-idle-timer secs repeat function &rest args
     Set up a timer which runs the next time Emacs is idle for SECS seconds.  The value of SECS may be a number or a value of the type returned by current-idle-time.

     If REPEAT is nil, the timer runs just once, the first time Emacs remains idle for a long enough time.  More often REPEAT is non-nil, which means to run the timer each time Emacs remains idle for SECS seconds.

     The function run-with-idle-timer returns a timer value which you can use in calling cancel-timer (see Timers).

Emacs becomes idle when it starts waiting for user input, and it remains idle until the user provides some input.  If a timer is set for five seconds of idleness, it runs approximately five seconds after Emacs first becomes idle.  Even if REPEAT is non-nil, this timer will not run again as long as Emacs remains idle, because the duration of idleness will continue to increase and will not go down to five seconds again.

Emacs can do various things while idle: garbage collect, autosave or handle data from a subprocess.  But these interludes during idleness do not interfere with idle timers, because they do not reset the clock of idleness to zero.  An idle timer set for 600 seconds will run when ten minutes have elapsed since the last user command was finished, even if subprocess output has been accepted thousands of times within those ten minutes, and even if there have been garbage collections and autosaves.

When the user supplies input, Emacs becomes non-idle while executing the input.  Then it becomes idle again, and all the idle timers that are set up to repeat will subsequently run another time, one by one.

Do not write an idle timer function containing a loop which does a certain amount of processing each time around, and exits when (input-pending-p) is non-nil.  This approach seems very natural but has two problems:

  * It blocks out all process output (since Emacs accepts process output only while waiting).

  * It blocks out any idle timers that ought to run during that time.

Similarly, do not write an idle timer function that sets up another idle timer (including the same idle timer) with SECS argument less than or equal to the current idleness time.  Such a timer will run almost immediately, and continue running again and again, instead of waiting for the next time Emacs becomes idle.  The correct approach is to reschedule with an appropriate increment of the current value of the idleness time, as described below.

 -- Function: current-idle-time
     If Emacs is idle, this function returns the length of time Emacs has been idle, as a list of four integers: (SEC-HIGH SEC-LOW MICROSEC PICOSEC), using the same format as current-time (see Time of Day).

     When Emacs is not idle, current-idle-time returns nil. This is a convenient way to test whether Emacs is idle.

The main use of current-idle-time is when an idle timer function wants to ``take a break'' for a while.  It can set up another idle timer to call the same function again, after a few seconds more idleness.  Here's an example:

     (defvar my-resume-timer nil
       "Timer for `my-timer-function' to reschedule itself, or nil.")

     (defun my-timer-function ()
       ;; If the user types a command while my-resume-timer
       ;; is active, the next time this function is called from
       ;; its main idle timer, deactivate my-resume-timer.
       (when my-resume-timer
         (cancel-timer my-resume-timer))
       ...DO THE WORK FOR A WHILE...
       (when TAKING-A-BREAK
         (setq my-resume-timer
               (run-with-idle-timer
                 ;; Compute an idle time BREAK-LENGTH
                 ;; more than the current value.
                 (time-add (current-idle-time)
                           (seconds-to-time BREAK-LENGTH))
                 nil
                 'my-timer-function))))

Terminal Input
==============

This section describes functions and variables for recording or manipulating terminal input.  See Display, for related functions.

Input Modes
-----------

 -- Function: set-input-mode interrupt flow meta &optional quit-char
     This function sets the mode for reading keyboard input.  If INTERRUPT is non-nil, then Emacs uses input interrupts. If it is nil, then it uses CBREAK mode.  The default setting is system-dependent.  Some systems always use CBREAK mode regardless of what is specified.

     When Emacs communicates directly with X, it ignores this argument and uses interrupts if that is the way it knows how to communicate.

     If FLOW is non-nil, then Emacs uses XON/XOFF (C-q, C-s) flow control for output to the terminal.  This has no effect except in CBREAK mode.

     The argument META controls support for input character codes above 127.  If META is t, Emacs converts characters with the 8th bit set into Meta characters.  If META is nil, Emacs disregards the 8th bit; this is necessary when the terminal uses it as a parity bit.  If META is neither t nor nil, Emacs uses all 8 bits of input unchanged.  This is good for terminals that use 8-bit character sets.

     If QUIT-CHAR is non-nil, it specifies the character to use for quitting.  Normally this character is C-g. See Quitting.

The current-input-mode function returns the input mode settings Emacs is currently using.

 -- Function: current-input-mode
     This function returns the current mode for reading keyboard input.  It returns a list, corresponding to the arguments of set-input-mode, of the form (INTERRUPT FLOW META QUIT) in which:

     interrupt
          is non-nil when Emacs is using interrupt-driven input.  If nil, Emacs is using CBREAK mode.

     flow
          is non-nil if Emacs uses XON/XOFF (C-q, C-s) flow control for output to the terminal.  This value is meaningful only when INTERRUPT is nil.

     meta
          is t if Emacs treats the eighth bit of input characters as the meta bit; nil means Emacs clears the eighth bit of every input character; any other value means Emacs uses all eight bits as the basic character code.

     quit
          is the character Emacs currently uses for quitting, usually C-g.

Recording Input
---------------

 -- Function: recent-keys
     This function returns a vector containing the last 300 input events from the keyboard or mouse.  All input events are included, whether or not they were used as parts of key sequences.  Thus, you always get the last 300 input events, not counting events generated by keyboard macros. (These are excluded because they are less interesting for debugging; it should be enough to see the events that invoked the macros.)

     A call to clear-this-command-keys (see Command Loop Info) causes this function to return an empty vector immediately afterward.

 -- Command: open-dribble-file filename
     This function opens a dribble file named FILENAME.  When a dribble file is open, each input event from the keyboard or mouse (but not those from keyboard macros) is written in that file.  A non-character event is expressed using its printed representation surrounded by <...>.  Be aware that sensitive information (such as passwords) may end up recorded in the dribble file.

     You close the dribble file by calling this function with an argument of nil.

See also the open-termscript function (see Terminal Output).

Terminal Output
===============

The terminal output functions send output to a text terminal, or keep track of output sent to the terminal.  The variable baud-rate tells you what Emacs thinks is the output speed of the terminal.

 -- User Option: baud-rate
     This variable's value is the output speed of the terminal, as far as Emacs knows.  Setting this variable does not change the speed of actual data transmission, but the value is used for calculations such as padding.

     It also affects decisions about whether to scroll part of the screen or repaint on text terminals.  See Forcing Redisplay, for the corresponding functionality on graphical terminals.

     The value is measured in baud.

If you are running across a network, and different parts of the network work at different baud rates, the value returned by Emacs may be different from the value used by your local terminal.  Some network protocols communicate the local terminal speed to the remote machine, so that Emacs and other programs can get the proper value, but others do not.  If Emacs has the wrong value, it makes decisions that are less than optimal.  To fix the problem, set baud-rate.

 -- Function: send-string-to-terminal string &optional terminal
     This function sends STRING to TERMINAL without alteration. Control characters in STRING have terminal-dependent effects. This function operates only on text terminals.  TERMINAL may be a terminal object, a frame, or nil for the selected frame's terminal.  In batch mode, STRING is sent to stdout when TERMINAL is nil.

     One use of this function is to define function keys on terminals that have downloadable function key definitions.  For example, this is how (on certain terminals) to define function key 4 to move forward four characters (by transmitting the characters C-u C-f to the computer):

          (send-string-to-terminal "\eF4\^U\^F")
               => nil

 -- Command: open-termscript filename
     This function is used to open a termscript file that will record all the characters sent by Emacs to the terminal.  It returns nil.  Termscript files are useful for investigating problems where Emacs garbles the screen, problems that are due to incorrect Termcap entries or to undesirable settings of terminal options more often than to actual Emacs bugs.  Once you are certain which characters were actually output, you can determine reliably whether they correspond to the Termcap specifications in use.

          (open-termscript "../junk/termscript")
               => nil

     You close the termscript file by calling this function with an argument of nil.

     See also open-dribble-file in Recording Input.

Sound Output
============

To play sound using Emacs, use the function play-sound.  Only certain systems are supported; if you call play-sound on a system which cannot really do the job, it gives an error.

The sound must be stored as a file in RIFF-WAVE format (.wav) or Sun Audio format (.au).

 -- Function: play-sound sound
     This function plays a specified sound.  The argument, SOUND, has the form (sound PROPERTIES...), where the PROPERTIES consist of alternating keywords (particular symbols recognized specially) and values corresponding to them.

     Here is a table of the keywords that are currently meaningful in SOUND, and their meanings:

     :file FILE
          This specifies the file containing the sound to play. If the file name is not absolute, it is expanded against the directory data-directory.

     :data DATA
          This specifies the sound to play without need to refer to a file.  The value, DATA, should be a string containing the same bytes as a sound file.  We recommend using a unibyte string.

     :volume VOLUME
          This specifies how loud to play the sound.  It should be a number in the range of 0 to 1.  The default is to use whatever volume has been specified before.

     :device DEVICE
          This specifies the system device on which to play the sound, as a string.  The default device is system-dependent.

     Before actually playing the sound, play-sound calls the functions in the list play-sound-functions. Each function is called with one argument, SOUND.

 -- Command: play-sound-file file &optional volume device
     This function is an alternative interface to playing a sound FILE specifying an optional VOLUME and DEVICE.

 -- Variable: play-sound-functions
     A list of functions to be called before playing a sound.  Each function is called with one argument, a property list that describes the sound.

Operating on X11 Keysyms
========================

To define system-specific X11 keysyms, set the variable system-key-alist.

 -- Variable: system-key-alist
     This variable's value should be an alist with one element for each system-specific keysym.  Each element has the form (CODE . SYMBOL), where CODE is the numeric keysym code (not including the ``vendor specific'' bit, -2**28), and SYMBOL is the name for the function key.

     For example (168 . mute-acute) defines a system-specific key (used by HP X servers) whose numeric code is -2**28 + 168.

     It is not crucial to exclude from the alist the keysyms of other X servers; those do no harm, as long as they don't conflict with the ones used by the X server actually in use.

     The variable is always local to the current terminal, and cannot be buffer-local.  See Multiple Terminals.

You can specify which keysyms Emacs should use for the Meta, Alt, Hyper, and Super modifiers by setting these variables:

 -- Variable: x-alt-keysym
 -- Variable: x-meta-keysym
 -- Variable: x-hyper-keysym
 -- Variable: x-super-keysym
     The name of the keysym that should stand for the Alt modifier (respectively, for Meta, Hyper, and Super).  For example, here is how to swap the Meta and Alt modifiers within Emacs:

          (setq x-alt-keysym 'meta)
          (setq x-meta-keysym 'alt)

Batch Mode
==========

The command-line option -batch causes Emacs to run noninteractively.  In this mode, Emacs does not read commands from the terminal, it does not alter the terminal modes, and it does not expect to be outputting to an erasable screen.  The idea is that you specify Lisp programs to run; when they are finished, Emacs should exit.  The way to specify the programs to run is with -l FILE, which loads the library named FILE, or -f FUNCTION, which calls FUNCTION with no arguments, or --eval FORM.

Any Lisp program output that would normally go to the echo area, either using message, or using prin1, etc., with t as the stream, goes instead to Emacs's standard error descriptor when in batch mode.  Similarly, input that would normally come from the minibuffer is read from the standard input descriptor. Thus, Emacs behaves much like a noninteractive application program.  (The echo area output that Emacs itself normally generates, such as command echoing, is suppressed entirely.)

 -- Variable: noninteractive
     This variable is non-nil when Emacs is running in batch mode.

Session Management
==================

Emacs supports the X Session Management Protocol, which is used to suspend and restart applications.  In the X Window System, a program called the session manager is responsible for keeping track of the applications that are running.  When the X server shuts down, the session manager asks applications to save their state, and delays the actual shutdown until they respond.  An application can also cancel the shutdown.

When the session manager restarts a suspended session, it directs these applications to individually reload their saved state.  It does this by specifying a special command-line argument that says what saved session to restore.  For Emacs, this argument is --smid SESSION.

 -- Variable: emacs-save-session-functions
     Emacs supports saving state via a hook called emacs-save-session-functions.  Emacs runs this hook when the session manager tells it that the window system is shutting down.  The functions are called with no arguments, and with the current buffer set to a temporary buffer.  Each function can use insert to add Lisp code to this buffer.  At the end, Emacs saves the buffer in a file, called the session file.

     Subsequently, when the session manager restarts Emacs, it loads the session file automatically (see Loading).  This is performed by a function named emacs-session-restore, which is called during startup.  See Startup Summary.

     If a function in emacs-save-session-functions returns non-nil, Emacs tells the session manager to cancel the shutdown.

Here is an example that just inserts some text into *scratch* when Emacs is restarted by the session manager.

     (add-hook 'emacs-save-session-functions 'save-yourself-test)

     (defun save-yourself-test ()
       (insert "(save-current-buffer
       (switch-to-buffer \"*scratch*\")
       (insert \"I am restored\"))")
       nil)

Desktop Notifications
=====================

Emacs is able to send notifications on systems that support the freedesktop.org Desktop Notifications Specification.  In order to use this functionality, Emacs must have been compiled with D-Bus support, and the notifications library must be loaded.  See D-Bus (D-Bus integration in Emacs).

 -- Function: notifications-notify &rest params
     This function sends a notification to the desktop via D-Bus, consisting of the parameters specified by the PARAMS arguments. These arguments should consist of alternating keyword and value pairs. The supported keywords and values are as follows:

     :bus BUS
          The D-Bus bus.  This argument is needed only if a bus other than :session shall be used.

     :title TITLE
          The notification title.

     :body TEXT
          The notification body text.  Depending on the implementation of the notification server, the text could contain HTML markups, like "<b>bold text</b>", hyperlinks, or images.  Special HTML characters must be encoded, as "Contact &lt;postmaster@localhost&gt;!".

     :app-name NAME
          The name of the application sending the notification.  The default is notifications-application-name.

     :replaces-id ID
          The notification ID that this notification replaces.  ID must be the result of a previous notifications-notify call.

     :app-icon ICON-FILE
          The file name of the notification icon.  If set to nil, no icon is displayed.  The default is notifications-application-icon.

     :actions (KEY TITLE KEY TITLE ...)
          A list of actions to be applied.  KEY and TITLE are both strings.  The default action (usually invoked by clicking the notification) should have a key named "default".  The title can be anything, though implementations are free not to display it.

     :timeout TIMEOUT
          The timeout time in milliseconds since the display of the notification at which the notification should automatically close.  If -1, the notification's expiration time is dependent on the notification server's settings, and may vary for the type of notification.  If 0, the notification never expires.  Default value is -1.

     :urgency URGENCY
          The urgency level.  It can be low, normal, or critical.

     :action-items
          When this keyword is given, the TITLE string of the actions is interpreted as icon name.

     :category CATEGORY
          The type of notification this is, a string.  See the Desktop Notifications Specification (http://developer.gnome.org/notification-spec/#categories) for a list of standard categories.

     :desktop-entry FILENAME
          This specifies the name of the desktop filename representing the calling program, like "emacs".

     :image-data (WIDTH HEIGHT ROWSTRIDE HAS-ALPHA BITS CHANNELS DATA)
          This is a raw data image format that describes the width, height, rowstride, whether there is an alpha channel, bits per sample, channels and image data, respectively.

     :image-path PATH
          This is represented either as a URI (file:// is the only URI schema supported right now) or a name in a freedesktop.org-compliant icon theme from $XDG_DATA_DIRS/icons.

     :sound-file FILENAME
          The path to a sound file to play when the notification pops up.

     :sound-name NAME
          A themable named sound from the freedesktop.org sound naming specification from $XDG_DATA_DIRS/sounds, to play when the notification pops up.  Similar to the icon name, only for sounds. An example would be "message-new-instant".

     :suppress-sound
          Causes the server to suppress playing any sounds, if it has that ability.

     :resident
          When set the server will not automatically remove the notification when an action has been invoked. The notification will remain resident in the server until it is explicitly removed by the user or by the sender. This hint is likely only useful when the server has the :persistence capability.

     :transient
          When set the server will treat the notification as transient and by-pass the server's persistence capability, if it should exist.

     :x POSITION
     :y POSITION
          Specifies the X, Y location on the screen that the notification should point to.  Both arguments must be used together.

     :on-action FUNCTION
          Function to call when an action is invoked.  The notification ID and the KEY of the action are passed as arguments to the function.

     :on-close FUNCTION
          Function to call when the notification has been closed by timeout or by the user.  The function receive the notification ID and the closing REASON as arguments:

            * expired if the notification has expired

            * dismissed if the notification was dismissed by the user

            * close-notification if the notification was closed by a call to notifications-close-notification

            * undefined if the notification server hasn't provided a reason

     Which parameters are accepted by the notification server can be checked via notifications-get-capabilities.

     This function returns a notification id, an integer, which can be used to manipulate the notification item with notifications-close-notification or the :replaces-id argument of another notifications-notify call.  For example:

          (defun my-on-action-function (id key)
            (message "Message %d, key \"%s\" pressed" id key))
               => my-on-action-function

          (defun my-on-close-function (id reason)
            (message "Message %d, closed due to \"%s\"" id reason))
               => my-on-close-function

          (notifications-notify
           :title "Title"
           :body "This is <b>important</b>."
           :actions '("Confirm" "I agree" "Refuse" "I disagree")
           :on-action 'my-on-action-function
           :on-close 'my-on-close-function)
               => 22

          A message window opens on the desktop.  Press "I agree"
               => Message 22, key "Confirm" pressed
                  Message 22, closed due to "dismissed"

 -- Function: notifications-close-notification id &optional bus
     This function closes a notification with identifier ID. BUS can be a string denoting a D-Bus connection, the default is :session.

 -- Function: notifications-get-capabilities &optional bus
     Returns the capabilities of the notification server, a list of symbols.  BUS can be a string denoting a D-Bus connection, the default is :session.  The following capabilities can be expected:

     :actions
          The server will provide the specified actions to the user.

     :body
          Supports body text.

     :body-hyperlinks
          The server supports hyperlinks in the notifications.

     :body-images
          The server supports images in the notifications.

     :body-markup
          Supports markup in the body text.

     :icon-multi
          The server will render an animation of all the frames in a given image array.

     :icon-static
          Supports display of exactly 1 frame of any given image array.  This value is mutually exclusive with :icon-multi.

     :persistence
          The server supports persistence of notifications.

     :sound
          The server supports sounds on notifications.

     Further vendor-specific caps start with :x-vendor, like :x-gnome-foo-cap.

 -- Function: notifications-get-server-information &optional bus
     Return information on the notification server, a list of strings. BUS can be a string denoting a D-Bus connection, the default is :session.  The returned list is (NAME VENDOR VERSION SPEC-VERSION).

     name
          The product name of the server.

     vendor
          The vendor name.  For example, "KDE", "GNOME".

     version
          The server's version number.

     spec-version
          The specification version the server is compliant with.

     If SPEC_VERSION is nil, the server supports a specification prior to "1.0".

Notifications on File Changes
=============================

Several operating systems support watching of filesystems for changes of files.  If configured properly, Emacs links a respective library like gfilenotify, inotify, or  w32notify statically.  These libraries enable watching of filesystems on the local machine.

It is also possible to watch filesystems on remote machines, see Remote Files (The GNU Emacs Manual) This does not depend on one of the libraries linked to Emacs.

Since all these libraries emit different events on notified file changes, there is the Emacs library filenotify which provides a unique interface.

 -- Function: file-notify-add-watch file flags callback
     Add a watch for filesystem events pertaining to FILE.  This arranges for filesystem events pertaining to FILE to be reported to Emacs.

     The returned value is a descriptor for the added watch.  Its type depends on the underlying library, it cannot be assumed to be an integer as in the example below.  It should be used for comparison by equal only.

     If the FILE cannot be watched for some reason, this function signals a file-notify-error error.

     Sometimes, mounted filesystems cannot be watched for file changes. This is not detected by this function, a non-nil return value does not guarantee that changes on FILE will be notified.

     FLAGS is a list of conditions to set what will be watched for. It can include the following symbols:

     change
          watch for file changes

     attribute-change
          watch for file attribute changes, like permissions or modification time

     If FILE is a directory, changes for all files in that directory will be notified.  This does not work recursively.

     When any event happens, Emacs will call the CALLBACK function passing it a single argument EVENT, which is of the form

          (DESCRIPTOR ACTION FILE [FILE1])

     DESCRIPTOR is the same object as the one returned by this function.  ACTION is the description of the event.  It could be any one of the following symbols:

     created
          FILE was created

     deleted
          FILE was deleted

     changed
          FILE has changed

     renamed
          FILE has been renamed to FILE1

     attribute-changed
          a FILE attribute was changed

     FILE and FILE1 are the name of the file(s) whose event is being reported.  For example:

          (require 'filenotify)
               => filenotify

          (defun my-notify-callback (event)
            (message "Event %S" event))
               => my-notify-callback

          (file-notify-add-watch
            "/tmp" '(change attribute-change) 'my-notify-callback)
               => 35025468

          (write-region "foo" nil "/tmp/foo")
               => Event (35025468 created "/tmp/.#foo")
                  Event (35025468 created "/tmp/foo")
                  Event (35025468 changed "/tmp/foo")
                  Event (35025468 deleted "/tmp/.#foo")

          (write-region "bla" nil "/tmp/foo")
               => Event (35025468 created "/tmp/.#foo")
                  Event (35025468 changed "/tmp/foo") [2 times]
                  Event (35025468 deleted "/tmp/.#foo")

          (set-file-modes "/tmp/foo" (default-file-modes))
               => Event (35025468 attribute-changed "/tmp/foo")

     Whether the action renamed is returned, depends on the used watch library.  It can be expected, when a directory is watched, and both FILE and FILE1 belong to this directory.  Otherwise, the actions deleted and created could be returned in a random order.

          (rename-file "/tmp/foo" "/tmp/bla")
               => Event (35025468 renamed "/tmp/foo" "/tmp/bla")

          (file-notify-add-watch
            "/var/tmp" '(change attribute-change) 'my-notify-callback)
               => 35025504

          (rename-file "/tmp/bla" "/var/tmp/bla")
               => ;; gfilenotify
                  Event (35025468 renamed "/tmp/bla" "/var/tmp/bla")

               => ;; inotify
                  Event (35025504 created "/var/tmp/bla")
                  Event (35025468 deleted "/tmp/bla")

 -- Function: file-notify-rm-watch descriptor
     Removes an existing file watch specified by its DESCRIPTOR. DESCRIPTOR should be an object returned by file-notify-add-watch.

Dynamically Loaded Libraries
============================

A dynamically loaded library is a library that is loaded on demand, when its facilities are first needed.  Emacs supports such on-demand loading of support libraries for some of its features.

 -- Variable: dynamic-library-alist
     This is an alist of dynamic libraries and external library files implementing them.

     Each element is a list of the form (LIBRARY FILES...), where the car is a symbol representing a supported external library, and the rest are strings giving alternate filenames for that library.

     Emacs tries to load the library from the files in the order they appear in the list; if none is found, the Emacs session won't have access to that library, and the features it provides will be unavailable.

     Image support on some platforms uses this facility.  Here's an example of setting this variable for supporting images on MS-Windows:

          (setq dynamic-library-alist
                '((xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
                  (png "libpng12d.dll" "libpng12.dll" "libpng.dll"
                       "libpng13d.dll" "libpng13.dll")
                  (jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll"
                        "jpeg.dll")
                  (tiff "libtiff3.dll" "libtiff.dll")
                  (gif "giflib4.dll" "libungif4.dll" "libungif.dll")
                  (svg "librsvg-2-2.dll")
                  (gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
                  (glib "libglib-2.0-0.dll")
          	(gobject "libgobject-2.0-0.dll")))

     Note that image types pbm and xbm do not need entries in this variable because they do not depend on external libraries and are always available in Emacs.

     Also note that this variable is not meant to be a generic facility for accessing external libraries; only those already known by Emacs can be loaded through it.

     This variable is ignored if the given LIBRARY is statically linked into Emacs.