Windows
*******

This chapter describes most of the functions and variables related to Emacs windows.  See Display, for information on how text is displayed in windows.

Basic Concepts of Emacs Windows
===============================

A window in Emacs is the physical area of the screen in which a buffer is displayed.  The term is also used to refer to a Lisp object that represents that screen area in Emacs Lisp.  It should be clear from the context which is meant.

Emacs groups windows into frames.  A frame represents an area of screen available for Emacs to use.  Each frame always contains at least one window, but you can subdivide it vertically or horizontally into multiple nonoverlapping Emacs windows.

In each frame, at any time, one and only one window is designated as selected within the frame.  The frame's cursor appears in that window.  At any time, one frame is the selected frame; and the window selected within that frame is the selected window.  The selected window's buffer is usually the current buffer (except when set-buffer has been used).  See Current Buffer.

For practical purposes, a window exists only while it is displayed in a frame.  Once removed from the frame, the window is effectively deleted and should not be used, even though there may still be references to it from other Lisp objects.  Restoring a saved window configuration is the only way for a window no longer on the screen to come back to life.  (see Deleting Windows.)

Each window has the following attributes:

  * containing frame

  * window height

  * window width

  * window edges with respect to the screen or frame

  * the buffer it displays

  * position within the buffer at the upper left of the window

  * amount of horizontal scrolling, in columns

  * point

  * the mark

  * how recently the window was selected

Users create multiple windows so they can look at several buffers at once.  Lisp libraries use multiple windows for a variety of reasons, but most often to display related information.  In Rmail, for example, you can move through a summary buffer in one window while the other window shows messages one at a time as they are reached.

The meaning of ``window'' in Emacs is similar to what it means in the context of general-purpose window systems such as X, but not identical. The X Window System places X windows on the screen; Emacs uses one or more X windows as frames, and subdivides them into Emacs windows.  When you use Emacs on a character-only terminal, Emacs treats the whole terminal screen as one frame.

Most window systems support arbitrarily located overlapping windows. In contrast, Emacs windows are tiled; they never overlap, and together they fill the whole screen or frame.  Because of the way in which Emacs creates new windows and resizes them, not all conceivable tilings of windows on an Emacs frame are actually possible. See Splitting Windows, and Size of Window.

See Display, for information on how the contents of the window's buffer are displayed in the window.

 -- Function: windowp object
     This function returns t if OBJECT is a window.

Splitting Windows
=================

The functions described here are the primitives used to split a window into two windows.  Two higher level functions sometimes split a window, but not always: pop-to-buffer and display-buffer (see Displaying Buffers).

The functions described here do not accept a buffer as an argument. The two ``halves'' of the split window initially display the same buffer previously visible in the window that was split.

 -- Command: split-window &optional window size horizontal
     This function splits WINDOW into two windows.  The original window WINDOW remains the selected window, but occupies only part of its former screen area.  The rest is occupied by a newly created window which is returned as the value of this function.

     If HORIZONTAL is non-nil, then WINDOW splits into two side by side windows.  The original window WINDOW keeps the leftmost SIZE columns, and gives the rest of the columns to the new window.  Otherwise, it splits into windows one above the other, and WINDOW keeps the upper SIZE lines and gives the rest of the lines to the new window.  The original window is therefore the left-hand or upper of the two, and the new window is the right-hand or lower.

     If WINDOW is omitted or nil, then the selected window is split.  If SIZE is omitted or nil, then WINDOW is divided evenly into two parts.  (If there is an odd line, it is allocated to the new window.)  When split-window is called interactively, all its arguments are nil.

     The following example starts with one window on a screen that is 50 lines high by 80 columns wide; then the window is split.

          (setq w (selected-window))
               => #<window 8 on windows.texi>
          (window-edges)          ; Edges in order:
               => (0 0 80 50)     ;   left--top--right--bottom

          ;; Returns window created
          (setq w2 (split-window w 15))
               => #<window 28 on windows.texi>

          (window-edges w2)
               => (0 15 80 50)    ; Bottom window;
                                  ;   top is line 15

          (window-edges w)
               => (0 0 80 15)     ; Top window

     The screen looks like this:

                   __________
                  |          |  line 0
                  |    w     |
                  |__________|
                  |          |  line 15
                  |    w2    |
                  |__________|
                                line 50
           column 0   column 80

     Next, the top window is split horizontally:

          (setq w3 (split-window w 35 t))
               => #<window 32 on windows.texi>

          (window-edges w3)
               => (35 0 80 15)  ; Left edge at column 35

          (window-edges w)
               => (0 0 35 15)   ; Right edge at column 35

          (window-edges w2)
               => (0 15 80 50)  ; Bottom window unchanged

     Now, the screen looks like this:

               column 35
                   __________
                  |   |      |  line 0
                  | w |  w3  |
                  |___|______|
                  |          |  line 15
                  |    w2    |
                  |__________|
                                line 50
           column 0   column 80

     Normally, Emacs indicates the border between two side-by-side windows with a scroll bar (see Scroll Bars) or | characters.  The display table can specify alternative border characters; see Display Tables.

 -- Command: split-window-vertically size
     This function splits the selected window into two windows, one above the other, leaving the selected window with SIZE lines.

     This function is simply an interface to split-windows. Here is the complete function definition for it:

          (defun split-window-vertically (&optional arg)
            "Split current window into two windows, ..."
            (interactive "P")
            (split-window nil (and arg (prefix-numeric-value arg))))

 -- Command: split-window-horizontally size
     This function splits the selected window into two windows side-by-side, leaving the selected window with SIZE columns.

     This function is simply an interface to split-windows.  Here is the complete definition for split-window-horizontally (except for part of the documentation string):

          (defun split-window-horizontally (&optional arg)
            "Split selected window into two windows, side by side..."
            (interactive "P")
            (split-window nil (and arg (prefix-numeric-value arg)) t))

 -- Function: one-window-p &optional no-mini all-frames
     This function returns non-nil if there is only one window.  The argument NO-MINI, if non-nil, means don't count the minibuffer even if it is active; otherwise, the minibuffer window is included, if active, in the total number of windows, which is compared against one.

     The argument ALL-FRAMES specifies which frames to consider.  Here are the possible values and their meanings:

     nil
          Count the windows in the selected frame, plus the minibuffer used by that frame even if it lies in some other frame.

     t
          Count all windows in all existing frames.

     visible
          Count all windows in all visible frames.

     0
          Count all windows in all visible or iconified frames.

     anything else
          Count precisely the windows in the selected frame, and no others.

