code.delx.au - gnu-emacs-elpa/blob - chess-perft.el

   1 ;;; chess-perft.el --- Perft tests for emacs-chess   -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2014  Mario Lang
   4
   5 ;; Author: Mario Lang <mlang@delysid.org>
   6 ;; Keywords: games
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; The classic perft function counts all leave nodes at a certain depth.
  24 ;; To make it easier to identify specific problems we also count properties
  25 ;; of the individual (final) plies.  We count capturing plies, en passant plies,
  26 ;; castling plies, plies that promote to a piece,
  27 ;; plies which bring the opponent king in check and plies which result in
  28 ;; checkmate.
  29
  30 ;; Typically depths greater than 4 will result in very long runtimes.
  31 ;; We only define tests which do not take a lot of execution time
  32 ;; (less than a million nodes).
  33
  34 ;; To make it easier to selectively run tests, all tests provide tags
  35 ;; to indentify which type of ply they are covering.
  36 ;; The available ERT tags are:
  37 ;; :capture, :en-passant, :castle, :promotion, :check and :checkmate.
  38 ;;
  39 ;; For instance, to make sure castling plies work as expected, run
  40 ;; M-: (ert '(tag :castle)) RET
  41
  42 ;;; Code:
  43
  44 (require 'chess-fen)
  45 (require 'chess-ply)
  46 (require 'chess-pos)
  47 (require 'cl-lib)
  48 (require 'ert)
  49
  50 (defun chess-perft (position depth)
  51   "Count all leave nodes of the tree starting at POSITION pruned at DEPTH.
  52 The result is a list of the form
  53  (LEAVES CAPTURES EN-PASSANTS CASTLES PROMOTIONS CHECKS CHECKMATES)."
  54   (if (zerop depth)
  55       (cl-values 1 0 0 0 0)
  56     (let ((plies (chess-legal-plies position
  57                                     :color (chess-pos-side-to-move position)))
  58           (nodes 0) (captures 0) (en-passants 0) (castles 0) (promotions 0)
  59           (checks 0) (checkmates 0))
  60       (if (= depth 1)
  61           (dolist (ply plies)
  62             (cl-incf nodes)
  63             (when (let ((position (chess-ply-pos ply)))
  64                     (chess-pos-piece-p position (chess-ply-target ply)
  65                                        (not (chess-pos-side-to-move position))))
  66               (cl-incf captures))
  67             (when (chess-ply-keyword ply :en-passant)
  68               (cl-incf captures)
  69               (cl-incf en-passants))
  70             (if (chess-ply-any-keyword ply :castle :long-castle)
  71                 (cl-incf castles)
  72               (when (chess-ply-keyword ply :promote)
  73                 (cl-incf promotions)))
  74             (when (chess-ply-any-keyword ply :check :checkmate)
  75               (cl-incf checks))
  76             (when (chess-ply-any-keyword ply :checkmate)
  77               (cl-incf checkmates))         )
  78         (dolist (ply plies)
  79           (cl-multiple-value-bind (n c e ca p ch cm)
  80               (chess-perft (chess-ply-next-pos ply) (1- depth))
  81             (cl-incf nodes n)
  82             (cl-incf captures c)
  83             (cl-incf en-passants e)
  84             (cl-incf castles ca)
  85             (cl-incf promotions p)
  86             (cl-incf checks ch)
  87             (cl-incf checkmates cm))))
  88
  89       (cl-values nodes
  90                  captures en-passants castles promotions checks checkmates))))
  91
  92 (ert-deftest chess-perft-startpos-depth1 ()
  93   (should (equal (chess-perft (chess-pos-create) 1) '(20 0 0 0 0 0 0))))
  94
  95 (ert-deftest chess-perft-startpos-depth2 ()
  96   (should (equal (chess-perft (chess-pos-create) 2) '(400 0 0 0 0 0 0))))
  97
  98 (ert-deftest chess-perft-startpos-depth3 ()
  99   :tags '(:capture :check)
 100   (should (equal (chess-perft (chess-pos-create) 3) '(8902 34 0 0 0 12 0))))
 101
 102 (ert-deftest chess-perft-startpos-depth4 ()
 103   :tags '(:capture :check :checkmate)
 104   (should (equal (chess-perft (chess-pos-create) 4) '(197281 1576 0 0 0 469 8))))
 105
 106 (ert-deftest chess-perft-kiwipete-depth1 ()
 107   :tags '(:capture :castle)
 108   (let ((position
 109          (chess-fen-to-pos
 110           "r3k2r/p1ppqpb1/bn2pnp1/3PN3/1p2P3/2N2Q1p/PPPBBPPP/R3K2R w KQkq -")))
 111     (should (equal (chess-perft position 1) '(48 8 0 2 0 0 0)))))
 112
 113 (ert-deftest chess-perft-kiwipete-depth2 ()
 114   :tags '(:capture :en-passant :castle :check)
 115   (let ((position
 116          (chess-fen-to-pos
 117           "r3k2r/p1ppqpb1/bn2pnp1/3PN3/1p2P3/2N2Q1p/PPPBBPPP/R3K2R w KQkq -")))
 118     (should (equal (chess-perft position 2) '(2039 351 1 91 0 3 0)))))
 119
 120 (ert-deftest chess-perft-kiwipete-depth3 ()
 121   :tags '(:capture :en-passant :castle :check :checkmate)
 122   (let ((position
 123          (chess-fen-to-pos
 124           "r3k2r/p1ppqpb1/bn2pnp1/3PN3/1p2P3/2N2Q1p/PPPBBPPP/R3K2R w KQkq -")))
 125     (should (equal (chess-perft position 3) '(97862 17102 45 3162 0 993 1)))))
 126
 127 (ert-deftest chess-perft-pos3-depth1 ()
 128   :tags '(:capture :check)
 129   (let ((position (chess-fen-to-pos "8/2p5/3p4/KP5r/1R3p1k/8/4P1P1/8 w - -")))
 130     (should (equal (chess-perft position 1) '(14 1 0 0 0 2 0)))))
 131
 132 (ert-deftest chess-perft-pos3-depth2 ()
 133   :tags '(:capture :check)
 134   (let ((position (chess-fen-to-pos "8/2p5/3p4/KP5r/1R3p1k/8/4P1P1/8 w - -")))
 135     (should (equal (chess-perft position 2) '(191 14 0 0 0 10 0)))))
 136
 137 (ert-deftest chess-perft-pos3-depth3 ()
 138   :tags '(:capture :en-passant :check)
 139   (let ((position (chess-fen-to-pos "8/2p5/3p4/KP5r/1R3p1k/8/4P1P1/8 w - -")))
 140     (should (equal (chess-perft position 3) '(2812 209 2 0 0 267 0)))))
 141
 142 (ert-deftest chess-perft-pos3-depth4 ()
 143   :tags '(:capture :en-passant :check :checkmate)
 144   (let ((position (chess-fen-to-pos "8/2p5/3p4/KP5r/1R3p1k/8/4P1P1/8 w - -")))
 145     (should (equal (chess-perft position 4) '(43238 3348 123 0 0 1680 17)))))
 146
 147 (ert-deftest chess-perft-pos3-depth5 ()
 148   :tags '(:capture :en-passant :check)
 149   (let ((position (chess-fen-to-pos "8/2p5/3p4/KP5r/1R3p1k/8/4P1P1/8 w - -")))
 150     (should (equal (chess-perft position 5) '(674624 52051 1165 0 0 52950 0)))))
 151
 152 (ert-deftest chess-perft-pos4-depth1 ()
 153   (let ((chess-ply-allow-interactive-query nil)
 154         (position
 155          (chess-fen-to-pos
 156           "r3k2r/Pppp1ppp/1b3nbN/nP6/BBP1P3/q4N2/Pp1P2PP/R2Q1RK1 w kq -")))
 157     (should (equal (chess-perft position 1) '(6 0 0 0 0 0 0)))))
 158
 159 (ert-deftest chess-perft-pos4-depth2 ()
 160   :tags '(:capture :castle :promotion :check)
 161   (let ((chess-ply-allow-interactive-query nil)
 162         (position
 163          (chess-fen-to-pos
 164           "r3k2r/Pppp1ppp/1b3nbN/nP6/BBP1P3/q4N2/Pp1P2PP/R2Q1RK1 w kq -")))
 165     (should (equal (chess-perft position 2) '(264 87 0 6 48 10 0)))))
 166
 167 (ert-deftest chess-perft-pos4-depth3 ()
 168   :tags '(:capture :en-passant :promotion :check :checkmate)
 169   (let ((chess-ply-allow-interactive-query nil)
 170         (position
 171          (chess-fen-to-pos
 172           "r3k2r/Pppp1ppp/1b3nbN/nP6/BBP1P3/q4N2/Pp1P2PP/R2Q1RK1 w kq -")))
 173     (should (equal (chess-perft position 3) '(9467 1021 4 0 120 38 22)))))
 174
 175 (ert-deftest chess-perft-pos4-depth4 ()
 176   :tags '(:capture :castle :promotion :check :checkmate)
 177   (let ((chess-ply-allow-interactive-query nil)
 178         (position
 179          (chess-fen-to-pos
 180           "r3k2r/Pppp1ppp/1b3nbN/nP6/BBP1P3/q4N2/Pp1P2PP/R2Q1RK1 w kq -")))
 181     (should (equal (chess-perft position 4) '(422333 131393 0 7795 60032 15492 5)))))
 182
 183 (provide 'chess-perft)
 184 ;;; chess-perft.el ends here