X-Git-Url: https://code.delx.au/gnu-emacs/blobdiff_plain/6c5d0c5224d10720ec3039bf7b4bbe3254d7b228..28c1e1cac4e08aa5dc31ff628e67fe1f90bec3a0:/src/.gdbinit

diff --git a/src/.gdbinit b/src/.gdbinit
index 1bcb9f6789..04581efcbb 100644
--- a/src/.gdbinit
+++ b/src/.gdbinit
@@ -1,5 +1,5 @@
-# Copyright (C) 1992, 93, 94, 95, 96, 97, 1998, 2000, 01, 2004
-#   Free Software Foundation, Inc.
+# Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 2000, 2001,
+#   2004, 2005, 2006 Free Software Foundation, Inc.
 #
 # This file is part of GNU Emacs.
 #
@@ -15,8 +15,8 @@
 #
 # You should have received a copy of the GNU General Public License
 # along with GNU Emacs; see the file COPYING.  If not, write to the
-# Free Software Foundation, Inc., 59 Temple Place - Suite 330,
-# Boston, MA 02111-1307, USA.
+# Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
+# Boston, MA 02110-1301, USA.
 
 # Force loading of symbols, enough to give us gdb_valbits etc.
 set main
@@ -31,29 +31,41 @@ dir ../lwlib
 # However, C-z works just as well in that case.
 handle 2 noprint pass
 
+# Make it work like SIGINT normally does.
+handle SIGTSTP nopass
+
 # Don't pass SIGALRM to Emacs.  This makes problems when
 # debugging.
 handle SIGALRM ignore
 
-# Set up a mask to use.
-# This should be EMACS_INT, but in some cases that is a macro.
-# long ought to work in all cases right now.
+# $valmask and $tagmask are mask values set up by the xreload macro below.
 
+# Use $bugfix so that the value isn't a constant.
+# Using a constant runs into GDB bugs sometimes.
 define xgetptr
-  set $ptr = (gdb_use_union ? $arg0.u.val : $arg0 & $valmask) | gdb_data_seg_bits
+  set $bugfix = $arg0
+  set $ptr = (gdb_use_union ? $bugfix.u.val : $bugfix & $valmask) | gdb_data_seg_bits
 end
 
 define xgetint
-  set $int = gdb_use_union ? $arg0.s.val : (gdb_use_lsb ? $arg0 : $arg0 << gdb_gctypebits) >> gdb_gctypebits
+  set $bugfix = $arg0
+  set $int = gdb_use_union ? $bugfix.s.val : (gdb_use_lsb ? $bugfix : $bugfix << gdb_gctypebits) >> gdb_gctypebits
 end
 
 define xgettype
-  set $type = gdb_use_union ? $arg0.s.type : (enum Lisp_Type) (gdb_use_lsb ? $arg0 & $tagmask : $arg0 >> gdb_valbits)
+  set $bugfix = $arg0
+  set $type = gdb_use_union ? $bugfix.s.type : (enum Lisp_Type) (gdb_use_lsb ? $bugfix & $tagmask : $bugfix >> gdb_valbits)
 end
 
 # Set up something to print out s-expressions.
+# We save and restore print_output_debug_flag to prevent the w32 port
+# from calling OutputDebugString, which causes GDB to display each
+# character twice (yuk!).
 define pr
+  set $output_debug = print_output_debug_flag
+  set print_output_debug_flag = 0
   set debug_print ($)
+  set print_output_debug_flag = $output_debug
 end
 document pr
 Print the emacs s-expression which is $.
@@ -63,13 +75,304 @@ end
 # Print out s-expressions
 define pp
   set $tmp = $arg0
-  set debug_print ($tmp)
+  set $output_debug = print_output_debug_flag
+  set print_output_debug_flag = 0
+  set safe_debug_print ($tmp)
+  set print_output_debug_flag = $output_debug
 end
 document pp
 Print the argument as an emacs s-expression
 Works only when an inferior emacs is executing.
 end
 