Deleting Windows
================

A window remains visible on its frame unless you delete it by calling certain functions that delete windows.  A deleted window cannot appear on the screen, but continues to exist as a Lisp object until there are no references to it.  There is no way to cancel the deletion of a window aside from restoring a saved window configuration (see Window Configurations).  Restoring a window configuration also deletes any windows that aren't part of that configuration.

When you delete a window, the space it took up is given to one adjacent sibling.  (In Emacs version 18, the space was divided evenly among all the siblings.)

 -- Function: window-live-p window
     This function returns nil if WINDOW is deleted, and t otherwise.

     Warning: Erroneous information or fatal errors may result from using a deleted window as if it were live.

 -- Command: delete-window &optional window
     This function removes WINDOW from the display.  If WINDOW is omitted, then the selected window is deleted.  An error is signaled if there is only one window when delete-window is called.

     This function returns nil.

     When delete-window is called interactively, WINDOW defaults to the selected window.

 -- Command: delete-other-windows &optional window
     This function makes WINDOW the only window on its frame, by deleting the other windows in that frame.  If WINDOW is omitted or nil, then the selected window is used by default.

     The result is nil.

 -- Command: delete-windows-on buffer &optional frame
     This function deletes all windows showing BUFFER.  If there are no windows showing BUFFER, it does nothing.

     delete-windows-on operates frame by frame.  If a frame has several windows showing different buffers, then those showing BUFFER are removed, and the others expand to fill the space.  If all windows in some frame are showing BUFFER (including the case where there is only one window), then the frame reverts to having a single window showing another buffer chosen with other-buffer. See The Buffer List.

     The argument FRAME controls which frames to operate on:

       * If it is nil, operate on the selected frame.

       * If it is t, operate on all frames.

       * If it is visible, operate on all visible frames.

       * 0 If it is 0, operate on all visible or iconified frames.

       * If it is a frame, operate on that frame.

     This function always returns nil.

Selecting Windows
=================

When a window is selected, the buffer in the window becomes the current buffer, and the cursor will appear in it.

 -- Function: selected-window
     This function returns the selected window.  This is the window in which the cursor appears and to which many commands apply.

 -- Function: select-window window
     This function makes WINDOW the selected window.  The cursor then appears in WINDOW (on redisplay).  The buffer being displayed in WINDOW is immediately designated the current buffer.

     The return value is WINDOW.

          (setq w (next-window))
          (select-window w)
               => #<window 65 on windows.texi>

 -- Macro: save-selected-window forms...
     This macro records the selected window, executes FORMS in sequence, then restores the earlier selected window.

     This macro does not save or restore anything about the sizes, arrangement or contents of windows; therefore, if the FORMS change them, the change persists.

     Each frame, at any time, has a window selected within the frame.  This macro only saves the selected window; it does not save anything about other frames.  If the FORMS select some other frame and alter the window selected within it, the change persists.

The following functions choose one of the windows on the screen, offering various criteria for the choice.

 -- Function: get-lru-window &optional frame
     This function returns the window least recently ``used'' (that is, selected).  The selected window is always the most recently used window.

     The selected window can be the least recently used window if it is the only window.  A newly created window becomes the least recently used window until it is selected.  A minibuffer window is never a candidate.

     The argument FRAME controls which windows are considered.

       * If it is nil, consider windows on the selected frame.

       * If it is t, consider windows on all frames.

       * If it is visible, consider windows on all visible frames.

       * If it is 0, consider windows on all visible or iconified frames.

       * If it is a frame, consider windows on that frame.

 -- Function: get-largest-window &optional frame
     This function returns the window with the largest area (height times width).  If there are no side-by-side windows, then this is the window with the most lines.  A minibuffer window is never a candidate.

     If there are two windows of the same size, then the function returns the window that is first in the cyclic ordering of windows (see following section), starting from the selected window.

     The argument FRAME controls which set of windows are considered.  See get-lru-window, above.

Cyclic Ordering of Windows
==========================

When you use the command C-x o (other-window) to select the next window, it moves through all the windows on the screen in a specific cyclic order.  For any given configuration of windows, this order never varies.  It is called the cyclic ordering of windows.

This ordering generally goes from top to bottom, and from left to right.  But it may go down first or go right first, depending on the order in which the windows were split.

