Variables
*********

A variable is a name used in a program to stand for a value. Nearly all programming languages have variables of some sort.  In the text of a Lisp program, variables are written using the syntax for symbols.

In Lisp, unlike most programming languages, programs are represented primarily as Lisp objects and only secondarily as text.  The Lisp objects used for variables are symbols: the symbol name is the variable name, and the variable's value is stored in the value cell of the symbol.  The use of a symbol as a variable is independent of its use as a function name.  See Symbol Components.

The Lisp objects that constitute a Lisp program determine the textual form of the program---it is simply the read syntax for those Lisp objects.  This is why, for example, a variable in a textual Lisp program is written using the read syntax for the symbol that represents the variable.

Global Variables
================

The simplest way to use a variable is globally.  This means that the variable has just one value at a time, and this value is in effect (at least for the moment) throughout the Lisp system.  The value remains in effect until you specify a new one.  When a new value replaces the old one, no trace of the old value remains in the variable.

You specify a value for a symbol with setq.  For example,

     (setq x '(a b))

gives the variable x the value (a b).  Note that setq does not evaluate its first argument, the name of the variable, but it does evaluate the second argument, the new value.

Once the variable has a value, you can refer to it by using the symbol by itself as an expression.  Thus,

     x => (a b)

assuming the setq form shown above has already been executed.

If you do set the same variable again, the new value replaces the old one:

     x
          => (a b)

     (setq x 4)
          => 4

     x
          => 4

Variables that Never Change
===========================

In Emacs Lisp, certain symbols normally evaluate to themselves.  These include nil and t, as well as any symbol whose name starts with : (these are called keywords).  These symbols cannot be rebound, nor can their values be changed.  Any attempt to set or bind nil or t signals a setting-constant error.  The same is true for a keyword (a symbol whose name starts with :), if it is interned in the standard obarray, except that setting such a symbol to itself is not an error.

     nil == 'nil
          => nil

     (setq nil 500)
     error--> Attempt to set constant symbol: nil

 -- Function: keywordp object
     function returns t if OBJECT is a symbol whose name starts with :, interned in the standard obarray, and returns nil otherwise.

Local Variables
===============

Global variables have values that last until explicitly superseded with new values.  Sometimes it is useful to create variable values that exist temporarily---only until a certain part of the program finishes. These values are called local, and the variables so used are called local variables.

For example, when a function is called, its argument variables receive new local values that last until the function exits.  The let special form explicitly establishes new local values for specified variables; these last until exit from the let form.

Establishing a local value saves away the previous value (or lack of one) of the variable.  When the life span of the local value is over, the previous value is restored.  In the mean time, we say that the previous value is shadowed and not visible.  Both global and local values may be shadowed (see Scope).

If you set a variable (such as with setq) while it is local, this replaces the local value; it does not alter the global value, or previous local values, that are shadowed.  To model this behavior, we speak of a local binding of the variable as well as a local value.

The local binding is a conceptual place that holds a local value. Entry to a function, or a special form such as let, creates the local binding; exit from the function or from the let removes the local binding.  As long as the local binding lasts, the variable's value is stored within it.  Use of setq or set while there is a local binding stores a different value into the local binding; it does not create a new binding.

We also speak of the global binding, which is where (conceptually) the global value is kept.

A variable can have more than one local binding at a time (for example, if there are nested let forms that bind it).  In such a case, the most recently created local binding that still exists is the current binding of the variable.  (This rule is called dynamic scoping; see Variable Scoping.)  If there are no local bindings, the variable's global binding is its current binding. We sometimes call the current binding the most-local existing binding, for emphasis.  Ordinary evaluation of a symbol always returns the value of its current binding.

The special forms let and let* exist to create local bindings.

 -- Special Form: let (bindings...) forms...
     This special form binds variables according to BINDINGS and then evaluates all of the FORMS in textual order.  The let-form returns the value of the last form in FORMS.

     Each of the BINDINGS is either (i) a symbol, in which case that symbol is bound to nil; or (ii) a list of the form (SYMBOL VALUE-FORM), in which case SYMBOL is bound to the result of evaluating VALUE-FORM.  If VALUE-FORM is omitted, nil is used.

     All of the VALUE-FORMs in BINDINGS are evaluated in the order they appear and before binding any of the symbols to them. Here is an example of this: z is bound to the old value of y, which is 2, not the new value of y, which is 1.

          (setq y 2)
               => 2

          (let ((y 1)
                (z y))
            (list y z))
               => (1 2)

 -- Special Form: let* (bindings...) forms...
     This special form is like let, but it binds each variable right after computing its local value, before computing the local value for the next variable.  Therefore, an expression in BINDINGS can reasonably refer to the preceding symbols bound in this let* form.  Compare the following example with the example above for let.

          (setq y 2)
               => 2

          (let* ((y 1)
                 (z y))    ; Use the just-established value of y.
            (list y z))
               => (1 1)

Here is a complete list of the other facilities that create local bindings:

  * Function calls (see Functions).

  * Macro calls (see Macros).

  * condition-case (see Errors).

Variables can also have buffer-local bindings (see Buffer-Local Variables) and frame-local bindings (see Frame-Local Variables); a few variables have terminal-local bindings (see Multiple Displays). These kinds of bindings work somewhat like ordinary local bindings, but they are localized depending on ``where'' you are in Emacs, rather than localized in time.

 -- Variable: max-specpdl-size
     This variable defines the limit on the total number of local variable bindings and unwind-protect cleanups (see Cleaning Up from Nonlocal Exits) that are allowed before signaling an error (with data "Variable binding depth exceeds max-specpdl-size").

     This limit, with the associated error when it is exceeded, is one way that Lisp avoids infinite recursion on an ill-defined function. max-lisp-eval-depth provides another limit on depth of nesting. See Eval.

     The default value is 600.  Entry to the Lisp debugger increases the value, if there is little room left, to make sure the debugger itself has room to execute.

When a Variable is ``Void''
===========================

If you have never given a symbol any value as a global variable, we say that that symbol's global value is void.  In other words, the symbol's value cell does not have any Lisp object in it.  If you try to evaluate the symbol, you get a void-variable error rather than a value.

Note that a value of nil is not the same as void.  The symbol nil is a Lisp object and can be the value of a variable just as any other object can be; but it is a value.  A void variable does not have any value.

After you have given a variable a value, you can make it void once more using makunbound.

 -- Function: makunbound symbol
     This function makes the current variable binding of SYMBOL void. Subsequent attempts to use this symbol's value as a variable will signal the error void-variable, unless and until you set it again.

     makunbound returns SYMBOL.

          (makunbound 'x)      ; Make the global value of x void.
               => x

          x
          error--> Symbol's value as variable is void: x

     If SYMBOL is locally bound, makunbound affects the most local existing binding.  This is the only way a symbol can have a void local binding, since all the constructs that create local bindings create them with values.  In this case, the voidness lasts at most as long as the binding does; when the binding is removed due to exit from the construct that made it, the previous local or global binding is reexposed as usual, and the variable is no longer void unless the newly reexposed binding was void all along.

          (setq x 1)               ; Put a value in the global binding.
               => 1
          (let ((x 2))             ; Locally bind it.
            (makunbound 'x)        ; Void the local binding.
            x)
          error--> Symbol's value as variable is void: x

          x                        ; The global binding is unchanged.
               => 1

          (let ((x 2))             ; Locally bind it.
            (let ((x 3))           ; And again.
              (makunbound 'x)      ; Void the innermost-local binding.
              x))                  ; And refer: it's void.
          error--> Symbol's value as variable is void: x

          (let ((x 2))
            (let ((x 3))
              (makunbound 'x))     ; Void inner binding, then remove it.
            x)                     ; Now outer let binding is visible.
               => 2

A variable that has been made void with makunbound is indistinguishable from one that has never received a value and has always been void.

You can use the function boundp to test whether a variable is currently void.

 -- Function: boundp variable
     boundp returns t if VARIABLE (a symbol) is not void; more precisely, if its current binding is not void.  It returns nil otherwise.

          (boundp 'abracadabra)          ; Starts out void.
               => nil

          (let ((abracadabra 5))         ; Locally bind it.
            (boundp 'abracadabra))
               => t

          (boundp 'abracadabra)          ; Still globally void.
               => nil

          (setq abracadabra 5)           ; Make it globally nonvoid.
               => 5

          (boundp 'abracadabra)
               => t

Defining Global Variables
=========================

You may announce your intention to use a symbol as a global variable with a variable definition: a special form, either defconst or defvar.

In Emacs Lisp, definitions serve three purposes.  First, they inform people who read the code that certain symbols are intended to be used a certain way (as variables).  Second, they inform the Lisp system of these things, supplying a value and documentation.  Third, they provide information to utilities such as etags and make-docfile, which create data bases of the functions and variables in a program.

The difference between defconst and defvar is primarily a matter of intent, serving to inform human readers of whether the value should ever change.  Emacs Lisp does not restrict the ways in which a variable can be used based on defconst or defvar declarations.  However, it does make a difference for initialization: defconst unconditionally initializes the variable, while defvar initializes it only if it is void.

 -- Special Form: defvar symbol [value [doc-string]]
     This special form defines SYMBOL as a variable and can also initialize and document it.  The definition informs a person reading your code that SYMBOL is used as a variable that might be set or changed.  Note that SYMBOL is not evaluated; the symbol to be defined must appear explicitly in the defvar.

     If SYMBOL is void and VALUE is specified, defvar evaluates it and sets SYMBOL to the result.  But if SYMBOL already has a value (i.e., it is not void), VALUE is not even evaluated, and SYMBOL's value remains unchanged.  If VALUE is omitted, the value of SYMBOL is not changed in any case.

     If SYMBOL has a buffer-local binding in the current buffer, defvar operates on the default value, which is buffer-independent, not the current (buffer-local) binding.  It sets the default value if the default value is void.  See Buffer-Local Variables.

     When you evaluate a top-level defvar form with C-M-x in Emacs Lisp mode (eval-defun), a special feature of eval-defun arranges to set the variable unconditionally, without testing whether its value is void.

     If the DOC-STRING argument appears, it specifies the documentation for the variable.  (This opportunity to specify documentation is one of the main benefits of defining the variable.)  The documentation is stored in the symbol's variable-documentation property.  The Emacs help functions (see Documentation) look for this property.

     If the variable is a user option that users would want to set interactively, you should use * as the first character of DOC-STRING.  This lets users set the variable conveniently using the set-variable command.  Note that you should nearly always use defcustom instead of defvar to define these variables, so that users can use M-x customize and related commands to set them.  See Customization.

     Here are some examples.  This form defines foo but does not initialize it:

          (defvar foo)
               => foo

     This example initializes the value of bar to 23, and gives it a documentation string:

          (defvar bar 23
            "The normal weight of a bar.")
               => bar

     The following form changes the documentation string for bar, making it a user option, but does not change the value, since bar already has a value.  (The addition (1+ nil) would get an error if it were evaluated, but since it is not evaluated, there is no error.)

          (defvar bar (1+ nil)
            "*The normal weight of a bar.")
               => bar

          bar
               => 23

     Here is an equivalent expression for the defvar special form:

          (defvar SYMBOL VALUE DOC-STRING)
          ==
          (progn
            (if (not (boundp 'SYMBOL))
                (setq SYMBOL VALUE))
            (if 'DOC-STRING
              (put 'SYMBOL 'variable-documentation 'DOC-STRING))
            'SYMBOL)

     The defvar form returns SYMBOL, but it is normally used at top level in a file where its value does not matter.

 -- Special Form: defconst symbol value [doc-string]
     This special form defines SYMBOL as a value and initializes it. It informs a person reading your code that SYMBOL has a standard global value, established here, that should not be changed by the user or by other programs.  Note that SYMBOL is not evaluated; the symbol to be defined must appear explicitly in the defconst.

     defconst always evaluates VALUE, and sets the value of SYMBOL to the result.  If SYMBOL does have a buffer-local binding in the current buffer, defconst sets the default value, not the buffer-local value.  (But you should not be making buffer-local bindings for a symbol that is defined with defconst.)

     Here, pi is a constant that presumably ought not to be changed by anyone (attempts by the Indiana State Legislature notwithstanding). As the second form illustrates, however, this is only advisory.

          (defconst pi 3.1415 "Pi to five places.")
               => pi

          (setq pi 3)
               => pi

          pi
               => 3

 -- Function: user-variable-p variable
     This function returns t if VARIABLE is a user option---a variable intended to be set by the user for customization---and nil otherwise.  (Variables other than user options exist for the internal purposes of Lisp programs, and users need not know about them.)

     User option variables are distinguished from other variables either though being declared using defcustom (They may also be declared equivalently in cus-start.el.) or by the first character of their variable-documentation property.  If the property exists and is a string, and its first character is *, then the variable is a user option.  Aliases of user options are also user options.

If a user option variable has a variable-interactive property, the set-variable command uses that value to control reading the new value for the variable.  The property's value is used as if it were specified in interactive (see Using Interactive).  However, this feature is largely obsoleted by defcustom (see Customization).

Warning: If the defconst and defvar special forms are used while the variable has a local binding (made with let, or a function argument), they set the local-binding's value; the top-level binding is not changed.  This is not what you usually want.  To prevent it, use these special forms at top level in a file, where normally no local binding is in effect, and make sure to load the file before making a local binding for the variable.

Tips for Defining Variables Robustly
====================================

When you define a variable whose value is a function, or a list of functions, use a name that ends in -function or -functions, respectively.

There are several other variable name conventions; here is a complete list:

...-hook
     The variable is a normal hook (see Hooks).

...-function
     The value is a function.

...-functions
     The value is a list of functions.

...-form
     The value is a form (an expression).

...-forms
     The value is a list of forms (expressions).

...-predicate
     The value is a predicate---a function of one argument that returns non-nil for ``good'' arguments and nil for ``bad'' arguments.

...-flag
     The value is significant only as to whether it is nil or not.

...-program
     The value is a program name.

...-command
     The value is a whole shell command.

-switches
     The value specifies options for a command.

When you define a variable, always consider whether you should mark it as ``risky''; see File Local Variables.

When defining and initializing a variable that holds a complicated value (such as a keymap with bindings in it), it's best to put the entire computation of the value into the defvar, like this:

     (defvar my-mode-map
       (let ((map (make-sparse-keymap)))
         (define-key map "\C-c\C-a" 'my-command)
         ...
         map)
       DOCSTRING)

This method has several benefits.  First, if the user quits while loading the file, the variable is either still uninitialized or initialized properly, never in-between.  If it is still uninitialized, reloading the file will initialize it properly.  Second, reloading the file once the variable is initialized will not alter it; that is important if the user has run hooks to alter part of the contents (such as, to rebind keys).  Third, evaluating the defvar form with C-M-x will reinitialize the map completely.

Putting so much code in the defvar form has one disadvantage: it puts the documentation string far away from the line which names the variable.  Here's a safe way to avoid that:

     (defvar my-mode-map nil
       DOCSTRING)
     (unless my-mode-map
       (let ((map (make-sparse-keymap)))
         (define-key map "\C-c\C-a" 'my-command)
         ...
         (setq my-mode-map map)))

This has all the same advantages as putting the initialization inside the defvar, except that you must type C-M-x twice, once on each form, if you do want to reinitialize the variable.

But be careful not to write the code like this:

     (defvar my-mode-map nil
       DOCSTRING)
     (unless my-mode-map
       (setq my-mode-map (make-sparse-keymap))
       (define-key my-mode-map "\C-c\C-a" 'my-command)
       ...)

This code sets the variable, then alters it, but it does so in more than one step.  If the user quits just after the setq, that leaves the variable neither correctly initialized nor void nor nil.  Once that happens, reloading the file will not initialize the variable; it will remain incomplete.

Accessing Variable Values
=========================

The usual way to reference a variable is to write the symbol which names it (see Symbol Forms).  This requires you to specify the variable name when you write the program.  Usually that is exactly what you want to do.  Occasionally you need to choose at run time which variable to reference; then you can use symbol-value.

 -- Function: symbol-value symbol
     This function returns the value of SYMBOL.  This is the value in the innermost local binding of the symbol, or its global value if it has no local bindings.

          (setq abracadabra 5)
               => 5

          (setq foo 9)
               => 9

          ;; Here the symbol abracadabra
          ;;   is the symbol whose value is examined.
          (let ((abracadabra 'foo))
            (symbol-value 'abracadabra))
               => foo

          ;; Here the value of abracadabra,
          ;;   which is foo,
          ;;   is the symbol whose value is examined.
          (let ((abracadabra 'foo))
            (symbol-value abracadabra))
               => 9

          (symbol-value 'abracadabra)
               => 5

     A void-variable error is signaled if the current binding of SYMBOL is void.

How to Alter a Variable Value
=============================

The usual way to change the value of a variable is with the special form setq.  When you need to compute the choice of variable at run time, use the function set.

 -- Special Form: setq [symbol form]...
     This special form is the most common method of changing a variable's value.  Each SYMBOL is given a new value, which is the result of evaluating the corresponding FORM.  The most-local existing binding of the symbol is changed.

     setq does not evaluate SYMBOL; it sets the symbol that you write.  We say that this argument is automatically quoted.  The q in setq stands for ``quoted.''

     The value of the setq form is the value of the last FORM.

          (setq x (1+ 2))
               => 3

          x                   ; x now has a global value.
               => 3

          (let ((x 5))
            (setq x 6)        ; The local binding of x is set.
            x)
               => 6

          x                   ; The global value is unchanged.
               => 3

     Note that the first FORM is evaluated, then the first SYMBOL is set, then the second FORM is evaluated, then the second SYMBOL is set, and so on:

          (setq x 10          ; Notice that x is set before
                y (1+ x))     ;   the value of y is computed.
               => 11

 -- Function: set symbol value
     This function sets SYMBOL's value to VALUE, then returns VALUE.  Since set is a function, the expression written for SYMBOL is evaluated to obtain the symbol to set.

     The most-local existing binding of the variable is the binding that is set; shadowed bindings are not affected.

          (set one 1)
          error--> Symbol's value as variable is void: one

          (set 'one 1)
               => 1

          (set 'two 'one)
               => one

          (set two 2)         ; two evaluates to symbol one.
               => 2

          one                 ; So it is one that was set.
               => 2
          (let ((one 1))      ; This binding of one is set,
            (set 'one 3)      ;   not the global value.
            one)
               => 3

          one
               => 2

     If SYMBOL is not actually a symbol, a wrong-type-argument error is signaled.

          (set '(x y) 'z)
          error--> Wrong type argument: symbolp, (x y)

     Logically speaking, set is a more fundamental primitive than setq.  Any use of setq can be trivially rewritten to use set; setq could even be defined as a macro, given the availability of set.  However, set itself is rarely used; beginners hardly need to know about it.  It is useful only for choosing at run time which variable to set.  For example, the command set-variable, which reads a variable name from the user and then sets the variable, needs to use set.

          Common Lisp note: In Common Lisp, set always changes the symbol's ``special'' or dynamic value, ignoring any lexical bindings. In Emacs Lisp, all variables and all bindings are dynamic, so set always affects the most local existing binding.

One other function for setting a variable is designed to add an element to a list if it is not already present in the list.

 -- Function: add-to-list symbol element &optional append
     This function sets the variable SYMBOL by consing ELEMENT onto the old value, if ELEMENT is not already a member of that value.  It returns the resulting list, whether updated or not.  The value of SYMBOL had better be a list already before the call. Membership is tested using equal.

     Normally, if ELEMENT is added, it is added to the front of SYMBOL, but if the optional argument APPEND is non-nil, it is added at the end.

     The argument SYMBOL is not implicitly quoted; add-to-list is an ordinary function, like set and unlike setq.  Quote the argument yourself if that is what you want.

Here's a scenario showing how to use add-to-list:

     (setq foo '(a b))
          => (a b)

     (add-to-list 'foo 'c)     ;; Add c.
          => (c a b)

     (add-to-list 'foo 'b)     ;; No effect.
          => (c a b)

     foo                       ;; foo was changed.
          => (c a b)

An equivalent expression for (add-to-list 'VAR VALUE) is this:

     (or (member VALUE VAR)
         (setq VAR (cons VALUE VAR)))

 -- Function: add-to-ordered-list symbol element &optional order
     This function sets the variable SYMBOL by inserting ELEMENT into the old value, which must be a list, at the position specified by ORDER.  If ELEMENT is already a member of the list, its position in the list is adjusted according to ORDER.  Membership is tested using eq. This function returns the resulting list, whether updated or not.

     The ORDER is typically a number (integer or float), and the elements of the list are sorted in non-decreasing numerical order.

     ORDER may also be omitted or nil.  Then the numeric order of ELEMENT stays unchanged if it already has one; otherwise, ELEMENT has no numeric order.  Elements without a numeric list order are placed at the end of the list, in no particular order.

     Any other value for ORDER removes the numeric order of ELEMENT if it already has one; otherwise, it is equivalent to nil.

     The argument SYMBOL is not implicitly quoted; add-to-ordered-list is an ordinary function, like set and unlike setq.  Quote the argument yourself if that is what you want.

     The ordering information is stored in a hash table on SYMBOL's list-order property.

Here's a scenario showing how to use add-to-ordered-list:

     (setq foo '())
          => nil

     (add-to-ordered-list 'foo 'a 1)     ;; Add a.
          => (a)

     (add-to-ordered-list 'foo 'c 3)     ;; Add c.
          => (a c)

     (add-to-ordered-list 'foo 'b 2)     ;; Add b.
          => (a b c)

     (add-to-ordered-list 'foo 'b 4)     ;; Move b.
          => (a c b)

     (add-to-ordered-list 'foo 'd)       ;; Append d.
          => (a c b d)

     (add-to-ordered-list 'foo 'e)       ;; Add e.
          => (a c b e d)

     foo                       ;; foo was changed.
          => (a c b e d)

Scoping Rules for Variable Bindings
===================================

A given symbol foo can have several local variable bindings, established at different places in the Lisp program, as well as a global binding.  The most recently established binding takes precedence over the others.

Local bindings in Emacs Lisp have indefinite scope and dynamic extent.  Scope refers to where textually in the source code the binding can be accessed.  ``Indefinite scope'' means that any part of the program can potentially access the variable binding.  Extent refers to when, as the program is executing, the binding exists.  ``Dynamic extent'' means that the binding lasts as long as the activation of the construct that established it.

The combination of dynamic extent and indefinite scope is called dynamic scoping.  By contrast, most programming languages use lexical scoping, in which references to a local variable must be located textually within the function or block that binds the variable.

     Common Lisp note: Variables declared ``special'' in Common Lisp are dynamically scoped, like all variables in Emacs Lisp.

Scope
-----

Emacs Lisp uses indefinite scope for local variable bindings. This means that any function anywhere in the program text might access a given binding of a variable.  Consider the following function definitions:

     (defun binder (x)   ; x is bound in binder.
        (foo 5))         ; foo is some other function.

     (defun user ()      ; x is used ``free'' in user.
       (list x))

In a lexically scoped language, the binding of x in binder would never be accessible in user, because user is not textually contained within the function binder.  However, in dynamically-scoped Emacs Lisp, user may or may not refer to the binding of x established in binder, depending on the circumstances:

  * If we call user directly without calling binder at all, then whatever binding of x is found, it cannot come from binder.

  * If we define foo as follows and then call binder, then the binding made in binder will be seen in user:

          (defun foo (lose)
            (user))

  * However, if we define foo as follows and then call binder, then the binding made in binder will not be seen in user:

          (defun foo (x)
            (user))

     Here, when foo is called by binder, it binds x. (The binding in foo is said to shadow the one made in binder.)  Therefore, user will access the x bound by foo instead of the one bound by binder.

Emacs Lisp uses dynamic scoping because simple implementations of lexical scoping are slow.  In addition, every Lisp system needs to offer dynamic scoping at least as an option; if lexical scoping is the norm, there must be a way to specify dynamic scoping instead for a particular variable.  It might not be a bad thing for Emacs to offer both, but implementing it with dynamic scoping only was much easier.

Extent
------

Extent refers to the time during program execution that a variable name is valid.  In Emacs Lisp, a variable is valid only while the form that bound it is executing.  This is called dynamic extent.  ``Local'' or ``automatic'' variables in most languages, including C and Pascal, have dynamic extent.

One alternative to dynamic extent is indefinite extent.  This means that a variable binding can live on past the exit from the form that made the binding.  Common Lisp and Scheme, for example, support this, but Emacs Lisp does not.

To illustrate this, the function below, make-add, returns a function that purports to add N to its own argument M.  This would work in Common Lisp, but it does not do the job in Emacs Lisp, because after the call to make-add exits, the variable n is no longer bound to the actual argument 2.

     (defun make-add (n)
         (function (lambda (m) (+ n m))))  ; Return a function.
          => make-add
     (fset 'add2 (make-add 2))  ; Define function add2
                                ;   with (make-add 2).
          => (lambda (m) (+ n m))
     (add2 4)                   ; Try to add 2 to 4.
     error--> Symbol's value as variable is void: n

Some Lisp dialects have ``closures'', objects that are like functions but record additional variable bindings.  Emacs Lisp does not have closures.

Implementation of Dynamic Scoping
---------------------------------

A simple sample implementation (which is not how Emacs Lisp actually works) may help you understand dynamic binding.  This technique is called deep binding and was used in early Lisp systems.

Suppose there is a stack of bindings, which are variable-value pairs. At entry to a function or to a let form, we can push bindings onto the stack for the arguments or local variables created there.  We can pop those bindings from the stack at exit from the binding construct.

We can find the value of a variable by searching the stack from top to bottom for a binding for that variable; the value from that binding is the value of the variable.  To set the variable, we search for the current binding, then store the new value into that binding.

As you can see, a function's bindings remain in effect as long as it continues execution, even during its calls to other functions.  That is why we say the extent of the binding is dynamic.  And any other function can refer to the bindings, if it uses the same variables while the bindings are in effect.  That is why we say the scope is indefinite.

The actual implementation of variable scoping in GNU Emacs Lisp uses a technique called shallow binding.  Each variable has a standard place in which its current value is always found---the value cell of the symbol.

In shallow binding, setting the variable works by storing a value in the value cell.  Creating a new binding works by pushing the old value (belonging to a previous binding) onto a stack, and storing the new local value in the value cell.  Eliminating a binding works by popping the old value off the stack, into the value cell.

We use shallow binding because it has the same results as deep binding, but runs faster, since there is never a need to search for a binding.

Proper Use of Dynamic Scoping
-----------------------------

Binding a variable in one function and using it in another is a powerful technique, but if used without restraint, it can make programs hard to understand.  There are two clean ways to use this technique:

  * Use or bind the variable only in a few related functions, written close together in one file.  Such a variable is used for communication within one program.

     You should write comments to inform other programmers that they can see all uses of the variable before them, and to advise them not to add uses elsewhere.

  * Give the variable a well-defined, documented meaning, and make all appropriate functions refer to it (but not bind it or set it) wherever that meaning is relevant.  For example, the variable case-fold-search is defined as ``non-nil means ignore case when searching''; various search and replace functions refer to it directly or through their subroutines, but do not bind or set it.

     Then you can bind the variable in other programs, knowing reliably what the effect will be.

In either case, you should define the variable with defvar. This helps other people understand your program by telling them to look for inter-function usage.  It also avoids a warning from the byte compiler.  Choose the variable's name to avoid name conflicts---don't use short names like x.

Buffer-Local Variables
======================

Global and local variable bindings are found in most programming languages in one form or another.  Emacs, however, also supports additional, unusual kinds of variable binding: buffer-local bindings, which apply only in one buffer, and frame-local bindings, which apply only in one frame.  Having different values for a variable in different buffers and/or frames is an important customization method.

This section describes buffer-local bindings; for frame-local bindings, see the following section, Frame-Local Variables.  (A few variables have bindings that are local to each terminal; see Multiple Displays.)

Introduction to Buffer-Local Variables
--------------------------------------

A buffer-local variable has a buffer-local binding associated with a particular buffer.  The binding is in effect when that buffer is current; otherwise, it is not in effect.  If you set the variable while a buffer-local binding is in effect, the new value goes in that binding, so its other bindings are unchanged.  This means that the change is visible only in the buffer where you made it.

The variable's ordinary binding, which is not associated with any specific buffer, is called the default binding.  In most cases, this is the global binding.

A variable can have buffer-local bindings in some buffers but not in other buffers.  The default binding is shared by all the buffers that don't have their own bindings for the variable.  (This includes all newly-created buffers.)  If you set the variable in a buffer that does not have a buffer-local binding for it, this sets the default binding (assuming there are no frame-local bindings to complicate the matter), so the new value is visible in all the buffers that see the default binding.

The most common use of buffer-local bindings is for major modes to change variables that control the behavior of commands.  For example, C mode and Lisp mode both set the variable paragraph-start to specify that only blank lines separate paragraphs.  They do this by making the variable buffer-local in the buffer that is being put into C mode or Lisp mode, and then setting it to the new value for that mode.  See Major Modes.

The usual way to make a buffer-local binding is with make-local-variable, which is what major mode commands typically use.  This affects just the current buffer; all other buffers (including those yet to be created) will continue to share the default value unless they are explicitly given their own buffer-local bindings.

A more powerful operation is to mark the variable as automatically buffer-local by calling make-variable-buffer-local.  You can think of this as making the variable local in all buffers, even those yet to be created.  More precisely, the effect is that setting the variable automatically makes the variable local to the current buffer if it is not already so.  All buffers start out by sharing the default value of the variable as usual, but setting the variable creates a buffer-local binding for the current buffer.  The new value is stored in the buffer-local binding, leaving the default binding untouched.  This means that the default value cannot be changed with setq in any buffer; the only way to change it is with setq-default.

Warning: When a variable has buffer-local or frame-local bindings in one or more buffers, let rebinds the binding that's currently in effect.  For instance, if the current buffer has a buffer-local value, let temporarily rebinds that.  If no buffer-local or frame-local bindings are in effect, let rebinds the default value.  If inside the let you then change to a different current buffer in which a different binding is in effect, you won't see the let binding any more.  And if you exit the let while still in the other buffer, you won't see the unbinding occur (though it will occur properly).  Here is an example to illustrate:

     (setq foo 'g)
     (set-buffer "a")
     (make-local-variable 'foo)

     (setq foo 'a)
     (let ((foo 'temp))
       ;; foo => 'temp  ; let binding in buffer a
       (set-buffer "b")
       ;; foo => 'g     ; the global value since foo is not local in b
       BODY...)

     foo => 'g        ; exiting restored the local value in buffer a,
                      ; but we don't see that in buffer b

     (set-buffer "a") ; verify the local value was restored
     foo => 'a

Note that references to foo in BODY access the buffer-local binding of buffer b.

When a file specifies local variable values, these become buffer-local values when you visit the file.  See File Variables (The GNU Emacs Manual).

Creating and Deleting Buffer-Local Bindings
-------------------------------------------

 -- Command: make-local-variable variable
     This function creates a buffer-local binding in the current buffer for VARIABLE (a symbol).  Other buffers are not affected.  The value returned is VARIABLE.

     The buffer-local value of VARIABLE starts out as the same value VARIABLE previously had.  If VARIABLE was void, it remains void.

          ;; In buffer b1:
          (setq foo 5)                ; Affects all buffers.
               => 5

          (make-local-variable 'foo)  ; Now it is local in b1.
               => foo

          foo                         ; That did not change
               => 5                   ;   the value.

          (setq foo 6)                ; Change the value
               => 6                   ;   in b1.

          foo
               => 6

          ;; In buffer b2, the value hasn't changed.
          (save-excursion
            (set-buffer "b2")
            foo)
               => 5

     Making a variable buffer-local within a let-binding for that variable does not work reliably, unless the buffer in which you do this is not current either on entry to or exit from the let.  This is because let does not distinguish between different kinds of bindings; it knows only which variable the binding was made for.

     If the variable is terminal-local, this function signals an error.  Such variables cannot have buffer-local bindings as well.  See Multiple Displays.

     Warning: do not use make-local-variable for a hook variable.  The hook variables are automatically made buffer-local as needed if you use the LOCAL argument to add-hook or remove-hook.

 -- Command: make-variable-buffer-local variable
     This function marks VARIABLE (a symbol) automatically buffer-local, so that any subsequent attempt to set it will make it local to the current buffer at the time.

     A peculiar wrinkle of this feature is that binding the variable (with let or other binding constructs) does not create a buffer-local binding for it.  Only setting the variable (with set or setq), while the variable does not have a let-style binding that was made in the current buffer, does so.

     If VARIABLE does not have a default value, then calling this command will give it a default value of nil.  If VARIABLE already has a default value, that value remains unchanged. Subsequently calling makunbound on VARIABLE will result in a void buffer-local value and leave the default value unaffected.

     The value returned is VARIABLE.

     Warning: Don't assume that you should use make-variable-buffer-local for user-option variables, simply because users might want to customize them differently in different buffers.  Users can make any variable local, when they wish to.  It is better to leave the choice to them.

     The time to use make-variable-buffer-local is when it is crucial that no two buffers ever share the same binding.  For example, when a variable is used for internal purposes in a Lisp program which depends on having separate values in separate buffers, then using make-variable-buffer-local can be the best solution.

 -- Function: local-variable-p variable &optional buffer
     This returns t if VARIABLE is buffer-local in buffer BUFFER (which defaults to the current buffer); otherwise, nil.

 -- Function: local-variable-if-set-p variable &optional buffer
     This returns t if VARIABLE will become buffer-local in buffer BUFFER (which defaults to the current buffer) if it is set there.

 -- Function: buffer-local-value variable buffer
     This function returns the buffer-local binding of VARIABLE (a symbol) in buffer BUFFER.  If VARIABLE does not have a buffer-local binding in buffer BUFFER, it returns the default value (see Default Value) of VARIABLE instead.

 -- Function: buffer-local-variables &optional buffer
     This function returns a list describing the buffer-local variables in buffer BUFFER.  (If BUFFER is omitted, the current buffer is used.)  It returns an association list (see Association Lists) in which each element contains one buffer-local variable and its value. However, when a variable's buffer-local binding in BUFFER is void, then the variable appears directly in the resulting list.

          (make-local-variable 'foobar)
          (makunbound 'foobar)
          (make-local-variable 'bind-me)
          (setq bind-me 69)

          (setq lcl (buffer-local-variables))
              ;; First, built-in variables local in all buffers:
          => ((mark-active . nil)
              (buffer-undo-list . nil)
              (mode-name . "Fundamental")
              ...

              ;; Next, non-built-in buffer-local variables.
              ;; This one is buffer-local and void:
              foobar
              ;; This one is buffer-local and nonvoid:
              (bind-me . 69))

     Note that storing new values into the CDRs of cons cells in this list does not change the buffer-local values of the variables.

 -- Command: kill-local-variable variable
     This function deletes the buffer-local binding (if any) for VARIABLE (a symbol) in the current buffer.  As a result, the default binding of VARIABLE becomes visible in this buffer.  This typically results in a change in the value of VARIABLE, since the default value is usually different from the buffer-local value just eliminated.

     If you kill the buffer-local binding of a variable that automatically becomes buffer-local when set, this makes the default value visible in the current buffer.  However, if you set the variable again, that will once again create a buffer-local binding for it.

     kill-local-variable returns VARIABLE.

     This function is a command because it is sometimes useful to kill one buffer-local variable interactively, just as it is useful to create buffer-local variables interactively.

 -- Function: kill-all-local-variables
     This function eliminates all the buffer-local variable bindings of the current buffer except for variables marked as ``permanent''.  As a result, the buffer will see the default values of most variables.

     This function also resets certain other information pertaining to the buffer: it sets the local keymap to nil, the syntax table to the value of (standard-syntax-table), the case table to (standard-case-table), and the abbrev table to the value of fundamental-mode-abbrev-table.

     The very first thing this function does is run the normal hook change-major-mode-hook (see below).

     Every major mode command begins by calling this function, which has the effect of switching to Fundamental mode and erasing most of the effects of the previous major mode.  To ensure that this does its job, the variables that major modes set should not be marked permanent.

     kill-all-local-variables returns nil.

 -- Variable: change-major-mode-hook
     The function kill-all-local-variables runs this normal hook before it does anything else.  This gives major modes a way to arrange for something special to be done if the user switches to a different major mode.  It is also useful for buffer-specific minor modes that should be forgotten if the user changes the major mode.

     For best results, make this variable buffer-local, so that it will disappear after doing its job and will not interfere with the subsequent major mode.  See Hooks.

A buffer-local variable is permanent if the variable name (a symbol) has a permanent-local property that is non-nil. Permanent locals are appropriate for data pertaining to where the file came from or how to save it, rather than with how to edit the contents.

The Default Value of a Buffer-Local Variable
--------------------------------------------

The global value of a variable with buffer-local bindings is also called the default value, because it is the value that is in effect whenever neither the current buffer nor the selected frame has its own binding for the variable.

The functions default-value and setq-default access and change a variable's default value regardless of whether the current buffer has a buffer-local binding.  For example, you could use setq-default to change the default setting of paragraph-start for most buffers; and this would work even when you are in a C or Lisp mode buffer that has a buffer-local value for this variable.

The special forms defvar and defconst also set the default value (if they set the variable at all), rather than any buffer-local or frame-local value.

 -- Function: default-value symbol
     This function returns SYMBOL's default value.  This is the value that is seen in buffers and frames that do not have their own values for this variable.  If SYMBOL is not buffer-local, this is equivalent to symbol-value (see Accessing Variables).

 -- Function: default-boundp symbol
     The function default-boundp tells you whether SYMBOL's default value is nonvoid.  If (default-boundp 'foo) returns nil, then (default-value 'foo) would get an error.

     default-boundp is to default-value as boundp is to symbol-value.

 -- Special Form: setq-default [symbol form]...
     This special form gives each SYMBOL a new default value, which is the result of evaluating the corresponding FORM.  It does not evaluate SYMBOL, but does evaluate FORM.  The value of the setq-default form is the value of the last FORM.

     If a SYMBOL is not buffer-local for the current buffer, and is not marked automatically buffer-local, setq-default has the same effect as setq.  If SYMBOL is buffer-local for the current buffer, then this changes the value that other buffers will see (as long as they don't have a buffer-local value), but not the value that the current buffer sees.

          ;; In buffer foo:
          (make-local-variable 'buffer-local)
               => buffer-local

          (setq buffer-local 'value-in-foo)
               => value-in-foo

          (setq-default buffer-local 'new-default)
               => new-default

          buffer-local
               => value-in-foo

          (default-value 'buffer-local)
               => new-default

          ;; In (the new) buffer bar:
          buffer-local
               => new-default

          (default-value 'buffer-local)
               => new-default

          (setq buffer-local 'another-default)
               => another-default

          (default-value 'buffer-local)
               => another-default

          ;; Back in buffer foo:
          buffer-local
               => value-in-foo
          (default-value 'buffer-local)
               => another-default

 -- Function: set-default symbol value
     This function is like setq-default, except that SYMBOL is an ordinary evaluated argument.

          (set-default (car '(a b c)) 23)
               => 23

          (default-value 'a)
               => 23

Frame-Local Variables
=====================

Just as variables can have buffer-local bindings, they can also have frame-local bindings.  These bindings belong to one frame, and are in effect when that frame is selected.  Frame-local bindings are actually frame parameters: you create a frame-local binding in a specific frame by calling modify-frame-parameters and specifying the variable name as the parameter name.

To enable frame-local bindings for a certain variable, call the function make-variable-frame-local.

 -- Command: make-variable-frame-local variable
     Enable the use of frame-local bindings for VARIABLE.  This does not in itself create any frame-local bindings for the variable; however, if some frame already has a value for VARIABLE as a frame parameter, that value automatically becomes a frame-local binding.

     If VARIABLE does not have a default value, then calling this command will give it a default value of nil.  If VARIABLE already has a default value, that value remains unchanged.

     If the variable is terminal-local, this function signals an error, because such variables cannot have frame-local bindings as well. See Multiple Displays.  A few variables that are implemented specially in Emacs can be buffer-local, but can never be frame-local.

     This command returns VARIABLE.

Buffer-local bindings take precedence over frame-local bindings.  Thus, consider a variable foo: if the current buffer has a buffer-local binding for foo, that binding is active; otherwise, if the selected frame has a frame-local binding for foo, that binding is active; otherwise, the default binding of foo is active.

Here is an example.  First we prepare a few bindings for foo:

     (setq f1 (selected-frame))
     (make-variable-frame-local 'foo)

     ;; Make a buffer-local binding for foo in b1.
     (set-buffer (get-buffer-create "b1"))
     (make-local-variable 'foo)
     (setq foo '(b 1))

     ;; Make a frame-local binding for foo in a new frame.
     ;; Store that frame in f2.
     (setq f2 (make-frame))
     (modify-frame-parameters f2 '((foo . (f 2))))

Now we examine foo in various contexts.  Whenever the buffer b1 is current, its buffer-local binding is in effect, regardless of the selected frame:

     (select-frame f1)
     (set-buffer (get-buffer-create "b1"))
     foo
          => (b 1)

     (select-frame f2)
     (set-buffer (get-buffer-create "b1"))
     foo
          => (b 1)

Otherwise, the frame gets a chance to provide the binding; when frame f2 is selected, its frame-local binding is in effect:

     (select-frame f2)
     (set-buffer (get-buffer "*scratch*"))
     foo
          => (f 2)

When neither the current buffer nor the selected frame provides a binding, the default binding is used:

     (select-frame f1)
     (set-buffer (get-buffer "*scratch*"))
     foo
          => nil

When the active binding of a variable is a frame-local binding, setting the variable changes that binding.  You can observe the result with frame-parameters:

     (select-frame f2)
     (set-buffer (get-buffer "*scratch*"))
     (setq foo 'nobody)
     (assq 'foo (frame-parameters f2))
          => (foo . nobody)

Possible Future Local Variables
===============================

We have considered the idea of bindings that are local to a category of frames---for example, all color frames, or all frames with dark backgrounds.  We have not implemented them because it is not clear that this feature is really useful.  You can get more or less the same results by adding a function to after-make-frame-functions, set up to define a particular frame parameter according to the appropriate conditions for each frame.

It would also be possible to implement window-local bindings.  We don't know of many situations where they would be useful, and it seems that indirect buffers (see Indirect Buffers) with buffer-local bindings offer a way to handle these situations more robustly.

If sufficient application is found for either of these two kinds of local bindings, we will provide it in a subsequent Emacs version.

File Local Variables
====================

This section describes the functions and variables that affect processing of file local variables.  See Local Variables in Files (The GNU Emacs Manual), for basic information about file local variables.

 -- User Option: enable-local-variables
     This variable controls whether to process file local variables.  A value of t means to process them, querying the user if unsafe variables are encountered; nil means ignore them; anything else means to query the user for each file.  The default value is t.

 -- Function: hack-local-variables &optional mode-only
     This function parses, and binds or evaluates as appropriate, any local variables specified by the contents of the current buffer.  The variable enable-local-variables has its effect here.  However, this function does not look for the mode: local variable in the -*- line.  set-auto-mode does that, also taking enable-local-variables into account (see Auto Major Mode).

     If the optional argument MODE-ONLY is non-nil, then all this function does is return t if the -*- line or the local variables list specifies a mode and nil otherwise. It does not set the mode nor any other file local variable.

If a file local variable could specify a function that would be called later, or an expression that would be executed later, simply visiting a file could take over your Emacs.  Emacs takes several measures to prevent this.

You can specify safe values for a variable with a safe-local-variable property.  If the property is t, setting that variable in a file is always considered safe, regardless of the value used.  If the property is a function of one argument, then any value is safe if the function returns non-nil given that value.  Many commonly encountered file variables standardly have safe-local-variable properties, including fill-column, fill-prefix, and indent-tabs-mode.

 -- User Option: safe-local-variable-values
     This variable provides another way to mark some variable values as safe.  It is a list of cons cells (VAR . VAL), where VAR is a variable name and VAL is a value which is safe for that variable.

     When Emacs asks the user whether or not to obey a set of file local variable specifications, the user can choose to mark them as safe. Doing so adds those variable/value pairs to safe-local-variable-values, and saves it to the user's custom file.

 -- Function: safe-local-variable-p sym val
     This function returns non-nil if it is safe to give SYM the value VAL, based on the above criteria.

Some variables are considered risky.  A variable whose name ends in any of -command, -frame-alist, -function, -functions, -hook, -hooks, -form, -forms, -map, -map-alist, -mode-alist, -program, or -predicate is considered risky.  The variables font-lock-keywords, font-lock-keywords followed by a digit, and font-lock-syntactic-keywords are also considered risky.  Finally, any variable whose name has a non-nil risky-local-variable property is considered risky.

 -- Function: risky-local-variable-p sym
     This function returns non-nil if SYM is a risky variable, based on the above criteria.

If a variable is risky, it will not be entered automatically into safe-local-variable-values as described above.  Therefore, Emacs will always query before setting a risky variable, unless the user explicitly allows the setting by customizing safe-local-variable-values directly.

 -- Variable: ignored-local-variables
     This variable holds a list of variables that should not be given local values by files.  Any value specified for one of these variables is completely ignored.

The Eval: ``variable'' is also a potential loophole, so Emacs normally asks for confirmation before handling it.

 -- User Option: enable-local-eval
     This variable controls processing of Eval: in -*- lines or local variables lists in files being visited.  A value of t means process them unconditionally; nil means ignore them; anything else means ask the user what to do for each file.  The default value is maybe.

Text properties are also potential loopholes, since their values could include functions to call.  So Emacs discards all text properties from string values specified for file local variables.

Variable Aliases
================

It is sometimes useful to make two variables synonyms, so that both variables always have the same value, and changing either one also changes the other.  Whenever you change the name of a variable---either because you realize its old name was not well chosen, or because its meaning has partly changed---it can be useful to keep the old name as an alias of the new one for compatibility.  You can do this with defvaralias.

 -- Function: defvaralias new-alias base-variable &optional docstring
     This function defines the symbol NEW-ALIAS as a variable alias for symbol BASE-VARIABLE. This means that retrieving the value of NEW-ALIAS returns the value of BASE-VARIABLE, and changing the value of NEW-ALIAS changes the value of BASE-VARIABLE.

     If the DOCSTRING argument is non-nil, it specifies the documentation for NEW-ALIAS; otherwise, the alias gets the same documentation as BASE-VARIABLE has, if any, unless BASE-VARIABLE is itself an alias, in which case NEW-ALIAS gets the documentation of the variable at the end of the chain of aliases.

     This function returns BASE-VARIABLE.

Variable aliases are convenient for replacing an old name for a variable with a new name.  make-obsolete-variable declares that the old name is obsolete and therefore that it may be removed at some stage in the future.

 -- Function: make-obsolete-variable obsolete-name current-name &optional when
     This function makes the byte-compiler warn that the variable OBSOLETE-NAME is obsolete.  If CURRENT-NAME is a symbol, it is the variable's new name; then the warning message says to use CURRENT-NAME instead of OBSOLETE-NAME.  If CURRENT-NAME is a string, this is the message and there is no replacement variable.

     If provided, WHEN should be a string indicating when the variable was first made obsolete---for example, a date or a release number.

You can make two variables synonyms and declare one obsolete at the same time using the macro define-obsolete-variable-alias.

 -- Macro: define-obsolete-variable-alias obsolete-name current-name &optional when docstring
     This macro marks the variable OBSOLETE-NAME as obsolete and also makes it an alias for the variable CURRENT-NAME.  It is equivalent to the following:

          (defvaralias OBSOLETE-NAME CURRENT-NAME DOCSTRING)
          (make-obsolete-variable OBSOLETE-NAME CURRENT-NAME WHEN)

 -- Function: indirect-variable variable
     This function returns the variable at the end of the chain of aliases of VARIABLE.  If VARIABLE is not a symbol, or if VARIABLE is not defined as an alias, the function returns VARIABLE.

     This function signals a cyclic-variable-indirection error if there is a loop in the chain of symbols.

     (defvaralias 'foo 'bar)
     (indirect-variable 'foo)
          => bar
     (indirect-variable 'bar)
          => bar
     (setq bar 2)
     bar
          => 2

     foo
          => 2

     (setq foo 0)
     bar
          => 0
     foo
          => 0

Variables with Restricted Values
================================

Ordinary Lisp variables can be assigned any value that is a valid Lisp object.  However, certain Lisp variables are not defined in Lisp, but in C.  Most of these variables are defined in the C code using DEFVAR_LISP.  Like variables defined in Lisp, these can take on any value.  However, some variables are defined using DEFVAR_INT or DEFVAR_BOOL.  See Writing Emacs Primitives, in particular the description of functions of the type syms_of_FILENAME, for a brief discussion of the C implementation.

Variables of type DEFVAR_BOOL can only take on the values nil or t.  Attempting to assign them any other value will set them to t:

     (let ((display-hourglass 5))
       display-hourglass)
          => t

 -- Variable: byte-boolean-vars
     This variable holds a list of all variables of type DEFVAR_BOOL.

Variables of type DEFVAR_INT can only take on integer values. Attempting to assign them any other value will result in an error:

     (setq window-min-height 5.0)
     error--> Wrong type argument: integerp, 5.0