+# Print out s-expressions from tool bar
+define pp1
+  set $tmp = $arg0
+  set $output_debug = print_output_debug_flag
+  set print_output_debug_flag = 0
+  set safe_debug_print ($tmp)
+  set print_output_debug_flag = $output_debug
+end
+document pp1
+Print the argument as an emacs s-expression.
+Works only when an inferior emacs is executing.
+For use on tool bar when debugging in Emacs
+where the variable name would not otherwise
+be recorded in the GUD buffer.
+end
+
+# Print value of lisp variable
+define pv
+  set $tmp = "$arg0"
+  set $output_debug = print_output_debug_flag
+  set print_output_debug_flag = 0
+  set safe_debug_print ( find_symbol_value (intern ($tmp)))
+  set print_output_debug_flag = $output_debug
+end
+document pv
+Print the value of the lisp variable given as argument.
+Works only when an inferior emacs is executing.
+end
+
+# Print value of lisp variable
+define pv1
+  set $tmp = "$arg0"
+  set $output_debug = print_output_debug_flag
+  set print_output_debug_flag = 0
+  set safe_debug_print (find_symbol_value (intern ($tmp)))
+  set print_output_debug_flag = $output_debug
+end
+document pv1
+Print the value of the lisp variable given as argument.
+Works only when an inferior emacs is executing.
+For use when debugging in Emacs where the variable
+name would not otherwise be recorded in the GUD buffer.
+end
+
+# Print out current buffer point and boundaries
+define ppt
+  set $b = current_buffer
+  set $t = $b->text
+  printf "BUF PT: %d", $b->pt
+  if ($b->pt != $b->pt_byte)
+    printf "[%d]", $b->pt_byte
+  end
+  printf " of 1..%d", $t->z
+  if ($t->z != $t->z_byte)
+    printf "[%d]", $t->z_byte
+  end
+  if ($b->begv != 1 || $b->zv != $t->z)
+    printf " NARROW=%d..%d", $b->begv, $b->zv
+    if ($b->begv != $b->begv_byte || $b->zv != $b->zv_byte)
+      printf " [%d..%d]", $b->begv_byte, $b->zv_byte
+    end
+  end
+  printf " GAP: %d", $t->gpt
+  if ($t->gpt != $t->gpt_byte)
+    printf "[%d]", $t->gpt_byte
+  end
+  printf " SZ=%d\n", $t->gap_size
+end
+document ppt
+Print point, beg, end, narrow, and gap for current buffer.
+end
+
+# Print out iterator given as first arg
+define pitx
+  set $it = $arg0
+  printf "cur=%d", $it->current.pos.charpos
+  if ($it->current.pos.charpos != $it->current.pos.bytepos)
+    printf "[%d]", $it->current.pos.bytepos
+  end
+  printf " start=%d", $it->start.pos.charpos
+  if ($it->start.pos.charpos != $it->start.pos.bytepos)
+    printf "[%d]", $it->start.pos.bytepos
+  end
+  printf " end=%d", $it->end_charpos
+  printf " stop=%d", $it->stop_charpos
+  printf " face=%d", $it->face_id
+  if ($it->multibyte_p)
+    printf " MB"
+  end
+  if ($it->header_line_p)
+    printf " HL"
+  end
+  if ($it->n_overlay_strings > 0)
+    printf " nov=%d", $it->n_overlay_strings
+  end
+  if ($it->sp != 0)
+    printf " sp=%d", $it->sp
+  end
+  if ($it->what == IT_CHARACTER)
+    if ($it->len == 1 && $it->c >= ' ' && it->c < 255)
+      printf " ch='%c'", $it->c
+    else
+      printf " ch=[%d,%d]", $it->c, $it->len
+    end
+  else
+    if ($it->what == IT_IMAGE)
+      printf " IMAGE=%d", $it->image_id
+    else
+      printf " "
+      output $it->what
+    end
+  end
+  if ($it->method != GET_FROM_BUFFER)
+    printf " next="
+    output $it->method
+    if ($it->method == GET_FROM_STRING)
+      printf "[%d]", $it->current.string_pos.charpos
+    end
+  end
+  printf "\n"
+  if ($it->region_beg_charpos >= 0)
+    printf "reg=%d-%d ", $it->region_beg_charpos, $it->region_end_charpos
+  end
+  printf "vpos=%d hpos=%d", $it->vpos, $it->hpos,
+  printf " y=%d lvy=%d", $it->current_y, $it->last_visible_y
+  printf " x=%d vx=%d-%d", $it->current_x, $it->first_visible_x, $it->last_visible_x
+  printf " w=%d", $it->pixel_width
+  printf " a+d=%d+%d=%d", $it->ascent, $it->descent, $it->ascent+$it->descent
+  printf " max=%d+%d=%d", $it->max_ascent, $it->max_descent, $it->max_ascent+$it->max_descent
+  printf "\n"
+end
+document pitx
+Pretty print a display iterator.
+Take one arg, an iterator object or pointer.
+end
+
+define pit
+  pitx it
+end
+document pit
+Pretty print the display iterator it.
+end
+
+define prowx
+  set $row = $arg0
+  printf "y=%d x=%d pwid=%d", $row->y, $row->x, $row->pixel_width
+  printf " a+d=%d+%d=%d", $row->ascent, $row->height-$row->ascent, $row->height
+  printf " phys=%d+%d=%d", $row->phys_ascent, $row->phys_height-$row->phys_ascent, $row->phys_height
+  printf " vis=%d", $row->visible_height
+  printf "  L=%d T=%d R=%d", $row->used[0], $row->used[1], $row->used[2]
+  printf "\n"
+  printf "start=%d end=%d", $row->start.pos.charpos, $row->end.pos.charpos
+  if ($row->enabled_p)
+    printf " ENA"
+  end
+  if ($row->displays_text_p)
+    printf " DISP"
+  end
+  if ($row->mode_line_p)
+    printf " MODEL"
+  end
+  if ($row->continued_p)
+    printf " CONT"
+  end
+  if ($row-> truncated_on_left_p)
+    printf " TRUNC:L"
+  end
+  if ($row-> truncated_on_right_p)
+    printf " TRUNC:R"
+  end
+  if ($row->starts_in_middle_of_char_p)
+    printf " STARTMID"
+  end
+  if ($row->ends_in_middle_of_char_p)
+    printf " ENDMID"
+  end
+  if ($row->ends_in_newline_from_string_p)
+    printf " ENDNLFS"
+  end
+  if ($row->ends_at_zv_p)
+    printf " ENDZV"
+  end
+  if ($row->overlapped_p)
+    printf " OLAPD"
+  end
+  if ($row->overlapping_p)
+    printf " OLAPNG"
+  end
+  printf "\n"
+end
+document prowx
+Pretty print information about glyph_row.
+Takes one argument, a row object or pointer.
+end
+
+define prow
+  prowx row
+end
+document prow
+Pretty print information about glyph_row in row.
+end
+
+
+define pcursorx
+  set $cp = $arg0
+  printf "y=%d x=%d vpos=%d hpos=%d", $cp->y, $cp->x, $cp->vpos, $cp->hpos
+end
+document pcursorx
+Pretty print a window cursor
+end
+
+define pcursor
+  printf "output: "
+  pcursorx output_cursor
+  printf "\n"
+end
+document pcursor
+Pretty print the output_cursor
+end
+
+define pwinx
+  set $w = $arg0
+  xgetint $w->sequence_number
+  if ($w->mini_p != Qnil)
+    printf "Mini "
+  end
+  printf "Window %d ", $int
+  xgetptr $w->buffer
+  set $tem = (struct buffer *) $ptr
+  xgetptr $tem->name
+  printf "%s", ((struct Lisp_String *) $ptr)->data
+  printf "\n"
+  xgetptr $w->start
+  set $tem = (struct Lisp_Marker *) $ptr
+  printf "start=%d end:", $tem->charpos
+  if ($w->window_end_valid != Qnil)
+    xgetint $w->window_end_pos
+    printf "pos=%d", $int
+    xgetint $w->window_end_vpos
+    printf " vpos=%d", $int
+  else
+    printf "invalid"
+  end
+  printf " vscroll=%d", $w->vscroll
+  if ($w->force_start != Qnil)
+    printf " FORCE_START"
+  end
+  if ($w->must_be_updated_p)
+    printf " MUST_UPD"
+  end
+  printf "\n"
+  printf "cursor: "
+  pcursorx $w->cursor
+  printf "  phys: "
+  pcursorx $w->phys_cursor
+  if ($w->phys_cursor_on_p)
+    printf " ON"
+  else
+    printf " OFF"
+  end
+  printf " blk="
+  if ($w->last_cursor_off_p != $w->cursor_off_p)
+    if ($w->last_cursor_off_p)
+      printf "ON->"
+    else
+      printf "OFF->"
+    end
+  end
+  if ($w->cursor_off_p)
+    printf "ON"
+  else
+    printf "OFF"
+  end
+  printf "\n"
+end
+document pwinx
+Pretty print a window structure.
+Takes one argument, a pointer to a window structure
+end
+
+define pwin
+  pwinx w
+end
+document pwin
+Pretty print window structure w.
+end
+
+
 define xtype
   xgettype $
   output $type
