code.delx.au - gnu-emacs-elpa/blob - company-capf.el

   1 ;;; company-capf.el --- company-mode completion-at-point-functions backend -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2013-2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'cl-lib)
  30
  31 (defvar company--capf-cache nil)
  32
  33 (defun company--capf-data ()
  34   (let ((cache company--capf-cache))
  35     (if (and (equal (current-buffer) (car cache))
  36              (equal (point) (car (setq cache (cdr cache))))
  37              (equal (buffer-chars-modified-tick) (car (setq cache (cdr cache)))))
  38         (cadr cache)
  39       (let ((data (company--capf-data-real)))
  40         (setq company--capf-cache
  41               (list (current-buffer) (point) (buffer-chars-modified-tick) data))
  42         data))))
  43
  44 (defun company--capf-data-real ()
  45   (cl-letf* (((default-value 'completion-at-point-functions)
  46               ;; Ignore tags-completion-at-point-function because it subverts
  47               ;; company-etags in the default value of company-backends, where
  48               ;; the latter comes later.
  49               (remove 'tags-completion-at-point-function
  50                       (default-value 'completion-at-point-functions)))
  51              (completion-at-point-functions (company--capf-workaround))
  52              (data (run-hook-wrapped 'completion-at-point-functions
  53                                      ;; Ignore misbehaving functions.
  54                                      #'completion--capf-wrapper 'optimist)))
  55     (when (and (consp (cdr data)) (integer-or-marker-p (nth 1 data))) data)))
  56
  57 (declare-function python-shell-get-process "python")
  58
  59 (defun company--capf-workaround ()
  60   ;; For http://debbugs.gnu.org/cgi/bugreport.cgi?bug=18067
  61   (if (or (not (memq 'python-completion-complete-at-point completion-at-point-functions))
  62           (python-shell-get-process))
  63       completion-at-point-functions
  64     (remq 'python-completion-complete-at-point completion-at-point-functions)))
  65
  66 (defun company-capf (command &optional arg &rest _args)
  67   "`company-mode' backend using `completion-at-point-functions'."
  68   (interactive (list 'interactive))
  69   (pcase command
  70     (`interactive (company-begin-backend 'company-capf))
  71     (`prefix
  72      (let ((res (company--capf-data)))
  73        (when res
  74          (if (> (nth 2 res) (point))
  75              'stop
  76            (buffer-substring-no-properties (nth 1 res) (point))))))
  77     (`candidates
  78      (let ((res (company--capf-data)))
  79        (when res
  80          (let* ((table (nth 3 res))
  81                 (pred (plist-get (nthcdr 4 res) :predicate))
  82                 (meta (completion-metadata
  83                       (buffer-substring (nth 1 res) (nth 2 res))
  84                       table pred))
  85                 (sortfun (cdr (assq 'display-sort-function meta)))
  86                 (candidates (completion-all-completions arg table pred (length arg)))
  87                 (last (last candidates))
  88                 (base-size (and (numberp (cdr last)) (cdr last))))
  89            (when base-size
  90              (setcdr last nil))
  91            (when sortfun
  92              (setq candidates (funcall sortfun candidates)))
  93            (if (not (zerop (or base-size 0)))
  94                (let ((before (substring arg 0 base-size)))
  95                  (mapcar (lambda (candidate)
  96                            (concat before candidate))
  97                          candidates))
  98              candidates)))))
  99     (`sorted
 100      (let ((res (company--capf-data)))
 101        (when res
 102          (let ((meta (completion-metadata
 103                       (buffer-substring (nth 1 res) (nth 2 res))
 104                       (nth 3 res) (plist-get (nthcdr 4 res) :predicate))))
 105            (cdr (assq 'display-sort-function meta))))))
 106     (`match
 107      ;; Can't just use 0 when base-size (see above) is non-zero.
 108      (let ((start (if (get-text-property 0 'font-lock-face arg)
 109                       0
 110                     (next-single-property-change 0 'font-lock-face arg))))
 111        (when start
 112          ;; completions-common-part comes first, but we can't just look for this
 113          ;; value because it can be in a list.
 114          (or
 115           (let ((value (get-text-property start 'font-lock-face arg)))
 116             (text-property-not-all start (length arg)
 117                                    'font-lock-face value arg))
 118           (length arg)))))
 119     (`duplicates t)
 120     (`no-cache t)   ;Not much can be done here, as long as we handle
 121                     ;non-prefix matches.
 122     (`meta
 123      (let ((f (plist-get (nthcdr 4 (company--capf-data)) :company-docsig)))
 124        (when f (funcall f arg))))
 125     (`doc-buffer
 126      (let ((f (plist-get (nthcdr 4 (company--capf-data)) :company-doc-buffer)))
 127        (when f (funcall f arg))))
 128     (`location
 129      (let ((f (plist-get (nthcdr 4 (company--capf-data)) :company-location)))
 130        (when f (funcall f arg))))
 131     (`annotation
 132      (save-excursion
 133        ;; FIXME: `company-begin' sets `company-point' after calling
 134        ;; `company--begin-new'.  We shouldn't rely on `company-point' here,
 135        ;; better to cache the capf-data value instead.  However: we can't just
 136        ;; save the last capf-data value in `prefix', because that command can
 137        ;; get called more often than `candidates', and at any point in the
 138        ;; buffer (https://github.com/company-mode/company-mode/issues/153).
 139        ;; We could try propertizing the returned prefix string, but it's not
 140        ;; passed to `annotation', and `company-prefix' is set only after
 141        ;; `company--strip-duplicates' is called.
 142        (when company-point
 143          (goto-char company-point))
 144        (let ((f (plist-get (nthcdr 4 (company--capf-data)) :annotation-function)))
 145          (when f (funcall f arg)))))
 146     (`require-match
 147      (plist-get (nthcdr 4 (company--capf-data)) :company-require-match))
 148     (`init nil)      ;Don't bother: plenty of other ways to initialize the code.
 149     (`post-completion
 150      (let* ((res (company--capf-data))
 151             (exit-function (plist-get (nthcdr 4 res) :exit-function))
 152             (table (nth 3 res))
 153             (pred (plist-get (nthcdr 4 res) :predicate)))
 154        (if exit-function
 155            ;; Follow the example of `completion--done'.
 156            (funcall exit-function arg
 157                     (if (eq (try-completion arg table pred) t)
 158                         'finished 'sole)))))
 159     ))
 160
 161 (provide 'company-capf)
 162
 163 ;;; company-capf.el ends here