If the first split was vertical (into windows one above each other), and then the subwindows were split horizontally, then the ordering is left to right in the top of the frame, and then left to right in the next lower part of the frame, and so on.  If the first split was horizontal, the ordering is top to bottom in the left part, and so on. In general, within each set of siblings at any level in the window tree, the order is left to right, or top to bottom.

 -- Function: next-window &optional window minibuf all-frames
     This function returns the window following WINDOW in the cyclic ordering of windows.  This is the window that C-x o would select if typed when WINDOW is selected.  If WINDOW is the only window visible, then this function returns WINDOW.  If omitted, WINDOW defaults to the selected window.

     The value of the argument MINIBUF determines whether the minibuffer is included in the window order.  Normally, when MINIBUF is nil, the minibuffer is included if it is currently active; this is the behavior of C-x o.  (The minibuffer window is active while the minibuffer is in use.  See Minibuffers.)

     If MINIBUF is t, then the cyclic ordering includes the minibuffer window even if it is not active.

     If MINIBUF is neither t nor nil, then the minibuffer window is not included even if it is active.

     The argument ALL-FRAMES specifies which frames to consider.  Here are the possible values and their meanings:

     nil
          Consider all the windows in WINDOW's frame, plus the minibuffer used by that frame even if it lies in some other frame.

     t
          Consider all windows in all existing frames.

     visible
          Consider all windows in all visible frames.  (To get useful results, you must ensure WINDOW is in a visible frame.)

     0
          Consider all windows in all visible or iconified frames.

     anything else
          Consider precisely the windows in WINDOW's frame, and no others.

     This example assumes there are two windows, both displaying the buffer windows.texi:

          (selected-window)
               => #<window 56 on windows.texi>

          (next-window (selected-window))
               => #<window 52 on windows.texi>

          (next-window (next-window (selected-window)))
               => #<window 56 on windows.texi>

 -- Function: previous-window &optional window minibuf all-frames
     This function returns the window preceding WINDOW in the cyclic ordering of windows.  The other arguments specify which windows to include in the cycle, as in next-window.

 -- Command: other-window count
     This function selects the COUNTth following window in the cyclic order.  If count is negative, then it selects the -COUNTth preceding window.  It returns nil.

     In an interactive call, COUNT is the numeric prefix argument.

 -- Function: walk-windows proc &optional minibuf all-frames
     This function cycles through all windows, calling proc once for each window with the window as its sole argument.

     The optional arguments MINIBUF and ALL-FRAMES specify the set of windows to include in the scan.  See next-window, above, for details.

Buffers and Windows
===================

This section describes low-level functions to examine windows or to display buffers in windows in a precisely controlled fashion. See Displaying Buffers, for related functions that find a window to use and specify a buffer for it. The functions described there are easier to use than these, but they employ heuristics in choosing or creating a window; use these functions when you need complete control.

 -- Function: set-window-buffer window buffer-or-name
     This function makes WINDOW display BUFFER-OR-NAME as its contents.  It returns nil.

          (set-window-buffer (selected-window) "foo")
               => nil

 -- Function: window-buffer &optional window
     This function returns the buffer that WINDOW is displaying.  If WINDOW is omitted, this function returns the buffer for the selected window.

          (window-buffer)
               => #<buffer windows.texi>

 -- Function: get-buffer-window buffer-or-name &optional all-frames
     This function returns a window currently displaying BUFFER-OR-NAME, or nil if there is none.  If there are several such windows, then the function returns the first one in the cyclic ordering of windows, starting from the selected window. See Cyclic Window Ordering.

     The argument ALL-FRAMES controls which windows to consider.

       * If it is nil, consider windows on the selected frame.

       * If it is t, consider windows on all frames.

       * If it is visible, consider windows on all visible frames.

       * If it is 0, consider windows on all visible or iconified frames.

       * If it is a frame, consider windows on that frame.

 -- Function: get-buffer-window-list buffer-or-name &optional minibuf all-frames
     This function returns a list of all the windows currently displaying BUFFER-OR-NAME.

     The two optional arguments work like the optional arguments of next-window (see Cyclic Window Ordering); they are not like the single optional argument of get-buffer-window.  Perhaps we should change get-buffer-window in the future to make it compatible with the other functions.

     The argument ALL-FRAMES controls which windows to consider.

       * If it is nil, consider windows on the selected frame.

       * If it is t, consider windows on all frames.

       * If it is visible, consider windows on all visible frames.

       * If it is 0, consider windows on all visible or iconified frames.

       * If it is a frame, consider windows on that frame.

Displaying Buffers in Windows
=============================

In this section we describe convenient functions that choose a window automatically and use it to display a specified buffer.  These functions can also split an existing window in certain circumstances.  We also describe variables that parameterize the heuristics used for choosing a window. See Buffers and Windows, for low-level functions that give you more precise control.

Do not use the functions in this section in order to make a buffer current so that a Lisp program can access or modify it; they are too drastic for that purpose, since they change the display of buffers in windows, which is gratuitous and will surprise the user.  Instead, use set-buffer (see Current Buffer) and save-excursion (see Excursions), which designate buffers as current for programmed access without affecting the display of buffers in windows.

 -- Command: switch-to-buffer buffer-or-name &optional norecord
     This function makes BUFFER-OR-NAME the current buffer, and also displays the buffer in the selected window.  This means that a human can see the buffer and subsequent keyboard commands will apply to it. Contrast this with set-buffer, which makes BUFFER-OR-NAME the current buffer but does not display it in the selected window. See Current Buffer.

     If BUFFER-OR-NAME does not identify an existing buffer, then a new buffer by that name is created.  The major mode for the new buffer is set according to the variable default-major-mode.  See Auto Major Mode.

     Normally the specified buffer is put at the front of the buffer list. This affects the operation of other-buffer.  However, if NORECORD is non-nil, this is not done.  See The Buffer List.

     The switch-to-buffer function is often used interactively, as the binding of C-x b.  It is also used frequently in programs.  It always returns nil.

 -- Command: switch-to-buffer-other-window buffer-or-name &optional norecord
     This function makes BUFFER-OR-NAME the current buffer and displays it in a window not currently selected.  It then selects that window.  The handling of the buffer is the same as in switch-to-buffer.

     The currently selected window is absolutely never used to do the job. If it is the only window, then it is split to make a distinct window for this purpose.  If the selected window is already displaying the buffer, then it continues to do so, but another window is nonetheless found to display it in as well.

     This function updates the buffer list just like switch-to-buffer unless NORECORD is non-nil.

 -- Function: pop-to-buffer buffer-or-name &optional other-window norecord
     This function makes BUFFER-OR-NAME the current buffer and switches to it in some window, preferably not the window previously selected.  The ``popped-to'' window becomes the selected window within its frame.

     If the variable pop-up-frames is non-nil, pop-to-buffer looks for a window in any visible frame already displaying the buffer; if there is one, it returns that window and makes it be selected within its frame.  If there is none, it creates a new frame and displays the buffer in it.

     If pop-up-frames is nil, then pop-to-buffer operates entirely within the selected frame.  (If the selected frame has just a minibuffer, pop-to-buffer operates within the most recently selected frame that was not just a minibuffer.)

     If the variable pop-up-windows is non-nil, windows may be split to create a new window that is different from the original window.  For details, see Choosing Window.

     If OTHER-WINDOW is non-nil, pop-to-buffer finds or creates another window even if BUFFER-OR-NAME is already visible in the selected window.  Thus BUFFER-OR-NAME could end up displayed in two windows.  On the other hand, if BUFFER-OR-NAME is already displayed in the selected window and OTHER-WINDOW is nil, then the selected window is considered sufficient display for BUFFER-OR-NAME, so that nothing needs to be done.

     All the variables that affect display-buffer affect pop-to-buffer as well.  See Choosing Window.

     If BUFFER-OR-NAME is a string that does not name an existing buffer, a buffer by that name is created.  The major mode for the new buffer is set according to the variable default-major-mode. See Auto Major Mode.

     This function updates the buffer list just like switch-to-buffer unless NORECORD is non-nil.

 -- Command: replace-buffer-in-windows buffer
     This function replaces BUFFER with some other buffer in all windows displaying it.  The other buffer used is chosen with other-buffer.  In the usual applications of this function, you don't care which other buffer is used; you just want to make sure that BUFFER is no longer displayed.

     This function returns nil.

 -- Variable: buffer-display-count
     This variable is always local in each buffer.  When the buffer is created, buffer-display-count has value 0.  Each time the buffer is displayed in a window, that increments the value of buffer-display-count.

