code.delx.au - gnu-emacs-elpa/blob - packages/hydra/hydra.el

   1 ;;; hydra.el --- Make bindings that stick around. -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; Maintainer: Oleh Krehel <ohwoeowho@gmail.com>
   7 ;; URL: https://github.com/abo-abo/hydra
   8 ;; Version: 0.12.1
   9 ;; Keywords: bindings
  10 ;; Package-Requires: ((cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This package can be used to tie related commands into a family of
  30 ;; short bindings with a common prefix - a Hydra.
  31 ;;
  32 ;; Once you summon the Hydra (through the prefixed binding), all the
  33 ;; heads can be called in succession with only a short extension.
  34 ;; The Hydra is vanquished once Hercules, any binding that isn't the
  35 ;; Hydra's head, arrives.  Note that Hercules, besides vanquishing the
  36 ;; Hydra, will still serve his orignal purpose, calling his proper
  37 ;; command.  This makes the Hydra very seamless, it's like a minor
  38 ;; mode that disables itself automagically.
  39 ;;
  40 ;; Here's an example Hydra, bound in the global map (you can use any
  41 ;; keymap in place of `global-map'):
  42 ;;
  43 ;;     (defhydra hydra-zoom (global-map "<f2>")
  44 ;;       "zoom"
  45 ;;       ("g" text-scale-increase "in")
  46 ;;       ("l" text-scale-decrease "out"))
  47 ;;
  48 ;; It allows to start a command chain either like this:
  49 ;; "<f2> gg4ll5g", or "<f2> lgllg".
  50 ;;
  51 ;; Here's another approach, when you just want a "callable keymap":
  52 ;;
  53 ;;     (defhydra hydra-toggle (:color blue)
  54 ;;       "toggle"
  55 ;;       ("a" abbrev-mode "abbrev")
  56 ;;       ("d" toggle-debug-on-error "debug")
  57 ;;       ("f" auto-fill-mode "fill")
  58 ;;       ("t" toggle-truncate-lines "truncate")
  59 ;;       ("w" whitespace-mode "whitespace")
  60 ;;       ("q" nil "cancel"))
  61 ;;
  62 ;; This binds nothing so far, but if you follow up with:
  63 ;;
  64 ;;     (global-set-key (kbd "C-c C-v") 'hydra-toggle/body)
  65 ;;
  66 ;; you will have bound "C-c C-v a", "C-c C-v d" etc.
  67 ;;
  68 ;; Knowing that `defhydra' defines e.g. `hydra-toggle/body' command,
  69 ;; you can nest Hydras if you wish, with `hydra-toggle/body' possibly
  70 ;; becoming a blue head of another Hydra.
  71 ;;
  72 ;; Initially, Hydra shipped with a simplified `hydra-create' macro, to
  73 ;; which you could hook up the examples from hydra-examples.el.  It's
  74 ;; better to take the examples simply as templates and use `defhydra'
  75 ;; instead of `hydra-create', since it's more flexible.
  76
  77 ;;; Code:
  78 ;;* Requires
  79 (require 'cl-lib)
  80 (require 'lv)
  81
  82 (defalias 'hydra-set-transient-map
  83     (if (fboundp 'set-transient-map)
  84         'set-transient-map
  85       (lambda (map _keep-pred &optional on-exit)
  86         (with-no-warnings
  87           (set-temporary-overlay-map map (hydra--pred on-exit))))))
  88
  89 (defun hydra--pred (on-exit)
  90   "Generate a predicate on whether to continue the Hydra state.
  91 Call ON-EXIT for clean-up.
  92 This is a compatibility code for Emacs older than 24.4."
  93   `(lambda ()
  94      (if (lookup-key hydra-curr-map (this-command-keys-vector))
  95          t
  96        (hydra-cleanup)
  97        ,(when on-exit
  98               `(funcall ,(hydra--make-callable on-exit)))
  99        nil)))
 100
 101 ;;* Customize
 102 (defgroup hydra nil
 103   "Make bindings that stick around."
 104   :group 'bindings
 105   :prefix "hydra-")
 106
 107 (defcustom hydra-is-helpful t
 108   "When t, display a hint with possible bindings in the echo area."
 109   :type 'boolean
 110   :group 'hydra)
 111
 112 (defcustom hydra-keyboard-quit "\a"
 113   "This binding will quit an amaranth Hydra.
 114 It's the only other way to quit it besides though a blue head.
 115 It's possible to set this to nil.")
 116
 117 (defcustom hydra-lv t
 118   "When non-nil, `lv-message' (not `message') will be used to display hints."
 119   :type 'boolean)
 120
 121 (defcustom hydra-verbose nil
 122   "When non-nil, hydra will issue some non essential style warnings."
 123   :type 'boolean)
 124
 125 (defcustom hydra-key-format-spec "%s"
 126   "Default `format'-style specifier for _a_  syntax in docstrings.
 127 When nil, you can specify your own at each location like this: _ 5a_.")
 128
 129 (defface hydra-face-red
 130     '((t (:foreground "#FF0000" :bold t)))
 131   "Red Hydra heads will persist indefinitely."
 132   :group 'hydra)
 133
 134 (defface hydra-face-blue
 135     '((t (:foreground "#0000FF" :bold t)))
 136   "Blue Hydra heads will vanquish the Hydra.")
 137
 138 (defface hydra-face-amaranth
 139     '((t (:foreground "#E52B50" :bold t)))
 140   "Amaranth body has red heads and warns on intercepting non-heads.
 141 Vanquishable only through a blue head.")
 142
 143 (defface hydra-face-pink
 144     '((t (:foreground "#FF6EB4" :bold t)))
 145   "Pink body has red heads and on intercepting non-heads calls them without quitting.
 146 Vanquishable only through a blue head.")
 147
 148 (defface hydra-face-teal
 149     '((t (:foreground "#367588" :bold t)))
 150   "Teal body has blue heads an warns on intercepting non-heads.
 151 Vanquishable only through a blue head.")
 152
 153 ;;* Fontification
 154 (defun hydra-add-font-lock ()
 155   "Fontify `defhydra' statements."
 156   (font-lock-add-keywords
 157    'emacs-lisp-mode
 158    '(("(\\(defhydra\\)\\_> +\\(.*?\\)\\_>"
 159       (1 font-lock-keyword-face)
 160       (2 font-lock-type-face))
 161      ("(\\(defhydradio\\)\\_> +\\(.*?\\)\\_>"
 162       (1 font-lock-keyword-face)
 163       (2 font-lock-type-face)))))
 164
 165 ;;* Universal Argument
 166 (defvar hydra-base-map
 167   (let ((map (make-sparse-keymap)))
 168     (define-key map [?\C-u] 'hydra--universal-argument)
 169     (define-key map [?-] 'hydra--negative-argument)
 170     (define-key map [?0] 'hydra--digit-argument)
 171     (define-key map [?1] 'hydra--digit-argument)
 172     (define-key map [?2] 'hydra--digit-argument)
 173     (define-key map [?3] 'hydra--digit-argument)
 174     (define-key map [?4] 'hydra--digit-argument)
 175     (define-key map [?5] 'hydra--digit-argument)
 176     (define-key map [?6] 'hydra--digit-argument)
 177     (define-key map [?7] 'hydra--digit-argument)
 178     (define-key map [?8] 'hydra--digit-argument)
 179     (define-key map [?9] 'hydra--digit-argument)
 180     (define-key map [kp-0] 'hydra--digit-argument)
 181     (define-key map [kp-1] 'hydra--digit-argument)
 182     (define-key map [kp-2] 'hydra--digit-argument)
 183     (define-key map [kp-3] 'hydra--digit-argument)
 184     (define-key map [kp-4] 'hydra--digit-argument)
 185     (define-key map [kp-5] 'hydra--digit-argument)
 186     (define-key map [kp-6] 'hydra--digit-argument)
 187     (define-key map [kp-7] 'hydra--digit-argument)
 188     (define-key map [kp-8] 'hydra--digit-argument)
 189     (define-key map [kp-9] 'hydra--digit-argument)
 190     (define-key map [kp-subtract] 'hydra--negative-argument)
 191     (define-key map [switch-frame] 'hydra--handle-switch-frame)
 192     map)
 193   "Keymap that all Hydras inherit.  See `universal-argument-map'.")
 194
 195 (defvar hydra-curr-map
 196   (make-sparse-keymap)
 197   "Keymap of the current Hydra called.")
 198
 199 (defun hydra--handle-switch-frame (evt)
 200   "Quit hydra and call old switch-frame event handler for EVT."
 201   (interactive "e")
 202   (hydra-keyboard-quit)
 203   (funcall (lookup-key (current-global-map) [switch-frame]) evt))
 204
 205 (defun hydra--universal-argument (arg)
 206   "Forward to (`universal-argument' ARG)."
 207   (interactive "P")
 208   (setq prefix-arg (if (consp arg)
 209                        (list (* 4 (car arg)))
 210                      (if (eq arg '-)
 211                          (list -4)
 212                        '(4))))
 213   (hydra-set-transient-map hydra-curr-map t))
 214
 215 (defun hydra--digit-argument (arg)
 216   "Forward to (`digit-argument' ARG)."
 217   (interactive "P")
 218   (let ((universal-argument-map hydra-curr-map))
 219     (digit-argument arg)))
 220
 221 (defun hydra--negative-argument (arg)
 222   "Forward to (`negative-argument' ARG)."
 223   (interactive "P")
 224   (let ((universal-argument-map hydra-curr-map))
 225     (negative-argument arg)))
 226 ;;* Repeat
 227 (defvar hydra-repeat--prefix-arg nil
 228   "Prefix arg to use with `hydra-repeat'.")
 229
 230 (defvar hydra-repeat--command nil
 231   "Command to use with `hydra-repeat'.")
 232
 233 (defun hydra-repeat (&optional arg)
 234   "Repeat last command with last prefix arg.
 235 When ARG is non-nil, use that instead."
 236   (interactive "p")
 237   (if (eq arg 1)
 238       (unless (string-match "hydra-repeat$" (symbol-name last-command))
 239         (setq hydra-repeat--command last-command)
 240         (setq hydra-repeat--prefix-arg last-prefix-arg))
 241     (setq hydra-repeat--prefix-arg arg))
 242   (setq current-prefix-arg hydra-repeat--prefix-arg)
 243   (funcall hydra-repeat--command))
 244
 245 ;;* Misc internals
 246 (defvar hydra-last nil
 247   "The result of the last `hydra-set-transient-map' call.")
 248
 249 (defun hydra--callablep (x)
 250   "Test if X is callable."
 251   (or (functionp x)
 252       (and (consp x)
 253            (memq (car x) '(function quote)))))
 254
 255 (defun hydra--make-callable (x)
 256   "Generate a callable symbol from X.
 257 If X is a function symbol or a lambda, return it.  Otherwise, it
 258 should be a single statement.  Wrap it in an interactive lambda."
 259   (if (or (symbolp x) (functionp x))
 260       x
 261     `(lambda ()
 262        (interactive)
 263        ,x)))
 264
 265 (defun hydra-plist-get-default (plist prop default)
 266   "Extract a value from a property list.
 267 PLIST is a property list, which is a list of the form
 268 \(PROP1 VALUE1 PROP2 VALUE2...).
 269
 270 Return the value corresponding to PROP, or DEFAULT if PROP is not
 271 one of the properties on the list."
 272   (if (memq prop plist)
 273       (plist-get plist prop)
 274     default))
 275
 276 (defun hydra--head-property (h prop &optional default)
 277   "Return for Hydra head H the value of property PROP.
 278 Return DEFAULT if PROP is not in H."
 279   (hydra-plist-get-default (cl-cdddr h) prop default))
 280
 281 (defun hydra--aggregate-color (head-color body-color)
 282   "Return the resulting head color for HEAD-COLOR and BODY-COLOR."
 283   (cond ((eq head-color 'red)
 284          (cl-case body-color
 285            (red 'red)
 286            (blue 'red)
 287            (amaranth 'amaranth)
 288            (pink 'pink)
 289            (cyan 'amaranth)))
 290         ((eq head-color 'blue)
 291          (cl-case body-color
 292            (red 'blue)
 293            (blue 'blue)
 294            (amaranth 'teal)
 295            (pink 'blue)
 296            (cyan 'teal)))
 297         (t
 298          (error "Can't aggregate head %S to body %S"
 299                 head-color body-color))))
 300
 301 (defun hydra--head-color (h body)
 302   "Return the color of a Hydra head H with BODY."
 303   (let* ((exit (hydra--head-property h :exit 'default))
 304          (color (hydra--head-property h :color))
 305          (foreign-keys (hydra--body-foreign-keys body))
 306          (head-color
 307           (cond ((eq exit 'default)
 308                  (cl-case color
 309                    (blue 'blue)
 310                    (red 'red)
 311                    (t
 312                     (unless (null color)
 313                       (error "Use only :blue or :red for heads: %S" h)))))
 314                 ((null exit)
 315                  (if color
 316                      (error "Don't mix :color and :exit - they are aliases: %S" h)
 317                    (cl-case foreign-keys
 318                      (run 'pink)
 319                      (warn 'amaranth)
 320                      (t 'red))))
 321                 ((eq exit t)
 322                  (if color
 323                      (error "Don't mix :color and :exit - they are aliases: %S" h)
 324                    'blue))
 325                 (t
 326                  (error "Unknown :exit %S" exit)))))
 327     (cond ((null (cadr h))
 328            (when head-color
 329              (hydra--complain
 330               "Doubly specified blue head - nil cmd is already blue: %S" h))
 331            'blue)
 332           ((null head-color)
 333            (hydra--body-color body))
 334           ((null foreign-keys)
 335            head-color)
 336           ((eq foreign-keys 'run)
 337            (if (eq head-color 'red)
 338                'pink
 339              'blue))
 340           ((eq foreign-keys 'warn)
 341            (if (memq head-color '(red amaranth))
 342                'amaranth
 343              'teal))
 344           (t
 345            (error "Unexpected %S %S" h body)))))
 346
 347 (defun hydra--body-foreign-keys (body)
 348   "Return what BODY does with a non-head binding."
 349   (or
 350    (plist-get (cddr body) :foreign-keys)
 351    (let ((color (plist-get (cddr body) :color)))
 352      (cl-case color
 353        ((amaranth teal) 'warn)
 354        (pink 'run)))))
 355
 356 (defun hydra--body-color (body)
 357   "Return the color of BODY.
 358 BODY is the second argument to `defhydra'"
 359   (let ((color (plist-get (cddr body) :color))
 360         (exit (plist-get (cddr body) :exit))
 361         (foreign-keys (plist-get (cddr body) :foreign-keys)))
 362     (cond ((eq foreign-keys 'warn)
 363            (if exit 'teal 'amaranth))
 364           ((eq foreign-keys 'run) 'pink)
 365           (exit 'blue)
 366           (color color)
 367           (t 'red))))
 368
 369 (defun hydra--face (h body)
 370   "Return the face for a Hydra head H with BODY."
 371   (cl-case (hydra--head-color h body)
 372     (blue 'hydra-face-blue)
 373     (red 'hydra-face-red)
 374     (amaranth 'hydra-face-amaranth)
 375     (pink 'hydra-face-pink)
 376     (teal 'hydra-face-teal)
 377     (t (error "Unknown color for %S" h))))
 378
 379 (defvar hydra--input-method-function nil
 380   "Store overridden `input-method-function' here.")
 381
 382 (defun hydra-default-pre ()
 383   "Default setup that happens in each head before :pre."
 384   (when (eq input-method-function 'key-chord-input-method)
 385     (unless hydra--input-method-function
 386       (setq hydra--input-method-function input-method-function)
 387       (setq input-method-function nil))))
 388
 389 (defun hydra-cleanup ()
 390   "Clean up after a Hydra."
 391   (when hydra--input-method-function
 392     (setq input-method-function hydra--input-method-function)
 393     (setq hydra--input-method-function nil))
 394   (when (window-live-p lv-wnd)
 395     (let ((buf (window-buffer lv-wnd)))
 396       (delete-window lv-wnd)
 397       (kill-buffer buf))))
 398
 399 (defvar hydra-timer (timer-create)
 400   "Timer for `hydra-timeout'.")
 401
 402 (defun hydra-keyboard-quit ()
 403   "Quitting function similar to `keyboard-quit'."
 404   (interactive)
 405   (hydra-disable)
 406   (hydra-cleanup)
 407   (cancel-timer hydra-timer)
 408   (unless hydra-lv
 409     (message ""))
 410   nil)
 411
 412 (defun hydra-disable ()
 413   "Disable the current Hydra."
 414   (cond
 415     ;; Emacs 25
 416     ((functionp hydra-last)
 417      (funcall hydra-last))
 418
 419     ;; Emacs 24.3 or older
 420     ((< emacs-minor-version 4)
 421      (setq emulation-mode-map-alists
 422            (cl-remove-if
 423             (lambda (x)
 424               (and (consp x)
 425                    (consp (car x))
 426                    (equal (cdar x) hydra-curr-map)))
 427             emulation-mode-map-alists)))
 428
 429     ;; Emacs 24.4.1
 430     (t
 431      (setq overriding-terminal-local-map nil))))
 432
 433 (defun hydra--unalias-var (str prefix)
 434   "Return the symbol named STR if it's bound as a variable.
 435 Otherwise, add PREFIX to the symbol name."
 436   (let ((sym (intern-soft str)))
 437     (if (boundp sym)
 438         sym
 439       (intern (concat prefix "/" str)))))
 440
 441 (defun hydra--hint (body heads)
 442   "Generate a hint for the echo area.
 443 BODY, and HEADS are parameters to `defhydra'."
 444   (let (alist)
 445     (dolist (h heads)
 446       (let ((val (assoc (cadr h) alist))
 447             (pstr (hydra-fontify-head h body)))
 448         (unless (null (cl-caddr h))
 449           (if val
 450               (setf (cadr val)
 451                     (concat (cadr val) " " pstr))
 452             (push
 453              (cons (cadr h)
 454                    (cons pstr (cl-caddr h)))
 455              alist)))))
 456     (mapconcat
 457      (lambda (x)
 458        (format
 459         (if (> (length (cdr x)) 0)
 460             (concat "[%s]: " (cdr x))
 461           "%s")
 462         (car x)))
 463      (nreverse (mapcar #'cdr alist))
 464      ", ")))
 465
 466 (defvar hydra-fontify-head-function nil
 467   "Possible replacement for `hydra-fontify-head-default'.")
 468
 469 (defun hydra-fontify-head-default (head body)
 470   "Produce a pretty string from HEAD and BODY.
 471 HEAD's binding is returned as a string with a colored face."
 472   (propertize (car head) 'face (hydra--face head body)))
 473
 474 (defun hydra-fontify-head-greyscale (head body)
 475   "Produce a pretty string from HEAD and BODY.
 476 HEAD's binding is returned as a string wrapped with [] or {}."
 477   (let ((color (hydra--head-color head body)))
 478     (format
 479      (if (eq color 'blue)
 480          "[%s]"
 481        "{%s}") (car head))))
 482
 483 (defun hydra-fontify-head (head body)
 484   "Produce a pretty string from HEAD and BODY."
 485   (funcall (or hydra-fontify-head-function 'hydra-fontify-head-default)
 486            head body))
 487
 488 (defun hydra--format (_name body docstring heads)
 489   "Generate a `format' statement from STR.
 490 \"%`...\" expressions are extracted into \"%S\".
 491 _NAME, BODY, DOCSTRING and HEADS are parameters of `defhydra'.
 492 The expressions can be auto-expanded according to NAME."
 493   (setq docstring (replace-regexp-in-string "\\^" "" docstring))
 494   (let ((rest (hydra--hint body heads))
 495         (start 0)
 496         varlist
 497         offset)
 498     (while (setq start
 499                  (string-match
 500                   "\\(?:%\\( ?-?[0-9]*s?\\)\\(`[a-z-A-Z/0-9]+\\|(\\)\\)\\|\\(?:_\\( ?-?[0-9]*\\)\\([a-z-A-Z~.,;:0-9/|?<>={}]+\\)_\\)"
 501                   docstring start))
 502       (cond ((eq ?_ (aref (match-string 0 docstring) 0))
 503              (let* ((key (match-string 4 docstring))
 504                     (head (assoc key heads)))
 505                (if head
 506                    (progn
 507                      (push (hydra-fontify-head head body) varlist)
 508                      (setq docstring
 509                            (replace-match
 510                             (or
 511                              hydra-key-format-spec
 512                              (concat "%" (match-string 3 docstring) "s"))
 513                             t nil docstring)))
 514                  (error "Unrecognized key: _%s_" key))))
 515
 516             (t
 517              (let* ((varp (if (eq ?` (aref (match-string 2 docstring) 0)) 1 0))
 518                     (spec (match-string 1 docstring))
 519                     (lspec (length spec)))
 520                (setq offset
 521                      (with-temp-buffer
 522                        (insert (substring docstring (+ 1 start varp
 523                                                        (length spec))))
 524                        (goto-char (point-min))
 525                        (push (read (current-buffer)) varlist)
 526                        (- (point) (point-min))))
 527                (when (or (zerop lspec)
 528                          (/= (aref spec (1- (length spec))) ?s))
 529                  (setq spec (concat spec "S")))
 530                (setq docstring
 531                      (concat
 532                       (substring docstring 0 start)
 533                       "%" spec
 534                       (substring docstring (+ start offset 1 lspec varp))))))))
 535     (if (eq ?\n (aref docstring 0))
 536         `(concat (format ,(substring docstring 1) ,@(nreverse varlist))
 537                  ,rest)
 538       `(format ,(concat docstring ": " rest ".")))))
 539
 540 (defun hydra--message (name body docstring heads)
 541   "Generate code to display the hint in the preferred echo area.
 542 Set `hydra-lv' to choose the echo area.
 543 NAME, BODY, DOCSTRING, and HEADS are parameters of `defhydra'."
 544   (let ((format-expr (hydra--format name body docstring heads)))
 545     `(if hydra-lv
 546          (lv-message ,format-expr)
 547        (message ,format-expr))))
 548
 549 (defun hydra--complain (format-string &rest args)
 550   "Forward to (`message' FORMAT-STRING ARGS) unless `hydra-verbose' is nil."
 551   (when hydra-verbose
 552     (apply #'warn format-string args)))
 553
 554 (defun hydra--doc (body-key body-name heads)
 555   "Generate a part of Hydra docstring.
 556 BODY-KEY is the body key binding.
 557 BODY-NAME is the symbol that identifies the Hydra.
 558 HEADS is a list of heads."
 559   (format
 560    "Create a hydra with %s body and the heads:\n\n%s\n\n%s"
 561    (if body-key
 562        (format "a \"%s\"" body-key)
 563      "no")
 564    (mapconcat
 565     (lambda (x)
 566       (format "\"%s\":    `%S'" (car x) (cadr x)))
 567     heads ",\n")
 568    (format "The body can be accessed via `%S'." body-name)))
 569
 570 (defun hydra--make-defun (name body doc head
 571                           keymap body-pre body-post &optional other-post)
 572   "Make a defun wrapper, using NAME, BODY, DOC, HEAD, and KEYMAP.
 573 NAME and BODY are the arguments to `defhydra'.
 574 DOC was generated with `hydra--doc'.
 575 HEAD is one of the HEADS passed to `defhydra'.
 576 BODY-PRE and BODY-POST are pre-processed in `defhydra'.
 577 OTHER-POST is an optional extension to the :post key of BODY."
 578   (let ((name (hydra--head-name head name body))
 579         (cmd (when (car head)
 580                (hydra--make-callable
 581                 (cadr head))))
 582         (color (when (car head)
 583                  (hydra--head-color head body)))
 584         (doc (if (car head)
 585                  (format "%s\n\nCall the head: `%S'." doc (cadr head))
 586                doc))
 587         (hint (intern (format "%S/hint" name)))
 588         (body-color (hydra--body-color body))
 589         (body-timeout (plist-get body :timeout)))
 590     `(defun ,name ()
 591        ,doc
 592        (interactive)
 593        (hydra-default-pre)
 594        ,@(when body-pre (list body-pre))
 595        (hydra-disable)
 596        ,@(when (memq color '(blue teal)) '((hydra-cleanup)))
 597        (catch 'hydra-disable
 598          ,@(delq nil
 599                  (if (memq color '(blue teal))
 600                      `(,(when cmd `(call-interactively #',cmd))
 601                         ,body-post)
 602                    `(,(when cmd
 603                             `(condition-case err
 604                                  (prog1 t
 605                                    (call-interactively #',cmd))
 606                                ((quit error)
 607                                 (message "%S" err)
 608                                 (unless hydra-lv
 609                                   (sit-for 0.8))
 610                                 nil)))
 611                       (when hydra-is-helpful
 612                         (,hint))
 613                       (setq hydra-last
 614                             (hydra-set-transient-map
 615                              (setq hydra-curr-map ',keymap)
 616                              t
 617                              ,(if (and
 618                                    (not (memq body-color
 619                                               '(amaranth pink teal)))
 620                                    body-post)
 621                                   `(lambda () (hydra-cleanup) ,body-post)
 622                                   `(lambda () (hydra-cleanup)))))
 623                       ,(or other-post
 624                            (when body-timeout
 625                              (list 'hydra-timeout
 626                                    body-timeout
 627                                    (when body-post
 628                                      (hydra--make-callable body-post))))))))))))
 629
 630 (defun hydra-pink-fallback ()
 631   "On intercepting a non-head, try to run it."
 632   (let ((keys (this-command-keys))
 633         kb)
 634     (when (equal keys [backspace])
 635       (setq keys "\7f"))
 636     (setq kb (key-binding keys))
 637     (if kb
 638         (if (commandp kb)
 639             (condition-case err
 640                 (call-interactively kb)
 641               ((quit error)
 642                (message "%S" err)
 643                (unless hydra-lv
 644                  (sit-for 0.8))))
 645           (message "Pink Hydra can't currently handle prefixes, continuing"))
 646       (message "Pink Hydra could not resolve: %S" keys))))
 647
 648 (defun hydra--modify-keymap (keymap def)
 649   "In KEYMAP, add DEF to each sub-keymap."
 650   (cl-labels
 651       ((recur (map)
 652          (if (atom map)
 653              map
 654            (if (eq (car map) 'keymap)
 655                (cons 'keymap
 656                      (cons
 657                       def
 658                       (recur (cdr map))))
 659              (cons
 660               (recur (car map))
 661               (recur (cdr map)))))))
 662     (recur keymap)))
 663
 664 (defmacro hydra--make-funcall (sym)
 665   "Transform SYM into a `funcall' that calls it."
 666   `(when (and ,sym (symbolp ,sym))
 667      (setq ,sym `(funcall #',,sym))))
 668
 669 (defun hydra--handle-nonhead (keymap name body heads)
 670   "Setup KEYMAP for intercepting non-head bindings.
 671 NAME, BODY and HEADS are parameters to `defhydra'."
 672   (let ((body-color (hydra--body-color body))
 673         (body-post (plist-get (cddr body) :post)))
 674     (if body-post
 675         (hydra--make-funcall body-post)
 676       (when hydra-keyboard-quit
 677         (define-key keymap hydra-keyboard-quit #'hydra-keyboard-quit)))
 678     (when (memq body-color '(amaranth pink teal))
 679       (if (cl-some (lambda (h)
 680                      (memq (hydra--head-color h body) '(blue teal)))
 681                    heads)
 682           (progn
 683             (setcdr
 684              keymap
 685              (cdr
 686               (hydra--modify-keymap
 687                keymap
 688                (cons t
 689                      `(lambda ()
 690                         (interactive)
 691                         ,(cond
 692                           ((memq body-color '(amaranth teal))
 693                            '(message "An amaranth Hydra can only exit through a blue head"))
 694                           (t
 695                            '(hydra-pink-fallback)))
 696                         (hydra-set-transient-map hydra-curr-map t)
 697                         (when hydra-is-helpful
 698                           (unless hydra-lv
 699                             (sit-for 0.8))
 700                           (,(intern (format "%S/hint" name))))))))))
 701         (unless (eq body-color 'teal)
 702           (error
 703            "An %S Hydra must have at least one blue head in order to exit"
 704            body-color))))))
 705
 706 (defun hydra--head-name (h name body)
 707   "Return the symbol for head H of hydra with NAME and BODY."
 708   (let ((str (format "%S/%s" name
 709                      (if (symbolp (cadr h))
 710                          (cadr h)
 711                        (concat "lambda-" (car h))))))
 712     (when (and (memq (hydra--head-color h body) '(blue teal))
 713                (not (memq (cadr h) '(body nil))))
 714       (setq str (concat str "-and-exit")))
 715     (intern str)))
 716
 717 (defun hydra--delete-duplicates (heads)
 718   "Return HEADS without entries that have the same CMD part.
 719 In duplicate HEADS, :cmd-name is modified to whatever they duplicate."
 720   (let ((ali '(((hydra-repeat . red) . hydra-repeat)))
 721         res entry)
 722     (dolist (h heads)
 723       (if (setq entry (assoc (cons (cadr h)
 724                                    (hydra--head-color h '(nil nil)))
 725                              ali))
 726           (setf (cl-cdddr h) (plist-put (cl-cdddr h) :cmd-name (cdr entry)))
 727         (push (cons (cons (cadr h)
 728                           (hydra--head-color h '(nil nil)))
 729                     (plist-get (cl-cdddr h) :cmd-name))
 730               ali)
 731         (push h res)))
 732     (nreverse res)))
 733
 734 (defun hydra--pad (lst n)
 735   "Pad LST with nil until length N."
 736   (let ((len (length lst)))
 737     (if (= len n)
 738         lst
 739       (append lst (make-list (- n len) nil)))))
 740
 741 (defmacro hydra-multipop (lst n)
 742   "Return LST's first N elements while removing them."
 743   `(if (<= (length ,lst) ,n)
 744        (prog1 ,lst
 745          (setq ,lst nil))
 746      (prog1 ,lst
 747        (setcdr
 748         (nthcdr (1- ,n) (prog1 ,lst (setq ,lst (nthcdr ,n ,lst))))
 749         nil))))
 750
 751 (defun hydra--matrix (lst rows cols)
 752   "Create a matrix from elements of LST.
 753 The matrix size is ROWS times COLS."
 754   (let ((ls (copy-sequence lst))
 755         res)
 756     (dotimes (_c cols)
 757       (push (hydra--pad (hydra-multipop ls rows) rows) res))
 758     (nreverse res)))
 759
 760 (defun hydra--cell (fstr names)
 761   "Format a rectangular cell based on FSTR and NAMES.
 762 FSTR is a format-style string with two string inputs: one for the
 763 doc and one for the symbol name.
 764 NAMES is a list of variables."
 765   (let ((len (cl-reduce
 766               (lambda (acc it) (max (length (symbol-name it)) acc))
 767               names
 768               :initial-value 0)))
 769     (mapconcat
 770      (lambda (sym)
 771        (if sym
 772            (format fstr
 773                    (documentation-property sym 'variable-documentation)
 774                    (let ((name (symbol-name sym)))
 775                      (concat name (make-string (- len (length name)) ?^)))
 776                    sym)
 777          ""))
 778      names
 779      "\n")))
 780
 781 (defun hydra--vconcat (strs &optional joiner)
 782   "Glue STRS vertically.  They must be the same height.
 783 JOINER is a function similar to `concat'."
 784   (setq joiner (or joiner #'concat))
 785   (mapconcat
 786    (lambda (s)
 787      (if (string-match " +$" s)
 788          (replace-match "" nil nil s)
 789        s))
 790    (apply #'cl-mapcar joiner
 791           (mapcar
 792            (lambda (s) (split-string s "\n"))
 793            strs))
 794    "\n"))
 795
 796 (defcustom hydra-cell-format "% -20s %% -8`%s"
 797   "The default format for docstring cells."
 798   :type 'string)
 799
 800 (defun hydra--table (names rows cols &optional cell-formats)
 801   "Format a `format'-style table from variables in NAMES.
 802 The size of the table is ROWS times COLS.
 803 CELL-FORMATS are `format' strings for each column.
 804 If CELL-FORMATS is a string, it's used for all columns.
 805 If CELL-FORMATS is nil, `hydra-cell-format' is used for all columns."
 806   (setq cell-formats
 807         (cond ((null cell-formats)
 808                (make-list cols hydra-cell-format))
 809               ((stringp cell-formats)
 810                (make-list cols cell-formats))
 811               (t
 812                cell-formats)))
 813   (hydra--vconcat
 814    (cl-mapcar
 815     #'hydra--cell
 816     cell-formats
 817     (hydra--matrix names rows cols))
 818    (lambda (&rest x)
 819      (mapconcat #'identity x "    "))))
 820
 821 (defun hydra-reset-radios (names)
 822   "Set varibles NAMES to their defaults.
 823 NAMES should be defined by `defhydradio' or similar."
 824   (dolist (n names)
 825     (set n (aref (get n 'range) 0))))
 826
 827 (defun hydra-timeout (secs &optional function)
 828   "In SECS seconds call FUNCTION, then function `hydra-keyboard-quit'.
 829 Cancel the previous `hydra-timeout'."
 830   (cancel-timer hydra-timer)
 831   (setq hydra-timer (timer-create))
 832   (timer-set-time hydra-timer
 833                   (timer-relative-time (current-time) secs))
 834   (timer-set-function
 835    hydra-timer
 836    `(lambda ()
 837       ,(when function
 838              `(funcall ,function))
 839       (hydra-keyboard-quit)))
 840   (timer-activate hydra-timer))
 841
 842 ;;* Macros
 843 ;;;###autoload
 844 (defmacro defhydra (name body &optional docstring &rest heads)
 845   "Create a Hydra - a family of functions with prefix NAME.
 846
 847 NAME should be a symbol, it will be the prefix of all functions
 848 defined here.
 849
 850 BODY has the format:
 851
 852     (BODY-MAP BODY-KEY &rest BODY-PLIST)
 853
 854 DOCSTRING will be displayed in the echo area to identify the
 855 Hydra.  When DOCSTRING starts with a newline, special Ruby-style
 856 substitution will be performed by `hydra--format'.
 857
 858 Functions are created on basis of HEADS, each of which has the
 859 format:
 860
 861     (KEY CMD &optional HINT &rest PLIST)
 862
 863 BODY-MAP is a keymap; `global-map' is used quite often.  Each
 864 function generated from HEADS will be bound in BODY-MAP to
 865 BODY-KEY + KEY (both are strings passed to `kbd'), and will set
 866 the transient map so that all following heads can be called
 867 though KEY only. BODY-KEY can be an empty string.
 868
 869 CMD is a callable expression: either an interactive function
 870 name, or an interactive lambda, or a single sexp (it will be
 871 wrapped in an interactive lambda).
 872
 873 HINT is a short string that identifies its head.  It will be
 874 printed beside KEY in the echo erea if `hydra-is-helpful' is not
 875 nil.  If you don't even want the KEY to be printed, set HINT
 876 explicitly to nil.
 877
 878 The heads inherit their PLIST from BODY-PLIST and are allowed to
 879 override some keys.  The keys recognized are :exit and :bind.
 880 :exit can be:
 881
 882 - nil (default): this head will continue the Hydra state.
 883 - t: this head will stop the Hydra state.
 884
 885 :bind can be:
 886 - nil: this head will not be bound in BODY-MAP.
 887 - a lambda taking KEY and CMD used to bind a head.
 888
 889 It is possible to omit both BODY-MAP and BODY-KEY if you don't
 890 want to bind anything.  In that case, typically you will bind the
 891 generated NAME/body command.  This command is also the return
 892 result of `defhydra'."
 893   (declare (indent defun))
 894   (cond ((stringp docstring))
 895         ((and (consp docstring)
 896               (memq (car docstring) '(hydra--table concat format)))
 897          (setq docstring (concat "\n" (eval docstring))))
 898         (t
 899          (setq heads (cons docstring heads))
 900          (setq docstring "hydra")))
 901   (when (keywordp (car body))
 902     (setq body (cons nil (cons nil body))))
 903   (let* ((keymap (copy-keymap hydra-base-map))
 904          (body-name (intern (format "%S/body" name)))
 905          (body-key (cadr body))
 906          (body-plist (cddr body))
 907          (body-map (or (car body)
 908                        (plist-get body-plist :bind)))
 909          (body-pre (plist-get body-plist :pre))
 910          (body-body-pre (plist-get body-plist :body-pre))
 911          (body-post (plist-get body-plist :post)))
 912     (hydra--make-funcall body-post)
 913     (when body-post
 914       (setq heads (cons (list hydra-keyboard-quit #'hydra-keyboard-quit nil :exit t)
 915                         heads)))
 916     (dolist (h heads)
 917       (let ((len (length h)))
 918         (cond ((< len 2)
 919                (error "Each head should have at least two items: %S" h))
 920               ((= len 2)
 921                (setcdr (cdr h)
 922                        (list
 923                         (hydra-plist-get-default body-plist :hint "")))
 924                (setcdr (nthcdr 2 h)
 925                        (list :cmd-name (hydra--head-name h name body))))
 926               (t
 927                (let ((hint (cl-caddr h)))
 928                  (unless (or (null hint)
 929                              (stringp hint))
 930                    (setcdr (cdr h) (cons
 931                                     (hydra-plist-get-default body-plist :hint "")
 932                                     (cddr h))))
 933                  (setcdr (cddr h)
 934                          `(:cmd-name
 935                            ,(hydra--head-name h name body)
 936                            ,@(cl-cdddr h))))))))
 937     (let ((doc (hydra--doc body-key body-name heads))
 938           (heads-nodup (hydra--delete-duplicates heads)))
 939       (mapc
 940        (lambda (x)
 941          (define-key keymap (kbd (car x))
 942            (plist-get (cl-cdddr x) :cmd-name)))
 943        heads)
 944       (hydra--make-funcall body-pre)
 945       (hydra--make-funcall body-body-pre)
 946       (hydra--handle-nonhead keymap name body heads)
 947       `(progn
 948          ;; create defuns
 949          ,@(mapcar
 950             (lambda (head)
 951               (hydra--make-defun name body doc head keymap
 952                                  body-pre body-post))
 953             heads-nodup)
 954          ;; free up keymap prefix
 955          ,@(unless (or (null body-key)
 956                        (null body-map)
 957                        (hydra--callablep body-map))
 958                    `((unless (keymapp (lookup-key ,body-map (kbd ,body-key)))
 959                        (define-key ,body-map (kbd ,body-key) nil))))
 960          ;; bind keys
 961          ,@(delq nil
 962                  (mapcar
 963                   (lambda (head)
 964                     (let ((name (hydra--head-property head :cmd-name)))
 965                       (when (and (cadr head)
 966                                  (not (eq (cadr head) 'hydra-keyboard-quit))
 967                                  (or body-key body-map))
 968                         (let ((bind (hydra--head-property head :bind body-map))
 969                               (final-key
 970                                (if body-key
 971                                    (vconcat (kbd body-key) (kbd (car head)))
 972                                  (kbd (car head)))))
 973                           (cond ((null bind) nil)
 974                                 ((hydra--callablep bind)
 975                                  `(funcall ,bind ,final-key (function ,name)))
 976                                 ((and (symbolp bind)
 977                                       (if (boundp bind)
 978                                           (keymapp (symbol-value bind))
 979                                         t))
 980                                  `(define-key ,bind ,final-key (function ,name)))
 981                                 (t
 982                                  (error "Invalid :bind property `%S' for head %S" bind  head)))))))
 983                   heads))
 984          (defun ,(intern (format "%S/hint" name)) ()
 985            ,(hydra--message name body docstring heads))
 986          ,(hydra--make-defun
 987            name body doc '(nil body)
 988            keymap
 989            (or body-body-pre body-pre) body-post
 990            '(setq prefix-arg current-prefix-arg))))))
 991
 992 (defmacro defhydradio (name _body &rest heads)
 993   "Create radios with prefix NAME.
 994 _BODY specifies the options; there are none currently.
 995 HEADS have the format:
 996
 997     (TOGGLE-NAME &optional VALUE DOC)
 998
 999 TOGGLE-NAME will be used along with NAME to generate a variable
1000 name and a function that cycles it with the same name.  VALUE
1001 should be an array.  The first element of VALUE will be used to
1002 inialize the variable.
1003 VALUE defaults to [nil t].
1004 DOC defaults to TOGGLE-NAME split and capitalized."
1005   (declare (indent defun))
1006   `(progn
1007      ,@(apply #'append
1008               (mapcar (lambda (h)
1009                         (hydra--radio name h))
1010                       heads))
1011      (defvar ,(intern (format "%S/names" name))
1012        ',(mapcar (lambda (h) (intern (format "%S/%S" name (car h))))
1013                  heads))))
1014
1015 (defun hydra--radio (parent head)
1016   "Generate a hydradio with PARENT from HEAD."
1017   (let* ((name (car head))
1018          (full-name (intern (format "%S/%S" parent name)))
1019          (doc (cadr head))
1020          (val (or (cl-caddr head) [nil t])))
1021     `((defvar ,full-name ,(hydra--quote-maybe (aref val 0)) ,doc)
1022       (put ',full-name 'range ,val)
1023       (defun ,full-name ()
1024         (hydra--cycle-radio ',full-name)))))
1025
1026 (defun hydra--quote-maybe (x)
1027   "Quote X if it's a symbol."
1028   (cond ((null x)
1029          nil)
1030         ((symbolp x)
1031          (list 'quote x))
1032         (t
1033          x)))
1034
1035 (defun hydra--cycle-radio (sym)
1036   "Set SYM to the next value in its range."
1037   (let* ((val (symbol-value sym))
1038          (range (get sym 'range))
1039          (i 0)
1040          (l (length range)))
1041     (setq i (catch 'done
1042               (while (< i l)
1043                 (if (equal (aref range i) val)
1044                     (throw 'done (1+ i))
1045                   (cl-incf i)))
1046               (error "Val not in range for %S" sym)))
1047     (set sym
1048          (aref range
1049                (if (>= i l)
1050                    0
1051                  i)))))
1052
1053 (provide 'hydra)
1054
1055 ;;; Local Variables:
1056 ;;; outline-regexp: ";;\\*+"
1057 ;;; End:
1058
1059 ;;; hydra.el ends here