@@ -242,6 +545,10 @@ end
 define xframe
   xgetptr $
   print (struct frame *) $ptr
+  xgetptr $->name
+  set $ptr = (struct Lisp_String *) $ptr
+  xprintstr $ptr
+  echo \n
 end
 document xframe
 Print $ as a frame pointer, assuming it is an Emacs Lisp frame value.
@@ -259,7 +566,16 @@ end
 define xwindow
   xgetptr $
   print (struct window *) $ptr
-  printf "%dx%d+%d+%d\n", $->width, $->height, $->left, $->top
+  set $window = (struct window *) $ptr
+  xgetint $window->total_cols
+  set $width=$int
+  xgetint $window->total_lines
+  set $height=$int
+  xgetint $window->left_col
+  set $left=$int
+  xgetint $window->top_line
+  set $top=$int
+  printf "%dx%d+%d+%d\n", $width, $height, $left, $top
 end
 document xwindow
 Print $ as a window pointer, assuming it is an Emacs Lisp window value.
@@ -339,7 +655,7 @@ Print the contents of $, assuming it is an Emacs Lisp cons.
 end
 
 define nextcons
-  p $.cdr
+  p $.u.cdr
   xcons
 end
 document nextcons
@@ -359,15 +675,40 @@ end
 define xcdr
   xgetptr $
   xgettype $
