Windows
*******

This chapter describes most of the functions and variables related to Emacs windows.  See Frames and Windows, for how windows relate to frames.  See Display, for information on how text is displayed in windows.

Basic Concepts of Emacs Windows
===============================

A window in Emacs is the physical area of the screen in which a buffer is displayed.  The term is also used to refer to a Lisp object that represents that screen area in Emacs Lisp.  It should be clear from the context which is meant.

Emacs groups windows into frames; see Frames.  A frame represents an area of screen available for Emacs to use.  Each frame always contains at least one window, but you can subdivide it vertically or horizontally into multiple, nonoverlapping Emacs windows.

In each frame, at any time, one and only one window is designated as selected within the frame.  The frame's cursor appears in that window, but the other windows have ``non-selected'' cursors, normally less visible.  (see Cursor Parameters, for customizing this.)  At any time, one frame is the selected frame; and the window selected within that frame is the selected window.  The selected window's buffer is usually the current buffer (except when set-buffer has been used); see Current Buffer.

For practical purposes, a window exists only while it is displayed in a frame.  Once removed from the frame, the window is effectively deleted and should not be used, even though there may still be references to it from other Lisp objects; see Deleting Windows.  Restoring a saved window configuration is the only way for a window no longer on the screen to come back to life; see Window Configurations.

Users create multiple windows so they can look at several buffers at once.  Lisp libraries use multiple windows for a variety of reasons, but most often to display related information.  In Rmail, for example, you can move through a summary buffer in one window while the other window shows messages one at a time as they are reached.

The meaning of ``window'' in Emacs is similar to what it means in the context of general-purpose window systems such as X, but not identical. The X Window System places X windows on the screen; Emacs uses one or more X windows as frames, and subdivides them into Emacs windows.  When you use Emacs on a character-only terminal, Emacs treats the whole terminal screen as one frame.

Most window systems support arbitrarily located overlapping windows. In contrast, Emacs windows are tiled; they never overlap, and together they fill the whole screen or frame.  Because of the way in which Emacs creates new windows (see Splitting Windows) and resizes them (see Resizing Windows), not all conceivable tilings of windows on an Emacs frame are actually possible.

 -- Function: windowp object
     This function returns t if OBJECT is a window.

Splitting Windows
=================

The functions described below are the primitives used to split a window into two windows.  They do not accept a buffer as an argument.  Rather, the two ``halves'' of the split window initially display the same buffer previously visible in the window that was split.

 -- Command: split-window &optional window size horizontal
     This function splits a new window out of WINDOW's screen area.  It returns the new window.  The default for WINDOW is the selected window.  When you split the selected window, it remains selected.

     If HORIZONTAL is non-nil, then WINDOW splits into two side by side windows.  The original window keeps the leftmost SIZE columns, and gives the rest of the columns to the new window. Otherwise, WINDOW splits into windows one above the other, the original window keeps the upper SIZE lines and gives the rest of the lines to the new window.  The original window WINDOW is therefore the left-hand or upper of the two, and the new window is the right-hand or lower.

     If SIZE is omitted or nil, then WINDOW is divided evenly into two parts.  (If there is an odd line, it is allocated to the new window.)  When split-window is called interactively, all its arguments are nil.

     If splitting would result in making a window that is smaller than window-min-height or window-min-width (see Resizing Windows), split-window signals an error and does not split the window at all.

     The following example starts with one window on a screen that is 50 lines high by 80 columns wide; then it splits the window.

          (setq w (selected-window))
               => #<window 8 on windows.texi>
          (window-edges)          ; Edges in order:
               => (0 0 80 50)     ;   left--top--right--bottom

          ;; Returns window created
          (setq w2 (split-window w 15))
               => #<window 28 on windows.texi>

          (window-edges w2)
               => (0 15 80 50)    ; Bottom window;
                                  ;   top is line 15

          (window-edges w)
               => (0 0 80 15)     ; Top window

     The screen looks like this:

                   __________
                  |          |  line 0
                  |    w     |
                  |__________|
                  |          |  line 15
                  |    w2    |
                  |__________|
                                line 50
           column 0   column 80

     Next, split the top window horizontally:

          (setq w3 (split-window w 35 t))
               => #<window 32 on windows.texi>

          (window-edges w3)
               => (35 0 80 15)  ; Left edge at column 35

          (window-edges w)
               => (0 0 35 15)   ; Right edge at column 35

          (window-edges w2)
               => (0 15 80 50)  ; Bottom window unchanged

     Now the screen looks like this:

               column 35
                   __________
                  |   |      |  line 0
                  | w |  w3  |
                  |___|______|
                  |          |  line 15
                  |    w2    |
                  |__________|
                                line 50
           column 0   column 80

     Normally, Emacs indicates the border between two side-by-side windows with a scroll bar (see Scroll Bars), or with | characters.  The display table can specify alternative border characters; see Display Tables.

 -- Command: split-window-vertically &optional size
     This function splits the selected window into two windows, one above the other, leaving the upper of the two windows selected, with SIZE lines.  (If SIZE is negative, then the lower of the two windows gets -SIZE lines and the upper window gets the rest, but the upper window is still the one selected.)  However, if split-window-keep-point (see below) is nil, then either window can be selected.

     In other respects, this function is similar to split-window. In particular, the upper window is the original one and the return value is the new, lower window.

 -- User Option: split-window-keep-point
     If this variable is non-nil (the default), then split-window-vertically behaves as described above.

     If it is nil, then split-window-vertically adjusts point in each of the two windows to avoid scrolling.  (This is useful on slow terminals.)  It selects whichever window contains the screen line that point was previously on.

     This variable affects the behavior of split-window-vertically only.  It has no effect on the other functions described here.

 -- Command: split-window-horizontally &optional size
     This function splits the selected window into two windows side-by-side, leaving the selected window on the left with SIZE columns.  If SIZE is negative, the rightmost window gets -SIZE columns, but the leftmost window still remains selected.

     This function is basically an interface to split-window. You could define a simplified version of the function like this:

          (defun split-window-horizontally (&optional arg)
            "Split selected window into two windows, side by side..."
            (interactive "P")

            (let ((size (and arg (prefix-numeric-value arg))))
              (and size (< size 0)
                   (setq size (+ (window-width) size)))
              (split-window nil size t)))

 -- Function: one-window-p &optional no-mini all-frames
     This function returns non-nil if there is only one window.  The argument NO-MINI, if non-nil, means don't count the minibuffer even if it is active; otherwise, the minibuffer window is counted when it is active.

     The argument ALL-FRAMES specifies which frames to consider.  Here are the possible values and their meanings:

     nil
          Count the windows in the selected frame, plus the minibuffer used by that frame even if it lies in some other frame.

     t
          Count all windows in all existing frames.

     visible
          Count all windows in all visible frames.

     0
          Count all windows in all visible or iconified frames.

     anything else
          Count precisely the windows in the selected frame, and no others.

Deleting Windows
================

A window remains visible on its frame unless you delete it by calling certain functions that delete windows.  A deleted window cannot appear on the screen, but continues to exist as a Lisp object until there are no references to it.  There is no way to cancel the deletion of a window aside from restoring a saved window configuration (see Window Configurations).  Restoring a window configuration also deletes any windows that aren't part of that configuration.

When you delete a window, the space it took up is given to one of its sibling windows adjacent to it.

 -- Function: window-live-p window
     This function returns nil if WINDOW is deleted, and t otherwise.

     Warning: Erroneous information or fatal errors may result from using a deleted window as if it were live.

 -- Command: delete-window &optional window
     This function removes WINDOW from display and returns nil. The default for WINDOW is the selected window.  An error is signaled if WINDOW is the only window on its frame.

 -- Command: delete-other-windows &optional window
     This function makes WINDOW the only window on its frame, by deleting the other windows in that frame.  The default for WINDOW is the selected window.  The return value is nil.

 -- Command: delete-windows-on &optional buffer-or-name frame
     This function deletes all windows showing BUFFER-OR-NAME.  If there are no windows showing BUFFER-OR-NAME, it does nothing.  The optional argument BUFFER-OR-NAME may be a buffer or the name of an existing buffer and defaults to the current buffer.

     delete-windows-on operates frame by frame.  If a frame has several windows showing different buffers, then those showing BUFFER-OR-NAME are removed, and the others expand to fill the space.  If all windows in some frame are showing BUFFER-OR-NAME (including the case where there is only one window), then the frame winds up with a single window showing another buffer chosen with other-buffer (see The Buffer List).  If, however, the window showing BUFFER-OR-NAME is dedicated to its buffer (see Dedicated Windows), and there are other frames left, that window's frame is deleted.

     The optional argument FRAME specifies which frames to operate on. This function does not use it in quite the same way as the other functions which scan all windows; specifically, the values t and nil have the opposite of their meanings in other functions.  Here are the full details:

       * If it is nil, operate on all frames.

       * If it is t, operate on the selected frame.

       * If it is visible, operate on all visible frames.

       * If it is 0, operate on all visible or iconified frames.

       * If it is a frame, operate on that frame.

     This function always returns nil.

Selecting Windows
=================

