code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.5.1
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (defface swiper-minibuffer-match-face-1
  65   '((((class color) (background light))
  66      :background "#d3d3d3")
  67     (((class color) (background dark))
  68      :background "#555555"))
  69   "The background face for `swiper' minibuffer matches."
  70   :group 'function-args-faces)
  71
  72 (defface swiper-minibuffer-match-face-2
  73   '((((class color) (background light))
  74      :background "#e99ce8" :weight bold)
  75     (((class color) (background dark))
  76      :background "#777777" :weight bold))
  77   "Face for `swiper' minibuffer matches modulo 1.")
  78
  79 (defface swiper-minibuffer-match-face-3
  80   '((((class color) (background light))
  81      :background "#bbbbff" :weight bold)
  82     (((class color) (background dark))
  83      :background "#7777ff" :weight bold))
  84   "Face for `swiper' minibuffer matches modulo 2.")
  85
  86 (defface swiper-minibuffer-match-face-4
  87   '((((class color) (background light))
  88      :background "#ffbbff" :weight bold)
  89     (((class color) (background dark))
  90      :background "#8a498a" :weight bold))
  91   "Face for `swiper' minibuffer matches modulo 3.")
  92
  93 (defface swiper-line-face
  94   '((t (:inherit highlight)))
  95   "Face for current `swiper' line.")
  96
  97 (defcustom swiper-faces '(swiper-match-face-1
  98                           swiper-match-face-2
  99                           swiper-match-face-3
 100                           swiper-match-face-4)
 101   "List of `swiper' faces for group matches.")
 102
 103 (defcustom swiper-min-highlight 2
 104   "Only highlight matches for regexps at least this long."
 105   :type 'integer)
 106
 107 (defvar swiper-map
 108   (let ((map (make-sparse-keymap)))
 109     (define-key map (kbd "M-q") 'swiper-query-replace)
 110     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
 111     (define-key map (kbd "C-'") 'swiper-avy)
 112     map)
 113   "Keymap for swiper.")
 114
 115 (defun swiper-query-replace ()
 116   "Start `query-replace' with string to replace from last search string."
 117   (interactive)
 118   (if (null (window-minibuffer-p))
 119       (user-error "Should only be called in the minibuffer through `swiper-map'")
 120     (let* ((enable-recursive-minibuffers t)
 121            (from (ivy--regex ivy-text))
 122            (to (query-replace-read-to from "Query replace" t)))
 123       (delete-minibuffer-contents)
 124       (ivy-set-action (lambda (_)
 125                         (with-ivy-window
 126                           (move-beginning-of-line 1)
 127                           (perform-replace from to
 128                                            t t nil))))
 129       (swiper--cleanup)
 130       (exit-minibuffer))))
 131
 132 (defvar avy-background)
 133 (defvar avy-all-windows)
 134 (declare-function avy--regex-candidates "ext:avy")
 135 (declare-function avy--process "ext:avy")
 136 (declare-function avy--overlay-post "ext:avy")
 137 (declare-function avy-action-goto "ext:avy")
 138
 139 ;;;###autoload
 140 (defun swiper-avy ()
 141   "Jump to one of the current swiper candidates."
 142   (interactive)
 143   (unless (string= ivy-text "")
 144     (let* ((avy-all-windows nil)
 145            (candidates (append
 146                         (with-ivy-window
 147                           (avy--regex-candidates
 148                            (ivy--regex ivy-text)))
 149                         (save-excursion
 150                           (save-restriction
 151                             (narrow-to-region (window-start) (window-end))
 152                             (goto-char (point-min))
 153                             (forward-line)
 154                             (let ((cands))
 155                               (while (< (point) (point-max))
 156                                 (push (cons (1+ (point))
 157                                             (selected-window))
 158                                       cands)
 159                                 (forward-line))
 160                               cands)))))
 161            (candidate (unwind-protect
 162                           (prog2
 163                               (avy--make-backgrounds
 164                                (append (avy-window-list)
 165                                        (list  (ivy-state-window ivy-last))))
 166                               (if (eq avy-style 'de-bruijn)
 167                                   (avy-read-de-bruijn
 168                                    candidates avy-keys)
 169                                 (avy-read (avy-tree candidates avy-keys)
 170                                           #'avy--overlay-post
 171                                           #'avy--remove-leading-chars))
 172                             (avy-push-mark))
 173                         (avy--done))))
 174       (if (window-minibuffer-p (cdr candidate))
 175           (progn
 176             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 177             (ivy--exhibit)
 178             (ivy-done)
 179             (ivy-call))
 180         (ivy-quit-and-run
 181          (avy-action-goto (caar candidate)))))))
 182
 183 (defun swiper-recenter-top-bottom (&optional arg)
 184   "Call (`recenter-top-bottom' ARG)."
 185   (interactive "P")
 186   (with-ivy-window
 187     (recenter-top-bottom arg)))
 188
 189 (defun swiper-font-lock-ensure ()
 190   "Ensure the entired buffer is highlighted."
 191   (unless (or (derived-mode-p 'magit-mode)
 192               (bound-and-true-p magit-blame-mode)
 193               (memq major-mode '(package-menu-mode
 194                                  gnus-summary-mode
 195                                  gnus-article-mode
 196                                  gnus-group-mode
 197                                  emms-playlist-mode erc-mode
 198                                  org-agenda-mode
 199                                  dired-mode
 200                                  jabber-chat-mode
 201                                  elfeed-search-mode
 202                                  fundamental-mode
 203                                  Man-mode
 204                                  woman-mode
 205                                  mu4e-view-mode
 206                                  mu4e-headers-mode)))
 207     (unless (> (buffer-size) 100000)
 208       (if (fboundp 'font-lock-ensure)
 209           (font-lock-ensure)
 210         (with-no-warnings (font-lock-fontify-buffer))))))
 211
 212 (defvar swiper--format-spec ""
 213   "Store the current candidates format spec.")
 214
 215 (defvar swiper--width nil
 216   "Store the amount of digits needed for the longest line nubmer.")
 217
 218 (defun swiper--candidates ()
 219   "Return a list of this buffer lines."
 220   (let ((n-lines (count-lines (point-min) (point-max))))
 221     (unless (zerop n-lines)
 222       (setq swiper--width (1+ (floor (log n-lines 10))))
 223       (setq swiper--format-spec
 224             (format "%%-%dd " swiper--width))
 225       (let ((line-number 0)
 226             (advancer (if visual-line-mode
 227                           (lambda (arg) (line-move arg t))
 228                         #'forward-line))
 229             candidates)
 230         (save-excursion
 231           (goto-char (point-min))
 232           (swiper-font-lock-ensure)
 233           (while (< (point) (point-max))
 234             (let ((str (concat " " (buffer-substring
 235                                     (point)
 236                                     (if visual-line-mode
 237                                         (save-excursion
 238                                           (end-of-visual-line)
 239                                           (point))
 240                                       (line-end-position))))))
 241               (put-text-property 0 1 'display
 242                                  (format swiper--format-spec
 243                                          (cl-incf line-number))
 244                                  str)
 245               (push str candidates))
 246             (funcall advancer 1))
 247           (nreverse candidates))))))
 248
 249 (defvar swiper--opoint 1
 250   "The point when `swiper' starts.")
 251
 252 ;;;###autoload
 253 (defun swiper (&optional initial-input)
 254   "`isearch' with an overview.
 255 When non-nil, INITIAL-INPUT is the initial search pattern."
 256   (interactive)
 257   (swiper--ivy initial-input))
 258
 259 (defvar swiper--anchor nil
 260   "A line number to which the search should be anchored.")
 261
 262 (defvar swiper--len 0
 263   "The last length of input for which an anchoring was made.")
 264
 265 (defun swiper--init ()
 266   "Perform initialization common to both completion methods."
 267   (setq swiper--opoint (point))
 268   (setq swiper--len 0)
 269   (setq swiper--anchor (line-number-at-pos)))
 270
 271 (defun swiper--re-builder (str)
 272   "Transform STR into a swiper regex.
 273 This is the regex used in the minibuffer, since the candidates
 274 there have line numbers. In the buffer, `ivy--regex' should be used."
 275   (cond
 276     ((equal str "")
 277      "")
 278     ((equal str "^")
 279      ".")
 280     ((string-match "^\\^" str)
 281      (setq ivy--old-re "")
 282      (let ((re (ivy--regex-plus (substring str 1))))
 283        (format "^[0-9][0-9 ]\\{%d\\}%s"
 284                swiper--width
 285                (if (zerop ivy--subexps)
 286                    (prog1 (format "\\(%s\\)" re)
 287                      (setq ivy--subexps 1))
 288                  re))))
 289     (t
 290      (ivy--regex-plus str))))
 291
 292 (defvar swiper-history nil
 293   "History for `swiper'.")
 294
 295 (defun swiper--ivy (&optional initial-input)
 296   "`isearch' with an overview using `ivy'.
 297 When non-nil, INITIAL-INPUT is the initial search pattern."
 298   (interactive)
 299   (swiper--init)
 300   (let ((candidates (swiper--candidates))
 301         (preselect (buffer-substring-no-properties
 302                     (line-beginning-position)
 303                     (line-end-position)))
 304         (minibuffer-allow-text-properties t)
 305         res)
 306     (unwind-protect
 307          (setq res (ivy-read
 308                     "Swiper: "
 309                     candidates
 310                     :initial-input initial-input
 311                     :keymap swiper-map
 312                     :preselect preselect
 313                     :require-match t
 314                     :update-fn #'swiper--update-input-ivy
 315                     :unwind #'swiper--cleanup
 316                     :re-builder #'swiper--re-builder
 317                     :history 'swiper-history))
 318       (if (null ivy-exit)
 319           (goto-char swiper--opoint)
 320         (swiper--action res ivy-text)))))
 321
 322 (defun swiper--ensure-visible ()
 323   "Remove overlays hiding point."
 324   (let ((overlays (overlays-at (point)))
 325         ov expose)
 326     (while (setq ov (pop overlays))
 327       (if (and (invisible-p (overlay-get ov 'invisible))
 328                (setq expose (overlay-get ov 'isearch-open-invisible)))
 329           (funcall expose ov)))))
 330
 331 (defvar swiper--overlays nil
 332   "Store overlays.")
 333
 334 (defun swiper--cleanup ()
 335   "Clean up the overlays."
 336   (while swiper--overlays
 337     (delete-overlay (pop swiper--overlays)))
 338   (save-excursion
 339     (goto-char (point-min))
 340     (isearch-clean-overlays)))
 341
 342 (defun swiper--update-input-ivy ()
 343   "Called when `ivy' input is updated."
 344   (with-ivy-window
 345     (swiper--cleanup)
 346     (when (> (length ivy--current) 0)
 347       (let* ((re (funcall ivy--regex-function ivy-text))
 348              (re (if (stringp re) re (caar re)))
 349              (str (get-text-property 0 'display ivy--current))
 350              (num (if (string-match "^[0-9]+" str)
 351                       (string-to-number (match-string 0 str))
 352                     0)))
 353         (goto-char (point-min))
 354         (when (cl-plusp num)
 355           (goto-char (point-min))
 356           (if visual-line-mode
 357               (line-move (1- num))
 358             (forward-line (1- num)))
 359           (if (and (equal ivy-text "")
 360                    (>= swiper--opoint (line-beginning-position))
 361                    (<= swiper--opoint (line-end-position)))
 362               (goto-char swiper--opoint)
 363             (re-search-forward re (line-end-position) t))
 364           (isearch-range-invisible (line-beginning-position)
 365                                    (line-end-position))
 366           (unless (and (>= (point) (window-start))
 367                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 368             (recenter)))
 369         (swiper--add-overlays re)))))
 370
 371 (defun swiper--add-overlays (re &optional beg end)
 372   "Add overlays for RE regexp in visible part of the current buffer.
 373 BEG and END, when specified, are the point bounds."
 374   (let ((ov (if visual-line-mode
 375                 (make-overlay
 376                  (save-excursion
 377                    (beginning-of-visual-line)
 378                    (point))
 379                  (save-excursion
 380                    (end-of-visual-line)
 381                    (point)))
 382               (make-overlay
 383                (line-beginning-position)
 384                (1+ (line-end-position))))))
 385     (overlay-put ov 'face 'swiper-line-face)
 386     (overlay-put ov 'window (ivy-state-window ivy-last))
 387     (push ov swiper--overlays)
 388     (let* ((wh (window-height))
 389            (beg (or beg (save-excursion
 390                           (forward-line (- wh))
 391                           (point))))
 392            (end (or end (save-excursion
 393                           (forward-line wh)
 394                           (point)))))
 395       (when (>= (length re) swiper-min-highlight)
 396         (save-excursion
 397           (goto-char beg)
 398           ;; RE can become an invalid regexp
 399           (while (and (ignore-errors (re-search-forward re end t))
 400                       (> (- (match-end 0) (match-beginning 0)) 0))
 401             (let ((i 0))
 402               (while (<= i ivy--subexps)
 403                 (when (match-beginning i)
 404                   (let ((overlay (make-overlay (match-beginning i)
 405                                                (match-end i)))
 406                         (face
 407                          (cond ((zerop ivy--subexps)
 408                                 (cadr swiper-faces))
 409                                ((zerop i)
 410                                 (car swiper-faces))
 411                                (t
 412                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 413                                      swiper-faces)))))
 414                     (push overlay swiper--overlays)
 415                     (overlay-put overlay 'face face)
 416                     (overlay-put overlay 'window (ivy-state-window ivy-last))
 417                     (overlay-put overlay 'priority i)))
 418                 (cl-incf i)))))))))
 419
 420 (defun swiper--action (x input)
 421   "Goto line X and search for INPUT."
 422   (if (null x)
 423       (user-error "No candidates")
 424     (goto-char (point-min))
 425     (funcall (if visual-line-mode
 426                  #'line-move
 427                #'forward-line)
 428              (1- (read (get-text-property 0 'display x))))
 429     (re-search-forward
 430      (ivy--regex input) (line-end-position) t)
 431     (swiper--ensure-visible)
 432     (when (/= (point) swiper--opoint)
 433       (unless (and transient-mark-mode mark-active)
 434         (push-mark swiper--opoint t)
 435         (message "Mark saved where search started")))))
 436
 437 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 438 (defun swiper-from-isearch ()
 439   "Invoke `swiper' from isearch."
 440   (interactive)
 441   (let ((query (if isearch-regexp
 442                    isearch-string
 443                  (regexp-quote isearch-string))))
 444     (isearch-exit)
 445     (swiper query)))
 446
 447 (defvar swiper-multi-buffers nil
 448   "Store the current list of buffers.")
 449
 450 (defvar swiper-multi-candidates nil
 451   "Store the list of candidates for `swiper-multi'.")
 452
 453 (defun swiper-multi-prompt ()
 454   (format "Buffers (%s): "
 455           (mapconcat #'identity swiper-multi-buffers ", ")))
 456
 457 (defun swiper-multi ()
 458   "Select one or more buffers.
 459 Run `swiper' for those buffers."
 460   (interactive)
 461   (setq swiper-multi-buffers nil)
 462   (setq swiper-multi-candidates nil)
 463   (ivy-read (swiper-multi-prompt)
 464             'internal-complete-buffer
 465             :action 'swiper-multi-action-1)
 466   (ivy-read "Swiper: " swiper-multi-candidates
 467             :action 'swiper-multi-action-2
 468             :unwind #'swiper--cleanup))
 469
 470 (defun swiper-multi-action-1 (x)
 471   (if (member x swiper-multi-buffers)
 472       (progn
 473         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 474     (unless (equal x "")
 475       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 476   (let ((prompt (swiper-multi-prompt)))
 477     (setf (ivy-state-prompt ivy-last) prompt)
 478     (setq ivy--prompt (concat "%-4d " prompt)))
 479   (cond ((memq this-command '(ivy-done
 480                               ivy-alt-done
 481                               ivy-immediate-done))
 482          (let ((ww (window-width)))
 483            (dolist (buf swiper-multi-buffers)
 484              (with-current-buffer buf
 485                (setq swiper-multi-candidates
 486                      (append
 487                       (mapcar
 488                        (lambda (s)
 489                          (setq s (concat s " "))
 490                          (let ((len (length s)))
 491                            (put-text-property
 492                             (1- len) len 'display
 493                             (concat
 494                              (make-string
 495                               (max
 496                                (- ww
 497                                   (string-width s)
 498                                   (length (buffer-name))
 499                                   1)
 500                                0)
 501                               ?\ )
 502                              (buffer-name))
 503                             s)
 504                            s))
 505                        (swiper--candidates))
 506                       swiper-multi-candidates))))))
 507         ((eq this-command 'ivy-call)
 508          (delete-minibuffer-contents))))
 509
 510 (defun swiper-multi-action-2 (x)
 511   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 512     (with-ivy-window
 513       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 514         (switch-to-buffer (match-string 1 buf-space))
 515         (goto-char (point-min))
 516         (forward-line (1- (read x)))
 517         (re-search-forward
 518          (ivy--regex ivy-text)
 519          (line-end-position) t)
 520         (unless (eq ivy-exit 'done)
 521           (swiper--cleanup)
 522           (swiper--add-overlays (ivy--regex ivy-text)))))))
 523
 524 (provide 'swiper)
 525
 526 ;;; swiper.el ends here