Choosing a Window for Display
=============================

This section describes the basic facility that chooses a window to display a buffer in---display-buffer.  All the higher-level functions and commands use this subroutine.  Here we describe how to use display-buffer and how to customize it.

 -- Command: display-buffer buffer-or-name &optional not-this-window frame
     This command makes BUFFER-OR-NAME appear in some window, like pop-to-buffer, but it does not select that window and does not make the buffer current.  The identity of the selected window is unaltered by this function.

     If NOT-THIS-WINDOW is non-nil, it means to display the specified buffer in a window other than the selected one, even if it is already on display in the selected window.  This can cause the buffer to appear in two windows at once.  Otherwise, if BUFFER-OR-NAME is already being displayed in any window, that is good enough, so this function does nothing.

     display-buffer returns the window chosen to display BUFFER-OR-NAME.

     If the argument FRAME is non-nil, it specifies which frames to check when deciding whether the buffer is already displayed.  Its value means the same thing as in functions get-buffer-window (see Buffers and Windows).  If the buffer is already displayed in some window on one of these frames, display-buffer simply returns that window.

     Precisely how display-buffer finds or creates a window depends on the variables described below.

 -- User Option: pop-up-windows
     This variable controls whether display-buffer makes new windows. If it is non-nil and there is only one window, then that window is split.  If it is nil, then display-buffer does not split the single window, but uses it whole.

 -- User Option: split-height-threshold
     This variable determines when display-buffer may split a window, if there are multiple windows.  display-buffer always splits the largest window if it has at least this many lines.  If the largest window is not this tall, it is split only if it is the sole window and pop-up-windows is non-nil.

 -- User Option: pop-up-frames
     This variable controls whether display-buffer makes new frames. If it is non-nil, display-buffer looks for an existing window already displaying the desired buffer, on any visible frame.  If it finds one, it returns that window.  Otherwise it makes a new frame. The variables pop-up-windows and split-height-threshold do not matter if pop-up-frames is non-nil.

     If pop-up-frames is nil, then display-buffer either splits a window or reuses one.

     See Frames, for more information.

 -- Variable: pop-up-frame-function
     This variable specifies how to make a new frame if pop-up-frames is non-nil.

     Its value should be a function of no arguments.  When display-buffer makes a new frame, it does so by calling that function, which should return a frame.  The default value of the variable is a function that creates a frame using parameters from pop-up-frame-alist.

 -- Variable: pop-up-frame-alist
     This variable holds an alist specifying frame parameters used when display-buffer makes a new frame.  See Frame Parameters, for more information about frame parameters.

 -- Variable: special-display-buffer-names
     A list of buffer names for buffers that should be displayed specially. If the buffer's name is in this list, display-buffer handles the buffer specially.

     By default, special display means to give the buffer a dedicated frame.

     If an element is a list, instead of a string, then the CAR of the list is the buffer name, and the rest of the list says how to create the frame.  There are two possibilities for the rest of the list.  It can be an alist, specifying frame parameters, or it can contain a function and arguments to give to it.  (The function's first argument is always the buffer to be displayed; the arguments from the list come after that.)

 -- Variable: special-display-regexps
     A list of regular expressions that specify buffers that should be displayed specially.  If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer specially.

     By default, special display means to give the buffer a dedicated frame.

     If an element is a list, instead of a string, then the CAR of the list is the regular expression, and the rest of the list says how to create the frame.  See above, under special-display-buffer-names.

 -- Variable: special-display-function
     This variable holds the function to call to display a buffer specially. It receives the buffer as an argument, and should return the window in which it is displayed.

     The default value of this variable is special-display-popup-frame.

 -- Function: special-display-popup-frame buffer
     This function makes BUFFER visible in a frame of its own.  If BUFFER is already displayed in a window in some frame, it makes the frame visible and raises it, to use that window.  Otherwise, it creates a frame that will be dedicated to BUFFER.

     This function uses an existing window displaying BUFFER whether or not it is in a frame of its own; but if you set up the above variables in your init file, before BUFFER was created, then presumably the window was previously made by this function.

 -- User Option: special-display-frame-alist
     This variable holds frame parameters for special-display-popup-frame to use when it creates a frame.

 -- User Option: same-window-buffer-names
     A list of buffer names for buffers that should be displayed in the selected window.  If the buffer's name is in this list, display-buffer handles the buffer by switching to it in the selected window.

 -- User Option: same-window-regexps
     A list of regular expressions that specify buffers that should be displayed in the selected window.  If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer by switching to it in the selected window.

 -- Variable: display-buffer-function
     This variable is the most flexible way to customize the behavior of display-buffer.  If it is non-nil, it should be a function that display-buffer calls to do the work.  The function should accept two arguments, the same two arguments that display-buffer received.  It should choose or create a window, display the specified buffer, and then return the window.

     This hook takes precedence over all the other options and hooks described above.

A window can be marked as ``dedicated'' to its buffer.  Then display-buffer does not try to use that window.

 -- Function: window-dedicated-p window
     This function returns t if WINDOW is marked as dedicated; otherwise nil.

 -- Function: set-window-dedicated-p window flag
     This function marks WINDOW as dedicated if FLAG is non-nil, and nondedicated otherwise.

Windows and Point
=================

Each window has its own value of point, independent of the value of point in other windows displaying the same buffer.  This makes it useful to have multiple windows showing one buffer.

  * The window point is established when a window is first created; it is initialized from the buffer's point, or from the window point of another window opened on the buffer if such a window exists.

  * Selecting a window sets the value of point in its buffer from the window's value of point.  Conversely, deselecting a window sets the window's value of point from that of the buffer.  Thus, when you switch between windows that display a given buffer, the point value for the selected window is in effect in the buffer, while the point values for the other windows are stored in those windows.

  * As long as the selected window displays the current buffer, the window's point and the buffer's point always move together; they remain equal.

  * See Positions, for more details on buffer positions.

As far as the user is concerned, point is where the cursor is, and when the user switches to another buffer, the cursor jumps to the position of point in that buffer.

 -- Function: window-point window
     This function returns the current position of point in WINDOW. For a nonselected window, this is the value point would have (in that window's buffer) if that window were selected.

     When WINDOW is the selected window and its buffer is also the current buffer, the value returned is the same as point in that buffer.

     Strictly speaking, it would be more correct to return the ``top-level'' value of point, outside of any save-excursion forms.  But that value is hard to find.

 -- Function: set-window-point window position
     This function positions point in WINDOW at position POSITION in WINDOW's buffer.

The Window Start Position
=========================

Each window contains a marker used to keep track of a buffer position that specifies where in the buffer display should start.  This position is called the display-start position of the window (or just the start).  The character after this position is the one that appears at the upper left corner of the window.  It is usually, but not inevitably, at the beginning of a text line.

 -- Function: window-start &optional window
     This function returns the display-start position of window WINDOW.  If WINDOW is nil, the selected window is used.  For example,

          (window-start)
               => 7058

     When you create a window, or display a different buffer in it, the display-start position is set to a display-start position recently used for the same buffer, or 1 if the buffer doesn't have any.

     Redisplay updates the window-start position (if you have not specified it explicitly since the previous redisplay) so that point appears on the screen.  Nothing except redisplay automatically changes the window-start position; if you move point, do not expect the window-start position to change in response until after the next redisplay.

     For a realistic example of using window-start, see the description of count-lines in Text Lines.

 -- Function: window-end &optional window
     This function returns the position of the end of the display in window WINDOW.  If WINDOW is nil, the selected window is used.

     Simply changing the buffer text or moving point does not update the value that window-end returns.  The value is updated only when Emacs redisplays and redisplay actually finishes.

     If the last redisplay of WINDOW was preempted, and did not finish, Emacs does not know the position of the end of display in that window. In that case, this function returns a value that is not correct.  In a future version, window-end will return nil in that case.

 -- Function: set-window-start window position &optional noforce
     This function sets the display-start position of WINDOW to POSITION in WINDOW's buffer.  It returns POSITION.

     The display routines insist that the position of point be visible when a buffer is displayed.  Normally, they change the display-start position (that is, scroll the window) whenever necessary to make point visible. However, if you specify the start position with this function using nil for NOFORCE, it means you want display to start at POSITION even if that would put the location of point off the screen.  If this does place point off screen, the display routines move point to the left margin on the middle line in the window.

     For example, if point is 1 and you set the start of the window to 2, then point would be ``above'' the top of the window.  The display routines will automatically move point if it is still 1 when redisplay occurs.  Here is an example:

          ;; Here is what foo looks like before executing
          ;;   the set-window-start expression.

          ---------- Buffer: foo ----------
          -!-This is the contents of buffer foo.
          2
          3
          4
          5
          6
          ---------- Buffer: foo ----------

          (set-window-start
           (selected-window)
           (1+ (window-start)))
          => 2

          ;; Here is what foo looks like after executing
          ;;   the set-window-start expression.
          ---------- Buffer: foo ----------
          his is the contents of buffer foo.
          2
          3
          -!-4
          5
          6
          ---------- Buffer: foo ----------

     If NOFORCE is non-nil, and POSITION would place point off screen at the next redisplay, then redisplay computes a new window-start position that works well with point, and thus POSITION is not used.

 -- Function: pos-visible-in-window-p &optional position window
     This function returns t if POSITION is within the range of text currently visible on the screen in WINDOW.  It returns nil if POSITION is scrolled vertically out of view.  The argument POSITION defaults to the current position of point; WINDOW, to the selected window.  Here is an example:

          (or (pos-visible-in-window-p
               (point) (selected-window))
              (recenter 0))

     The pos-visible-in-window-p function considers only vertical scrolling.  If POSITION is out of view only because WINDOW has been scrolled horizontally, pos-visible-in-window-p returns t.  See Horizontal Scrolling.

Vertical Scrolling
==================

Vertical scrolling means moving the text up or down in a window.  It works by changing the value of the window's display-start location.  It may also change the value of window-point to keep it on the screen.

In the commands scroll-up and scroll-down, the directions ``up'' and ``down'' refer to the motion of the text in the buffer at which you are looking through the window.  Imagine that the text is written on a long roll of paper and that the scrolling commands move the paper up and down.  Thus, if you are looking at text in the middle of a buffer and repeatedly call scroll-down, you will eventually see the beginning of the buffer.

Some people have urged that the opposite convention be used: they imagine that the window moves over text that remains in place.  Then ``down'' commands would take you to the end of the buffer.  This view is more consistent with the actual relationship between windows and the text in the buffer, but it is less like what the user sees.  The position of a window on the terminal does not move, and short scrolling commands clearly move the text up or down on the screen.  We have chosen names that fit the user's point of view.

The scrolling functions (aside from scroll-other-window) have unpredictable results if the current buffer is different from the buffer that is displayed in the selected window.  See Current Buffer.

 -- Command: scroll-up &optional count
     This function scrolls the text in the selected window upward COUNT lines.  If COUNT is negative, scrolling is actually downward.

     If COUNT is nil (or omitted), then the length of scroll is next-screen-context-lines lines less than the usable height of the window (not counting its mode line).

     scroll-up returns nil.

 -- Command: scroll-down &optional count
     This function scrolls the text in the selected window downward COUNT lines.  If COUNT is negative, scrolling is actually upward.

     If COUNT is omitted or nil, then the length of the scroll is next-screen-context-lines lines less than the usable height of the window (not counting its mode line).

     scroll-down returns nil.

 -- Command: scroll-other-window &optional count
     This function scrolls the text in another window upward COUNT lines.  Negative values of COUNT, or nil, are handled as in scroll-up.

     You can specify a buffer to scroll with the variable other-window-scroll-buffer.  When the selected window is the minibuffer, the next window is normally the one at the top left corner. You can specify a different window to scroll with the variable minibuffer-scroll-window.  This variable has no effect when any other window is selected.  See Minibuffer Misc.

     When the minibuffer is active, it is the next window if the selected window is the one at the bottom right corner.  In this case, scroll-other-window attempts to scroll the minibuffer.  If the minibuffer contains just one line, it has nowhere to scroll to, so the line reappears after the echo area momentarily displays the message ``Beginning of buffer''.

 -- Variable: other-window-scroll-buffer
     If this variable is non-nil, it tells scroll-other-window which buffer to scroll.

 -- User Option: scroll-step
     This variable controls how scrolling is done automatically when point moves off the screen.  If the value is zero, then redisplay scrolls the text to center point vertically in the window.  If the value is a positive integer N, then redisplay brings point back on screen by scrolling N lines in either direction, if possible; otherwise, it centers point.  The default value is zero.

 -- User Option: next-screen-context-lines
     The value of this variable is the number of lines of continuity to retain when scrolling by full screens.  For example, scroll-up with an argument of nil scrolls so that this many lines at the bottom of the window appear instead at the top.  The default value is 2.

 -- Command: recenter &optional count
     This function scrolls the selected window to put the text where point is located at a specified vertical position within the window.

     If COUNT is a nonnegative number, it puts the line containing point COUNT lines down from the top of the window.  If COUNT is a negative number, then it counts upward from the bottom of the window, so that -1 stands for the last usable line in the window. If COUNT is a non-nil list, then it stands for the line in the middle of the window.

     If COUNT is nil, recenter puts the line containing point in the middle of the window, then clears and redisplays the entire selected frame.

     When recenter is called interactively, COUNT is the raw prefix argument.  Thus, typing C-u as the prefix sets the COUNT to a non-nil list, while typing C-u 4 sets COUNT to 4, which positions the current line four lines from the top.

     With an argument of zero, recenter positions the current line at the top of the window.  This action is so handy that some people make a separate key binding to do this.  For example,

          (defun line-to-top-of-window ()
            "Scroll current line to top of window.
          Replaces three keystroke sequence C-u 0 C-l."
            (interactive)
            (recenter 0))

          (global-set-key [kp-multiply] 'line-to-top-of-window)

Horizontal Scrolling
====================

Because we read English first from top to bottom and second from left to right, horizontal scrolling is not like vertical scrolling.  Vertical scrolling involves selection of a contiguous portion of text to display. Horizontal scrolling causes part of each line to go off screen.  The amount of horizontal scrolling is therefore specified as a number of columns rather than as a position in the buffer.  It has nothing to do with the display-start position returned by window-start.

Usually, no horizontal scrolling is in effect; then the leftmost column is at the left edge of the window.  In this state, scrolling to the right is meaningless, since there is no data to the left of the screen to be revealed by it; so this is not allowed.  Scrolling to the left is allowed; it scrolls the first columns of text off the edge of the window and can reveal additional columns on the right that were truncated before.  Once a window has a nonzero amount of leftward horizontal scrolling, you can scroll it back to the right, but only so far as to reduce the net horizontal scroll to zero.  There is no limit to how far left you can scroll, but eventually all the text will disappear off the left edge.

 -- Command: scroll-left count
     This function scrolls the selected window COUNT columns to the left (or to the right if COUNT is negative).  The return value is the total amount of leftward horizontal scrolling in effect after the change---just like the value returned by window-hscroll (below).

 -- Command: scroll-right count
     This function scrolls the selected window COUNT columns to the right (or to the left if COUNT is negative).  The return value is the total amount of leftward horizontal scrolling in effect after the change---just like the value returned by window-hscroll (below).

     Once you scroll a window as far right as it can go, back to its normal position where the total leftward scrolling is zero, attempts to scroll any farther right have no effect.

 -- Function: window-hscroll &optional window
     This function returns the total leftward horizontal scrolling of WINDOW---the number of columns by which the text in WINDOW is scrolled left past the left margin.

     The value is never negative.  It is zero when no horizontal scrolling has been done in WINDOW (which is usually the case).

     If WINDOW is nil, the selected window is used.

          (window-hscroll)
               => 0

          (scroll-left 5)
               => 5

          (window-hscroll)
               => 5

 -- Function: set-window-hscroll window columns
     This function sets the number of columns from the left margin that WINDOW is scrolled from the value of COLUMNS.  The argument COLUMNS should be zero or positive; if not, it is taken as zero.

     The value returned is COLUMNS.

          (set-window-hscroll (selected-window) 10)
               => 10

Here is how you can determine whether a given position POSITION is off the screen due to horizontal scrolling:

     (defun hscroll-on-screen (window position)
       (save-excursion
         (goto-char position)
         (and
          (>= (- (current-column) (window-hscroll window)) 0)
          (< (- (current-column) (window-hscroll window))
             (window-width window)))))

The Size of a Window
====================

An Emacs window is rectangular, and its size information consists of the height (the number of lines) and the width (the number of character positions in each line).  The mode line is included in the height.  But the width does not count the scroll bar or the column of | characters that separates side-by-side windows.

The following three functions return size information about a window:

 -- Function: window-height &optional window
     This function returns the number of lines in WINDOW, including its mode line.  If WINDOW fills its entire frame, this is one less than the value of frame-height on that frame (since the last line is always reserved for the minibuffer).

     If WINDOW is nil, the function uses the selected window.

          (window-height)
               => 23

          (split-window-vertically)
               => #<window 4 on windows.texi>

          (window-height)
               => 11

 -- Function: window-width &optional window
     This function returns the number of columns in WINDOW.  If WINDOW fills its entire frame, this is the same as the value of frame-width on that frame.  The width does not include the window's scroll bar or the column of | characters that separates side-by-side windows.

     If WINDOW is nil, the function uses the selected window.

          (window-width)
               => 80

 -- Function: window-edges &optional window
     This function returns a list of the edge coordinates of WINDOW. If WINDOW is nil, the selected window is used.

     The order of the list is (LEFT TOP RIGHT BOTTOM), all elements relative to 0, 0 at the top left corner of the frame.  The element RIGHT of the value is one more than the rightmost column used by WINDOW, and BOTTOM is one more than the bottommost row used by WINDOW and its mode-line.

     When you have side-by-side windows, the right edge value for a window with a neighbor on the right includes the width of the separator between the window and that neighbor.  This separator may be a column of | characters or it may be a scroll bar.  Since the width of the window does not include this separator, the width does not equal the difference between the right and left edges in this case.

     Here is the result obtained on a typical 24-line terminal with just one window:

          (window-edges (selected-window))
               => (0 0 80 23)

     The bottom edge is at line 23 because the last line is the echo area.

     If WINDOW is at the upper left corner of its frame, then BOTTOM is the same as the value of (window-height), RIGHT is almost the same as the value of (window-width) (They are not exactly equal because RIGHT includes the vertical separator line or scroll bar, while (window-width) does not.), and TOP and LEFT are zero. For example, the edges of the following window are 0 0 5 8. Assuming that the frame has more than 8 columns, the last column of the window (column 7) holds a border rather than text.  The last row (row 4) holds the mode line, shown here with xxxxxxxxx.

                     0
                     _______
                  0 |       |
                    |       |
                    |       |
                    |       |
                    xxxxxxxxx  4

                            7

     When there are side-by-side windows, any window not at the right edge of its frame has a separator in its last column or columns.  The separator counts as one or two columns in the width of the window.  A window never includes a separator on its left, since that belongs to the window to the left.

     In the following example, let's suppose that the frame is 7 columns wide.  Then the edges of the left window are 0 0 4 3 and the edges of the right window are 4 0 7 3.

                     ___ ___
                    |   |   |
                    |   |   |
                    xxxxxxxxx

                     0  34  7

Changing the Size of a Window
=============================

The window size functions fall into two classes: high-level commands that change the size of windows and low-level functions that access window size.  Emacs does not permit overlapping windows or gaps between windows, so resizing one window affects other windows.

 -- Command: enlarge-window size &optional horizontal
     This function makes the selected window SIZE lines taller, stealing lines from neighboring windows.  It takes the lines from one window at a time until that window is used up, then takes from another. If a window from which lines are stolen shrinks below window-min-height lines, that window disappears.

     If HORIZONTAL is non-nil, this function makes WINDOW wider by SIZE columns, stealing columns instead of lines.  If a window from which columns are stolen shrinks below window-min-width columns, that window disappears.

     If the requested size would exceed that of the window's frame, then the function makes the window occupy the entire height (or width) of the frame.

     If SIZE is negative, this function shrinks the window by -SIZE lines or columns.  If that makes the window smaller than the minimum size (window-min-height and window-min-width), enlarge-window deletes the window.

     enlarge-window returns nil.

 -- Command: enlarge-window-horizontally columns
     This function makes the selected window COLUMNS wider. It could be defined as follows:

          (defun enlarge-window-horizontally (columns)
            (enlarge-window columns t))

 -- Command: shrink-window size &optional horizontal
     This function is like enlarge-window but negates the argument SIZE, making the selected window smaller by giving lines (or columns) to the other windows.  If the window shrinks below window-min-height or window-min-width, then it disappears.

     If SIZE is negative, the window is enlarged by -SIZE lines or columns.

 -- Command: shrink-window-horizontally columns
     This function makes the selected window COLUMNS narrower. It could be defined as follows:

          (defun shrink-window-horizontally (columns)
            (shrink-window columns t))

The following two variables constrain the window-size-changing functions to a minimum height and width.

 -- User Option: window-min-height
     The value of this variable determines how short a window may become before it is automatically deleted.  Making a window smaller than window-min-height automatically deletes it, and no window may be created shorter than this.  The absolute minimum height is two (allowing one line for the mode line, and one line for the buffer display). Actions that change window sizes reset this variable to two if it is less than two.  The default value is 4.

 -- User Option: window-min-width
     The value of this variable determines how narrow a window may become before it automatically deleted.  Making a window smaller than window-min-width automatically deletes it, and no window may be created narrower than this.  The absolute minimum width is one; any value below that is ignored.  The default value is 10.

Coordinates and Windows
=======================

This section describes how to relate screen coordinates to windows.

 -- Function: window-at x y &optional frame
     This function returns the window containing the specified cursor position in the frame FRAME.  The coordinates X and Y are measured in characters and count from the top left corner of the frame.  If they are out of range, window-at returns nil.

     If you omit FRAME, the selected frame is used.

 -- Function: coordinates-in-window-p coordinates window
     This function checks whether a particular frame position falls within the window WINDOW.

     The argument COORDINATES is a cons cell of this form:

          (X . Y)

     The coordinates X and Y are measured in characters, and count from the top left corner of the screen or frame.

     The value returned by coordinates-in-window-p is non-nil if the coordinates are inside WINDOW.  The value also indicates what part of the window the position is in, as follows:

     (RELX . RELY)
          The coordinates are inside WINDOW.  The numbers RELX and RELY are the equivalent window-relative coordinates for the specified position, counting from 0 at the top left corner of the window.

     mode-line
          The coordinates are in the mode line of WINDOW.

     vertical-split
          The coordinates are in the vertical line between WINDOW and its neighbor to the right.  This value occurs only if the window doesn't have a scroll bar; positions in a scroll bar are considered outside the window.

     nil
          The coordinates are not in any part of WINDOW.

     The function coordinates-in-window-p does not require a frame as argument because it always uses the frame that WINDOW is on.

Window Configurations
=====================

A window configuration records the entire layout of one frame---all windows, their sizes, which buffers they contain, what part of each buffer is displayed, and the values of point and the mark.  You can bring back an entire previous layout by restoring a window configuration previously saved.

If you want to record all frames instead of just one, use a frame configuration instead of a window configuration.  See Frame Configurations.

 -- Function: current-window-configuration
     This function returns a new object representing the selected frame's current window configuration, including the number of windows, their sizes and current buffers, which window is the selected window, and for each window the displayed buffer, the display-start position, and the positions of point and the mark.  An exception is made for point in the current buffer, whose value is not saved.

 -- Function: set-window-configuration configuration
     This function restores the configuration of windows and buffers as specified by CONFIGURATION.  The argument CONFIGURATION must be a value that was previously returned by current-window-configuration.  This function operates on the frame for which CONFIGURATION was made, whether that frame is selected or not.

     This function always counts as a window size change and triggers execution of the window-size-change-functions.  (It doesn't know how to tell whether the new configuration actually differs from the old one.)

     Here is a way of using this function to get the same effect as save-window-excursion:

          (let ((config (current-window-configuration)))
            (unwind-protect
                (progn (split-window-vertically nil)
                       ...)
              (set-window-configuration config)))

 -- Special Form: save-window-excursion forms...
     This special form records the window configuration, executes FORMS in sequence, then restores the earlier window configuration.  The window configuration includes the value of point and the portion of the buffer that is visible.  It also includes the choice of selected window. However, it does not include the value of point in the current buffer; use save-excursion also, if you wish to preserve that.

     Don't use this construct when save-selected-window is all you need.

     Exit from save-window-excursion always triggers execution of the window-size-change-functions.  (It doesn't know how to tell whether the restored configuration actually differs from the one in effect at the end of the FORMS.)

     The return value is the value of the final form in FORMS. For example:

          (split-window)
               => #<window 25 on control.texi>

          (setq w (selected-window))
               => #<window 19 on control.texi>

          (save-window-excursion
            (delete-other-windows w)
            (switch-to-buffer "foo")
            'do-something)
               => do-something
               ;; The screen is now split again.

 -- Function: window-configuration-p object
     This function returns t if OBJECT is a window configuration.

Primitives to look inside of window configurations would make sense, but none are implemented.  It is not clear they are useful enough to be worth implementing.

Hooks for Window Scrolling and Changes
======================================

This section describes how a Lisp program can take action whenever a window displays a different part of its buffer or a different buffer. There are three actions that can change this: scrolling the window, switching buffers in the window, and changing the size of the window. The first two actions run window-scroll-functions; the last runs window-size-change-functions.  The paradigmatic use of these hooks is Lazy Lock mode; see Font Lock Support Modes (The GNU Emacs Manual).

 -- Variable: window-scroll-functions
     This variable holds a list of functions that Emacs should call before redisplaying a window with scrolling.  It is not a normal hook, because each function is called with two arguments: the window, and its new display-start position.

     Displaying a different buffer in the window also runs these functions.

     These functions cannot expect window-end (see Window Start) to return a meaningful value, because that value is updated only by redisplaying the buffer.  So if one of these functions needs to know the last character that will fit in the window with its current display-start position, it has to find that character using vertical-motion (see Screen Lines).

 -- Variable: window-size-change-functions
     This variable holds a list of functions to be called if the size of any window changes for any reason.  The functions are called just once per redisplay, and just once for each frame on which size changes have occurred.

     Each function receives the frame as its sole argument.  There is no direct way to find out which windows on that frame have changed size, or precisely how.  However, if a size-change function records, at each call, the existing windows and their sizes, it can also compare the present sizes and the previous sizes.

     Creating or deleting windows counts as a size change, and therefore causes these functions to be called.  Changing the frame size also counts, because it changes the sizes of the existing windows.

     It is not a good idea to use save-window-excursion (see Window Configurations) in these functions, because that always counts as a size change, and it would cause these functions to be called over and over.  In most cases, save-selected-window (see Selecting Windows) is what you need here.

 -- Variable: redisplay-end-trigger-functions
     This abnormal hook is run whenever redisplay in window uses text that extends past a specified end trigger position.  You set the end trigger position with the function set-window-redisplay-end-trigger.  The functions are called with two arguments: the window, and the end trigger position.  Storing nil for the end trigger position turns off the feature, and the trigger value is automatically reset to nil just after the hook is run.

 -- Function: set-window-redisplay-end-trigger window position
     This function sets WINDOW's end trigger position at POSITION.

 -- Function: window-redisplay-end-trigger window
     This function returns WINDOW's current end trigger position.

 -- Variable: window-configuration-change-hook
     A normal hook that is run every time you change the window configuration of an existing frame.  This includes splitting or deleting windows, changing the sizes of windows, or displaying a different buffer in a window.  The frame whose window configuration has changed is the selected frame when this hook runs.