When a window is selected, the buffer in the window becomes the current buffer, and the cursor will appear in it.

 -- Function: selected-window
     This function returns the selected window.  This is the window in which the cursor appears and to which many commands apply.

 -- Function: select-window window &optional norecord
     This function makes WINDOW the selected window.  The cursor then appears in WINDOW (after redisplay).  Unless WINDOW was already selected, select-window makes WINDOW's buffer the current buffer.  The return value is WINDOW.

     Normally, WINDOW's selected buffer is moved to the front of the buffer list (see The Buffer List) and WINDOW becomes the most recently selected window.  But if NORECORD is non-nil, the buffer list remains unchanged and WINDOW does not become the most recently selected one.

          (setq w (next-window))
          (select-window w)
               => #<window 65 on windows.texi>

 -- Macro: save-selected-window forms...
     This macro records the selected frame, as well as the selected window of each frame, executes FORMS in sequence, then restores the earlier selected frame and windows.  It also saves and restores the current buffer.  It returns the value of the last form in FORMS.

     This macro does not save or restore anything about the sizes, arrangement or contents of windows; therefore, if FORMS change them, the change persists.  If the previously selected window of some frame is no longer live at the time of exit from FORMS, that frame's selected window is left alone.  If the previously selected window is no longer live, then whatever window is selected at the end of FORMS remains selected.  The current buffer is restored if and only if it is still live when exiting FORMS.

     This macro changes neither the ordering of recently selected windows nor the buffer list.

 -- Macro: with-selected-window window forms...
     This macro selects WINDOW, executes FORMS in sequence, then restores the previously selected window and current buffer.  The ordering of recently selected windows and the buffer list remain unchanged unless you deliberately change them within FORMS, for example, by calling select-window with argument NORECORD nil.

The following functions choose one of the windows on the screen, offering various criteria for the choice.

 -- Function: get-lru-window &optional frame dedicated
     This function returns the window least recently ``used'' (that is, selected) among a set of candidate windows.  If any full-width windows are present, it only considers these.

     The selected window is returned if it is the only candidate.  A minibuffer window is never a candidate.  A dedicated window (see Dedicated Windows) is never a candidate unless the optional argument DEDICATED is non-nil.

     The optional argument FRAME specifies which windows are considered.

       * If it is nil, consider windows on the selected frame.

       * If it is t, consider windows on all frames.

       * If it is visible, consider windows on all visible frames.

       * If it is 0, consider windows on all visible or iconified frames.

       * If it is a frame, consider windows on that frame.

 -- Function: get-largest-window &optional frame dedicated
     This function returns the window with the largest area (height times width).  If there are no side-by-side windows, then this is the window with the most lines.  A minibuffer window is never a candidate.  A dedicated window (see Dedicated Windows) is never a candidate unless the optional argument DEDICATED is non-nil.

     If there are two candidate windows of the same size, this function prefers the one that comes first in the cyclic ordering of windows, starting from the selected window (see Cyclic Window Ordering).

     The optional argument FRAME specifies which set of windows to consider, see get-lru-window above.

 -- Function: get-window-with-predicate predicate &optional minibuf all-frames default
     This function returns a window satisfying PREDICATE.  It cycles through all visible windows using walk-windows (see Cyclic Window Ordering), calling PREDICATE on each one of them with that window as its argument.  The function returns the first window for which PREDICATE returns a non-nil value; if that never happens, it returns DEFAULT (which defaults to nil).

     The optional arguments MINIBUF and ALL-FRAMES specify the set of windows to include in the scan.  See the description of next-window in Cyclic Window Ordering, for details.

Cyclic Ordering of Windows
==========================

When you use the command C-x o (other-window) to select some other window, it moves through the windows on the screen in a specific order.  For any given configuration of windows, this order never varies.  It is called the cyclic ordering of windows.

For a particular frame, this ordering generally goes from top to bottom, and from left to right.  But it may go down first or go right first, depending on the order in which windows were split.

If the first split was vertical (into windows one above each other), and then the subwindows were split horizontally, then the ordering is left to right in the top of the frame, and then left to right in the next lower part of the frame, and so on.  If the first split was horizontal, the ordering is top to bottom in the left part, and so on. In general, within each set of siblings at any level in the window tree (see Window Tree), the order is left to right, or top to bottom.

 -- Function: next-window &optional window minibuf all-frames
     This function returns the window following WINDOW in the cyclic ordering of windows.  This is the window C-x o selects if typed when WINDOW is selected.  The default for WINDOW is the selected window.

     The value of the optional argument MINIBUF specifies whether the minibuffer is included in the window order.  Normally, when MINIBUF is nil, the minibuffer is included only if it is currently ``active''; this matches the behavior of C-x o.  (The minibuffer window is active while the minibuffer is in use; see Minibuffers.)

     If MINIBUF is t, the cyclic ordering includes the minibuffer window even if it is not active.  If MINIBUF is neither t nor nil, the minibuffer window is not included even if it is active.

     The optional argument ALL-FRAMES specifies which frames to consider.  Here are the possible values and their meanings:

     nil
          Consider all the windows in WINDOW's frame, plus the minibuffer used by that frame even if it lies in some other frame.  If the minibuffer counts (as determined by MINIBUF), then all windows on all frames that share that minibuffer count too.

     t
          Consider all windows in all existing frames.

     visible
          Consider all windows in all visible frames.  (To get useful results, you must ensure WINDOW is in a visible frame.)

     0
          Consider all windows in all visible or iconified frames.

     a frame
          Consider all windows on that frame.

     anything else
          Consider precisely the windows in WINDOW's frame, and no others.

     This example assumes there are two windows, both displaying the buffer windows.texi:

          (selected-window)
               => #<window 56 on windows.texi>

          (next-window (selected-window))
               => #<window 52 on windows.texi>

          (next-window (next-window (selected-window)))
               => #<window 56 on windows.texi>

 -- Function: previous-window &optional window minibuf all-frames
     This function returns the window preceding WINDOW in the cyclic ordering of windows.  The other arguments specify which windows to include in the cycle, as in next-window.

 -- Command: other-window count &optional all-frames
     This function selects another window in the cyclic ordering of windows. COUNT specifies the number of windows to skip in the ordering, starting with the selected window, before making the selection.  If COUNT is a positive number, it skips COUNT windows forwards. COUNT negative means skip -COUNT windows backwards. If COUNT is zero, it does not skip any window, thus re-selecting the selected window.  In an interactive call, COUNT is the numeric prefix argument.

     The optional argument ALL-FRAMES has the same meaning as in next-window, but the MINIBUF argument of next-window is always effectively nil.  This function returns nil.

 -- Function: walk-windows proc &optional minibuf all-frames
     This function cycles through all windows.  It calls the function proc once for each window, with the window as its sole argument.

     The optional arguments MINIBUF and ALL-FRAMES specify the set of windows to include in the walk.  See next-window, above, for details.

 -- Function: window-list &optional frame minibuf window
     This function returns a list of all windows on FRAME, starting with WINDOW.  The default for FRAME is the selected frame; the default for WINDOW is the selected window.

     The value of MINIBUF specifies if the minibuffer window shall be included in the result list.  If MINIBUF is t, the result always includes the minibuffer window.  If MINIBUF is nil or omitted, that includes the minibuffer window if it is active.  If MINIBUF is neither nil nor t, the result never includes the minibuffer window.

Buffers and Windows
===================

This section describes low-level functions to examine windows or to display buffers in windows in a precisely controlled fashion. See Displaying Buffers, for related functions that find a window to use and specify a buffer for it. The functions described there are easier to use, but they employ heuristics in choosing or creating a window; use the functions described here when you need complete control.

 -- Function: set-window-buffer window buffer-or-name &optional keep-margins
     This function makes WINDOW display BUFFER-OR-NAME as its contents.  It returns nil.  The default for WINDOW is the selected window.  The argument BUFFER-OR-NAME must specify a buffer or the name of an existing buffer.

     set-window-buffer is the fundamental primitive for changing which buffer is displayed in a window, and all ways of doing that call this function.

          (set-window-buffer (selected-window) "foo")
               => nil

     Normally, displaying BUFFER-OR-NAME in WINDOW resets the window's position, display margins, fringe widths, and scroll bar settings based on the local variables of that buffer. However, if KEEP-MARGINS is non-nil, display margins and fringe widths of WINDOW remain unchanged.  See Fringes.

     set-window-buffer signals an error when WINDOW is strongly dedicated to its buffer (see Dedicated Windows) and does not already display BUFFER-OR-NAME.

     Note that this function runs window-scroll-functions before running window-configuration-change-hook.

 -- Variable: buffer-display-count
     This buffer-local variable records the number of times a buffer has been displayed in a window.  It is incremented each time set-window-buffer is called for the buffer.

 -- Function: window-buffer &optional window
     This function returns the buffer that WINDOW is displaying.  The default for WINDOW is the selected window.

          (window-buffer)
               => #<buffer windows.texi>

 -- Function: get-buffer-window &optional buffer-or-name all-frames
     This function returns a window currently displaying BUFFER-OR-NAME, or nil if there is none.  If there are several such windows, then the function returns the first one in the cyclic ordering of windows, starting from the selected window. See Cyclic Window Ordering.

     The argument BUFFER-OR-NAME may be a buffer or a buffer name and defaults to the current buffer.  The optional argument ALL-FRAMES specifies which windows to consider:

       * nil means consider windows on the selected frame.

       * t means consider windows on all existing frames.

       * visible means consider windows on all visible frames.

       * 0 means consider windows on all visible or iconified frames.

       * A frame means consider windows on that frame only.

     Observe that the behavior of get-buffer-window may differ from that of next-window (see Cyclic Window Ordering) when ALL-FRAMES equals nil or any value not listed here. Perhaps we will change get-buffer-window in the future to make it compatible with the other functions.

 -- Function: get-buffer-window-list &optional buffer-or-name minibuf all-frames
     This function returns a list of all windows currently displaying BUFFER-OR-NAME.  The argument BUFFER-OR-NAME may be a buffer or the name of an existing buffer and defaults to the current buffer.

     The two remaining arguments work like the same-named arguments of next-window; they are not like the optional arguments of get-buffer-window.

 -- Variable: buffer-display-time
     This variable records the time at which a buffer was last made visible in a window.  It is always local in each buffer; each time set-window-buffer is called, it sets this variable to (current-time) in the specified buffer (see Time of Day). When a buffer is first created, buffer-display-time starts out with the value nil.