-  print/x ($type == Lisp_Cons ? ((struct Lisp_Cons *) $ptr)->cdr : 0)
+  print/x ($type == Lisp_Cons ? ((struct Lisp_Cons *) $ptr)->u.cdr : 0)
 end
 document xcdr
 Print the cdr of $, assuming it is an Emacs Lisp pair.
 end
 
+define xlist
+  xgetptr $
+  set $cons = (struct Lisp_Cons *) $ptr
+  xgetptr Qnil
+  set $nil = $ptr
+  set $i = 0
+  while $cons != $nil && $i < 10
+    p/x $cons->car
+    xpr
+    xgetptr $cons->u.cdr
+    set $cons = (struct Lisp_Cons *) $ptr
+    set $i = $i + 1
+    printf "---\n"
+  end
+  if $cons == $nil
+    printf "nil\n"
+  else
+    printf "...\n"
+    p $ptr
+  end
+end
+document xlist
+Print $ assuming it is a list.
+end
+
 define xfloat
   xgetptr $
-  print ((struct Lisp_Float *) $ptr)->data
+  print ((struct Lisp_Float *) $ptr)->u.data
 end
 document xfloat
 Print $ assuming it is a lisp floating-point number.
@@ -383,6 +724,108 @@ document xscrollbar
 Print $ as a scrollbar pointer.
 end
 
+define xpr
+  xtype
+  if $type == Lisp_Int
+    xint
+  end
+  if $type == Lisp_Symbol
+    xsymbol
+  end
+  if $type == Lisp_String
+    xstring
+  end
+  if $type == Lisp_Cons
+    xcons
+  end
+  if $type == Lisp_Float
+    xfloat
+  end
+  if $type == Lisp_Misc
+    set $misc = (enum Lisp_Misc_Type) (((struct Lisp_Free *) $ptr)->type)
+    if $misc == Lisp_Misc_Free
+      xmiscfree
+    end
+    if $misc == Lisp_Misc_Boolfwd
+      xboolfwd
+    end
+    if $misc == Lisp_Misc_Marker
+      xmarker
+    end
+    if $misc == Lisp_Misc_Intfwd
+      xintfwd
+    end
+    if $misc == Lisp_Misc_Boolfwd
+      xboolfwd
+    end
+    if $misc == Lisp_Misc_Objfwd
+      xobjfwd
+    end
+    if $misc == Lisp_Misc_Buffer_Objfwd
+      xbufobjfwd
+    end
+    if $misc == Lisp_Misc_Buffer_Local_Value
+      xbuflocal
+    end
+#    if $misc == Lisp_Misc_Some_Buffer_Local_Value
+#      xvalue
+#    end
+    if $misc == Lisp_Misc_Overlay
+      xoverlay
+    end
+    if $misc == Lisp_Misc_Kboard_Objfwd
+      xkbobjfwd
+    end
+#    if $misc == Lisp_Misc_Save_Value
+#      xsavevalue
+#    end
+  end
+  if $type == Lisp_Vectorlike
+    set $size = ((struct Lisp_Vector *) $ptr)->size
+    if ($size & PVEC_FLAG)
+      set $vec = (enum pvec_type) ($size & PVEC_TYPE_MASK)
+      if $vec == PVEC_NORMAL_VECTOR
+	xvector
+      end
+      if $vec == PVEC_PROCESS
+	xprocess
+      end
+      if $vec == PVEC_FRAME
+	xframe
+      end
+      if $vec == PVEC_COMPILED
+	xcompiled
+      end
+      if $vec == PVEC_WINDOW
+	xwindow
+      end
+      if $vec == PVEC_WINDOW_CONFIGURATION
+	xwinconfig
+      end
+      if $vec == PVEC_SUBR
+	xsubr
+      end
+      if $vec == PVEC_CHAR_TABLE
+	xchartable
+      end
+      if $vec == PVEC_BOOL_VECTOR
+	xboolvector
+      end
+      if $vec == PVEC_BUFFER
+	xbuffer
+      end
+      if $vec == PVEC_HASH_TABLE
+	xhashtable
+      end
+    else
+      xvector
+    end
+  end
+end
+document xpr
+Print $ as a lisp object of any type.
+end
+
 define xprintstr
   set $data = $arg0->data
   output ($arg0->size > 1000) ? 0 : ($data[0])@($arg0->size_byte < 0 ? $arg0->size & ~gdb_array_mark_flag : $arg0->size_byte)
