+# Print out s-expressions
+define pp
+ set $tmp = $arg0
+ set $output_debug = print_output_debug_flag
+ set print_output_debug_flag = 0
+ set safe_debug_print ($tmp)
+ set print_output_debug_flag = $output_debug
+end
+document pp
+Print the argument as an emacs s-expression
+Works only when an inferior emacs is executing.
+end
+
+# Print out s-expressions from tool bar
+define pp1
+ set $tmp = $arg0
+ set $output_debug = print_output_debug_flag
+ set print_output_debug_flag = 0
+ set safe_debug_print ($tmp)
+ set print_output_debug_flag = $output_debug
+end
+document pp1
+Print the argument as an emacs s-expression.
+Works only when an inferior emacs is executing.
+For use on tool bar when debugging in Emacs
+where the variable name would not otherwise
+be recorded in the GUD buffer.
+end
+
+# Print value of lisp variable
+define pv
+ set $tmp = "$arg0"
+ set $output_debug = print_output_debug_flag
+ set print_output_debug_flag = 0
+ set safe_debug_print ( find_symbol_value (intern ($tmp)))
+ set print_output_debug_flag = $output_debug
+end
+document pv
+Print the value of the lisp variable given as argument.
+Works only when an inferior emacs is executing.
+end
+
+# Print value of lisp variable
+define pv1
+ set $tmp = "$arg0"
+ set $output_debug = print_output_debug_flag
+ set print_output_debug_flag = 0
+ set safe_debug_print (find_symbol_value (intern ($tmp)))
+ set print_output_debug_flag = $output_debug
+end
+document pv1
+Print the value of the lisp variable given as argument.
+Works only when an inferior emacs is executing.
+For use when debugging in Emacs where the variable
+name would not otherwise be recorded in the GUD buffer.
+end
+
+# Print out current buffer point and boundaries
+define ppt
+ set $b = current_buffer
+ set $t = $b->text
+ printf "BUF PT: %d", $b->pt
+ if ($b->pt != $b->pt_byte)
+ printf "[%d]", $b->pt_byte
+ end
+ printf " of 1..%d", $t->z
+ if ($t->z != $t->z_byte)
+ printf "[%d]", $t->z_byte
+ end
+ if ($b->begv != 1 || $b->zv != $t->z)
+ printf " NARROW=%d..%d", $b->begv, $b->zv
+ if ($b->begv != $b->begv_byte || $b->zv != $b->zv_byte)
+ printf " [%d..%d]", $b->begv_byte, $b->zv_byte
+ end
+ end
+ printf " GAP: %d", $t->gpt
+ if ($t->gpt != $t->gpt_byte)
+ printf "[%d]", $t->gpt_byte
+ end
+ printf " SZ=%d\n", $t->gap_size
+end
+document ppt
+Print point, beg, end, narrow, and gap for current buffer.
+end
+
+# Print out iterator given as first arg
+define pitx
+ set $it = $arg0
+ printf "cur=%d", $it->current.pos.charpos
+ if ($it->current.pos.charpos != $it->current.pos.bytepos)
+ printf "[%d]", $it->current.pos.bytepos
+ end
+ printf " pos=%d", $it->position.charpos
+ if ($it->position.charpos != $it->position.bytepos)
+ printf "[%d]", $it->position.bytepos
+ end
+ printf " start=%d", $it->start.pos.charpos
+ if ($it->start.pos.charpos != $it->start.pos.bytepos)
+ printf "[%d]", $it->start.pos.bytepos
+ end
+ printf " end=%d", $it->end_charpos
+ printf " stop=%d", $it->stop_charpos
+ printf " face=%d", $it->face_id
+ if ($it->multibyte_p)
+ printf " MB"
+ end
+ if ($it->header_line_p)
+ printf " HL"
+ end
+ if ($it->n_overlay_strings > 0)
+ printf " nov=%d", $it->n_overlay_strings
+ end
+ if ($it->sp != 0)
+ printf " sp=%d", $it->sp
+ end
+ if ($it->what == IT_CHARACTER)
+ if ($it->len == 1 && $it->c >= ' ' && it->c < 255)
+ printf " ch='%c'", $it->c
+ else
+ printf " ch=[%d,%d]", $it->c, $it->len
+ end
+ else
+ printf " "
+ output $it->what
+ end
+ if ($it->method != GET_FROM_BUFFER)
+ printf " next="
+ output $it->method
+ if ($it->method == GET_FROM_STRING)
+ printf "[%d]", $it->current.string_pos.charpos
+ end
+ if ($it->method == GET_FROM_IMAGE)
+ printf "[%d]", $it->image_id
+ end
+ if ($it->method == GET_FROM_COMPOSITION)
+ printf "[%d,%d,%d]", $it->cmp_id, $it->len, $it->cmp_len
+ end
+ end
+ printf "\n"
+ if ($it->region_beg_charpos >= 0)
+ printf "reg=%d-%d ", $it->region_beg_charpos, $it->region_end_charpos
+ end
+ printf "vpos=%d hpos=%d", $it->vpos, $it->hpos,
+ printf " y=%d lvy=%d", $it->current_y, $it->last_visible_y
+ printf " x=%d vx=%d-%d", $it->current_x, $it->first_visible_x, $it->last_visible_x
+ printf " w=%d", $it->pixel_width
+ printf " a+d=%d+%d=%d", $it->ascent, $it->descent, $it->ascent+$it->descent
+ printf " max=%d+%d=%d", $it->max_ascent, $it->max_descent, $it->max_ascent+$it->max_descent
+ printf "\n"
+ set $i = 0
+ while ($i < $it->sp && $i < 4)
+ set $e = $it->stack[$i]
+ printf "stack[%d]: ", $i
+ output $e->method
+ printf "[%d]", $e->position.charpos
+ printf "\n"
+ set $i = $i + 1
+ end
+end
+document pitx
+Pretty print a display iterator.
+Take one arg, an iterator object or pointer.
+end
+
+define pit
+ pitx it
+end
+document pit
+Pretty print the display iterator it.
+end
+
+define prowx
+ set $row = $arg0
+ printf "y=%d x=%d pwid=%d", $row->y, $row->x, $row->pixel_width
+ printf " a+d=%d+%d=%d", $row->ascent, $row->height-$row->ascent, $row->height
+ printf " phys=%d+%d=%d", $row->phys_ascent, $row->phys_height-$row->phys_ascent, $row->phys_height
+ printf " vis=%d", $row->visible_height
+ printf " L=%d T=%d R=%d", $row->used[0], $row->used[1], $row->used[2]
+ printf "\n"
+ printf "start=%d end=%d", $row->start.pos.charpos, $row->end.pos.charpos
+ if ($row->enabled_p)
+ printf " ENA"
+ end
+ if ($row->displays_text_p)
+ printf " DISP"
+ end
+ if ($row->mode_line_p)
+ printf " MODEL"
+ end
+ if ($row->continued_p)
+ printf " CONT"
+ end
+ if ($row-> truncated_on_left_p)
+ printf " TRUNC:L"
+ end
+ if ($row-> truncated_on_right_p)
+ printf " TRUNC:R"
+ end
+ if ($row->starts_in_middle_of_char_p)
+ printf " STARTMID"
+ end
+ if ($row->ends_in_middle_of_char_p)
+ printf " ENDMID"
+ end
+ if ($row->ends_in_newline_from_string_p)
+ printf " ENDNLFS"
+ end
+ if ($row->ends_at_zv_p)
+ printf " ENDZV"
+ end
+ if ($row->overlapped_p)
+ printf " OLAPD"
+ end
+ if ($row->overlapping_p)
+ printf " OLAPNG"
+ end
+ printf "\n"
+end
+document prowx
+Pretty print information about glyph_row.
+Takes one argument, a row object or pointer.
+end
+
+define prow
+ prowx row
+end
+document prow
+Pretty print information about glyph_row in row.
+end
+
+
+define pcursorx
+ set $cp = $arg0
+ printf "y=%d x=%d vpos=%d hpos=%d", $cp->y, $cp->x, $cp->vpos, $cp->hpos
+end
+document pcursorx
+Pretty print a window cursor
+end
+
+define pcursor
+ printf "output: "
+ pcursorx output_cursor
+ printf "\n"
+end
+document pcursor
+Pretty print the output_cursor
+end
+
+define pwinx
+ set $w = $arg0
+ xgetint $w->sequence_number
+ if ($w->mini_p != Qnil)
+ printf "Mini "
+ end
+ printf "Window %d ", $int
+ xgetptr $w->buffer
+ set $tem = (struct buffer *) $ptr
+ xgetptr $tem->name
+ printf "%s", ((struct Lisp_String *) $ptr)->data
+ printf "\n"
+ xgetptr $w->start
+ set $tem = (struct Lisp_Marker *) $ptr
+ printf "start=%d end:", $tem->charpos
+ if ($w->window_end_valid != Qnil)
+ xgetint $w->window_end_pos
+ printf "pos=%d", $int
+ xgetint $w->window_end_vpos
+ printf " vpos=%d", $int
+ else
+ printf "invalid"
+ end
+ printf " vscroll=%d", $w->vscroll
+ if ($w->force_start != Qnil)
+ printf " FORCE_START"
+ end
+ if ($w->must_be_updated_p)
+ printf " MUST_UPD"
+ end
+ printf "\n"
+ printf "cursor: "
+ pcursorx $w->cursor
+ printf " phys: "
+ pcursorx $w->phys_cursor
+ if ($w->phys_cursor_on_p)
+ printf " ON"
+ else
+ printf " OFF"
+ end
+ printf " blk="
+ if ($w->last_cursor_off_p != $w->cursor_off_p)
+ if ($w->last_cursor_off_p)
+ printf "ON->"
+ else
+ printf "OFF->"
+ end
+ end
+ if ($w->cursor_off_p)
+ printf "ON"
+ else
+ printf "OFF"
+ end
+ printf "\n"
+end
+document pwinx
+Pretty print a window structure.
+Takes one argument, a pointer to a window structure
+end
+
+define pwin
+ pwinx w
+end
+document pwin
+Pretty print window structure w.
+end
+
+define pgx
+ set $g = $arg0
+ if ($g->type == CHAR_GLYPH)
+ if ($g->u.ch >= ' ' && $g->u.ch < 127)
+ printf "CHAR[%c]", $g->u.ch
+ else
+ printf "CHAR[0x%x]", $g->u.ch
+ end
+ end
+ if ($g->type == COMPOSITE_GLYPH)
+ printf "COMP[%d]", $g->u.cmp_id
+ end
+ if ($g->type == IMAGE_GLYPH)
+ printf "IMAGE[%d]", $g->u.img_id
+ end
+ if ($g->type == STRETCH_GLYPH)
+ printf "STRETCH[%d+%d]", $g->u.stretch.height, $g->u.stretch.ascent
+ end
+ xgettype ($g->object)
+ if ($type == Lisp_String)
+ printf " str=%x[%d]", $g->object, $g->charpos
+ else
+ printf " pos=%d", $g->charpos
+ end
+ printf " w=%d a+d=%d+%d", $g->pixel_width, $g->ascent, $g->descent
+ if ($g->face_id != DEFAULT_FACE_ID)
+ printf " face=%d", $g->face_id
+ end
+ if ($g->voffset)
+ printf " vof=%d", $g->voffset
+ end
+ if ($g->multibyte_p)
+ printf " MB"
+ end
+ if ($g->padding_p)
+ printf " PAD"
+ end
+ if ($g->glyph_not_available_p)
+ printf " N/A"
+ end
+ if ($g->overlaps_vertically_p)
+ printf " OVL"
+ end
+ if ($g->left_box_line_p)
+ printf " ["
+ end
+ if ($g->right_box_line_p)
+ printf " ]"
+ end
+ if ($g->slice.x || $g->slice.y || $g->slice.width || $g->slice.height)
+ printf " slice=%d,%d,%d,%d" ,$g->slice.x, $g->slice.y, $g->slice.width, $g->slice.height
+ end
+ printf "\n"
+end
+document pgx
+Pretty print a glyph structure.
+Takes one argument, a pointer to a glyph structure
+end
+
+define pg
+ set $pgidx = 0
+ pgx glyph
+end
+document pg
+Pretty print glyph structure glyph.
+end
+
+define pgi
+ set $pgidx = $arg0
+ pgx (&glyph[$pgidx])
+end
+document pgi
+Pretty print glyph structure glyph[I].
+Takes one argument, a integer I.
+end
+
+define pgn
+ set $pgidx = $pgidx + 1
+ pgx (&glyph[$pgidx])
+end
+document pgn
+Pretty print next glyph structure.
+end
+
+define pgrowx
+ set $row = $arg0
+ set $area = 0
+ set $xofs = $row->x
+ while ($area < 3)
+ set $used = $row->used[$area]
+ if ($used > 0)
+ set $gl0 = $row->glyphs[$area]
+ set $pgidx = 0
+ printf "%s: %d glyphs\n", ($area == 0 ? "LEFT" : $area == 2 ? "RIGHT" : "TEXT"), $used
+ while ($pgidx < $used)
+ printf "%3d %4d: ", $pgidx, $xofs
+ pgx $gl0[$pgidx]
+ set $xofs = $xofs + $gl0[$pgidx]->pixel_width
+ set $pgidx = $pgidx + 1
+ end
+ end
+ set $area = $area + 1
+ end
+end
+document pgrowx
+Pretty print all glyphs in a row structure.
+Takes one argument, a pointer to a row structure.
+end
+
+define pgrow
+ pgrowx row
+end
+document pgrow
+Pretty print all glyphs in row structure row.
+end
+