Displaying Buffers in Windows
=============================

In this section we describe convenient functions that choose a window automatically and use it to display a specified buffer.  These functions can also split an existing window in certain circumstances.  We also describe variables that parameterize the heuristics used for choosing a window. See Buffers and Windows, for low-level primitives that give you more precise control.  All of these functions work by calling set-window-buffer.

Do not use the functions in this section in order to make a buffer current so that a Lisp program can access or modify it; they are too drastic for that purpose, since they change the display of buffers in windows, which would be gratuitous and surprise the user.  Instead, use set-buffer and save-current-buffer (see Current Buffer), which designate buffers as current for programmed access without affecting the display of buffers in windows.

 -- Command: switch-to-buffer buffer-or-name &optional norecord
     This function makes BUFFER-OR-NAME the current buffer, and also displays the buffer in the selected window.  This means that a human can see the buffer and subsequent keyboard commands will apply to it. Contrast this with set-buffer, which makes BUFFER-OR-NAME the current buffer but does not display it in the selected window; see Current Buffer.

     If BUFFER-OR-NAME is nil, switch-to-buffer chooses a buffer using other-buffer.  If BUFFER-OR-NAME is a string that does not identify an existing buffer, then a new buffer by that name is created.  The major mode for the new buffer is set according to the variable major-mode; see Auto Major Mode.

     When the selected window is the minibuffer window or is strongly dedicated to its buffer (see Dedicated Windows), this function calls pop-to-buffer (see below) to display the buffer in some other window.

     Normally the specified buffer is put at the front of the buffer list (both the selected frame's buffer list and the frame-independent buffer list).  This affects the operation of other-buffer.  However, if NORECORD is non-nil, this is not done.  See The Buffer List.

     The switch-to-buffer function is often used interactively, as the binding of C-x b.  It is also used frequently in programs.  It returns the buffer that it switched to.

The next two functions are similar to switch-to-buffer, except for the described features.

 -- Command: switch-to-buffer-other-window buffer-or-name &optional norecord
     This function makes the buffer specified by BUFFER-OR-NAME current and displays it in a window not currently selected, using the function pop-to-buffer (see below).

     The currently selected window is absolutely never used to do the job. If the selected window already displays BUFFER-OR-NAME, then it continues to do so, but another window is nonetheless found to display it in as well.

     This function updates the buffer list just like switch-to-buffer unless NORECORD is non-nil.

 -- Function: pop-to-buffer buffer-or-name &optional other-window norecord
     This function makes BUFFER-OR-NAME the current buffer and switches to it in some window, preferably not the window previously selected. The ``popped-to'' window becomes the selected window.  Its frame is given the X server's focus, if possible; see Input Focus.  The return value is the buffer that was switched to.

     If BUFFER-OR-NAME is nil, that means to choose some other buffer, but you don't specify which.  If BUFFER-OR-NAME is a string that does not name an existing buffer, a buffer by that name is created.  The major mode for the new buffer is set according to the variable major-mode.  See Auto Major Mode.

     If either of the variables display-buffer-reuse-frames or pop-up-frames is non-nil, pop-to-buffer looks for a window in any visible frame already displaying the buffer; if there is one, it selects and returns that window.  If no such window exists and pop-up-frames is non-nil, it creates a new frame and displays the buffer in it.  Otherwise, pop-to-buffer operates entirely within the selected frame.  (If the selected frame has just a minibuffer, pop-to-buffer operates within the most recently selected frame that was not just a minibuffer.)

     If the variable pop-up-windows is non-nil, windows may be split to create a new window that is different from the original window. For details, see Choosing Window.

     If OTHER-WINDOW is non-nil, pop-to-buffer finds or creates another window even if BUFFER-OR-NAME is already visible in the selected window.  Thus BUFFER-OR-NAME could end up displayed in two windows.  On the other hand, if BUFFER-OR-NAME is already displayed in the selected window and OTHER-WINDOW is nil, then the selected window is considered sufficient for displaying BUFFER-OR-NAME, so that nothing needs to be done.

     All the variables that affect display-buffer affect pop-to-buffer as well.  See Choosing Window.

     This function updates the buffer list just like switch-to-buffer unless NORECORD is non-nil.

 -- Command: replace-buffer-in-windows &optional buffer-or-name
     This function replaces BUFFER-OR-NAME in all windows displaying it with some other buffer.  It uses other-buffer to choose the other buffer.  In the usual applications of this function, you don't care which other buffer is used; you just want to make sure that BUFFER-OR-NAME is no longer displayed.

     The argument BUFFER-OR-NAME may be a buffer or the name of an existing buffer and defaults to the current buffer.

     If a window displaying BUFFER-OR-NAME is dedicated (see Dedicated Windows), and is not the only window on its frame, that window is deleted.  If that window is the only window on its frame and there are other frames left, the window's frame is deleted too.  If there are no other frames left, some other buffer is displayed in that window.

     This function returns nil.

Choosing a Window for Display
=============================

This section describes the basic facility that chooses a window to display a buffer in---display-buffer.  Higher-level functions and commands, like switch-to-buffer and pop-to-buffer, use this subroutine.  Here we describe how to use display-buffer and how to customize it.

 -- Command: display-buffer buffer-or-name &optional not-this-window frame
     This command makes BUFFER-OR-NAME appear in some window, but it does not select that window and does not make the buffer specified by BUFFER-OR-NAME current.  The identity of the selected window is unaltered by this function.  The argument BUFFER-OR-NAME must be a buffer or the name of an existing buffer.

     NOT-THIS-WINDOW non-nil means to display the specified buffer in a window other than the selected one, even if it is already displayed in the selected window.  This can cause the buffer to appear in two windows at once.  Otherwise, if BUFFER-OR-NAME is already being displayed in any window, that is good enough, so this function does nothing.

     display-buffer returns the window chosen to display BUFFER-OR-NAME.

     If the optional argument FRAME is non-nil, it specifies which frames to check when deciding whether the buffer is already displayed.  If the buffer is already displayed in some window on one of these frames, display-buffer simply returns that window.  Here are the possible values of FRAME:

       * nil means consider windows on the selected frame. (Actually, the last non-minibuffer frame.)

       * t means consider windows on all frames.

       * visible means consider windows on all visible frames.

       * 0 means consider windows on all visible or iconified frames.

       * A frame means consider windows on that frame only.

     Precisely how display-buffer finds or creates a window depends on the variables described below.

 -- User Option: display-buffer-reuse-frames
     If this variable is non-nil, display-buffer searches visible and iconified frames for a window displaying BUFFER-OR-NAME.  If there is such a window, display-buffer makes that window's frame visible and raises it if necessary, and returns the window.  If there is no such window or display-buffer-reuse-frames is nil, the behavior of display-buffer is determined by the variables described next.

 -- User Option: pop-up-windows
     This variable specifies whether display-buffer is allowed to split (see Splitting Windows) an existing window.  If this variable is non-nil, display-buffer tries to split the largest or least recently used window on the selected frame.  (If the selected frame is a minibuffer-only frame, display-buffer tries to split a window on another frame instead.)  If this variable is nil or the variable pop-up-frames (see below) is non-nil, display-buffer does not split any window.

 -- User Option: split-window-preferred-function
     This variable must specify a function with one argument, which is a window.  The display-buffer routines will call this function with one or more candidate windows when they look for a window to split.  The function is expected to split that window and return the new window.  If the function returns nil, this means that the argument window cannot (or shall not) be split.

     The default value of split-window-preferred-function is the function split-window-sensibly described below.  If you customize this option, bear in mind that the display-buffer routines may call your function up to two times when trying to split a window.  The argument of the first call is the largest window on the chosen frame (as returned by get-largest-window).  If that call fails to return a live window, your function is called a second time with the least recently used window on that frame (as returned by get-lru-window).

     The function specified by this option may try to split any other window instead of the argument window.  Note that the window selected at the time display-buffer was invoked is still selected when your function is called.  Hence, you can split the selected window (instead of the largest or least recently used one) by simply ignoring the window argument in the body of your function.  You can even choose to not split any window as long as the return value of your function specifies a live window or nil, but you are not encouraged to do so unconditionally.  If you want display-buffer to never split any windows, set pop-up-windows to nil.

 -- Function: split-window-sensibly window
     This function takes a window as argument and tries to split that window in a suitable way.  The two variables described next are useful for tuning the behavior of this function.

 -- User Option: split-height-threshold
     This variable specifies whether split-window-sensibly may split windows vertically.  If it is an integer, split-window-sensibly tries to vertically split a window only if it has at least this many lines.  If the window has less lines, splitting fails, or the value of this variable is nil, split-window-sensibly will try to split the window horizontally, subject to restrictions of split-width-threshold (see below).  If splitting horizontally fails too and the window is the only window on its frame, split-window-sensibly will try to split the window vertically disregarding the value of split-height-threshold.  If this fails as well, split-window-sensibly returns nil.

     split-window-sensibly does not split vertically a window whose height is fixed (see Resizing Windows).  Also, it vertically splits a window only if the space taken up by that window can accommodate two windows one above the other that are both at least window-min-height lines tall.  Moreover, if the window that shall be split has a mode line, split-window-sensibly does not split the window unless the new window can accommodate a mode line too.

 -- User Option: split-width-threshold
     This variable specifies whether split-window-sensibly may split windows horizontally.  If it is an integer, split-window-sensibly tries to horizontally split a window only if it has at least this many columns.  If it is nil, split-window-sensibly will not split the window horizontally.  (It still might split the window vertically, though, see above.)

     split-window-sensibly does not split horizontally a window if that window's width is fixed (see Resizing Windows).  Also, it horizontally splits a window only if the space that window takes up can accommodate two windows side by side that are both at least window-min-width columns wide.

 -- User Option: even-window-heights
     This variable specifies whether display-buffer should even out window heights if the buffer gets displayed in an existing window, above or beneath another window.  If even-window-heights is non-nil, the default, window heights will be evened out.  If either of the involved window has fixed height (see Resizing Windows) or even-window-heights is nil, the original window heights will be left alone.

 -- User Option: pop-up-frames
     This variable specifies whether display-buffer should make new frames.  If it is non-nil, display-buffer looks for a window already displaying BUFFER-OR-NAME on any visible or iconified frame.  If it finds such a window, it makes that window's frame visible and raises it if necessary, and returns the window. Otherwise it makes a new frame, unless the variable's value is graphic-only and the selected frame is not on a graphic display. See Frames, for more information.

     Note that the value of pop-up-windows does not matter if pop-up-frames is non-nil.  If pop-up-frames is nil, then display-buffer either splits a window or reuses one.

 -- User Option: pop-up-frame-function
     This variable specifies how to make a new frame if pop-up-frames is non-nil.

     The value of this variable must be a function of no arguments.  When display-buffer makes a new frame, it does so by calling that function, which should return a frame.  The default value of this variable is a function that creates a frame using the parameters specified by pop-up-frame-alist described next.

 -- User Option: pop-up-frame-alist
     This variable holds an alist specifying frame parameters used by the default value of pop-up-frame-function for making new frames. See Frame Parameters, for more information about frame parameters.

 -- User Option: special-display-buffer-names
     A list of buffer names identifying buffers that should be displayed specially.  If the name of BUFFER-OR-NAME is in this list, display-buffer handles the buffer specially.  By default, special display means to give the buffer a dedicated frame.

     If an element is a list, instead of a string, then the CAR of that list is the buffer name, and the rest of that list says how to create the frame.  There are two possibilities for the rest of that list (its CDR): It can be an alist, specifying frame parameters, or it can contain a function and arguments to give to it.  (The function's first argument is always the buffer to be displayed; the arguments from the list come after that.)

     For example:

          (("myfile" (minibuffer) (menu-bar-lines . 0)))

     specifies to display a buffer named myfile in a dedicated frame with specified minibuffer and menu-bar-lines parameters.

     The list of frame parameters can also use the phony frame parameters same-frame and same-window.  If the specified frame parameters include (same-window . VALUE) and VALUE is non-nil, that means to display the buffer in the current selected window.  Otherwise, if they include (same-frame . VALUE) and VALUE is non-nil, that means to display the buffer in a new window in the currently selected frame.

 -- User Option: special-display-regexps
     A list of regular expressions specifying buffers that should be displayed specially.  If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer specially.  By default, special display means to give the buffer a dedicated frame.

     If an element is a list, instead of a string, then the CAR of the list is the regular expression, and the rest of the list says how to create the frame.  See special-display-buffer-names above.

 -- Function: special-display-p buffer-name
     This function returns non-nil if displaying a buffer named BUFFER-NAME with display-buffer would create a special frame.  The value is t if it would use the default frame parameters, or else the specified list of frame parameters.

 -- User Option: special-display-function
     This variable holds the function to call to display a buffer specially. It receives the buffer as an argument, and should return the window in which it is displayed.  The default value of this variable is special-display-popup-frame, see below.

 -- Function: special-display-popup-frame buffer &optional args
     This function tries to make BUFFER visible in a frame of its own. If BUFFER is already displayed in some window, it makes that window's frame visible and raises it.  Otherwise, it creates a frame that is dedicated to BUFFER.  The return value is the window used to display BUFFER.

     If ARGS is an alist, it specifies frame parameters for the new frame.  If ARGS is a list whose CAR is a symbol, then (car ARGS) is called as a function to actually create and set up the frame; it is called with BUFFER as first argument, and (cdr ARGS) as additional arguments.

     This function always uses an existing window displaying BUFFER, whether or not it is in a frame of its own; but if you set up the above variables in your init file, before BUFFER was created, then presumably the window was previously made by this function.

 -- User Option: special-display-frame-alist
     This variable holds frame parameters for special-display-popup-frame to use when it creates a frame.

 -- User Option: same-window-buffer-names
     A list of buffer names for buffers that should be displayed in the selected window.  If the buffer's name is in this list, display-buffer handles the buffer by switching to it in the selected window.

 -- User Option: same-window-regexps
     A list of regular expressions that specify buffers that should be displayed in the selected window.  If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer by switching to it in the selected window.

 -- Function: same-window-p buffer-name
     This function returns t if displaying a buffer named BUFFER-NAME with display-buffer would put it in the selected window.

 -- User Option: display-buffer-function
     This variable is the most flexible way to customize the behavior of display-buffer.  If it is non-nil, it should be a function that display-buffer calls to do the work.  The function should accept two arguments, the first two arguments that display-buffer received.  It should choose or create a window, display the specified buffer in it, and then return the window.

     This variable takes precedence over all the other options described above.

If all options described above fail to produce a suitable window, display-buffer tries to reuse an existing window.  As a last resort, it will try to display BUFFER-OR-NAME on a separate frame. In that case, the value of pop-up-frames is disregarded.

Dedicated Windows
=================

Functions for displaying a buffer can be told to not use specific windows by marking these windows as dedicated to their buffers. display-buffer (see Choosing Window) never uses a dedicated window for displaying another buffer in it.  get-lru-window and get-largest-window (see Selecting Windows) do not consider dedicated windows as candidates when their DEDICATED argument is non-nil.  The behavior of set-window-buffer (see Buffers and Windows) with respect to dedicated windows is slightly different, see below.

When delete-windows-on (see Deleting Windows) wants to delete a dedicated window and that window is the only window on its frame, it deletes the window's frame too, provided there are other frames left. replace-buffer-in-windows (see Displaying Buffers) tries to delete all dedicated windows showing its buffer argument.  When such a window is the only window on its frame, that frame is deleted, provided there are other frames left.  If there are no more frames left, some other buffer is displayed in the window, and the window is marked as non-dedicated.

When you kill a buffer (see Killing Buffers) displayed in a dedicated window, any such window usually gets deleted too, since kill-buffer calls replace-buffer-in-windows for cleaning up windows.  Burying a buffer (see The Buffer List) deletes the selected window if it is dedicated to that buffer.  If, however, that window is the only window on its frame, bury-buffer displays another buffer in it and iconifies the frame.

 -- Function: window-dedicated-p &optional window
     This function returns non-nil if WINDOW is dedicated to its buffer and nil otherwise.  More precisely, the return value is the value assigned by the last call of set-window-dedicated-p for WINDOW or nil if that function was never called with WINDOW as its argument.  The default for WINDOW is the selected window.

 -- Function: set-window-dedicated-p window flag
     This function marks WINDOW as dedicated to its buffer if FLAG is non-nil, and non-dedicated otherwise.

     As a special case, if FLAG is t, WINDOW becomes strongly dedicated to its buffer.  set-window-buffer signals an error when the window it acts upon is strongly dedicated to its buffer and does not already display the buffer it is asked to display.  Other functions do not treat t differently from any non-nil value.

Windows and Point
=================

Each window has its own value of point (see Point), independent of the value of point in other windows displaying the same buffer.  This makes it useful to have multiple windows showing one buffer.

  * The window point is established when a window is first created; it is initialized from the buffer's point, or from the window point of another window opened on the buffer if such a window exists.

  * Selecting a window sets the value of point in its buffer from the window's value of point.  Conversely, deselecting a window sets the window's value of point from that of the buffer.  Thus, when you switch between windows that display a given buffer, the point value for the selected window is in effect in the buffer, while the point values for the other windows are stored in those windows.

  * As long as the selected window displays the current buffer, the window's point and the buffer's point always move together; they remain equal.

As far as the user is concerned, point is where the cursor is, and when the user switches to another buffer, the cursor jumps to the position of point in that buffer.

 -- Function: window-point &optional window
     This function returns the current position of point in WINDOW. For a nonselected window, this is the value point would have (in that window's buffer) if that window were selected.  The default for WINDOW is the selected window.

     When WINDOW is the selected window and its buffer is also the current buffer, the value returned is the same as point in that buffer. Strictly speaking, it would be more correct to return the ``top-level'' value of point, outside of any save-excursion forms.  But that value is hard to find.

 -- Function: set-window-point window position
     This function positions point in WINDOW at position POSITION in WINDOW's buffer.  It returns POSITION.

     If WINDOW is selected, and its buffer is current, this simply does goto-char.

 -- Variable: window-point-insertion-type
     This variable specifies the marker insertion type (see Marker Insertion Types) of window-point.  The default is nil, so window-point will stay behind text inserted there.

The Window Start and End Positions
==================================

Each window maintains a marker used to keep track of a buffer position that specifies where in the buffer display should start.  This position is called the display-start position of the window (or just the start).  The character after this position is the one that appears at the upper left corner of the window.  It is usually, but not inevitably, at the beginning of a text line.

After switching windows or buffers, and in some other cases, if the window start is in the middle of a line, Emacs adjusts the window start to the start of a line.  This prevents certain operations from leaving the window start at a meaningless point within a line.  This feature may interfere with testing some Lisp code by executing it using the commands of Lisp mode, because they trigger this readjustment.  To test such code, put it into a command and bind the command to a key.

 -- Function: window-start &optional window
     This function returns the display-start position of window WINDOW.  If WINDOW is nil, the selected window is used.  For example,

          (window-start)
               => 7058

     When you create a window, or display a different buffer in it, the display-start position is set to a display-start position recently used for the same buffer, or to point-min if the buffer doesn't have any.

     Redisplay updates the window-start position (if you have not specified it explicitly since the previous redisplay)---to make sure point appears on the screen.  Nothing except redisplay automatically changes the window-start position; if you move point, do not expect the window-start position to change in response until after the next redisplay.

     For a realistic example of using window-start, see the description of count-lines.  See Definition of count-lines.

 -- Function: window-end &optional window update
     This function returns the position where display of its buffer ends in WINDOW.  The default for WINDOW is the selected window.

     Simply changing the buffer text or moving point does not update the value that window-end returns.  The value is updated only when Emacs redisplays and redisplay completes without being preempted.

     If the last redisplay of WINDOW was preempted, and did not finish, Emacs does not know the position of the end of display in that window. In that case, this function returns nil.

     If UPDATE is non-nil, window-end always returns an up-to-date value for where display ends, based on the current window-start value.  If a previously saved value of that position is still valid, window-end returns that value; otherwise it computes the correct value by scanning the buffer text.

     Even if UPDATE is non-nil, window-end does not attempt to scroll the display if point has moved off the screen, the way real redisplay would do.  It does not alter the window-start value.  In effect, it reports where the displayed text will end if scrolling is not required.

 -- Function: set-window-start window position &optional noforce
     This function sets the display-start position of WINDOW to POSITION in WINDOW's buffer.  It returns POSITION.

     The display routines insist that the position of point be visible when a buffer is displayed.  Normally, they change the display-start position (that is, scroll the window) whenever necessary to make point visible. However, if you specify the start position with this function using nil for NOFORCE, it means you want display to start at POSITION even if that would put the location of point off the screen.  If this does place point off screen, the display routines move point to the left margin on the middle line in the window.

     For example, if point is 1 and you set the start of the window to 37, the start of the next line, point will be ``above'' the top of the window.  The display routines will automatically move point if it is still 1 when redisplay occurs.  Here is an example:

          ;; Here is what foo looks like before executing
          ;;   the set-window-start expression.

          ---------- Buffer: foo ----------
          -!-This is the contents of buffer foo.
          2
          3
          4
          5
          6
          ---------- Buffer: foo ----------

          (set-window-start
           (selected-window)
           (save-excursion
             (goto-char 1)
             (forward-line 1)
             (point)))
          => 37

          ;; Here is what foo looks like after executing
          ;;   the set-window-start expression.
          ---------- Buffer: foo ----------
          2
          3
          -!-4
          5
          6
          ---------- Buffer: foo ----------

     If NOFORCE is non-nil, and POSITION would place point off screen at the next redisplay, then redisplay computes a new window-start position that works well with point, and thus POSITION is not used.

 -- Function: pos-visible-in-window-p &optional position window partially
     This function returns non-nil if POSITION is within the range of text currently visible on the screen in WINDOW.  It returns nil if POSITION is scrolled vertically out of view. Locations that are partially obscured are not considered visible unless PARTIALLY is non-nil.  The argument POSITION defaults to the current position of point in WINDOW; WINDOW, to the selected window.  If POSITION is t, that means to check the last visible position in WINDOW.

     The pos-visible-in-window-p function considers only vertical scrolling.  If POSITION is out of view only because WINDOW has been scrolled horizontally, pos-visible-in-window-p returns non-nil anyway.  See Horizontal Scrolling.

     If POSITION is visible, pos-visible-in-window-p returns t if PARTIALLY is nil; if PARTIALLY is non-nil, and the character following POSITION is fully visible, it returns a list of the form (X Y), where X and Y are the pixel coordinates relative to the top left corner of the window; otherwise it returns an extended list of the form (X Y RTOP RBOT ROWH VPOS), where RTOP and RBOT specify the number of off-window pixels at the top and bottom of the row at POSITION, ROWH specifies the visible height of that row, and VPOS specifies the vertical position (zero-based row number) of that row.

     Here is an example:

          ;; If point is off the screen now, recenter it now.
          (or (pos-visible-in-window-p
               (point) (selected-window))
              (recenter 0))

 -- Function: window-line-height &optional line window
     This function returns the height of text line LINE in WINDOW.  If LINE is one of header-line or mode-line, window-line-height returns information about the corresponding line of the window.  Otherwise, LINE is a text line number starting from 0.  A negative number counts from the end of the window.  The default for LINE is the current line in WINDOW; the default for WINDOW is the selected window.

     If the display is not up to date, window-line-height returns nil.  In that case, pos-visible-in-window-p may be used to obtain related information.

     If there is no line corresponding to the specified LINE, window-line-height returns nil.  Otherwise, it returns a list (HEIGHT VPOS YPOS OFFBOT), where HEIGHT is the height in pixels of the visible part of the line, VPOS and YPOS are the vertical position in lines and pixels of the line relative to the top of the first text line, and OFFBOT is the number of off-window pixels at the bottom of the text line.  If there are off-window pixels at the top of the (first) text line, YPOS is negative.

Textual Scrolling
=================

Textual scrolling means moving the text up or down through a window.  It works by changing the value of the window's display-start location.  It may also change the value of window-point to keep point on the screen.

Textual scrolling was formerly called ``vertical scrolling,'' but we changed its name to distinguish it from the new vertical fractional scrolling feature (see Vertical Scrolling).

In the commands scroll-up and scroll-down, the directions ``up'' and ``down'' refer to the motion of the text in the buffer at which you are looking through the window.  Imagine that the text is written on a long roll of paper and that the scrolling commands move the paper up and down.  Thus, if you are looking at text in the middle of a buffer and repeatedly call scroll-down, you will eventually see the beginning of the buffer.

Some people have urged that the opposite convention be used: they imagine that the window moves over text that remains in place.  Then ``down'' commands would take you to the end of the buffer.  This view is more consistent with the actual relationship between windows and the text in the buffer, but it is less like what the user sees.  The position of a window on the terminal does not move, and short scrolling commands clearly move the text up or down on the screen.  We have chosen names that fit the user's point of view.

The textual scrolling functions (aside from scroll-other-window) have unpredictable results if the current buffer is different from the buffer that is displayed in the selected window.  See Current Buffer.

If the window contains a row which is taller than the height of the window (for example in the presence of a large image), the scroll functions will adjust the window's vertical scroll position to scroll the partially visible row.  To disable this feature, Lisp code may bind the variable auto-window-vscroll to nil (see Vertical Scrolling).

 -- Command: scroll-up &optional count
     This function scrolls the text in the selected window upward COUNT lines.  If COUNT is negative, scrolling is actually downward.

     If COUNT is nil (or omitted), then the length of scroll is next-screen-context-lines lines less than the usable height of the window (not counting its mode line).

     scroll-up returns nil, unless it gets an error because it can't scroll any further.

 -- Command: scroll-down &optional count
     This function scrolls the text in the selected window downward COUNT lines.  If COUNT is negative, scrolling is actually upward.

     If COUNT is omitted or nil, then the length of the scroll is next-screen-context-lines lines less than the usable height of the window (not counting its mode line).

     scroll-down returns nil, unless it gets an error because it can't scroll any further.

 -- Command: scroll-other-window &optional count
     This function scrolls the text in another window upward COUNT lines.  Negative values of COUNT, or nil, are handled as in scroll-up.

     You can specify which buffer to scroll by setting the variable other-window-scroll-buffer to a buffer.  If that buffer isn't already displayed, scroll-other-window displays it in some window.

     When the selected window is the minibuffer, the next window is normally the one at the top left corner.  You can specify a different window to scroll, when the minibuffer is selected, by setting the variable minibuffer-scroll-window.  This variable has no effect when any other window is selected.  When it is non-nil and the minibuffer is selected, it takes precedence over other-window-scroll-buffer.  See Definition of minibuffer-scroll-window.

     When the minibuffer is active, it is the next window if the selected window is the one at the bottom right corner.  In this case, scroll-other-window attempts to scroll the minibuffer.  If the minibuffer contains just one line, it has nowhere to scroll to, so the line reappears after the echo area momentarily displays the message Beginning of buffer.

 -- Variable: other-window-scroll-buffer
     If this variable is non-nil, it tells scroll-other-window which buffer's window to scroll.

 -- User Option: scroll-margin
     This option specifies the size of the scroll margin---a minimum number of lines between point and the top or bottom of a window.  Whenever point gets within this many lines of the top or bottom of the window, redisplay scrolls the text automatically (if possible) to move point out of the margin, closer to the center of the window.

 -- User Option: scroll-conservatively
     This variable controls how scrolling is done automatically when point moves off the screen (or into the scroll margin).  If the value is a positive integer N, then redisplay scrolls the text up to N lines in either direction, if that will bring point back into proper view.  This behavior is called conservative scrolling. Otherwise, scrolling happens in the usual way, under the control of other variables such as scroll-up-aggressively and scroll-down-aggressively.

     The default value is zero, which means that conservative scrolling never happens.

 -- User Option: scroll-down-aggressively
     The value of this variable should be either nil or a fraction F between 0 and 1.  If it is a fraction, that specifies where on the screen to put point when scrolling down.  More precisely, when a window scrolls down because point is above the window start, the new start position is chosen to put point F part of the window height from the top.  The larger F, the more aggressive the scrolling.

     A value of nil is equivalent to .5, since its effect is to center point.  This variable automatically becomes buffer-local when set in any fashion.

 -- User Option: scroll-up-aggressively
     Likewise, for scrolling up.  The value, F, specifies how far point should be placed from the bottom of the window; thus, as with scroll-up-aggressively, a larger value scrolls more aggressively.

 -- User Option: scroll-step
     This variable is an older variant of scroll-conservatively. The difference is that if its value is N, that permits scrolling only by precisely N lines, not a smaller number.  This feature does not work with scroll-margin.  The default value is zero.

 -- User Option: scroll-preserve-screen-position
     If this option is t, scrolling which would move the current point position out of the window chooses the new position of point so that the vertical position of the cursor is unchanged, if possible.

     If it is non-nil and not t, then the scrolling functions always preserve the vertical position of point, if possible.

 -- User Option: next-screen-context-lines
     The value of this variable is the number of lines of continuity to retain when scrolling by full screens.  For example, scroll-up with an argument of nil scrolls so that this many lines at the bottom of the window appear instead at the top.  The default value is 2.

 -- Command: recenter &optional count
     This function scrolls the text in the selected window so that point is displayed at a specified vertical position within the window.  It does not ``move point'' with respect to the text.

     If COUNT is a nonnegative number, that puts the line containing point COUNT lines down from the top of the window.  If COUNT is a negative number, then it counts upward from the bottom of the window, so that -1 stands for the last usable line in the window.  If COUNT is a non-nil list, then it stands for the line in the middle of the window.

     If COUNT is nil, recenter puts the line containing point in the middle of the window, then clears and redisplays the entire selected frame.

     When recenter is called interactively, COUNT is the raw prefix argument.  Thus, typing C-u as the prefix sets the COUNT to a non-nil list, while typing C-u 4 sets COUNT to 4, which positions the current line four lines from the top.

     With an argument of zero, recenter positions the current line at the top of the window.  This action is so handy that some people make a separate key binding to do this.  For example,

          (defun line-to-top-of-window ()
            "Scroll current line to top of window.
          Replaces three keystroke sequence C-u 0 C-l."
            (interactive)
            (recenter 0))

          (global-set-key [kp-multiply] 'line-to-top-of-window)

Vertical Fractional Scrolling
=============================

Vertical fractional scrolling means shifting text in a window up or down by a specified multiple or fraction of a line.  Each window has a vertical scroll position, which is a number, never less than zero.  It specifies how far to raise the contents of the window. Raising the window contents generally makes all or part of some lines disappear off the top, and all or part of some other lines appear at the bottom.  The usual value is zero.

The vertical scroll position is measured in units of the normal line height, which is the height of the default font.  Thus, if the value is .5, that means the window contents are scrolled up half the normal line height.  If it is 3.3, that means the window contents are scrolled up somewhat over three times the normal line height.

What fraction of a line the vertical scrolling covers, or how many lines, depends on what the lines contain.  A value of .5 could scroll a line whose height is very short off the screen, while a value of 3.3 could scroll just part of the way through a tall line or an image.

 -- Function: window-vscroll &optional window pixels-p
     This function returns the current vertical scroll position of WINDOW.  The default for WINDOW is the selected window. If PIXELS-P is non-nil, the return value is measured in pixels, rather than in units of the normal line height.

          (window-vscroll)
               => 0

 -- Function: set-window-vscroll window lines &optional pixels-p
     This function sets WINDOW's vertical scroll position to LINES.  If WINDOW is nil, the selected window is used.  The argument LINES should be zero or positive; if not, it is taken as zero.

     The actual vertical scroll position must always correspond to an integral number of pixels, so the value you specify is rounded accordingly.

     The return value is the result of this rounding.

          (set-window-vscroll (selected-window) 1.2)
               => 1.13

     If PIXELS-P is non-nil, LINES specifies a number of pixels.  In this case, the return value is LINES.

 -- Variable: auto-window-vscroll
     If this variable is non-nil, the line-move, scroll-up, and scroll-down functions will automatically modify the vertical scroll position to scroll through display rows that are taller than the height of the window, for example in the presence of large images.

Horizontal Scrolling
====================

Horizontal scrolling means shifting the image in the window left or right by a specified multiple of the normal character width.  Each window has a horizontal scroll position, which is a number, never less than zero.  It specifies how far to shift the contents left. Shifting the window contents left generally makes all or part of some characters disappear off the left, and all or part of some other characters appear at the right.  The usual value is zero.

The horizontal scroll position is measured in units of the normal character width, which is the width of space in the default font.  Thus, if the value is 5, that means the window contents are scrolled left by 5 times the normal character width.  How many characters actually disappear off to the left depends on their width, and could vary from line to line.

Because we read from side to side in the ``inner loop,'' and from top to bottom in the ``outer loop,'' the effect of horizontal scrolling is not like that of textual or vertical scrolling.  Textual scrolling involves selection of a portion of text to display, and vertical scrolling moves the window contents contiguously; but horizontal scrolling causes part of each line to go off screen.

Usually, no horizontal scrolling is in effect; then the leftmost column is at the left edge of the window.  In this state, scrolling to the right is meaningless, since there is no data to the left of the edge to be revealed by it; so this is not allowed.  Scrolling to the left is allowed; it scrolls the first columns of text off the edge of the window and can reveal additional columns on the right that were truncated before.  Once a window has a nonzero amount of leftward horizontal scrolling, you can scroll it back to the right, but only so far as to reduce the net horizontal scroll to zero.  There is no limit to how far left you can scroll, but eventually all the text will disappear off the left edge.

If auto-hscroll-mode is set, redisplay automatically alters the horizontal scrolling of a window as necessary to ensure that point is always visible.  However, you can still set the horizontal scrolling value explicitly.  The value you specify serves as a lower bound for automatic scrolling, i.e. automatic scrolling will not scroll a window to a column less than the specified one.

 -- Command: scroll-left &optional count set-minimum
     This function scrolls the selected window COUNT columns to the left (or to the right if COUNT is negative).  The default for COUNT is the window width, minus 2.

     The return value is the total amount of leftward horizontal scrolling in effect after the change---just like the value returned by window-hscroll (below).

     Once you scroll a window as far right as it can go, back to its normal position where the total leftward scrolling is zero, attempts to scroll any farther right have no effect.

     If SET-MINIMUM is non-nil, the new scroll amount becomes the lower bound for automatic scrolling; that is, automatic scrolling will not scroll a window to a column less than the value returned by this function.  Interactive calls pass non-nil for SET-MINIMUM.

 -- Command: scroll-right &optional count set-minimum
     This function scrolls the selected window COUNT columns to the right (or to the left if COUNT is negative).  The default for COUNT is the window width, minus 2.  Aside from the direction of scrolling, this works just like scroll-left.

 -- Function: window-hscroll &optional window
     This function returns the total leftward horizontal scrolling of WINDOW---the number of columns by which the text in WINDOW is scrolled left past the left margin.  The default for WINDOW is the selected window.

     The return value is never negative.  It is zero when no horizontal scrolling has been done in WINDOW (which is usually the case).

          (window-hscroll)
               => 0

          (scroll-left 5)
               => 5

          (window-hscroll)
               => 5

 -- Function: set-window-hscroll window columns
     This function sets horizontal scrolling of WINDOW.  The value of COLUMNS specifies the amount of scrolling, in terms of columns from the left margin.  The argument COLUMNS should be zero or positive; if not, it is taken as zero.  Fractional values of COLUMNS are not supported at present.

     Note that set-window-hscroll may appear not to work if you test it by evaluating a call with M-: in a simple way.  What happens is that the function sets the horizontal scroll value and returns, but then redisplay adjusts the horizontal scrolling to make point visible, and this overrides what the function did.  You can observe the function's effect if you call it while point is sufficiently far from the left margin that it will remain visible.

     The value returned is COLUMNS.

          (set-window-hscroll (selected-window) 10)
               => 10

Here is how you can determine whether a given position POSITION is off the screen due to horizontal scrolling:

     (defun hscroll-on-screen (window position)
       (save-excursion
         (goto-char position)
         (and
          (>= (- (current-column) (window-hscroll window)) 0)
          (< (- (current-column) (window-hscroll window))
             (window-width window)))))

The Size of a Window
====================

An Emacs window is rectangular, and its size information consists of the height (the number of lines) and the width (the number of character positions in each line).  The mode line is included in the height.  But the width does not count the scroll bar or the column of | characters that separates side-by-side windows.

The following three functions return size information about a window:

 -- Function: window-height &optional window
     This function returns the number of lines in WINDOW (by default the selected window), including any mode line and header line. The result is almost always less than the value of frame-height for the associated frame, because the latter also includes any echo area.  Depending on the toolkit in use, the frame height can also include the menu bar and tool bar (see Size and Position). Therefore in general it is not straightforward to compare window and frame heights (see window-full-height-p below).

          (window-height)
               => 23

          (split-window-vertically)
               => #<window 4 on windows.texi>

          (window-height)
               => 11

 -- Function: window-body-height &optional window
     Like window-height but the value does not include the mode line (if any) or the header line (if any).

 -- Function: window-full-height-p &optional window
     This function returns non-nil if WINDOW is as tall as the frame that contains it.  The default for WINDOW is the selected window.

 -- Function: window-width &optional window
     This function returns the number of columns in WINDOW.  The default for WINDOW is the selected window.

     The return value does not include the window's scroll bar or the column of | characters that separates side-by-side windows.  Moreover, the return value does not include the space used for displaying fringes and margins.  Hence you cannot, in general, compare the return values of window-width and frame-width for equality to determine whether a window is a wide as the containing frame.  Use the function window-full-width-p, see below, instead.

          (window-width)
               => 80

 -- Function: window-full-width-p &optional window
     This function returns non-nil if WINDOW is as wide as the frame that contains it; otherwise nil.  The default for WINDOW is the selected window.

 -- Function: window-edges &optional window
     This function returns a list of the edge coordinates of WINDOW. The default for WINDOW is the selected window.

     The order of the list is (LEFT TOP RIGHT BOTTOM), all elements relative to 0, 0 at the top left corner of the frame.  The element RIGHT of the value is one more than the rightmost column used by WINDOW, and BOTTOM is one more than the bottommost row used by WINDOW and its mode-line.

     The edges include the space used by the window's scroll bar, display margins, fringes, header line, and mode line, if it has them.  Also, if the window has a neighbor on the right, its right edge value includes the width of the separator line between the window and that neighbor.  Since the width of the window does not include this separator, the width does not usually equal the difference between the right and left edges.

 -- Function: window-inside-edges &optional window
     This is similar to window-edges, but the edge values it returns include only the text area of the window.  They do not include the header line, mode line, scroll bar or vertical separator, fringes, or display margins.

Here are the results obtained on a typical 24-line terminal with just one window, with menu bar enabled:

     (window-edges (selected-window))
          => (0 1 80 23)

     (window-inside-edges (selected-window))
          => (0 1 80 22)

The bottom edge is at line 23 because the last line is the echo area. The bottom inside edge is at line 22, which is the window's mode line.

If WINDOW is at the upper left corner of its frame, and there is no menu bar, then BOTTOM returned by window-edges is the same as the value of (window-height), RIGHT is almost the same as the value of (window-width), and TOP and LEFT are zero.  For example, the edges of the following window are 0 0 8 5.  Assuming that the frame has more than 8 columns, the last column of the window (column 7) holds a border rather than text.  The last row (row 4) holds the mode line, shown here with xxxxxxxxx.

                0
                _______
             0 |       |
               |       |
               |       |
               |       |
               xxxxxxxxx  4

                       7

In the following example, let's suppose that the frame is 7 columns wide.  Then the edges of the left window are 0 0 4 3 and the edges of the right window are 4 0 7 3. The inside edges of the left window are 0 0 3 2, and the inside edges of the right window are 4 0 7 2,

                ___ ___
               |   |   |
               |   |   |
               xxxxxxxxx

                0  34  7

 -- Function: window-pixel-edges &optional window
     This function is like window-edges except that, on a graphical display, the edge values are measured in pixels instead of in character lines and columns.

 -- Function: window-inside-pixel-edges &optional window
     This function is like window-inside-edges except that, on a graphical display, the edge values are measured in pixels instead of in character lines and columns.

Changing the Size of a Window
=============================

The window size functions fall into two classes: high-level commands that change the size of windows and low-level functions that access window size.  Emacs does not permit overlapping windows or gaps between windows, so resizing a window always affects at least one other window.

 -- Command: enlarge-window size &optional horizontal
     This function makes the selected window SIZE lines taller by stealing lines from windows above or below.  In a first round, it takes lines from one window at a time until that window is window-min-height lines tall, then takes from another.  If, at the end of the first round, the selected window is still not tall enough, enlarge-window starts a second round, where it deletes windows above or below the selected one.

     If HORIZONTAL is non-nil, this function makes the window SIZE columns wider, stealing columns instead of lines.  If a window from which columns are stolen shrinks below window-min-width columns, that window disappears.

     If the requested size would exceed that of the window's frame, then the function makes the window occupy the entire height (or width) of the frame.

     If there are various other windows from which lines or columns can be stolen, and some of them specify fixed size (using window-size-fixed, see below), they are left untouched while other windows are ``robbed.''  If it would be necessary to alter the size of a fixed-size window, enlarge-window gets an error instead.

     If SIZE is negative, this function shrinks the selected window by -SIZE lines or columns.  If that makes the window smaller than the minimum size (window-min-height and window-min-width), then enlarge-window deletes the window.

     enlarge-window returns nil.

 -- Command: enlarge-window-horizontally columns
     This function makes the selected window COLUMNS wider. It could be defined as follows:

          (defun enlarge-window-horizontally (columns)
            (interactive "p")
            (enlarge-window columns t))

 -- Command: shrink-window size &optional horizontal
     This function is like enlarge-window but negates the argument SIZE, making the selected window smaller by giving lines (or columns) to the other windows.  If the window shrinks below window-min-height or window-min-width, then it disappears.

     If SIZE is negative, the window is enlarged by -SIZE lines or columns.

 -- Command: shrink-window-horizontally columns
     This function makes the selected window COLUMNS narrower. It could be defined as follows:

          (defun shrink-window-horizontally (columns)
            (interactive "p")
            (shrink-window columns t))

 -- Function: adjust-window-trailing-edge window delta horizontal
     This function makes the selected window DELTA lines taller or DELTA columns wider, by moving the bottom or right edge.  This function does not delete other windows; if it cannot make the requested size adjustment, it signals an error.  On success, this function returns nil.

 -- Command: fit-window-to-buffer &optional window max-height min-height
     This command makes WINDOW the right height to display its contents exactly.  The default for WINDOW is the selected window.

     The optional argument MAX-HEIGHT specifies the maximum height the window is allowed to be; nil means use the maximum permissible height of a window on WINDOW's frame.  The optional argument MIN-HEIGHT specifies the minimum height for the window; nil means use window-min-height.  All these height values include the mode line and/or header line.

     This function can delete windows when their height shrinks below MIN-HEIGHT.  It returns non-nil if it orderly resized WINDOW, and nil otherwise.

 -- Command: shrink-window-if-larger-than-buffer &optional window
     This command shrinks WINDOW vertically to be as small as possible while still showing the full contents of its buffer---but not less than window-min-height lines.  The default for WINDOW is the selected window.

     However, this command does nothing if the window is already too small to display the whole text of the buffer, or if part of the contents are currently scrolled off screen, or if the window is not the full width of its frame, or if the window is the only window in its frame.

     This command returns non-nil if it actually shrank the window and nil otherwise.

 -- Variable: window-size-fixed
     If this variable is non-nil, in a given buffer, then the size of any window displaying that buffer remains fixed unless you either explicitly change it or Emacs has no other choice.

     If the value is height, then only the window's height is fixed; if the value is width, then only the window's width is fixed. Any other non-nil value fixes both the width and the height.

     This variable automatically becomes buffer-local when set.

     Explicit size-change functions such as enlarge-window get an error if they would have to change a window size which is fixed. Therefore, when you want to change the size of such a window, you should bind window-size-fixed to nil, like this:

          (let ((window-size-fixed nil))
             (enlarge-window 10))

     Deleting an adjacent window or changing the frame size may change the size of a fixed-size window, if there is no other alternative.

The following two variables constrain the window-structure-changing functions to a minimum height and width.

 -- User Option: window-min-height
     The value of this variable specifies how short a window may become before it is automatically deleted.  Making a window smaller than window-min-height automatically deletes it, and no window may be created shorter than this.  The value is measured in line units.  When the window wants a mode line and/or a header line, they are counted as one line each.  The default value is 4.  A value less than 1 is ignored.

 -- User Option: window-min-width
     The value of this variable specifies how narrow a window may become before it is automatically deleted.  Making a window smaller than window-min-width automatically deletes it, and no window may be created narrower than this.  The value is measured in characters and includes any fringes or the scroll bar.  The default value is 10. A value less than 2 is ignored.

Emacs provides two functions to balance windows, that is, to even out the sizes of windows on the same frame.  The minibuffer window and fixed-size windows are not resized by these functions.

 -- Command: balance-windows &optional window-or-frame
     This function balances windows in a way that gives more space to full-width and/or full-height windows.  If WINDOW-OR-FRAME specifies a frame, it balances all windows on that frame.  If WINDOW-OR-FRAME specifies a window, it balances this window and its ``siblings'' only.  Think of a sibling as the other (original or new) window with respect to the present one, involved in the process of splitting; see Splitting Windows.  Since a sibling may have been split again, a window can have more than one sibling.

 -- Command: balance-windows-area
     This function attempts to give all windows on the selected frame approximately the same share of the screen area.  This means that full-width or full-height windows are not given more space than other windows.

Coordinates and Windows
=======================

This section describes how to relate screen coordinates to windows.

 -- Function: window-at x y &optional frame
     This function returns the window containing the specified cursor position in the frame FRAME.  The coordinates X and Y are measured in characters and count from the top left corner of the frame.  If they are out of range, window-at returns nil.

     If you omit FRAME, the selected frame is used.

 -- Function: coordinates-in-window-p coordinates window
     This function checks whether a particular frame position falls within the window WINDOW.

     The argument COORDINATES is a cons cell of the form (X . Y).  The coordinates X and Y are measured in characters, and count from the top left corner of the screen or frame.

     The value returned by coordinates-in-window-p is non-nil if the coordinates are inside WINDOW.  The value also indicates what part of the window the position is in, as follows:

     (RELX . RELY)
          The coordinates are inside WINDOW.  The numbers RELX and RELY are the equivalent window-relative coordinates for the specified position, counting from 0 at the top left corner of the window.

     mode-line
          The coordinates are in the mode line of WINDOW.

     header-line
          The coordinates are in the header line of WINDOW.

     vertical-line
          The coordinates are in the vertical line between WINDOW and its neighbor to the right.  This value occurs only if the window doesn't have a scroll bar; positions in a scroll bar are considered outside the window for these purposes.

     left-fringe
     right-fringe
          The coordinates are in the left or right fringe of the window.

     left-margin
     right-margin
          The coordinates are in the left or right margin of the window.

     nil
          The coordinates are not in any part of WINDOW.

     The function coordinates-in-window-p does not require a frame as argument because it always uses the frame that WINDOW is on.

The Window Tree
===============

A window tree specifies the layout, size, and relationship between all windows in one frame.

 -- Function: window-tree &optional frame
     This function returns the window tree for frame FRAME. If FRAME is omitted, the selected frame is used.

     The return value is a list of the form (ROOT MINI), where ROOT represents the window tree of the frame's root window, and MINI is the frame's minibuffer window.

     If the root window is not split, ROOT is the root window itself. Otherwise, ROOT is a list (DIR EDGES W1 W2 ...) where DIR is nil for a horizontal split, and t for a vertical split, EDGES gives the combined size and position of the subwindows in the split, and the rest of the elements are the subwindows in the split.  Each of the subwindows may again be a window or a list representing a window split, and so on.  The EDGES element is a list (LEFT TOP RIGHT BOTTOM) similar to the value returned by window-edges.

Window Configurations
=====================

A window configuration records the entire layout of one frame---all windows, their sizes, which buffers they contain, how those buffers are scrolled, and their values of point and the mark; also their fringes, margins, and scroll bar settings.  It also includes the value of minibuffer-scroll-window.  As a special exception, the window configuration does not record the value of point in the selected window for the current buffer.  Also, the window configuration does not record the values of window parameters; see Window Parameters.

You can bring back an entire frame layout by restoring a previously saved window configuration.  If you want to record the layout of all frames instead of just one, use a frame configuration instead of a window configuration; see Frame Configurations.

 -- Function: current-window-configuration &optional frame
     This function returns a new object representing FRAME's current window configuration.  The default for FRAME is the selected frame.

 -- Function: set-window-configuration configuration
     This function restores the configuration of windows and buffers as specified by CONFIGURATION, for the frame that CONFIGURATION was created for.

     The argument CONFIGURATION must be a value that was previously returned by current-window-configuration.  The configuration is restored in the frame from which CONFIGURATION was made, whether that frame is selected or not.  This always counts as a window size change and triggers execution of the window-size-change-functions (see Window Hooks), because set-window-configuration doesn't know how to tell whether the new configuration actually differs from the old one.

     If the frame which CONFIGURATION was saved from is dead, all this function does is restore the three variables window-min-height, window-min-width and minibuffer-scroll-window. In this case, the function returns nil.  Otherwise, it returns t.

     Here is a way of using this function to get the same effect as save-window-excursion:

          (let ((config (current-window-configuration)))
            (unwind-protect
                (progn (split-window-vertically nil)
                       ...)
              (set-window-configuration config)))

 -- Special Form: save-window-excursion forms...
     This special form records the window configuration, executes FORMS in sequence, then restores the earlier window configuration.  The window configuration includes, for each window, the value of point and the portion of the buffer that is visible.  It also includes the choice of selected window.  However, it does not include the value of point in the current buffer; use save-excursion also, if you wish to preserve that.

     Don't use this construct when save-selected-window is sufficient.

     Exit from save-window-excursion always triggers execution of window-size-change-functions.  (It doesn't know how to tell whether the restored configuration actually differs from the one in effect at the end of the FORMS.)

     The return value is the value of the final form in FORMS. For example:

          (split-window)
               => #<window 25 on control.texi>

          (setq w (selected-window))
               => #<window 19 on control.texi>

          (save-window-excursion
            (delete-other-windows w)
            (switch-to-buffer "foo")
            'do-something)
               => do-something
               ;; The screen is now split again.

 -- Function: window-configuration-p object
     This function returns t if OBJECT is a window configuration.

 -- Function: compare-window-configurations config1 config2
     This function compares two window configurations as regards the structure of windows, but ignores the values of point and mark and the saved scrolling positions---it can return t even if those aspects differ.

     The function equal can also compare two window configurations; it regards configurations as unequal if they differ in any respect, even a saved point or mark.

 -- Function: window-configuration-frame config
     This function returns the frame for which the window configuration CONFIG was made.

Other primitives to look inside of window configurations would make sense, but are not implemented because we did not need them.  See the file winner.el for some more operations on windows configurations.

Window Parameters
=================

This sections describes how window parameters can be used to associate additional information with windows.

 -- Function: window-parameter window parameter
     This function returns WINDOW's value for PARAMETER.  The default for WINDOW is the selected window.  If WINDOW has no setting for PARAMETER, this function returns nil.

 -- Function: window-parameters &optional window
     This function returns all parameters of WINDOW and their values. The default for WINDOW is the selected window.  The return value is an association list of elements of the form (PARAMETER . VALUE).

 -- Function: set-window-parameter window parameter value
     This function sets WINDOW's value of PARAMETER to VALUE and returns VALUE.  The default for WINDOW is the selected window.

Currently, window parameters are not saved in window configurations and consequently not restored by set-window-configuration.  Hence, any change of a parameter introduced via set-window-parameter can be undone only by invoking set-window-parameter for the same parameter again.  Since save-window-excursion relies on window configurations (see Window Configurations), window parameters are not saved and restored by that special form, either.

Hooks for Window Scrolling and Changes
======================================

This section describes how a Lisp program can take action whenever a window displays a different part of its buffer or a different buffer. There are three actions that can change this: scrolling the window, switching buffers in the window, and changing the size of the window. The first two actions run window-scroll-functions; the last runs window-size-change-functions.

 -- Variable: window-scroll-functions
     This variable holds a list of functions that Emacs should call before redisplaying a window with scrolling.  Displaying a different buffer in the window also runs these functions.

     This variable is not a normal hook, because each function is called with two arguments: the window, and its new display-start position.

     These functions must be careful in using window-end (see Window Start and End); if you need an up-to-date value, you must use the UPDATE argument to ensure you get it.

     Warning: don't use this feature to alter the way the window is scrolled.  It's not designed for that, and such use probably won't work.

 -- Variable: window-size-change-functions
     This variable holds a list of functions to be called if the size of any window changes for any reason.  The functions are called just once per redisplay, and just once for each frame on which size changes have occurred.

     Each function receives the frame as its sole argument.  There is no direct way to find out which windows on that frame have changed size, or precisely how.  However, if a size-change function records, at each call, the existing windows and their sizes, it can also compare the present sizes and the previous sizes.

     Creating or deleting windows counts as a size change, and therefore causes these functions to be called.  Changing the frame size also counts, because it changes the sizes of the existing windows.

     It is not a good idea to use save-window-excursion (see Window Configurations) in these functions, because that always counts as a size change, and it would cause these functions to be called over and over.  In most cases, save-selected-window (see Selecting Windows) is what you need here.

 -- Variable: window-configuration-change-hook
     A normal hook that is run every time you change the window configuration of an existing frame.  This includes splitting or deleting windows, changing the sizes of windows, or displaying a different buffer in a window.

     The buffer-local part of this hook is run once per each window on the affected frame, with the relevant window selected and its buffer current.  The global part is run once for the modified frame, with that frame selected.

In addition, you can use jit-lock-register to register a Font Lock fontification function, which will be called whenever parts of a buffer are (re)fontified because a window was scrolled or its size changed.  See Other Font Lock Variables.