@@ -405,7 +848,7 @@ define xbacktrace
     xgettype (*$bt->function)
     if $type == Lisp_Symbol
       xprintsym (*$bt->function)
-      echo \n
+      printf " (0x%x)\n", *$bt->args
     else
       printf "0x%x ", *$bt->function
       if $type == Lisp_Vectorlike
@@ -426,6 +869,37 @@ document xbacktrace
   an error was signaled.
 end
 
+define which
+  set debug_print (which_symbols ($arg0))
+end
+document which
+  Print symbols which references a given lisp object,
+  either as its symbol value or symbol function.
+end
+
+define xbytecode
+  set $bt = byte_stack_list
+  while $bt
+    xgettype ($bt->byte_string)
+    printf "0x%x => ", $bt->byte_string
+    which $bt->byte_string
+    set $bt = $bt->next
+  end
+end
+document xbytecode
+  Print a backtrace of the byte code stack.
+end
+
+# Show Lisp backtrace after normal backtrace.
+define hookpost-backtrace
+  set $bt = backtrace_list
+  if $bt
+    echo \n
+    echo Lisp Backtrace:\n
+    xbacktrace
+  end
+end
+
 define xreload
   set $tagmask = (((long)1 << gdb_gctypebits) - 1)
   set $valmask = gdb_use_lsb ? ~($tagmask) : ((long)1 << gdb_valbits) - 1
@@ -465,13 +939,43 @@ show environment DISPLAY
 show environment TERM
 set args -geometry 80x40+0+0
 
-# Don't let abort actually run, as it will make
-# stdio stop working and therefore the `pr' command above as well.
-break abort
-
-# If we are running in synchronous mode, we want a chance to look around
-# before Emacs exits.  Perhaps we should put the break somewhere else
-# instead...
-break x_error_quitter
+# People get bothered when they see messages about non-existent functions...
+xgetptr Vsystem_type
+# $ptr is NULL in temacs
+if ($ptr != 0)
+  set $tem = (struct Lisp_Symbol *) $ptr
+  xgetptr $tem->xname
+  set $tem = (struct Lisp_String *) $ptr
+  set $tem = (char *) $tem->data
+
+  # Don't let abort actually run, as it will make stdio stop working and
+  # therefore the `pr' command above as well.
+  if $tem[0] == 'w' && $tem[1] == 'i' && $tem[2] == 'n' && $tem[3] == 'd'
+    # The windows-nt build replaces abort with its own function.
+    break w32_abort
+  else
+    break abort
+  end
+end
 
+# x_error_quitter is defined only on X.  But window-system is set up
+# only at run time, during Emacs startup, so we need to defer setting
+# the breakpoint.  init_sys_modes is the first function called on
+# every platform after init_display, where window-system is set.
+tbreak init_sys_modes
+commands
+  silent
+  xgetptr Vwindow_system
+  set $tem = (struct Lisp_Symbol *) $ptr
+  xgetptr $tem->xname
+  set $tem = (struct Lisp_String *) $ptr
+  set $tem = (char *) $tem->data
+  # If we are running in synchronous mode, we want a chance to look
+  # around before Emacs exits.  Perhaps we should put the break
+  # somewhere else instead...
+  if $tem[0] == 'x' && $tem[1] == '\0'
+    break x_error_quitter
+  end
+  continue
+end
 # arch-tag: 12f34321-7bfa-4240-b77a-3cd3a1696dfe