code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.5.1
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (defface swiper-minibuffer-match-face-1
  65   '((((class color) (background light))
  66      :background "#d3d3d3")
  67     (((class color) (background dark))
  68      :background "#555555"))
  69   "The background face for `swiper' minibuffer matches."
  70   :group 'function-args-faces)
  71
  72 (defface swiper-minibuffer-match-face-2
  73   '((((class color) (background light))
  74      :background "#e99ce8" :weight bold)
  75     (((class color) (background dark))
  76      :background "#777777" :weight bold))
  77   "Face for `swiper' minibuffer matches modulo 1.")
  78
  79 (defface swiper-minibuffer-match-face-3
  80   '((((class color) (background light))
  81      :background "#bbbbff" :weight bold)
  82     (((class color) (background dark))
  83      :background "#7777ff" :weight bold))
  84   "Face for `swiper' minibuffer matches modulo 2.")
  85
  86 (defface swiper-minibuffer-match-face-4
  87   '((((class color) (background light))
  88      :background "#ffbbff" :weight bold)
  89     (((class color) (background dark))
  90      :background "#8a498a" :weight bold))
  91   "Face for `swiper' minibuffer matches modulo 3.")
  92
  93 (defface swiper-line-face
  94   '((t (:inherit highlight)))
  95   "Face for current `swiper' line.")
  96
  97 (defcustom swiper-faces '(swiper-match-face-1
  98                           swiper-match-face-2
  99                           swiper-match-face-3
 100                           swiper-match-face-4)
 101   "List of `swiper' faces for group matches.")
 102
 103 (defcustom swiper-min-highlight 2
 104   "Only highlight matches for regexps at least this long."
 105   :type 'integer)
 106
 107 (defvar swiper-map
 108   (let ((map (make-sparse-keymap)))
 109     (define-key map (kbd "M-q") 'swiper-query-replace)
 110     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
 111     (define-key map (kbd "C-'") 'swiper-avy)
 112     map)
 113   "Keymap for swiper.")
 114
 115 (defun swiper-query-replace ()
 116   "Start `query-replace' with string to replace from last search string."
 117   (interactive)
 118   (if (null (window-minibuffer-p))
 119       (user-error "Should only be called in the minibuffer through `swiper-map'")
 120     (let* ((enable-recursive-minibuffers t)
 121            (from (ivy--regex ivy-text))
 122            (to (query-replace-read-to from "Query replace" t)))
 123       (delete-minibuffer-contents)
 124       (ivy-set-action (lambda (_)
 125                         (with-ivy-window
 126                           (move-beginning-of-line 1)
 127                           (perform-replace from to
 128                                            t t nil))))
 129       (swiper--cleanup)
 130       (exit-minibuffer))))
 131
 132 (defvar avy-background)
 133 (defvar avy-all-windows)
 134 (declare-function avy--regex-candidates "ext:avy")
 135 (declare-function avy--process "ext:avy")
 136 (declare-function avy--overlay-post "ext:avy")
 137 (declare-function avy-action-goto "ext:avy")
 138
 139 ;;;###autoload
 140 (defun swiper-avy ()
 141   "Jump to one of the current swiper candidates."
 142   (interactive)
 143   (unless (string= ivy-text "")
 144     (let* ((avy-all-windows nil)
 145            (candidates (append
 146                         (with-ivy-window
 147                           (avy--regex-candidates
 148                            (ivy--regex ivy-text)))
 149                         (save-excursion
 150                           (save-restriction
 151                             (narrow-to-region (window-start) (window-end))
 152                             (goto-char (point-min))
 153                             (forward-line)
 154                             (let ((cands))
 155                               (while (< (point) (point-max))
 156                                 (push (cons (1+ (point))
 157                                             (selected-window))
 158                                       cands)
 159                                 (forward-line))
 160                               cands)))))
 161            (candidate (unwind-protect
 162                           (prog2
 163                               (avy--make-backgrounds
 164                                (append (avy-window-list)
 165                                        (list  (ivy-state-window ivy-last))))
 166                               (if (eq avy-style 'de-bruijn)
 167                                   (avy-read-de-bruijn
 168                                    candidates avy-keys)
 169                                 (avy-read (avy-tree candidates avy-keys)
 170                                           #'avy--overlay-post
 171                                           #'avy--remove-leading-chars))
 172                             (avy-push-mark))
 173                         (avy--done))))
 174       (if (window-minibuffer-p (cdr candidate))
 175           (progn
 176             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 177             (ivy--exhibit)
 178             (ivy-done)
 179             (ivy-call))
 180         (ivy-quit-and-run
 181          (avy-action-goto (caar candidate)))))))
 182
 183 (defun swiper-recenter-top-bottom (&optional arg)
 184   "Call (`recenter-top-bottom' ARG)."
 185   (interactive "P")
 186   (with-ivy-window
 187     (recenter-top-bottom arg)))
 188
 189 (defun swiper-font-lock-ensure ()
 190   "Ensure the entired buffer is highlighted."
 191   (unless (or (derived-mode-p 'magit-mode)
 192               (bound-and-true-p magit-blame-mode)
 193               (memq major-mode '(package-menu-mode
 194                                  gnus-summary-mode
 195                                  gnus-article-mode
 196                                  gnus-group-mode
 197                                  emms-playlist-mode erc-mode
 198                                  org-agenda-mode
 199                                  dired-mode
 200                                  jabber-chat-mode
 201                                  elfeed-search-mode
 202                                  fundamental-mode
 203                                  Man-mode
 204                                  woman-mode
 205                                  mu4e-view-mode
 206                                  mu4e-headers-mode
 207                                  help-mode)))
 208     (unless (> (buffer-size) 100000)
 209       (if (fboundp 'font-lock-ensure)
 210           (font-lock-ensure)
 211         (with-no-warnings (font-lock-fontify-buffer))))))
 212
 213 (defvar swiper--format-spec ""
 214   "Store the current candidates format spec.")
 215
 216 (defvar swiper--width nil
 217   "Store the amount of digits needed for the longest line nubmer.")
 218
 219 (defvar swiper-use-visual-line nil
 220   "When non-nil, use `line-move' instead of `forward-line'.")
 221
 222 (defun swiper--candidates ()
 223   "Return a list of this buffer lines."
 224   (setq swiper-use-visual-line
 225         (and (not (eq major-mode 'org-mode))
 226              visual-line-mode
 227              (< (buffer-size) 20000)))
 228   (let ((n-lines (count-lines (point-min) (point-max))))
 229     (unless (zerop n-lines)
 230       (setq swiper--width (1+ (floor (log n-lines 10))))
 231       (setq swiper--format-spec
 232             (format "%%-%dd " swiper--width))
 233       (let ((line-number 0)
 234             (advancer (if swiper-use-visual-line
 235                           (lambda (arg) (line-move arg t))
 236                         #'forward-line))
 237             candidates)
 238         (save-excursion
 239           (goto-char (point-min))
 240           (swiper-font-lock-ensure)
 241           (while (< (point) (point-max))
 242             (let ((str (concat " " (buffer-substring
 243                                     (point)
 244                                     (if swiper-use-visual-line
 245                                         (save-excursion
 246                                           (end-of-visual-line)
 247                                           (point))
 248                                       (line-end-position))))))
 249               (put-text-property 0 1 'display
 250                                  (format swiper--format-spec
 251                                          (cl-incf line-number))
 252                                  str)
 253               (push str candidates))
 254             (funcall advancer 1))
 255           (nreverse candidates))))))
 256
 257 (defvar swiper--opoint 1
 258   "The point when `swiper' starts.")
 259
 260 ;;;###autoload
 261 (defun swiper (&optional initial-input)
 262   "`isearch' with an overview.
 263 When non-nil, INITIAL-INPUT is the initial search pattern."
 264   (interactive)
 265   (swiper--ivy initial-input))
 266
 267 (defvar swiper--anchor nil
 268   "A line number to which the search should be anchored.")
 269
 270 (defvar swiper--len 0
 271   "The last length of input for which an anchoring was made.")
 272
 273 (defun swiper--init ()
 274   "Perform initialization common to both completion methods."
 275   (setq swiper--opoint (point))
 276   (setq swiper--len 0)
 277   (setq swiper--anchor (line-number-at-pos)))
 278
 279 (defun swiper--re-builder (str)
 280   "Transform STR into a swiper regex.
 281 This is the regex used in the minibuffer, since the candidates
 282 there have line numbers. In the buffer, `ivy--regex' should be used."
 283   (cond
 284     ((equal str "")
 285      "")
 286     ((equal str "^")
 287      ".")
 288     ((string-match "^\\^" str)
 289      (setq ivy--old-re "")
 290      (let ((re (ivy--regex-plus (substring str 1))))
 291        (format "^[0-9][0-9 ]\\{%d\\}%s"
 292                swiper--width
 293                (if (zerop ivy--subexps)
 294                    (prog1 (format "\\(%s\\)" re)
 295                      (setq ivy--subexps 1))
 296                  re))))
 297     (t
 298      (ivy--regex-plus str))))
 299
 300 (defvar swiper-history nil
 301   "History for `swiper'.")
 302
 303 (defun swiper--ivy (&optional initial-input)
 304   "`isearch' with an overview using `ivy'.
 305 When non-nil, INITIAL-INPUT is the initial search pattern."
 306   (interactive)
 307   (swiper--init)
 308   (let ((candidates (swiper--candidates))
 309         (preselect (buffer-substring-no-properties
 310                     (line-beginning-position)
 311                     (line-end-position)))
 312         (minibuffer-allow-text-properties t)
 313         res)
 314     (unwind-protect
 315          (setq res (ivy-read
 316                     "Swiper: "
 317                     candidates
 318                     :initial-input initial-input
 319                     :keymap swiper-map
 320                     :preselect preselect
 321                     :require-match t
 322                     :update-fn #'swiper--update-input-ivy
 323                     :unwind #'swiper--cleanup
 324                     :re-builder #'swiper--re-builder
 325                     :history 'swiper-history))
 326       (if (null ivy-exit)
 327           (goto-char swiper--opoint)
 328         (swiper--action res ivy-text)))))
 329
 330 (defun swiper--ensure-visible ()
 331   "Remove overlays hiding point."
 332   (let ((overlays (overlays-at (point)))
 333         ov expose)
 334     (while (setq ov (pop overlays))
 335       (if (and (invisible-p (overlay-get ov 'invisible))
 336                (setq expose (overlay-get ov 'isearch-open-invisible)))
 337           (funcall expose ov)))))
 338
 339 (defvar swiper--overlays nil
 340   "Store overlays.")
 341
 342 (defun swiper--cleanup ()
 343   "Clean up the overlays."
 344   (while swiper--overlays
 345     (delete-overlay (pop swiper--overlays)))
 346   (save-excursion
 347     (goto-char (point-min))
 348     (isearch-clean-overlays)))
 349
 350 (defun swiper--update-input-ivy ()
 351   "Called when `ivy' input is updated."
 352   (with-ivy-window
 353     (swiper--cleanup)
 354     (when (> (length ivy--current) 0)
 355       (let* ((re (funcall ivy--regex-function ivy-text))
 356              (re (if (stringp re) re (caar re)))
 357              (str (get-text-property 0 'display ivy--current))
 358              (num (if (string-match "^[0-9]+" str)
 359                       (string-to-number (match-string 0 str))
 360                     0)))
 361         (goto-char (point-min))
 362         (when (cl-plusp num)
 363           (goto-char (point-min))
 364           (if swiper-use-visual-line
 365               (line-move (1- num))
 366             (forward-line (1- num)))
 367           (if (and (equal ivy-text "")
 368                    (>= swiper--opoint (line-beginning-position))
 369                    (<= swiper--opoint (line-end-position)))
 370               (goto-char swiper--opoint)
 371             (re-search-forward re (line-end-position) t))
 372           (isearch-range-invisible (line-beginning-position)
 373                                    (line-end-position))
 374           (unless (and (>= (point) (window-start))
 375                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 376             (recenter)))
 377         (swiper--add-overlays re)))))
 378
 379 (defun swiper--add-overlays (re &optional beg end)
 380   "Add overlays for RE regexp in visible part of the current buffer.
 381 BEG and END, when specified, are the point bounds."
 382   (let ((ov (if visual-line-mode
 383                 (make-overlay
 384                  (save-excursion
 385                    (beginning-of-visual-line)
 386                    (point))
 387                  (save-excursion
 388                    (end-of-visual-line)
 389                    (point)))
 390               (make-overlay
 391                (line-beginning-position)
 392                (1+ (line-end-position))))))
 393     (overlay-put ov 'face 'swiper-line-face)
 394     (overlay-put ov 'window (ivy-state-window ivy-last))
 395     (push ov swiper--overlays)
 396     (let* ((wh (window-height))
 397            (beg (or beg (save-excursion
 398                           (forward-line (- wh))
 399                           (point))))
 400            (end (or end (save-excursion
 401                           (forward-line wh)
 402                           (point)))))
 403       (when (>= (length re) swiper-min-highlight)
 404         (save-excursion
 405           (goto-char beg)
 406           ;; RE can become an invalid regexp
 407           (while (and (ignore-errors (re-search-forward re end t))
 408                       (> (- (match-end 0) (match-beginning 0)) 0))
 409             (let ((i 0))
 410               (while (<= i ivy--subexps)
 411                 (when (match-beginning i)
 412                   (let ((overlay (make-overlay (match-beginning i)
 413                                                (match-end i)))
 414                         (face
 415                          (cond ((zerop ivy--subexps)
 416                                 (cadr swiper-faces))
 417                                ((zerop i)
 418                                 (car swiper-faces))
 419                                (t
 420                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 421                                      swiper-faces)))))
 422                     (push overlay swiper--overlays)
 423                     (overlay-put overlay 'face face)
 424                     (overlay-put overlay 'window (ivy-state-window ivy-last))
 425                     (overlay-put overlay 'priority i)))
 426                 (cl-incf i)))))))))
 427
 428 (defun swiper--action (x input)
 429   "Goto line X and search for INPUT."
 430   (if (null x)
 431       (user-error "No candidates")
 432     (goto-char (point-min))
 433     (funcall (if swiper-use-visual-line
 434                  #'line-move
 435                #'forward-line)
 436              (1- (read (get-text-property 0 'display x))))
 437     (re-search-forward
 438      (ivy--regex input) (line-end-position) t)
 439     (swiper--ensure-visible)
 440     (when (/= (point) swiper--opoint)
 441       (unless (and transient-mark-mode mark-active)
 442         (push-mark swiper--opoint t)
 443         (message "Mark saved where search started")))))
 444
 445 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 446 (defun swiper-from-isearch ()
 447   "Invoke `swiper' from isearch."
 448   (interactive)
 449   (let ((query (if isearch-regexp
 450                    isearch-string
 451                  (regexp-quote isearch-string))))
 452     (isearch-exit)
 453     (swiper query)))
 454
 455 (defvar swiper-multi-buffers nil
 456   "Store the current list of buffers.")
 457
 458 (defvar swiper-multi-candidates nil
 459   "Store the list of candidates for `swiper-multi'.")
 460
 461 (defun swiper-multi-prompt ()
 462   (format "Buffers (%s): "
 463           (mapconcat #'identity swiper-multi-buffers ", ")))
 464
 465 (defun swiper-multi ()
 466   "Select one or more buffers.
 467 Run `swiper' for those buffers."
 468   (interactive)
 469   (setq swiper-multi-buffers nil)
 470   (setq swiper-multi-candidates nil)
 471   (ivy-read (swiper-multi-prompt)
 472             'internal-complete-buffer
 473             :action 'swiper-multi-action-1)
 474   (ivy-read "Swiper: " swiper-multi-candidates
 475             :action 'swiper-multi-action-2
 476             :unwind #'swiper--cleanup))
 477
 478 (defun swiper-multi-action-1 (x)
 479   (if (member x swiper-multi-buffers)
 480       (progn
 481         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 482     (unless (equal x "")
 483       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 484   (let ((prompt (swiper-multi-prompt)))
 485     (setf (ivy-state-prompt ivy-last) prompt)
 486     (setq ivy--prompt (concat "%-4d " prompt)))
 487   (cond ((memq this-command '(ivy-done
 488                               ivy-alt-done
 489                               ivy-immediate-done))
 490          (let ((ww (window-width)))
 491            (dolist (buf swiper-multi-buffers)
 492              (with-current-buffer buf
 493                (setq swiper-multi-candidates
 494                      (append
 495                       (mapcar
 496                        (lambda (s)
 497                          (setq s (concat s " "))
 498                          (let ((len (length s)))
 499                            (put-text-property
 500                             (1- len) len 'display
 501                             (concat
 502                              (make-string
 503                               (max
 504                                (- ww
 505                                   (string-width s)
 506                                   (length (buffer-name))
 507                                   1)
 508                                0)
 509                               ?\ )
 510                              (buffer-name))
 511                             s)
 512                            s))
 513                        (swiper--candidates))
 514                       swiper-multi-candidates))))))
 515         ((eq this-command 'ivy-call)
 516          (delete-minibuffer-contents))))
 517
 518 (defun swiper-multi-action-2 (x)
 519   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 520     (with-ivy-window
 521       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 522         (switch-to-buffer (match-string 1 buf-space))
 523         (goto-char (point-min))
 524         (forward-line (1- (read x)))
 525         (re-search-forward
 526          (ivy--regex ivy-text)
 527          (line-end-position) t)
 528         (unless (eq ivy-exit 'done)
 529           (swiper--cleanup)
 530           (swiper--add-overlays (ivy--regex ivy-text)))))))
 531
 532 (provide 'swiper)
 533
 534 ;;; swiper.el ends here