code.delx.au - gnu-emacs-elpa/blob - context-coloring.el

   1 ;;; context-coloring.el --- Highlight by scope  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2014-2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Jackson Ray Hamilton <jackson@jacksonrayhamilton.com>
   6 ;; Version: 6.3.0
   7 ;; Keywords: convenience faces tools
   8 ;; Package-Requires: ((emacs "24") (js2-mode "20150126"))
   9 ;; URL: https://github.com/jacksonrayhamilton/context-coloring
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This program is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Highlights code by scope.  Top-level scopes are one color, second-level
  29 ;; scopes are another color, and so on.  Variables retain the color of the scope
  30 ;; in which they are defined.  A variable defined in an outer scope referenced
  31 ;; by an inner scope is colored the same as the outer scope.
  32
  33 ;; By default, comments and strings are still highlighted syntactically.
  34
  35 ;;; Code:
  36
  37 (require 'js2-mode)
  38
  39
  40 ;;; Utilities
  41
  42 (defun context-coloring-join (strings delimiter)
  43   "Join a list of STRINGS with the string DELIMITER."
  44   (mapconcat 'identity strings delimiter))
  45
  46 (defsubst context-coloring-trim-right (string)
  47   "Remove leading whitespace from STRING."
  48   (if (string-match "[ \t\n\r]+\\'" string)
  49       (replace-match "" t t string)
  50     string))
  51
  52 (defsubst context-coloring-trim-left (string)
  53   "Remove trailing whitespace from STRING."
  54   (if (string-match "\\`[ \t\n\r]+" string)
  55       (replace-match "" t t string)
  56     string))
  57
  58 (defsubst context-coloring-trim (string)
  59   "Remove leading and trailing whitespace from STRING."
  60   (context-coloring-trim-left (context-coloring-trim-right string)))
  61
  62
  63 ;;; Faces
  64
  65 (defun context-coloring-defface (level tty light dark)
  66   "Define a face for LEVEL with colors for TTY, LIGHT and DARK
  67 backgrounds."
  68   (let ((face (intern (format "context-coloring-level-%s-face" level)))
  69         (doc (format "Context coloring face, level %s." level)))
  70     (custom-declare-face
  71      face
  72      `((((type tty)) (:foreground ,tty))
  73        (((background light)) (:foreground ,light))
  74        (((background dark)) (:foreground ,dark)))
  75      doc
  76      :group 'context-coloring)))
  77
  78 (defun context-coloring-defface-neutral (level)
  79   "Define a face for LEVEL with the default neutral colors."
  80   (context-coloring-defface level nil "#3f3f3f" "#cdcdcd"))
  81
  82 (context-coloring-defface 0 nil       "#000000" "#ffffff")
  83 (context-coloring-defface 1 "yellow"  "#008b8b" "#00ffff")
  84 (context-coloring-defface 2 "green"   "#0000ff" "#87cefa")
  85 (context-coloring-defface 3 "cyan"    "#483d8b" "#b0c4de")
  86 (context-coloring-defface 4 "blue"    "#a020f0" "#eedd82")
  87 (context-coloring-defface 5 "magenta" "#a0522d" "#98fb98")
  88 (context-coloring-defface 6 "red"     "#228b22" "#7fffd4")
  89 (context-coloring-defface-neutral 7)
  90
  91 (defvar context-coloring-maximum-face nil
  92   "Index of the highest face available for coloring.")
  93
  94 (defvar context-coloring-original-maximum-face nil
  95   "Fallback value for `context-coloring-maximum-face' when all
  96   themes have been disabled.")
  97
  98 (setq context-coloring-maximum-face 7)
  99
 100 (setq context-coloring-original-maximum-face
 101       context-coloring-maximum-face)
 102
 103 ;; Theme authors can have up to 26 levels: 1 (0th) for globals, 24 (1st-24th)
 104 ;; for nested levels, and 1 (25th) for infinity.
 105 (dotimes (number 18)
 106   (context-coloring-defface-neutral (+ number context-coloring-maximum-face 1)))
 107
 108
 109 ;;; Face functions
 110
 111 (defsubst context-coloring-level-face (level)
 112   "Return the symbol for a face with LEVEL."
 113   ;; `concat' is faster than `format' here.
 114   (intern-soft
 115    (concat "context-coloring-level-" (number-to-string level) "-face")))
 116
 117 (defsubst context-coloring-bounded-level-face (level)
 118   "Return the symbol for a face with LEVEL, bounded by
 119 `context-coloring-maximum-face'."
 120   (context-coloring-level-face (min level context-coloring-maximum-face)))
 121
 122
 123 ;;; Colorization utilities
 124
 125 (defsubst context-coloring-colorize-region (start end level)
 126   "Color characters from the 1-indexed START point (inclusive) to
 127 the END point (exclusive) with the face corresponding to LEVEL."
 128   (add-text-properties
 129    start
 130    end
 131    `(face ,(context-coloring-bounded-level-face level))))
 132
 133 (make-obsolete-variable
 134  'context-coloring-comments-and-strings
 135  "use `context-coloring-syntactic-comments' and
 136  `context-coloring-syntactic-strings' instead."
 137  "6.1.0")
 138
 139 (defcustom context-coloring-syntactic-comments t
 140   "If non-nil, also color comments using `font-lock'."
 141   :group 'context-coloring)
 142
 143 (defcustom context-coloring-syntactic-strings t
 144   "If non-nil, also color strings using `font-lock'."
 145   :group 'context-coloring)
 146
 147 (defun context-coloring-font-lock-syntactic-comment-function (state)
 148   "Tell `font-lock' to color a comment but not a string."
 149   (if (nth 3 state) nil font-lock-comment-face))
 150
 151 (defun context-coloring-font-lock-syntactic-string-function (state)
 152   "Tell `font-lock' to color a string but not a comment."
 153   (if (nth 3 state) font-lock-string-face nil))
 154
 155 (defsubst context-coloring-maybe-colorize-comments-and-strings (&optional min max)
 156   "Color the current buffer's comments or strings if
 157 `context-coloring-syntactic-comments' or
 158 `context-coloring-syntactic-strings' are non-nil."
 159   (when (or context-coloring-syntactic-comments
 160             context-coloring-syntactic-strings)
 161     (let ((min (or min (point-min)))
 162           (max (or max (point-max)))
 163           (font-lock-syntactic-face-function
 164            (cond
 165             ((and context-coloring-syntactic-comments
 166                   (not context-coloring-syntactic-strings))
 167              'context-coloring-font-lock-syntactic-comment-function)
 168             ((and context-coloring-syntactic-strings
 169                   (not context-coloring-syntactic-comments))
 170              'context-coloring-font-lock-syntactic-string-function)
 171             (t
 172              font-lock-syntactic-face-function))))
 173       (save-excursion
 174         (font-lock-fontify-syntactically-region min max)
 175         ;; TODO: Make configurable at the dispatch level.
 176         (when (eq major-mode 'emacs-lisp-mode)
 177           (font-lock-fontify-keywords-region min max))))))
 178
 179
 180 ;;; js2-mode colorization
 181
 182 (defvar-local context-coloring-js2-scope-level-hash-table nil
 183   "Associate `js2-scope' structures and with their scope
 184   levels.")
 185
 186 (defcustom context-coloring-js-block-scopes nil
 187   "If non-nil, also color block scopes in the scope hierarchy in JavaScript.
 188
 189 The block-scoped `let' and `const' are introduced in ES6.  Enable
 190 this for ES6 code; disable it elsewhere.
 191
 192 Supported modes: `js2-mode'"
 193   :group 'context-coloring)
 194
 195 (defsubst context-coloring-js2-scope-level (scope)
 196   "Return the level of SCOPE."
 197   (cond ((gethash scope context-coloring-js2-scope-level-hash-table))
 198         (t
 199          (let ((level 0)
 200                (current-scope scope)
 201                enclosing-scope)
 202            (while (and current-scope
 203                        (js2-node-parent current-scope)
 204                        (setq enclosing-scope
 205                              (js2-node-get-enclosing-scope current-scope)))
 206              (when (or context-coloring-js-block-scopes
 207                        (let ((type (js2-scope-type current-scope)))
 208                          (or (= type js2-SCRIPT)
 209                              (= type js2-FUNCTION)
 210                              (= type js2-CATCH))))
 211                (setq level (+ level 1)))
 212              (setq current-scope enclosing-scope))
 213            (puthash scope level context-coloring-js2-scope-level-hash-table)))))
 214
 215 (defsubst context-coloring-js2-local-name-node-p (node)
 216   "Determine if NODE is a `js2-name-node' representing a local
 217 variable."
 218   (and (js2-name-node-p node)
 219        (let ((parent (js2-node-parent node)))
 220          (not (or (and (js2-object-prop-node-p parent)
 221                        (eq node (js2-object-prop-node-left parent)))
 222                   (and (js2-prop-get-node-p parent)
 223                        ;; For nested property lookup, the node on the left is a
 224                        ;; `js2-prop-get-node', so this always works.
 225                        (eq node (js2-prop-get-node-right parent))))))))
 226
 227 (defvar-local context-coloring-point-max nil
 228   "Cached value of `point-max'.")
 229
 230 (defsubst context-coloring-js2-colorize-node (node level)
 231   "Color NODE with the color for LEVEL."
 232   (let ((start (js2-node-abs-pos node)))
 233     (context-coloring-colorize-region
 234      start
 235      (min
 236       ;; End
 237       (+ start (js2-node-len node))
 238       ;; Somes nodes (like the ast when there is an unterminated multiline
 239       ;; comment) will stretch to the value of `point-max'.
 240       context-coloring-point-max)
 241      level)))
 242
 243 (defun context-coloring-js2-colorize ()
 244   "Color the current buffer using the abstract syntax tree
 245 generated by `js2-mode'."
 246   ;; Reset the hash table; the old one could be obsolete.
 247   (setq context-coloring-js2-scope-level-hash-table (make-hash-table :test 'eq))
 248   (setq context-coloring-point-max (point-max))
 249   (with-silent-modifications
 250     (js2-visit-ast
 251      js2-mode-ast
 252      (lambda (node end-p)
 253        (when (null end-p)
 254          (cond
 255           ((js2-scope-p node)
 256            (context-coloring-js2-colorize-node
 257             node
 258             (context-coloring-js2-scope-level node)))
 259           ((context-coloring-js2-local-name-node-p node)
 260            (let* ((enclosing-scope (js2-node-get-enclosing-scope node))
 261                   (defining-scope (js2-get-defining-scope
 262                                    enclosing-scope
 263                                    (js2-name-node-name node))))
 264              ;; The tree seems to be walked lexically, so an entire scope will
 265              ;; be colored, including its name nodes, before they are reached.
 266              ;; Coloring the nodes defined in that scope would be redundant, so
 267              ;; don't do it.
 268              (when (not (eq defining-scope enclosing-scope))
 269                (context-coloring-js2-colorize-node
 270                 node
 271                 (context-coloring-js2-scope-level defining-scope))))))
 272          ;; The `t' indicates to search children.
 273          t)))
 274     (context-coloring-maybe-colorize-comments-and-strings)))
 275
 276
 277 ;;; Emacs Lisp colorization
 278
 279 (defsubst context-coloring-forward-sws ()
 280   "Move forward through whitespace and comments."
 281   (while (forward-comment 1)))
 282
 283 (defsubst context-coloring-get-syntax-code ()
 284   (syntax-class (syntax-after (point))))
 285
 286 (defsubst context-coloring-exact-regexp (word)
 287   "Create a regexp that matches exactly WORD."
 288   (concat "\\`" (regexp-quote word) "\\'"))
 289
 290 (defsubst context-coloring-exact-or-regexp (words)
 291   "Create a regexp that matches any exact word in WORDS."
 292   (context-coloring-join
 293    (mapcar 'context-coloring-exact-regexp words) "\\|"))
 294
 295 (defconst context-coloring-elisp-defun-regexp
 296   (context-coloring-exact-or-regexp
 297    '("defun" "defun*" "defsubst" "defmacro"
 298      "cl-defun" "cl-defsubst" "cl-defmacro")))
 299
 300 (defconst context-coloring-elisp-lambda-regexp
 301   (context-coloring-exact-regexp "lambda"))
 302
 303 (defconst context-coloring-elisp-let-regexp
 304   (context-coloring-exact-regexp "let"))
 305
 306 (defconst context-coloring-elisp-let*-regexp
 307   (context-coloring-exact-regexp "let*"))
 308
 309 (defconst context-coloring-elisp-arglist-arg-regexp
 310   "\\`[^&:]")
 311
 312 (defconst context-coloring-ignored-word-regexp
 313   (context-coloring-join (list "\\`[-+]?[0-9]"
 314                                "\\`[&:].+"
 315                                (context-coloring-exact-or-regexp
 316                                 '("t" "nil" "." "?")))
 317                          "\\|"))
 318
 319 (defconst context-coloring-WORD-CODE 2)
 320 (defconst context-coloring-SYMBOL-CODE 3)
 321 (defconst context-coloring-OPEN-PARENTHESIS-CODE 4)
 322 (defconst context-coloring-CLOSE-PARENTHESIS-CODE 5)
 323 (defconst context-coloring-EXPRESSION-PREFIX-CODE 6)
 324 (defconst context-coloring-STRING-QUOTE-CODE 7)
 325 (defconst context-coloring-ESCAPE-CODE 9)
 326 (defconst context-coloring-COMMENT-START-CODE 11)
 327 (defconst context-coloring-COMMENT-END-CODE 12)
 328
 329 (defconst context-coloring-APOSTROPHE-CHAR (string-to-char "'"))
 330 (defconst context-coloring-OPEN-PARENTHESIS-CHAR (string-to-char "("))
 331 (defconst context-coloring-COMMA-CHAR (string-to-char ","))
 332 (defconst context-coloring-BACKTICK-CHAR (string-to-char "`"))
 333
 334 (defvar context-coloring-elisp-scope-stack '())
 335
 336 (defsubst context-coloring-elisp-make-scope (level)
 337   (list
 338    :level level
 339    :variables '()))
 340
 341 (defsubst context-coloring-elisp-scope-get-level (scope)
 342   (plist-get scope :level))
 343
 344 (defsubst context-coloring-elisp-scope-add-variable (scope variable)
 345   (plist-put scope :variables (cons variable (plist-get scope :variables))))
 346
 347 (defsubst context-coloring-elisp-scope-has-variable (scope variable)
 348   (member variable (plist-get scope :variables)))
 349
 350 (defsubst context-coloring-elisp-get-variable-level (variable)
 351   (let* ((scope-stack context-coloring-elisp-scope-stack)
 352          scope
 353          level)
 354     (while (and scope-stack (not level))
 355       (setq scope (car scope-stack))
 356       (cond
 357        ((context-coloring-elisp-scope-has-variable scope variable)
 358         (setq level (context-coloring-elisp-scope-get-level scope)))
 359        (t
 360         (setq scope-stack (cdr scope-stack)))))
 361     ;; Assume a global variable.
 362     (or level 0)))
 363
 364 (defsubst context-coloring-elisp-current-scope-level ()
 365   (cond
 366    ((car context-coloring-elisp-scope-stack)
 367     (context-coloring-elisp-scope-get-level (car context-coloring-elisp-scope-stack)))
 368    (t
 369     0)))
 370
 371 (defsubst context-coloring-elisp-push-scope ()
 372   (push (context-coloring-elisp-make-scope
 373          (1+ (context-coloring-elisp-current-scope-level)))
 374         context-coloring-elisp-scope-stack))
 375
 376 (defsubst context-coloring-elisp-pop-scope ()
 377   (pop context-coloring-elisp-scope-stack))
 378
 379 (defsubst context-coloring-elisp-add-variable (variable)
 380   (context-coloring-elisp-scope-add-variable
 381    (car context-coloring-elisp-scope-stack)
 382    variable))
 383
 384 (defun context-coloring-elisp-parse-arg (callback)
 385   (let (arg-pos
 386         arg-end
 387         arg-string)
 388     (setq arg-pos (point))
 389     (forward-sexp)
 390     (setq arg-end (point))
 391     (setq arg-string (buffer-substring-no-properties
 392                       arg-pos
 393                       arg-end))
 394     (when (string-match-p
 395            context-coloring-elisp-arglist-arg-regexp
 396            arg-string)
 397       (funcall callback arg-string))))
 398
 399 (defun context-coloring-elisp-parse-let-varlist (type)
 400   (let ((varlist '())
 401         syntax-code)
 402     ;; Enter.
 403     (forward-char)
 404     (while (/= (setq syntax-code (context-coloring-get-syntax-code))
 405                context-coloring-CLOSE-PARENTHESIS-CODE)
 406       (cond
 407        ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 408         (forward-char)
 409         (context-coloring-forward-sws)
 410         (setq syntax-code (context-coloring-get-syntax-code))
 411         (when (or (= syntax-code context-coloring-WORD-CODE)
 412                   (= syntax-code context-coloring-SYMBOL-CODE))
 413           (context-coloring-elisp-parse-arg
 414            (lambda (var)
 415              (push var varlist)))
 416           (context-coloring-forward-sws)
 417           (setq syntax-code (context-coloring-get-syntax-code))
 418           (when (/= syntax-code context-coloring-CLOSE-PARENTHESIS-CODE)
 419             (context-coloring-elisp-colorize-sexp)))
 420         (context-coloring-forward-sws)
 421         ;; Skip past the closing parenthesis.
 422         (forward-char))
 423        ((or (= syntax-code context-coloring-WORD-CODE)
 424             (= syntax-code context-coloring-SYMBOL-CODE))
 425         (context-coloring-elisp-parse-arg
 426          (lambda (var)
 427            (push var varlist)))))
 428       (when (eq type 'let*)
 429         (context-coloring-elisp-add-variable (pop varlist)))
 430       (context-coloring-forward-sws))
 431     (when (eq type 'let)
 432       (while varlist
 433         (context-coloring-elisp-add-variable (pop varlist))))
 434     ;; Exit.
 435     (forward-char)))
 436
 437 (defun context-coloring-elisp-parse-arglist ()
 438   (let (syntax-code)
 439     ;; Enter.
 440     (forward-char)
 441     (while (/= (setq syntax-code (context-coloring-get-syntax-code))
 442                context-coloring-CLOSE-PARENTHESIS-CODE)
 443       (cond
 444        ((or (= syntax-code context-coloring-WORD-CODE)
 445             (= syntax-code context-coloring-SYMBOL-CODE))
 446         (context-coloring-elisp-parse-arg
 447          (lambda (arg)
 448            (context-coloring-elisp-add-variable arg))))
 449        (t
 450         (forward-sexp)))
 451       (context-coloring-forward-sws))
 452     ;; Exit.
 453     (forward-char)))
 454
 455 (defun context-coloring-elisp-colorize-defun (&optional anonymous-p
 456                                                         let-type)
 457   (let ((start (point))
 458         end
 459         stop
 460         syntax-code
 461         defun-name-pos
 462         defun-name-end)
 463     (context-coloring-elisp-push-scope)
 464     ;; Color the whole sexp.
 465     (forward-sexp)
 466     (setq end (point))
 467     (context-coloring-colorize-region
 468      start
 469      end
 470      (context-coloring-elisp-current-scope-level))
 471     (goto-char start)
 472     ;; Skip past the "defun".
 473     (skip-syntax-forward "^w_")
 474     (forward-sexp)
 475     (context-coloring-forward-sws)
 476     (setq stop nil)
 477     (unless anonymous-p
 478       ;; Check for the defun's name.
 479       (setq syntax-code (context-coloring-get-syntax-code))
 480       (cond
 481        ((or (= syntax-code context-coloring-WORD-CODE)
 482             (= syntax-code context-coloring-SYMBOL-CODE))
 483         ;; Color the defun's name with the top-level color.
 484         (setq defun-name-pos (point))
 485         (forward-sexp)
 486         (setq defun-name-end (point))
 487         (context-coloring-colorize-region defun-name-pos defun-name-end 0)
 488         (context-coloring-forward-sws))
 489        (t
 490         (setq stop t))))
 491     (cond
 492      (stop
 493       ;; Skip it.
 494       (goto-char start)
 495       (forward-sexp))
 496      (t
 497       (setq syntax-code (context-coloring-get-syntax-code))
 498       (cond
 499        ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 500         (cond
 501          (let-type
 502           (context-coloring-elisp-parse-let-varlist let-type))
 503          (t
 504           (context-coloring-elisp-parse-arglist)))
 505         ;; Colorize the rest of the function.
 506         (context-coloring-elisp-colorize-region (point) (1- end))
 507         ;; Exit the defun.
 508         (forward-char))
 509        (t
 510         ;; Skip it.
 511         (goto-char start)
 512         (forward-sexp)))))
 513     (context-coloring-elisp-pop-scope)))
 514
 515 (defun context-coloring-elisp-colorize-lambda ()
 516   (context-coloring-elisp-colorize-defun t))
 517
 518 (defun context-coloring-elisp-colorize-let ()
 519   (context-coloring-elisp-colorize-defun t 'let))
 520
 521 (defun context-coloring-elisp-colorize-let* ()
 522   (context-coloring-elisp-colorize-defun t 'let*))
 523
 524 (defun context-coloring-elisp-colorize-parenthesized-sexp ()
 525   (let ((start (point))
 526         end
 527         syntax-code
 528         child-0-pos
 529         child-0-end
 530         child-0-string)
 531     (forward-sexp)
 532     (setq end (point))
 533     (goto-char start)
 534     (forward-char)
 535     (context-coloring-forward-sws)
 536     (setq syntax-code (context-coloring-get-syntax-code))
 537     ;; Figure out if the sexp is a special form.
 538     (cond
 539      ((when (or (= syntax-code context-coloring-WORD-CODE)
 540                 (= syntax-code context-coloring-SYMBOL-CODE))
 541         (setq child-0-pos (point))
 542         (forward-sexp)
 543         (setq child-0-end (point))
 544         (setq child-0-string (buffer-substring-no-properties
 545                               child-0-pos
 546                               child-0-end))
 547         (cond
 548          ((string-match-p context-coloring-elisp-defun-regexp child-0-string)
 549           (goto-char start)
 550           (context-coloring-elisp-colorize-defun)
 551           t)
 552          ((string-match-p context-coloring-elisp-lambda-regexp child-0-string)
 553           (goto-char start)
 554           (context-coloring-elisp-colorize-lambda)
 555           t)
 556          ((string-match-p context-coloring-elisp-let-regexp child-0-string)
 557           (goto-char start)
 558           (context-coloring-elisp-colorize-let)
 559           t)
 560          ((string-match-p context-coloring-elisp-let*-regexp child-0-string)
 561           (goto-char start)
 562           (context-coloring-elisp-colorize-let*)
 563           t)
 564          (t
 565           nil))))
 566      ;; Not a special form; just colorize the remaining region.
 567      (t
 568       (context-coloring-colorize-region
 569        start
 570        end
 571        (context-coloring-elisp-current-scope-level))
 572       (context-coloring-elisp-colorize-region (point) (1- end))
 573       (forward-char)))))
 574
 575 (defun context-coloring-elisp-colorize-symbol ()
 576   (let (symbol-pos
 577         symbol-end
 578         symbol-string)
 579     (setq symbol-pos (point))
 580     (forward-sexp)
 581     (setq symbol-end (point))
 582     (setq symbol-string (buffer-substring-no-properties
 583                          symbol-pos
 584                          symbol-end))
 585     (cond
 586      ((string-match-p context-coloring-ignored-word-regexp symbol-string))
 587      (t
 588       (context-coloring-colorize-region
 589        symbol-pos
 590        symbol-end
 591        (context-coloring-elisp-get-variable-level
 592         symbol-string))))))
 593
 594 (defun context-coloring-elisp-colorize-expression-prefix ()
 595   (let (start
 596         end
 597         char)
 598     (setq char (char-after))
 599     (cond
 600      ((= char context-coloring-APOSTROPHE-CHAR)
 601       (forward-sexp))
 602      ((= char context-coloring-BACKTICK-CHAR)
 603       (setq start (point))
 604       (forward-sexp)
 605       (setq end (point))
 606       (goto-char start)
 607       (while (> end (progn (forward-char)
 608                            (point)))
 609         (setq char (char-after))
 610         (when (= char context-coloring-COMMA-CHAR)
 611           (forward-char)
 612           (context-coloring-forward-sws)
 613           (context-coloring-elisp-colorize-sexp)))))))
 614
 615 (defvar context-coloring-parse-interruptable-p t
 616   "Set this to nil to force parse to continue until finished.")
 617
 618 (defconst context-coloring-elisp-sexps-per-pause 1000
 619   "Pause after this many iterations to check for user input.
 620 If user input is pending, stop the parse.  This makes for a
 621 smoother user experience for large files.
 622
 623 As of this writing, emacs lisp colorization seems to run at about
 624 60,000 iterations per second.  A default value of 1000 should
 625 provide visually \"instant\" updates at 60 frames per second.")
 626
 627 (defvar context-coloring-elisp-sexp-count 0)
 628
 629 (defun context-coloring-elisp-increment-sexp-count ()
 630   (setq context-coloring-elisp-sexp-count
 631         (1+ context-coloring-elisp-sexp-count))
 632   (when (and (zerop (% context-coloring-elisp-sexp-count
 633                        context-coloring-elisp-sexps-per-pause))
 634              context-coloring-parse-interruptable-p
 635              (input-pending-p))
 636     (throw 'interrupted t)))
 637
 638 (defun context-coloring-elisp-colorize-sexp ()
 639   (let (syntax-code)
 640     (context-coloring-elisp-increment-sexp-count)
 641     (setq syntax-code (context-coloring-get-syntax-code))
 642     (cond
 643      ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 644       (context-coloring-elisp-colorize-parenthesized-sexp))
 645      ((or (= syntax-code context-coloring-WORD-CODE)
 646           (= syntax-code context-coloring-SYMBOL-CODE))
 647       (context-coloring-elisp-colorize-symbol))
 648      ((= syntax-code context-coloring-EXPRESSION-PREFIX-CODE)
 649       (context-coloring-elisp-colorize-expression-prefix))
 650      (t
 651       (forward-char)))))
 652
 653 (defun context-coloring-elisp-colorize-comment ()
 654   (let ((start (point)))
 655     (context-coloring-elisp-increment-sexp-count)
 656     (context-coloring-forward-sws)
 657     (context-coloring-maybe-colorize-comments-and-strings
 658      start
 659      (point))))
 660
 661 (defun context-coloring-elisp-colorize-string ()
 662   (let ((start (point)))
 663     (context-coloring-elisp-increment-sexp-count)
 664     (forward-sexp)
 665     (context-coloring-maybe-colorize-comments-and-strings
 666      start
 667      (point))))
 668
 669 (defun context-coloring-elisp-colorize-region (start end)
 670   (let (syntax-code)
 671     (goto-char start)
 672     (while (> end (progn (skip-syntax-forward "^()w_'<\"" end)
 673                          (point)))
 674       (setq syntax-code (context-coloring-get-syntax-code))
 675       (cond
 676        ((or (= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 677             (= syntax-code context-coloring-WORD-CODE)
 678             (= syntax-code context-coloring-SYMBOL-CODE)
 679             (= syntax-code context-coloring-EXPRESSION-PREFIX-CODE))
 680         (context-coloring-elisp-colorize-sexp))
 681        ((= syntax-code context-coloring-COMMENT-START-CODE)
 682         (context-coloring-elisp-colorize-comment))
 683        ((= syntax-code context-coloring-STRING-QUOTE-CODE)
 684         (context-coloring-elisp-colorize-string))
 685        (t
 686         (forward-char))))))
 687
 688 (defun context-coloring-elisp-colorize (start end)
 689   (setq context-coloring-elisp-sexp-count 0)
 690   (setq context-coloring-elisp-scope-stack '())
 691   (context-coloring-elisp-colorize-region start end))
 692
 693 (defun context-coloring-elisp-colorize-changed-region (start end)
 694   (with-silent-modifications
 695     (save-excursion
 696       (let ((start (progn (goto-char start)
 697                           (beginning-of-defun)
 698                           (point)))
 699             (end (progn (goto-char end)
 700                         (end-of-defun)
 701                         (point))))
 702         (context-coloring-elisp-colorize start end)))))
 703
 704 (defun context-coloring-elisp-colorize-buffer ()
 705   (interactive)
 706   (with-silent-modifications
 707     (save-excursion
 708       (context-coloring-elisp-colorize (point-min) (point-max)))))
 709
 710 (defalias 'ccecb 'context-coloring-elisp-colorize-buffer)
 711
 712
 713 ;;; Shell command scopification / colorization
 714
 715 (defun context-coloring-apply-tokens (tokens)
 716   "Process a vector of TOKENS to apply context-based coloring to
 717 the current buffer.  Tokens are 3 integers: start, end, level.
 718 The vector is flat, with a new token occurring after every 3rd
 719 element."
 720   (with-silent-modifications
 721     (let ((i 0)
 722           (len (length tokens)))
 723       (while (< i len)
 724         (context-coloring-colorize-region
 725          (elt tokens i)
 726          (elt tokens (+ i 1))
 727          (elt tokens (+ i 2)))
 728         (setq i (+ i 3))))
 729     (context-coloring-maybe-colorize-comments-and-strings)))
 730
 731 (defun context-coloring-parse-array (array)
 732   "Parse ARRAY as a flat JSON array of numbers."
 733   (let ((braceless (substring (context-coloring-trim array) 1 -1)))
 734     (cond
 735      ((> (length braceless) 0)
 736       (vconcat
 737        (mapcar 'string-to-number (split-string braceless ","))))
 738      (t
 739       (vector)))))
 740
 741 (defvar-local context-coloring-scopifier-process nil
 742   "The single scopifier process that can be running.")
 743
 744 (defun context-coloring-kill-scopifier ()
 745   "Kill the currently-running scopifier process."
 746   (when (not (null context-coloring-scopifier-process))
 747     (delete-process context-coloring-scopifier-process)
 748     (setq context-coloring-scopifier-process nil)))
 749
 750 (defun context-coloring-scopify-shell-command (command callback)
 751   "Invoke a scopifier via COMMAND, read its response
 752 asynchronously and invoke CALLBACK with its output."
 753
 754   ;; Prior running tokenization is implicitly obsolete if this function is
 755   ;; called.
 756   (context-coloring-kill-scopifier)
 757
 758   ;; Start the process.
 759   (setq context-coloring-scopifier-process
 760         (start-process-shell-command "scopifier" nil command))
 761
 762   (let ((output ""))
 763
 764     ;; The process may produce output in multiple chunks.  This filter
 765     ;; accumulates the chunks into a message.
 766     (set-process-filter
 767      context-coloring-scopifier-process
 768      (lambda (_process chunk)
 769        (setq output (concat output chunk))))
 770
 771     ;; When the process's message is complete, this sentinel parses it as JSON
 772     ;; and applies the tokens to the buffer.
 773     (set-process-sentinel
 774      context-coloring-scopifier-process
 775      (lambda (_process event)
 776        (when (equal "finished\n" event)
 777          (funcall callback output))))))
 778
 779 (defun context-coloring-send-buffer-to-scopifier ()
 780   "Give the scopifier process its input so it can begin
 781 scopifying."
 782   (process-send-region
 783    context-coloring-scopifier-process
 784    (point-min) (point-max))
 785   (process-send-eof
 786    context-coloring-scopifier-process))
 787
 788 (defun context-coloring-scopify-and-colorize (command &optional callback)
 789   "Invoke a scopifier via COMMAND with the current buffer's contents,
 790 read the scopifier's response asynchronously and apply a parsed
 791 list of tokens to `context-coloring-apply-tokens'.
 792
 793 Invoke CALLBACK when complete."
 794   (let ((buffer (current-buffer)))
 795     (context-coloring-scopify-shell-command
 796      command
 797      (lambda (output)
 798        (let ((tokens (context-coloring-parse-array output)))
 799          (with-current-buffer buffer
 800            (context-coloring-apply-tokens tokens))
 801          (setq context-coloring-scopifier-process nil)
 802          (when callback (funcall callback))))))
 803   (context-coloring-send-buffer-to-scopifier))
 804
 805
 806 ;;; Dispatch
 807
 808 (defvar context-coloring-dispatch-hash-table (make-hash-table :test 'eq)
 809   "Map dispatch strategy names to their corresponding property
 810   lists, which contain details about the strategies.")
 811
 812 (defvar context-coloring-mode-hash-table (make-hash-table :test 'eq)
 813   "Map major mode names to dispatch property lists.")
 814
 815 (defun context-coloring-get-dispatch-for-mode (mode)
 816   "Return the dispatch for MODE (or a derivative mode)."
 817   (let ((parent mode)
 818         dispatch)
 819     (while (and parent
 820                 (not (setq dispatch (gethash parent context-coloring-mode-hash-table)))
 821                 (setq parent (get parent 'derived-mode-parent))))
 822     dispatch))
 823
 824 (defun context-coloring-define-dispatch (symbol &rest properties)
 825   "Define a new dispatch named SYMBOL with PROPERTIES.
 826
 827 A \"dispatch\" is a property list describing a strategy for
 828 coloring a buffer.  There are three possible strategies: Parse
 829 and color in a single function (`:colorizer'), parse in a
 830 function that returns scope data (`:scopifier'), or parse with a
 831 shell command that returns scope data (`:command').  In the
 832 latter two cases, the scope data will be used to automatically
 833 color the buffer.
 834
 835 PROPERTIES must include `:modes' and one of `:colorizer',
 836 `:scopifier' or `:command'.
 837
 838 `:modes' - List of major modes this dispatch is valid for.
 839
 840 `:colorizer' - Symbol referring to a function that parses and
 841 colors the buffer.
 842
 843 `:scopifier' - Symbol referring to a function that parses the
 844 buffer a returns a flat vector of start, end and level data.
 845
 846 `:executable' - Optional name of an executable required by
 847 `:command'.
 848
 849 `:command' - Shell command to execute with the current buffer
 850 sent via stdin, and with a flat JSON array of start, end and
 851 level data returned via stdout.
 852
 853 `:version' - Minimum required version that should be printed when
 854 executing `:command' with a \"--version\" flag.  The version
 855 should be numeric, e.g. \"2\", \"19700101\", \"1.2.3\",
 856 \"v1.2.3\" etc.
 857
 858 `:setup' - Arbitrary code to set up this dispatch when
 859 `context-coloring-mode' is enabled.
 860
 861 `:teardown' - Arbitrary code to tear down this dispatch when
 862 `context-coloring-mode' is disabled."
 863   (let ((modes (plist-get properties :modes))
 864         (colorizer (plist-get properties :colorizer))
 865         (scopifier (plist-get properties :scopifier))
 866         (command (plist-get properties :command)))
 867     (when (null modes)
 868       (error "No mode defined for dispatch"))
 869     (when (not (or colorizer
 870                    scopifier
 871                    command))
 872       (error "No colorizer, scopifier or command defined for dispatch"))
 873     (puthash symbol properties context-coloring-dispatch-hash-table)
 874     (dolist (mode modes)
 875       (puthash mode properties context-coloring-mode-hash-table))))
 876
 877
 878 ;;; Colorization
 879
 880 (defvar context-coloring-colorize-hook nil
 881   "Hooks to run after coloring a buffer.")
 882
 883 (defun context-coloring-colorize (&optional callback)
 884   "Color the current buffer by function context.
 885
 886 Invoke CALLBACK when complete; see `context-coloring-dispatch'."
 887   (interactive)
 888   (context-coloring-dispatch
 889    (lambda ()
 890      (when callback (funcall callback))
 891      (run-hooks 'context-coloring-colorize-hook))))
 892
 893 (defvar-local context-coloring-changed nil
 894   "Indication that the buffer has changed recently, which implies
 895 that it should be colored again by
 896 `context-coloring-colorize-idle-timer' if that timer is being
 897 used.")
 898
 899 (defun context-coloring-change-function (_start _end _length)
 900   "Register a change so that a buffer can be colorized soon."
 901   ;; Tokenization is obsolete if there was a change.
 902   (context-coloring-kill-scopifier)
 903   (setq context-coloring-changed t))
 904
 905 (defun context-coloring-maybe-colorize (buffer)
 906   "Colorize the current buffer if it has changed."
 907   (when (and (eq buffer (current-buffer))
 908              context-coloring-changed)
 909     (setq context-coloring-changed nil)
 910     (context-coloring-colorize)))
 911
 912
 913 ;;; Versioning
 914
 915 (defun context-coloring-parse-version (string)
 916   "Extract segments of a version STRING into a list.  \"v1.0.0\"
 917 produces (1 0 0), \"19700101\" produces (19700101), etc."
 918   (let (version)
 919     (while (string-match "[0-9]+" string)
 920       (setq version (append version
 921                             (list (string-to-number (match-string 0 string)))))
 922       (setq string (substring string (match-end 0))))
 923     version))
 924
 925 (defun context-coloring-check-version (expected actual)
 926   "Check that version EXPECTED is less than or equal to ACTUAL."
 927   (let ((expected (context-coloring-parse-version expected))
 928         (actual (context-coloring-parse-version actual))
 929         (continue t)
 930         (acceptable t))
 931     (while (and continue expected)
 932       (let ((an-expected (car expected))
 933             (an-actual (car actual)))
 934         (cond
 935          ((> an-actual an-expected)
 936           (setq acceptable t)
 937           (setq continue nil))
 938          ((< an-actual an-expected)
 939           (setq acceptable nil)
 940           (setq continue nil))))
 941       (setq expected (cdr expected))
 942       (setq actual (cdr actual)))
 943     acceptable))
 944
 945 (defvar context-coloring-check-scopifier-version-hook nil
 946   "Hooks to run after checking the scopifier version.")
 947
 948 (defun context-coloring-check-scopifier-version (&optional callback)
 949   "Asynchronously invoke CALLBACK with a predicate indicating
 950 whether the current scopifier version satisfies the minimum
 951 version number required for the current major mode."
 952   (let ((dispatch (context-coloring-get-dispatch-for-mode major-mode)))
 953     (when dispatch
 954       (let ((version (plist-get dispatch :version))
 955             (command (plist-get dispatch :command)))
 956         (context-coloring-scopify-shell-command
 957          (context-coloring-join (list command "--version") " ")
 958          (lambda (output)
 959            (if (context-coloring-check-version version output)
 960                (progn
 961                  (when callback (funcall callback t)))
 962              (when callback (funcall callback nil)))
 963            (run-hooks 'context-coloring-check-scopifier-version-hook)))))))
 964
 965
 966 ;;; Themes
 967
 968 (defvar context-coloring-theme-hash-table (make-hash-table :test 'eq)
 969   "Map theme names to theme properties.")
 970
 971 (defun context-coloring-theme-p (theme)
 972   "Return t if THEME is defined, nil otherwise."
 973   (and (gethash theme context-coloring-theme-hash-table)))
 974
 975 (defconst context-coloring-level-face-regexp
 976   "context-coloring-level-\\([[:digit:]]+\\)-face"
 977   "Extract a level from a face.")
 978
 979 (defvar context-coloring-originally-set-theme-hash-table
 980   (make-hash-table :test 'eq)
 981   "Cache custom themes who originally set their own
 982   `context-coloring-level-N-face' faces.")
 983
 984 (defun context-coloring-theme-originally-set-p (theme)
 985   "Return t if there is a `context-coloring-level-N-face'
 986 originally set for THEME, nil otherwise."
 987   (let (originally-set)
 988     (cond
 989      ;; `setq' might return a non-nil value for the sake of this `cond'.
 990      ((setq
 991        originally-set
 992        (gethash
 993         theme
 994         context-coloring-originally-set-theme-hash-table))
 995       (eq originally-set 'yes))
 996      (t
 997       (let* ((settings (get theme 'theme-settings))
 998              (tail settings)
 999              found)
1000         (while (and tail (not found))
1001           (and (eq (nth 0 (car tail)) 'theme-face)
1002                (string-match
1003                 context-coloring-level-face-regexp
1004                 (symbol-name (nth 1 (car tail))))
1005                (setq found t))
1006           (setq tail (cdr tail)))
1007         found)))))
1008
1009 (defun context-coloring-cache-originally-set (theme originally-set)
1010   "Remember if THEME had colors originally set for it.  If
1011 ORIGINALLY-SET is non-nil, it did, otherwise it didn't."
1012   ;; Caching whether a theme was originally set is kind of dirty, but we have to
1013   ;; do it to remember the past state of the theme.  There are probably some
1014   ;; edge cases where caching will be an issue, but they are probably rare.
1015   (puthash
1016    theme
1017    (if originally-set 'yes 'no)
1018    context-coloring-originally-set-theme-hash-table))
1019
1020 (defun context-coloring-warn-theme-originally-set (theme)
1021   "Warn the user that the colors for THEME are already originally
1022 set."
1023   (warn "Context coloring colors for theme `%s' are already defined" theme))
1024
1025 (defun context-coloring-theme-highest-level (theme)
1026   "Return the highest level N of a face like
1027 `context-coloring-level-N-face' set for THEME, or `-1' if there
1028 is none."
1029   (let* ((settings (get theme 'theme-settings))
1030          (tail settings)
1031          face-string
1032          number
1033          (found -1))
1034     (while tail
1035       (and (eq (nth 0 (car tail)) 'theme-face)
1036            (setq face-string (symbol-name (nth 1 (car tail))))
1037            (string-match
1038             context-coloring-level-face-regexp
1039             face-string)
1040            (setq number (string-to-number
1041                          (substring face-string
1042                                     (match-beginning 1)
1043                                     (match-end 1))))
1044            (> number found)
1045            (setq found number))
1046       (setq tail (cdr tail)))
1047     found))
1048
1049 (defun context-coloring-apply-theme (theme)
1050   "Apply THEME's properties to its respective custom theme,
1051 which must already exist and which *should* already be enabled."
1052   (let* ((properties (gethash theme context-coloring-theme-hash-table))
1053          (colors (plist-get properties :colors))
1054          (level -1))
1055     ;; Only clobber when we have to.
1056     (when (custom-theme-enabled-p theme)
1057       (setq context-coloring-maximum-face (- (length colors) 1)))
1058     (apply
1059      'custom-theme-set-faces
1060      theme
1061      (mapcar
1062       (lambda (color)
1063         (setq level (+ level 1))
1064         `(,(context-coloring-level-face level) ((t (:foreground ,color)))))
1065       colors))))
1066
1067 (defun context-coloring-define-theme (theme &rest properties)
1068   "Define a context theme named THEME for coloring scope levels.
1069
1070 PROPERTIES is a property list specifiying the following details:
1071
1072 `:aliases': List of symbols of other custom themes that these
1073 colors are applicable to.
1074
1075 `:colors': List of colors that this context theme uses.
1076
1077 `:override': If non-nil, this context theme is intentionally
1078 overriding colors set by a custom theme.  Don't set this non-nil
1079 unless there is a custom theme you want to use which sets
1080 `context-coloring-level-N-face' faces that you want to replace.
1081
1082 `:recede': If non-nil, this context theme should not apply its
1083 colors if a custom theme already sets
1084 `context-coloring-level-N-face' faces.  This option is
1085 optimistic; set this non-nil if you would rather confer the duty
1086 of picking colors to a custom theme author (if / when he ever
1087 gets around to it).
1088
1089 By default, context themes will always override custom themes,
1090 even if those custom themes set `context-coloring-level-N-face'
1091 faces.  If a context theme does override a custom theme, a
1092 warning will be raised, at which point you may want to enable the
1093 `:override' option, or just delete your context theme and opt to
1094 use your custom theme's author's colors instead.
1095
1096 Context themes only work for the custom theme with the highest
1097 precedence, i.e. the car of `custom-enabled-themes'."
1098   (let ((aliases (plist-get properties :aliases))
1099         (override (plist-get properties :override))
1100         (recede (plist-get properties :recede)))
1101     (dolist (name (append `(,theme) aliases))
1102       (puthash name properties context-coloring-theme-hash-table)
1103       (when (custom-theme-p name)
1104         (let ((originally-set (context-coloring-theme-originally-set-p name)))
1105           (context-coloring-cache-originally-set name originally-set)
1106           ;; In the particular case when you innocently define colors that a
1107           ;; custom theme originally set, warn.  Arguably this only has to be
1108           ;; done at enable time, but it is probably more useful to do it at
1109           ;; definition time for prompter feedback.
1110           (when (and originally-set
1111                      (not recede)
1112                      (not override))
1113             (context-coloring-warn-theme-originally-set name))
1114           ;; Set (or overwrite) colors.
1115           (when (not (and originally-set
1116                           recede))
1117             (context-coloring-apply-theme name)))))))
1118
1119 (defun context-coloring-enable-theme (theme)
1120   "Apply THEME if its colors are not already set, else just set
1121 `context-coloring-maximum-face' to the correct value for THEME."
1122   (let* ((properties (gethash theme context-coloring-theme-hash-table))
1123          (recede (plist-get properties :recede))
1124          (override (plist-get properties :override)))
1125     (cond
1126      (recede
1127       (let ((highest-level (context-coloring-theme-highest-level theme)))
1128         (cond
1129          ;; This can be true whether originally set by a custom theme or by a
1130          ;; context theme.
1131          ((> highest-level -1)
1132           (setq context-coloring-maximum-face highest-level))
1133          ;; It is possible that the corresponding custom theme did not exist at
1134          ;; the time of defining this context theme, and in that case the above
1135          ;; condition proves the custom theme did not originally set any faces,
1136          ;; so we have license to apply the context theme for the first time
1137          ;; here.
1138          (t
1139           (context-coloring-apply-theme theme)))))
1140      (t
1141       (let ((originally-set (context-coloring-theme-originally-set-p theme)))
1142         ;; Cache now in case the context theme was defined after the custom
1143         ;; theme.
1144         (context-coloring-cache-originally-set theme originally-set)
1145         (when (and originally-set
1146                    (not override))
1147           (context-coloring-warn-theme-originally-set theme))
1148         (context-coloring-apply-theme theme))))))
1149
1150 (defadvice enable-theme (after context-coloring-enable-theme (theme) activate)
1151   "Enable colors for context themes just-in-time."
1152   (when (and (not (eq theme 'user)) ; Called internally by `enable-theme'.
1153              (custom-theme-p theme) ; Guard against non-existent themes.
1154              (context-coloring-theme-p theme))
1155     (when (= (length custom-enabled-themes) 1)
1156       ;; Cache because we can't reliably figure it out in reverse.
1157       (setq context-coloring-original-maximum-face
1158             context-coloring-maximum-face))
1159     (context-coloring-enable-theme theme)))
1160
1161 (defadvice disable-theme (after context-coloring-disable-theme (theme) activate)
1162   "Update `context-coloring-maximum-face'."
1163   (when (custom-theme-p theme) ; Guard against non-existent themes.
1164     (let ((enabled-theme (car custom-enabled-themes)))
1165       (if (context-coloring-theme-p enabled-theme)
1166           (progn
1167             (context-coloring-enable-theme enabled-theme))
1168         ;; Assume we are back to no theme; act as if nothing ever happened.
1169         ;; This is still prone to intervention, but rather extraordinarily.
1170         (setq context-coloring-maximum-face
1171               context-coloring-original-maximum-face)))))
1172
1173 (context-coloring-define-theme
1174  'ample
1175  :recede t
1176  :colors '("#bdbdb3"
1177            "#baba36"
1178            "#6aaf50"
1179            "#5180b3"
1180            "#ab75c3"
1181            "#cd7542"
1182            "#df9522"
1183            "#454545"))
1184
1185 (context-coloring-define-theme
1186  'anti-zenburn
1187  :recede t
1188  :colors '("#232333"
1189            "#6c1f1c"
1190            "#401440"
1191            "#0f2050"
1192            "#205070"
1193            "#336c6c"
1194            "#23733c"
1195            "#6b400c"
1196            "#603a60"
1197            "#2f4070"
1198            "#235c5c"))
1199
1200 (context-coloring-define-theme
1201  'grandshell
1202  :recede t
1203  :colors '("#bebebe"
1204            "#5af2ee"
1205            "#b2baf6"
1206            "#f09fff"
1207            "#efc334"
1208            "#f6df92"
1209            "#acfb5a"
1210            "#888888"))
1211
1212 (context-coloring-define-theme
1213  'leuven
1214  :recede t
1215  :colors '("#333333"
1216            "#0000ff"
1217            "#6434a3"
1218            "#ba36a5"
1219            "#d0372d"
1220            "#036a07"
1221            "#006699"
1222            "#006fe0"
1223            "#808080"))
1224
1225 (context-coloring-define-theme
1226  'monokai
1227  :recede t
1228  :colors '("#f8f8f2"
1229            "#66d9ef"
1230            "#a1efe4"
1231            "#a6e22e"
1232            "#e6db74"
1233            "#fd971f"
1234            "#f92672"
1235            "#fd5ff0"
1236            "#ae81ff"))
1237
1238 (context-coloring-define-theme
1239  'solarized
1240  :recede t
1241  :aliases '(solarized-light
1242             solarized-dark
1243             sanityinc-solarized-light
1244             sanityinc-solarized-dark)
1245  :colors '("#839496"
1246            "#268bd2"
1247            "#2aa198"
1248            "#859900"
1249            "#b58900"
1250            "#cb4b16"
1251            "#dc322f"
1252            "#d33682"
1253            "#6c71c4"
1254            "#69b7f0"
1255            "#69cabf"
1256            "#b4c342"
1257            "#deb542"
1258            "#f2804f"
1259            "#ff6e64"
1260            "#f771ac"
1261            "#9ea0e5"))
1262
1263 (context-coloring-define-theme
1264  'spacegray
1265  :recede t
1266  :colors '("#ffffff"
1267            "#89aaeb"
1268            "#c189eb"
1269            "#bf616a"
1270            "#dca432"
1271            "#ebcb8b"
1272            "#b4eb89"
1273            "#89ebca"))
1274
1275 (context-coloring-define-theme
1276  'tango
1277  :recede t
1278  :colors '("#2e3436"
1279            "#346604"
1280            "#204a87"
1281            "#5c3566"
1282            "#a40000"
1283            "#b35000"
1284            "#c4a000"
1285            "#8ae234"
1286            "#8cc4ff"
1287            "#ad7fa8"
1288            "#ef2929"
1289            "#fcaf3e"
1290            "#fce94f"))
1291
1292 (context-coloring-define-theme
1293  'zenburn
1294  :recede t
1295  :colors '("#dcdccc"
1296            "#93e0e3"
1297            "#bfebbf"
1298            "#f0dfaf"
1299            "#dfaf8f"
1300            "#cc9393"
1301            "#dc8cc3"
1302            "#94bff3"
1303            "#9fc59f"
1304            "#d0bf8f"
1305            "#dca3a3"))
1306
1307
1308 ;;; Change detection
1309
1310 (defvar-local context-coloring-colorize-idle-timer nil
1311   "The currently-running idle timer.")
1312
1313 (defcustom context-coloring-delay 0.25
1314   "Delay between a buffer update and colorization.
1315
1316 Increase this if your machine is high-performing.  Decrease it if
1317 it ain't.
1318
1319 Supported modes: `js-mode', `js3-mode', `emacs-lisp-mode'"
1320   :group 'context-coloring)
1321
1322 (defun context-coloring-setup-idle-change-detection ()
1323   "Setup idle change detection."
1324   (add-hook
1325    'after-change-functions 'context-coloring-change-function nil t)
1326   (add-hook
1327    'kill-buffer-hook 'context-coloring-teardown-idle-change-detection nil t)
1328   (setq context-coloring-colorize-idle-timer
1329         (run-with-idle-timer
1330          context-coloring-delay
1331          t
1332          'context-coloring-maybe-colorize
1333          (current-buffer))))
1334
1335 (defun context-coloring-teardown-idle-change-detection ()
1336   "Teardown idle change detection."
1337   (context-coloring-kill-scopifier)
1338   (when context-coloring-colorize-idle-timer
1339     (cancel-timer context-coloring-colorize-idle-timer))
1340   (remove-hook
1341    'kill-buffer-hook 'context-coloring-teardown-idle-change-detection t)
1342   (remove-hook
1343    'after-change-functions 'context-coloring-change-function t))
1344
1345
1346 ;;; Built-in dispatches
1347
1348 (context-coloring-define-dispatch
1349  'javascript-node
1350  :modes '(js-mode js3-mode)
1351  :executable "scopifier"
1352  :command "scopifier"
1353  :version "v1.1.1")
1354
1355 (context-coloring-define-dispatch
1356  'javascript-js2
1357  :modes '(js2-mode)
1358  :colorizer 'context-coloring-js2-colorize
1359  :setup
1360  (lambda ()
1361    (add-hook 'js2-post-parse-callbacks 'context-coloring-colorize nil t))
1362  :teardown
1363  (lambda ()
1364    (remove-hook 'js2-post-parse-callbacks 'context-coloring-colorize t)))
1365
1366 (context-coloring-define-dispatch
1367  'emacs-lisp
1368  :modes '(emacs-lisp-mode)
1369  :colorizer 'context-coloring-elisp-colorize-buffer
1370  :setup 'context-coloring-setup-idle-change-detection
1371  :teardown 'context-coloring-teardown-idle-change-detection)
1372
1373 (defun context-coloring-dispatch (&optional callback)
1374   "Determine the optimal track for scopification / coloring of
1375 the current buffer, then execute it.
1376
1377 Invoke CALLBACK when complete.  It is invoked synchronously for
1378 elisp tracks, and asynchronously for shell command tracks."
1379   (let* ((dispatch (context-coloring-get-dispatch-for-mode major-mode))
1380          (colorizer (plist-get dispatch :colorizer))
1381          (scopifier (plist-get dispatch :scopifier))
1382          (command (plist-get dispatch :command))
1383          interrupted-p)
1384     (cond
1385      ((or colorizer scopifier)
1386       (setq interrupted-p
1387             (catch 'interrupted
1388               (cond
1389                (colorizer
1390                 (funcall colorizer))
1391                (scopifier
1392                 (context-coloring-apply-tokens (funcall scopifier))))))
1393       (cond
1394        (interrupted-p
1395         (setq context-coloring-changed t))
1396        (t
1397         (when callback (funcall callback)))))
1398      (command
1399       (context-coloring-scopify-and-colorize command callback)))))
1400
1401
1402 ;;; Minor mode
1403
1404 ;;;###autoload
1405 (define-minor-mode context-coloring-mode
1406   "Context-based code coloring, inspired by Douglas Crockford."
1407   nil " Context" nil
1408   (if (not context-coloring-mode)
1409       (progn
1410         (let ((dispatch (context-coloring-get-dispatch-for-mode major-mode)))
1411           (when dispatch
1412             (let ((command (plist-get dispatch :command))
1413                   (teardown (plist-get dispatch :teardown)))
1414               (when command
1415                 (context-coloring-teardown-idle-change-detection))
1416               (when teardown
1417                 (funcall teardown)))))
1418         (font-lock-mode)
1419         (jit-lock-mode t))
1420
1421     ;; Font lock is incompatible with this mode; the converse is also true.
1422     (font-lock-mode 0)
1423     (jit-lock-mode nil)
1424
1425     ;; ...but we do use font-lock functions here.
1426     (font-lock-set-defaults)
1427
1428     ;; Safely change the valye of this function as necessary.
1429     (make-local-variable 'font-lock-syntactic-face-function)
1430
1431     (let ((dispatch (context-coloring-get-dispatch-for-mode major-mode)))
1432       (if dispatch
1433           (progn
1434             (let ((command (plist-get dispatch :command))
1435                   (version (plist-get dispatch :version))
1436                   (executable (plist-get dispatch :executable))
1437                   (setup (plist-get dispatch :setup))
1438                   (colorize-initially-p t))
1439               (when command
1440                 ;; Shell commands recolor on change, idly.
1441                 (cond
1442                  ((and executable
1443                        (null (executable-find executable)))
1444                   (message "Executable \"%s\" not found" executable)
1445                   (setq colorize-initially-p nil))
1446                  (version
1447                   (context-coloring-check-scopifier-version
1448                    (lambda (sufficient-p)
1449                      (if sufficient-p
1450                          (progn
1451                            (context-coloring-setup-idle-change-detection)
1452                            (context-coloring-colorize))
1453                        (message "Update to the minimum version of \"%s\" (%s)"
1454                                 executable version))))
1455                   (setq colorize-initially-p nil))
1456                  (t
1457                   (context-coloring-setup-idle-change-detection))))
1458               (when setup
1459                 (funcall setup))
1460               ;; Colorize once initially.
1461               (when colorize-initially-p
1462                 (let ((context-coloring-parse-interruptable-p nil))
1463                   (context-coloring-colorize)))))
1464         (when (null dispatch)
1465           (message "Context coloring is not available for this major mode"))))))
1466
1467 (provide 'context-coloring)
1468
1469 ;;; context-coloring.el ends here