+\f
+;;; Defining themes.
+
+;; deftheme is used at the beginning of the file that records a theme.
+
+(defmacro deftheme (theme &optional doc &rest args)
+ "Declare custom theme THEME.
+The optional argument DOC is a doc string describing the theme.
+The remaining arguments should have the form
+
+ [KEYWORD VALUE]...
+
+The following KEYWORD's are defined:
+
+:short-description
+ VALUE is a short (one line) description of the theme. If not
+ given, DOC is used.
+:immediate
+ If VALUE is non-nil, variables specified in this theme are set
+ immediately when loading the theme.
+:variable-set-string
+ VALUE is a string used to indicate that a variable takes its
+ setting from this theme. It is passed to FORMAT with the name
+ of the theme as an additional argument. If not given, a
+ generic description is used.
+:variable-reset-string
+ VALUE is a string used in the case a variable has been forced
+ to its value in this theme. It is passed to FORMAT with the
+ name of the theme as an additional argument. If not given, a
+ generic description is used.
+:face-set-string
+ VALUE is a string used to indicate that a face takes its
+ setting from this theme. It is passed to FORMAT with the name
+ of the theme as an additional argument. If not given, a
+ generic description is used.
+:face-reset-string
+ VALUE is a string used in the case a face has been forced to
+ its value in this theme. It is passed to FORMAT with the name
+ of the theme as an additional argument. If not given, a
+ generic description is used.
+
+Any theme `foo' should be defined in a file called `foo-theme.el';
+see `custom-make-theme-feature' for more information."
+ (let ((feature (custom-make-theme-feature theme)))
+ ;; It is better not to use backquote in this file,
+ ;; because that makes a bootstrapping problem
+ ;; if you need to recompile all the Lisp files using interpreted code.
+ (nconc (list 'custom-declare-theme
+ (list 'quote theme)
+ (list 'quote feature)
+ doc)
+ args)))
+
+(defun custom-declare-theme (theme feature &optional doc &rest args)
+ "Like `deftheme', but THEME is evaluated as a normal argument.
+FEATURE is the feature this theme provides. This symbol is created
+from THEME by `custom-make-theme-feature'."
+ (add-to-list 'custom-known-themes theme)
+ (put theme 'theme-feature feature)
+ (when doc
+ (put theme 'theme-documentation doc))
+ (while args
+ (let ((arg (car args)))
+ (setq args (cdr args))
+ (unless (symbolp arg)
+ (error "Junk in args %S" args))
+ (let ((keyword arg)
+ (value (car args)))
+ (unless args
+ (error "Keyword %s is missing an argument" keyword))
+ (setq args (cdr args))
+ (cond ((eq keyword :short-description)
+ (put theme 'theme-short-description value))
+ ((eq keyword :immediate)
+ (put theme 'theme-immediate value))
+ ((eq keyword :variable-set-string)
+ (put theme 'theme-variable-set-string value))
+ ((eq keyword :variable-reset-string)
+ (put theme 'theme-variable-reset-string value))
+ ((eq keyword :face-set-string)
+ (put theme 'theme-face-set-string value))
+ ((eq keyword :face-reset-string)
+ (put theme 'theme-face-reset-string value)))))))
+
+(defun custom-make-theme-feature (theme)
+ "Given a symbol THEME, create a new symbol by appending \"-theme\".
+Store this symbol in the `theme-feature' property of THEME.
+Calling `provide-theme' to provide THEME actually puts `THEME-theme'
+into `features'.
+
+This allows for a file-name convention for autoloading themes:
+Every theme X has a property `provide-theme' whose value is \"X-theme\".
+\(require-theme X) then attempts to load the file `X-theme.el'."
+ (intern (concat (symbol-name theme) "-theme")))
+\f
+;;; Loading themes.
+
+;; The variable and face settings of a theme are recorded in
+;; the `theme-settings' property of the theme name.
+;; This property's value is a list of elements, each of the form
+;; (PROP SYMBOL THEME MODE VALUE), where PROP is `theme-value' or `theme-face'
+;; and SYMBOL is the face or variable name.
+;; THEME is the theme name itself; that's redundant, but simplifies things.
+;; MODE is `set' or `reset'.
+;; If MODE is `set', then VALUE is an expression that specifies the
+;; theme's setting for SYMBOL.
+;; If MODE is `reset', then VALUE is another theme,
+;; and it means to use the value from that theme.
+
+;; Each variable has a `theme-value' property that describes all the
+;; settings of enabled themes that apply to it.
+;; Each face name has a `theme-face' property that describes all the
+;; settings of enabled themes that apply to it.
+;; The property value is a list of settings, each with the form
+;; (THEME MODE VALUE). THEME, MODE and VALUE are as above.
+;; Each of these lists is ordered by decreasing theme precedence.
+;; Thus, the first element is always the one that is in effect.
+
+;; Disabling a theme removes its settings from the `theme-value' and
+;; `theme-face' properties, but the theme's own `theme-settings'
+;; property remains unchanged.
+
+;; Loading a theme implicitly enables it. Enabling a theme adds its
+;; settings to the symbols' `theme-value' and `theme-face' properties,
+;; or moves them to the front of those lists if they're already present.
+
+(defvar custom-loaded-themes nil
+ "Custom themes that have been loaded.")
+
+(defcustom custom-theme-directory
+ (if (eq system-type 'ms-dos)
+ ;; MS-DOS cannot have initial dot.
+ "~/_emacs.d/"
+ "~/.emacs.d/")
+ "Directory in which Custom theme files should be written.
+`require-theme' searches this directory in addition to load-path.
+The command `customize-create-theme' writes the files it produces
+into this directory."
+ :type 'string
+ :group 'customize
+ :version "22.1")
+
+(defun custom-theme-loaded-p (theme)
+ "Return non-nil if THEME has been loaded."
+ (memq theme custom-loaded-themes))
+
+(defvar custom-enabled-themes '(user)
+ "Custom themes currently enabled, highest precedence first.
+The first one is always `user'.")
+
+(defun custom-theme-enabled-p (theme)
+ "Return non-nil if THEME is enabled."
+ (memq theme custom-enabled-themes))
+
+(defun provide-theme (theme)
+ "Indicate that this file provides THEME.
+Add THEME to `custom-loaded-themes', and `provide' whatever
+feature name is stored in THEME's property `theme-feature'.
+
+Usually the `theme-feature' property contains a symbol created
+by `custom-make-theme-feature'."
+ (custom-check-theme theme)
+ (provide (get theme 'theme-feature))
+ (push theme custom-loaded-themes)
+ ;; Loading a theme also installs its settings,
+ ;; so mark it as "enabled".
+ (push theme custom-enabled-themes)
+ ;; `user' must always be the highest-precedence enabled theme.
+ ;; Make that remain true. (This has the effect of making user settings
+ ;; override the ones just loaded, too.)
+ (custom-enable-theme 'user))
+
+(defun require-theme (theme)
+ "Try to load a theme's settings from its file.
+This also enables the theme; use `custom-disable-theme' to disable it."
+
+ ;; THEME's feature is stored in THEME's `theme-feature' property.
+ ;; Usually the `theme-feature' property contains a symbol created
+ ;; by `custom-make-theme-feature'.
+
+ ;; Note we do no check for validity of the theme here.
+ ;; This allows to pull in themes by a file-name convention
+ (let ((load-path (if (file-directory-p custom-theme-directory)
+ (cons custom-theme-directory load-path)
+ load-path)))
+ (require (or (get theme 'theme-feature)
+ (custom-make-theme-feature theme)))))
+\f
+;;; How to load and enable various themes as part of `user'.
+
+(defun custom-theme-load-themes (by-theme &rest body)
+ "Load the themes specified by BODY.
+Record them as required by theme BY-THEME.
+
+BODY is a sequence of either
+
+THEME
+ Load THEME and enable it.
+\(reset THEME)
+ Undo all the settings made by THEME
+\(hidden THEME)
+ Load THEME but do not enable it.
+
+All the themes loaded for BY-THEME are recorded in BY-THEME's property
+`theme-loads-themes'."
+ (custom-check-theme by-theme)
+ (let ((themes-loaded (get by-theme 'theme-loads-themes)))
+ (dolist (theme body)
+ (cond ((and (consp theme) (eq (car theme) 'reset))
+ (custom-disable-theme (cadr theme)))
+ ((and (consp theme) (eq (car theme) 'hidden))
+ (require-theme (cadr theme))
+ (custom-disable-theme (cadr theme)))
+ (t
+ (require-theme theme)))
+ (push theme themes-loaded))
+ (put by-theme 'theme-loads-themes themes-loaded)))
+
+(defun custom-load-themes (&rest body)
+ "Load themes for the USER theme as specified by BODY.
+
+See `custom-theme-load-themes' for more information on BODY."
+ (apply 'custom-theme-load-themes 'user body))
+\f
+;;; Enabling and disabling loaded themes.
+
+(defun custom-enable-theme (theme)
+ "Reenable all variable and face settings defined by THEME.
+The newly enabled theme gets the highest precedence (after `user').
+If it is already enabled, just give it highest precedence (after `user')."
+ (let ((settings (get theme 'theme-settings)))
+ (dolist (s settings)
+ (let* ((prop (car s))
+ (symbol (cadr s))
+ (spec-list (get symbol prop)))
+ (put symbol prop (cons (cddr s) (assq-delete-all theme spec-list)))
+ (if (eq prop 'theme-value)
+ (custom-theme-recalc-variable symbol)
+ (custom-theme-recalc-face symbol)))))
+ (setq custom-enabled-themes
+ (cons theme (delq theme custom-enabled-themes)))
+ ;; `user' must always be the highest-precedence enabled theme.
+ (unless (eq theme 'user)
+ (custom-enable-theme 'user)))
+
+(defun custom-disable-theme (theme)
+ "Disable all variable and face settings defined by THEME.
+See `custom-known-themes' for a list of known themes."
+ (let ((settings (get theme 'theme-settings)))
+ (dolist (s settings)
+ (let* ((prop (car s))
+ (symbol (cadr s))
+ (spec-list (get symbol prop)))
+ (put symbol 'theme-value (assq-delete-all theme spec-list))
+ (if (eq prop 'theme-value)
+ (custom-theme-recalc-variable symbol)
+ (custom-theme-recalc-face symbol)))))
+ (setq custom-enabled-themes
+ (delq theme custom-enabled-themes)))
+
+(defun custom-theme-value (theme setting-list)
+ "Determine the value specified for THEME according to SETTING-LIST.
+Returns a list whose car is the specified value, if we
+find one; nil otherwise.
+
+SETTING-LIST is an alist with themes as its key.
+Each element has the form:
+
+ \(THEME MODE VALUE)
+
+MODE is either the symbol `set' or the symbol `reset'. See
+`custom-push-theme' for more information on the format of
+SETTING-LIST."
+ ;; Note we do _NOT_ signal an error if the theme is unknown
+ ;; it might have gone away without the user knowing.
+ (let ((elt (cdr (assoc theme setting-list))))
+ (if elt
+ (if (eq (car elt) 'set)
+ (cdr elt)
+ ;; `reset' means refer to another theme's value in the same alist.
+ (custom-theme-value (cadr elt) setting-list)))))
+
+(defun custom-variable-theme-value (variable)
+ "Return (list VALUE) indicating the custom theme value of VARIABLE.
+That is to say, it specifies what the value should be according to
+currently enabled custom themes.
+
+This function returns nil if no custom theme specifies a value for VARIABLE."
+ (let* ((theme-value (get variable 'theme-value)))
+ (if theme-value
+ (custom-theme-value (car (car theme-value)) theme-value))))
+
+(defun custom-face-theme-value (face)
+ "Return the face spec of FACE according to currently enabled custom themes.
+This function returns nil if no custom theme specifies anything for FACE."
+ (let* ((theme-value (get face 'theme-face)))
+ (if theme-value
+ (custom-theme-value (car (car theme-value)) theme-value))))
+
+(defun custom-theme-recalc-variable (variable)
+ "Set VARIABLE according to currently enabled custom themes."
+ (let ((valspec (custom-variable-theme-value variable)))
+ (when valspec
+ (put variable 'saved-value valspec))
+ (unless valspec
+ (setq valspec (get variable 'standard-value)))
+ (when valspec
+ (if (or (get 'force-value variable) (default-boundp variable))
+ (funcall (or (get variable 'custom-set) 'set-default) variable
+ (eval (car valspec)))))))
+
+(defun custom-theme-recalc-face (face)
+ "Set FACE according to currently enabled custom themes."
+ (let ((spec (custom-face-theme-value face)))
+ (when spec
+ (put face 'save-face spec))
+ (unless spec
+ (setq spec (get face 'face-defface-spec)))
+ (when spec
+ (when (or (get face 'force-face) (facep face))
+ (unless (facep face)
+ (make-empty-face face))
+ (face-spec-set face spec)))))
+\f
+(defun custom-theme-reset-variables (theme &rest args)
+ "Reset the specs in THEME of some variables to their values in other themes.
+Each of the arguments ARGS has this form:
+
+ (VARIABLE FROM-THEME)
+
+This means reset VARIABLE to its value in FROM-THEME."
+ (custom-check-theme theme)
+ (dolist (arg args)
+ (custom-push-theme 'theme-value (car arg) theme 'reset (cadr arg))))
+
+(defun custom-reset-variables (&rest args)
+ "Reset the specs of some variables to their values in certain themes.
+This creates settings in the `user' theme.
+
+Each of the arguments ARGS has this form:
+
+ (VARIABLE FROM-THEME)
+
+This means reset VARIABLE to its value in FROM-THEME."
+ (apply 'custom-theme-reset-variables 'user args))