code.delx.au - dotemacs/blob - lisp/my-editing-defuns.el

   1 ;;; -*- lexical-binding: t -*-
   2
   3 (defun my/comment-dwim (arg)
   4   "Toggles the comment on for the active region if present or the current line otherwise."
   5   (interactive "*p")
   6   (cond
   7    ((and mark-active transient-mark-mode)
   8     (let ((start (save-excursion (goto-char (region-beginning)) (line-beginning-position)))
   9           (end (save-excursion (goto-char (region-end)) (line-end-position))))
  10       (comment-or-uncomment-region start end)))
  11    (t
  12     (comment-or-uncomment-region (line-beginning-position) (line-end-position arg))
  13     (forward-line arg))))
  14
  15 (defun my/copy-line (arg)
  16   "Copy the current line into the kill ring. With ARG copies that many lines."
  17   (interactive "*p")
  18   (kill-ring-save (line-beginning-position 1)
  19                   (line-beginning-position (+ 1 arg)))
  20   (message "Copied %d lines" arg))
  21
  22 (defun my/duplicate-line (arg)
  23   "Duplicate current line, leaving point in lower line. With ARG duplicates the line that many lines."
  24   (interactive "*p")
  25   (kill-ring-save (line-beginning-position 1)
  26                   (line-beginning-position 2))
  27   (forward-line)
  28   (dotimes (ignored arg)
  29     (yank))
  30   (forward-line (- arg))
  31   (back-to-indentation))
  32
  33 (defun my/open-line-above (arg)
  34   "Open a new line above point with indentation. With ARG insert that many lines."
  35   (interactive "*p")
  36   (beginning-of-line)
  37   (newline arg)
  38   (forward-line (- arg))
  39   (indent-for-tab-command))
  40
  41 (defun my/open-line-below (arg)
  42   "Open a new line below point with indentation. With ARG insert that many lines."
  43   (interactive "*p")
  44   (end-of-line)
  45   (newline arg)
  46   (indent-for-tab-command))
  47
  48 (defun my/substitute-line (arg)
  49   "Kill the current line and leave point at correct indentation level. With ARG kill that many lines first."
  50   (interactive "*P")
  51   (beginning-of-line)
  52   (if (not (and (null arg) (equal (line-beginning-position) (line-end-position))))
  53       (kill-line arg))
  54   (if (not (string-equal major-mode "fundamental-mode"))
  55       (indent-for-tab-command)))
  56
  57 (defun my/yank (arg)
  58   "If the text to be yanked has a newline then move to beginning of line before yanking. Otherwise same as normal `yank'."
  59   (interactive "*P")
  60   (advice-add 'insert-for-yank :around #'my/yank/advice)
  61   (unwind-protect
  62       (yank arg)
  63     (advice-remove 'insert-for-yank #'my/yank/advice)))
  64
  65 (defun my/yank/advice (original-function string)
  66   (if (string-match-p "\n" string)
  67       (beginning-of-line))
  68   (funcall original-function string))