code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (defface swiper-line-face
  65   '((t (:inherit highlight)))
  66   "Face for current `swiper' line.")
  67
  68 (defcustom swiper-faces '(swiper-match-face-1
  69                           swiper-match-face-2
  70                           swiper-match-face-3
  71                           swiper-match-face-4)
  72   "List of `swiper' faces for group matches."
  73   :group 'ivy-faces
  74   :type 'list)
  75
  76 (defcustom swiper-min-highlight 2
  77   "Only highlight matches for regexps at least this long."
  78   :type 'integer)
  79
  80 (defvar swiper-map
  81   (let ((map (make-sparse-keymap)))
  82     (define-key map (kbd "M-q") 'swiper-query-replace)
  83     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  84     (define-key map (kbd "C-'") 'swiper-avy)
  85     (define-key map (kbd "C-7") 'swiper-mc)
  86     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  87     map)
  88   "Keymap for swiper.")
  89
  90 (defun swiper-query-replace ()
  91   "Start `query-replace' with string to replace from last search string."
  92   (interactive)
  93   (if (null (window-minibuffer-p))
  94       (user-error "Should only be called in the minibuffer through `swiper-map'")
  95     (let* ((enable-recursive-minibuffers t)
  96            (from (ivy--regex ivy-text))
  97            (to (query-replace-read-to from "Query replace" t)))
  98       (swiper--cleanup)
  99       (ivy-exit-with-action
 100        (lambda (_)
 101          (with-ivy-window
 102            (move-beginning-of-line 1)
 103            (perform-replace from to
 104                             t t nil)))))))
 105
 106 (defvar avy-background)
 107 (defvar avy-all-windows)
 108 (defvar avy-style)
 109 (defvar avy-keys)
 110 (declare-function avy--regex-candidates "ext:avy")
 111 (declare-function avy--process "ext:avy")
 112 (declare-function avy--overlay-post "ext:avy")
 113 (declare-function avy-action-goto "ext:avy")
 114 (declare-function avy--done "ext:avy")
 115 (declare-function avy--make-backgrounds "ext:avy")
 116 (declare-function avy-window-list "ext:avy")
 117 (declare-function avy-read "ext:avy")
 118 (declare-function avy-read-de-bruijn "ext:avy")
 119 (declare-function avy-tree "ext:avy")
 120 (declare-function avy-push-mark "ext:avy")
 121 (declare-function avy--remove-leading-chars "ext:avy")
 122
 123 ;;;###autoload
 124 (defun swiper-avy ()
 125   "Jump to one of the current swiper candidates."
 126   (interactive)
 127   (unless (string= ivy-text "")
 128     (let* ((avy-all-windows nil)
 129            (candidates (append
 130                         (with-ivy-window
 131                           (avy--regex-candidates
 132                            (ivy--regex ivy-text)))
 133                         (save-excursion
 134                           (save-restriction
 135                             (narrow-to-region (window-start) (window-end))
 136                             (goto-char (point-min))
 137                             (forward-line)
 138                             (let ((cands))
 139                               (while (< (point) (point-max))
 140                                 (push (cons (1+ (point))
 141                                             (selected-window))
 142                                       cands)
 143                                 (forward-line))
 144                               cands)))))
 145            (candidate (unwind-protect
 146                            (prog2
 147                                (avy--make-backgrounds
 148                                 (append (avy-window-list)
 149                                         (list (ivy-state-window ivy-last))))
 150                                (if (eq avy-style 'de-bruijn)
 151                                    (avy-read-de-bruijn
 152                                     candidates avy-keys)
 153                                  (avy-read (avy-tree candidates avy-keys)
 154                                            #'avy--overlay-post
 155                                            #'avy--remove-leading-chars))
 156                              (avy-push-mark))
 157                         (avy--done))))
 158       (if (window-minibuffer-p (cdr candidate))
 159           (progn
 160             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 161             (ivy--exhibit)
 162             (ivy-done)
 163             (ivy-call))
 164         (ivy-quit-and-run
 165          (avy-action-goto (caar candidate)))))))
 166
 167 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 168 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 169
 170 ;;;###autoload
 171 (defun swiper-mc ()
 172   (interactive)
 173   (unless (require 'multiple-cursors nil t)
 174     (error "multiple-cursors isn't installed"))
 175   (let ((cands (nreverse ivy--old-cands)))
 176     (unless (string= ivy-text "")
 177       (ivy-exit-with-action
 178        (lambda (_)
 179          (let (cand)
 180            (while (setq cand (pop cands))
 181              (swiper--action cand)
 182              (when cands
 183                (mc/create-fake-cursor-at-point))))
 184          (multiple-cursors-mode 1))))))
 185
 186 (defun swiper-recenter-top-bottom (&optional arg)
 187   "Call (`recenter-top-bottom' ARG)."
 188   (interactive "P")
 189   (with-ivy-window
 190     (recenter-top-bottom arg)))
 191
 192 (defvar swiper-font-lock-exclude
 193   '(package-menu-mode
 194     gnus-summary-mode
 195     gnus-article-mode
 196     gnus-group-mode
 197     emms-playlist-mode
 198     emms-stream-mode
 199     erc-mode
 200     org-agenda-mode
 201     dired-mode
 202     jabber-chat-mode
 203     elfeed-search-mode
 204     elfeed-show-mode
 205     fundamental-mode
 206     Man-mode
 207     woman-mode
 208     mu4e-view-mode
 209     mu4e-headers-mode
 210     help-mode
 211     debbugs-gnu-mode
 212     occur-mode
 213     occur-edit-mode
 214     bongo-mode
 215     bongo-library-mode
 216     bongo-playlist-mode
 217     eww-mode
 218     twittering-mode
 219     vc-dir-mode
 220     rcirc-mode
 221     sauron-mode
 222     w3m-mode)
 223   "List of major-modes that are incompatible with font-lock-ensure.")
 224
 225 (defun swiper-font-lock-ensure-p ()
 226   "Return non-nil if we should font-lock-ensure."
 227   (or (derived-mode-p 'magit-mode)
 228               (bound-and-true-p magit-blame-mode)
 229               (memq major-mode swiper-font-lock-exclude)))
 230
 231 (defun swiper-font-lock-ensure ()
 232   "Ensure the entired buffer is highlighted."
 233   (unless (swiper-font-lock-ensure-p)
 234     (unless (or (> (buffer-size) 100000) (null font-lock-mode))
 235       (if (fboundp 'font-lock-ensure)
 236           (font-lock-ensure)
 237         (with-no-warnings (font-lock-fontify-buffer))))))
 238
 239 (defvar swiper--format-spec ""
 240   "Store the current candidates format spec.")
 241
 242 (defvar swiper--width nil
 243   "Store the number of digits needed for the longest line nubmer.")
 244
 245 (defvar swiper-use-visual-line nil
 246   "When non-nil, use `line-move' instead of `forward-line'.")
 247
 248 (declare-function outline-show-all "outline")
 249
 250 (defun swiper--candidates (&optional numbers-width)
 251   "Return a list of this buffer lines.
 252
 253 NUMBERS-WIDTH, when specified, is used for width spec of line
 254 numbers; replaces calculating the width from buffer line count."
 255   (if (and visual-line-mode
 256            ;; super-slow otherwise
 257            (< (buffer-size) 20000))
 258       (progn
 259         (when (eq major-mode 'org-mode)
 260           (require 'outline)
 261           (if (fboundp 'outline-show-all)
 262               (outline-show-all)
 263             (with-no-warnings
 264               (show-all))))
 265         (setq swiper-use-visual-line t))
 266     (setq swiper-use-visual-line nil))
 267   (let ((n-lines (count-lines (point-min) (point-max))))
 268     (unless (zerop n-lines)
 269       (setq swiper--width (or numbers-width
 270                               (1+ (floor (log n-lines 10)))))
 271       (setq swiper--format-spec
 272             (format "%%-%dd " swiper--width))
 273       (let ((line-number 0)
 274             (advancer (if swiper-use-visual-line
 275                           (lambda (arg) (line-move arg t))
 276                         #'forward-line))
 277             candidates)
 278         (save-excursion
 279           (goto-char (point-min))
 280           (swiper-font-lock-ensure)
 281           (while (< (point) (point-max))
 282             (let ((str (concat
 283                         " "
 284                         (replace-regexp-in-string
 285                          "\t" "    "
 286                          (if swiper-use-visual-line
 287                              (buffer-substring
 288                               (save-excursion
 289                                 (beginning-of-visual-line)
 290                                 (point))
 291                               (save-excursion
 292                                 (end-of-visual-line)
 293                                 (point)))
 294                            (buffer-substring
 295                             (point)
 296                             (line-end-position)))))))
 297               (when (eq major-mode 'twittering-mode)
 298                 (remove-text-properties 0 (length str) '(field) str))
 299               (put-text-property 0 1 'display
 300                                  (format swiper--format-spec
 301                                          (cl-incf line-number))
 302                                  str)
 303               (push str candidates))
 304             (funcall advancer 1))
 305           (nreverse candidates))))))
 306
 307 (defvar swiper--opoint 1
 308   "The point when `swiper' starts.")
 309
 310 ;;;###autoload
 311 (defun swiper (&optional initial-input)
 312   "`isearch' with an overview.
 313 When non-nil, INITIAL-INPUT is the initial search pattern."
 314   (interactive)
 315   (swiper--ivy (swiper--candidates) initial-input))
 316
 317 (declare-function string-trim-right "subr-x")
 318
 319 (defun swiper-occur (&optional revert)
 320   "Generate a custom occur buffer for `swiper'.
 321 When REVERT is non-nil, regenerate the current *ivy-occur* buffer."
 322   (let* ((buffer (ivy-state-buffer ivy-last))
 323          (fname (propertize
 324                  (with-ivy-window
 325                    (if (buffer-file-name buffer)
 326                        (file-name-nondirectory
 327                         (buffer-file-name buffer))
 328                      (buffer-name buffer)))
 329                  'face
 330                  'compilation-info))
 331          (cands (mapcar
 332                  (lambda (s)
 333                    (format "%s:%s:%s"
 334                            fname
 335                            (propertize
 336                             (string-trim-right
 337                              (get-text-property 0 'display s))
 338                             'face 'compilation-line-number)
 339                            (substring s 1)))
 340                  (if (null revert)
 341                      ivy--old-cands
 342                    (setq ivy--old-re nil)
 343                    (let ((ivy--regex-function 'swiper--re-builder))
 344                      (ivy--filter
 345                       (progn (string-match "\"\\(.*\\)\"" (buffer-name))
 346                              (match-string 1 (buffer-name)))
 347                       (with-current-buffer buffer
 348                         (swiper--candidates))))))))
 349     (unless (eq major-mode 'ivy-occur-grep-mode)
 350       (ivy-occur-grep-mode)
 351       (font-lock-mode -1))
 352     (insert (format "-*- mode:grep; default-directory: %S -*-\n\n\n"
 353                     default-directory))
 354     (insert (format "%d candidates:\n" (length cands)))
 355     (ivy--occur-insert-lines
 356      (mapcar
 357       (lambda (cand) (concat "./" cand))
 358       cands))
 359     (goto-char (point-min))
 360     (forward-line 4)))
 361
 362 (ivy-set-occur 'swiper 'swiper-occur)
 363
 364 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 365
 366 (defvar swiper--current-line nil)
 367 (defvar swiper--current-match-start nil)
 368
 369 (defun swiper--init ()
 370   "Perform initialization common to both completion methods."
 371   (setq swiper--current-line nil)
 372   (setq swiper--current-match-start nil)
 373   (setq swiper--opoint (point))
 374   (when (bound-and-true-p evil-jumper-mode)
 375     (evil-jumper--set-jump)))
 376
 377 (defun swiper--re-builder (str)
 378   "Transform STR into a swiper regex.
 379 This is the regex used in the minibuffer where candidates have
 380 line numbers. For the buffer, use `ivy--regex' instead."
 381   (replace-regexp-in-string
 382    "\t" "    "
 383    (cond
 384      ((equal str "")
 385       "")
 386      ((equal str "^")
 387       (setq ivy--subexps 0)
 388       ".")
 389      ((string-match "^\\^" str)
 390       (setq ivy--old-re "")
 391       (let ((re (ivy--regex-plus (substring str 1))))
 392         (if (zerop ivy--subexps)
 393             (prog1 (format "^ ?\\(%s\\)" re)
 394               (setq ivy--subexps 1))
 395           (format "^ %s" re))))
 396      (t
 397       (ivy--regex-plus str)))))
 398
 399 (defvar swiper-history nil
 400   "History for `swiper'.")
 401
 402 (defvar swiper-invocation-face nil
 403   "The face at the point of invocation of `swiper'.")
 404
 405 (defun swiper--ivy (candidates &optional initial-input)
 406   "Select one of CANDIDATES and move there.
 407 When non-nil, INITIAL-INPUT is the initial search pattern."
 408   (interactive)
 409   (swiper--init)
 410   (setq swiper-invocation-face
 411         (plist-get (text-properties-at (point)) 'face))
 412   (let ((preselect
 413          (if swiper-use-visual-line
 414              (count-screen-lines
 415               (point-min)
 416               (save-excursion (beginning-of-visual-line) (point)))
 417            (1- (line-number-at-pos))))
 418         (minibuffer-allow-text-properties t)
 419         res)
 420     (unwind-protect
 421          (and
 422           (setq res
 423                 (ivy-read
 424                  "Swiper: "
 425                  candidates
 426                  :initial-input initial-input
 427                  :keymap swiper-map
 428                  :preselect preselect
 429                  :require-match t
 430                  :update-fn #'swiper--update-input-ivy
 431                  :unwind #'swiper--cleanup
 432                  :action #'swiper--action
 433                  :re-builder #'swiper--re-builder
 434                  :history 'swiper-history
 435                  :caller 'swiper))
 436           (point))
 437       (unless res
 438         (goto-char swiper--opoint)))))
 439
 440 (defun swiper-toggle-face-matching ()
 441   "Toggle matching only the candidates with `swiper-invocation-face'."
 442   (interactive)
 443   (setf (ivy-state-matcher ivy-last)
 444         (if (ivy-state-matcher ivy-last)
 445             nil
 446           #'swiper--face-matcher))
 447   (setq ivy--old-re nil))
 448
 449 (defun swiper--face-matcher (regexp candidates)
 450   "Return REGEXP-matching CANDIDATES.
 451 Matched candidates should have `swiper-invocation-face'."
 452   (cl-remove-if-not
 453    (lambda (x)
 454      (and
 455       (string-match regexp x)
 456       (let ((s (match-string 0 x))
 457             (i 0))
 458         (while (and (< i (length s))
 459                     (text-property-any
 460                      i (1+ i)
 461                      'face swiper-invocation-face
 462                      s))
 463           (cl-incf i))
 464         (eq i (length s)))))
 465    candidates))
 466
 467 (defun swiper--ensure-visible ()
 468   "Remove overlays hiding point."
 469   (let ((overlays (overlays-at (1- (point))))
 470         ov expose)
 471     (while (setq ov (pop overlays))
 472       (if (and (invisible-p (overlay-get ov 'invisible))
 473                (setq expose (overlay-get ov 'isearch-open-invisible)))
 474           (funcall expose ov)))))
 475
 476 (defvar swiper--overlays nil
 477   "Store overlays.")
 478
 479 (defun swiper--cleanup ()
 480   "Clean up the overlays."
 481   (while swiper--overlays
 482     (delete-overlay (pop swiper--overlays)))
 483   (save-excursion
 484     (goto-char (point-min))
 485     (isearch-clean-overlays)))
 486
 487 (defun swiper--update-input-ivy ()
 488   "Called when `ivy' input is updated."
 489   (with-ivy-window
 490     (swiper--cleanup)
 491     (when (> (length ivy--current) 0)
 492       (let* ((re (replace-regexp-in-string
 493                   "    " "\t"
 494                   (funcall ivy--regex-function ivy-text)))
 495              (re (if (stringp re) re (caar re)))
 496              (str (get-text-property 0 'display ivy--current))
 497              (num (if (string-match "^[0-9]+" str)
 498                       (string-to-number (match-string 0 str))
 499                     0)))
 500         (unless (eq this-command 'ivy-yank-word)
 501           (when (cl-plusp num)
 502             (unless (if swiper--current-line
 503                         (eq swiper--current-line num)
 504                       (eq (line-number-at-pos) num))
 505               (goto-char (point-min))
 506               (if swiper-use-visual-line
 507                   (line-move (1- num))
 508                 (forward-line (1- num))))
 509             (if (and (equal ivy-text "")
 510                      (>= swiper--opoint (line-beginning-position))
 511                      (<= swiper--opoint (line-end-position)))
 512                 (goto-char swiper--opoint)
 513               (if (eq swiper--current-line num)
 514                   (when swiper--current-match-start
 515                     (goto-char swiper--current-match-start))
 516                 (setq swiper--current-line num))
 517               (when (re-search-forward re (line-end-position) t)
 518                 (setq swiper--current-match-start (match-beginning 0))))
 519             (isearch-range-invisible (line-beginning-position)
 520                                      (line-end-position))
 521             (unless (and (>= (point) (window-start))
 522                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 523               (recenter))))
 524         (swiper--add-overlays re)))))
 525
 526 (defun swiper--add-overlays (re &optional beg end wnd)
 527   "Add overlays for RE regexp in visible part of the current buffer.
 528 BEG and END, when specified, are the point bounds.
 529 WND, when specified is the window."
 530   (setq wnd (or wnd (ivy-state-window ivy-last)))
 531   (let ((ov (if visual-line-mode
 532                 (make-overlay
 533                  (save-excursion
 534                    (beginning-of-visual-line)
 535                    (point))
 536                  (save-excursion
 537                    (end-of-visual-line)
 538                    (point)))
 539               (make-overlay
 540                (line-beginning-position)
 541                (1+ (line-end-position))))))
 542     (overlay-put ov 'face 'swiper-line-face)
 543     (overlay-put ov 'window wnd)
 544     (push ov swiper--overlays)
 545     (let* ((wh (window-height))
 546            (beg (or beg (save-excursion
 547                           (forward-line (- wh))
 548                           (point))))
 549            (end (or end (save-excursion
 550                           (forward-line wh)
 551                           (point)))))
 552       (when (>= (length re) swiper-min-highlight)
 553         (save-excursion
 554           (goto-char beg)
 555           ;; RE can become an invalid regexp
 556           (while (and (ignore-errors (re-search-forward re end t))
 557                       (> (- (match-end 0) (match-beginning 0)) 0))
 558             (let ((i 0))
 559               (while (<= i ivy--subexps)
 560                 (when (match-beginning i)
 561                   (let ((overlay (make-overlay (match-beginning i)
 562                                                (match-end i)))
 563                         (face
 564                          (cond ((zerop ivy--subexps)
 565                                 (cadr swiper-faces))
 566                                ((zerop i)
 567                                 (car swiper-faces))
 568                                (t
 569                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 570                                      swiper-faces)))))
 571                     (push overlay swiper--overlays)
 572                     (overlay-put overlay 'face face)
 573                     (overlay-put overlay 'window wnd)
 574                     (overlay-put overlay 'priority i)))
 575                 (cl-incf i)))))))))
 576
 577 (defun swiper--action (x)
 578   "Goto line X."
 579   (let ((ln (1- (read (or (get-text-property 0 'display x)
 580                           (and (string-match ":\\([0-9]+\\):.*\\'" x)
 581                                (match-string-no-properties 1 x))))))
 582         (re (ivy--regex ivy-text)))
 583     (if (null x)
 584         (user-error "No candidates")
 585       (with-ivy-window
 586         (unless (equal (current-buffer)
 587                        (ivy-state-buffer ivy-last))
 588           (switch-to-buffer (ivy-state-buffer ivy-last)))
 589         (goto-char (point-min))
 590         (funcall (if swiper-use-visual-line
 591                      #'line-move
 592                    #'forward-line)
 593                  ln)
 594         (re-search-forward re (line-end-position) t)
 595         (swiper--ensure-visible)
 596         (when (/= (point) swiper--opoint)
 597           (unless (and transient-mark-mode mark-active)
 598             (when (eq ivy-exit 'done)
 599               (push-mark swiper--opoint t)
 600               (message "Mark saved where search started"))))
 601         (add-to-history
 602          'regexp-search-ring
 603          re
 604          regexp-search-ring-max)))))
 605
 606 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 607 (defun swiper-from-isearch ()
 608   "Invoke `swiper' from isearch."
 609   (interactive)
 610   (let ((query (if isearch-regexp
 611                    isearch-string
 612                  (regexp-quote isearch-string))))
 613     (isearch-exit)
 614     (swiper query)))
 615
 616 (defvar swiper-multi-buffers nil
 617   "Store the current list of buffers.")
 618
 619 (defvar swiper-multi-candidates nil
 620   "Store the list of candidates for `swiper-multi'.")
 621
 622 (defun swiper-multi-prompt ()
 623   (format "Buffers (%s): "
 624           (mapconcat #'identity swiper-multi-buffers ", ")))
 625
 626 (defun swiper-multi ()
 627   "Select one or more buffers.
 628 Run `swiper' for those buffers."
 629   (interactive)
 630   (setq swiper-multi-buffers nil)
 631   (ivy-read (swiper-multi-prompt)
 632             'internal-complete-buffer
 633             :action 'swiper-multi-action-1)
 634   (ivy-read "Swiper: " swiper-multi-candidates
 635             :action 'swiper-multi-action-2
 636             :unwind #'swiper--cleanup
 637             :caller 'swiper-multi))
 638
 639 (defun swiper-all ()
 640   "Run `swiper' for all opened buffers."
 641   (interactive)
 642   (ivy-read "Swiper: " (swiper--multi-candidates
 643                         (cl-remove-if-not
 644                          #'buffer-file-name
 645                          (buffer-list)))
 646             :action 'swiper-multi-action-2
 647             :unwind #'swiper--cleanup
 648             :update-fn (lambda ()
 649                          (swiper-multi-action-2 ivy--current))
 650             :caller 'swiper-multi))
 651
 652 (defun swiper--multi-candidates (buffers)
 653   (let* ((ww (window-width))
 654          (res nil)
 655          (column-2 (apply #'max
 656                           (mapcar
 657                            (lambda (b)
 658                              (length (buffer-name b)))
 659                            buffers)))
 660          (column-1 (- ww 4 column-2 1)))
 661     (dolist (buf buffers)
 662       (with-current-buffer buf
 663         (setq res
 664               (append
 665                (mapcar
 666                 (lambda (s)
 667                   (setq s (concat (ivy--truncate-string s column-1) " "))
 668                   (let ((len (length s)))
 669                     (put-text-property
 670                      (1- len) len 'display
 671                      (concat
 672                       (make-string
 673                        (- ww (string-width s) (length (buffer-name)) 3)
 674                        ?\ )
 675                       (buffer-name))
 676                      s)
 677                     s))
 678                 (swiper--candidates 4))
 679                res))
 680         nil))
 681     res))
 682
 683 (defun swiper-multi-action-1 (x)
 684   (if (member x swiper-multi-buffers)
 685       (progn
 686         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 687     (unless (equal x "")
 688       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 689   (let ((prompt (swiper-multi-prompt)))
 690     (setf (ivy-state-prompt ivy-last) prompt)
 691     (setq ivy--prompt (concat "%-4d " prompt)))
 692   (cond ((memq this-command '(ivy-done
 693                               ivy-alt-done
 694                               ivy-immediate-done))
 695          (setq swiper-multi-candidates
 696                (swiper--multi-candidates
 697                 (mapcar #'get-buffer swiper-multi-buffers))))
 698         ((eq this-command 'ivy-call)
 699          (delete-minibuffer-contents))))
 700
 701 (defun swiper-multi-action-2 (x)
 702   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 703     (with-ivy-window
 704       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 705         (switch-to-buffer (match-string 1 buf-space))
 706         (goto-char (point-min))
 707         (forward-line (1- (read (get-text-property 0 'display x))))
 708         (re-search-forward
 709          (ivy--regex ivy-text)
 710          (line-end-position) t)
 711         (unless (eq ivy-exit 'done)
 712           (swiper--cleanup)
 713           (swiper--add-overlays (ivy--regex ivy-text)))))))
 714
 715 (provide 'swiper)
 716
 717 ;;; swiper.el ends here