code.delx.au - gnu-emacs-elpa/blob - company-tests.el

   1 ;;; company-tests.el --- company-mode tests
   2
   3 ;; Copyright (C) 2011, 2013-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'ert)
  30 (require 'company)
  31 (require 'company-keywords)
  32 (require 'company-elisp)
  33 (require 'company-clang)
  34
  35 ;;; Core
  36
  37 (ert-deftest company-sorted-keywords ()
  38   "Test that keywords in `company-keywords-alist' are in alphabetical order."
  39   (dolist (pair company-keywords-alist)
  40     (when (consp (cdr pair))
  41       (let ((prev (cadr pair)))
  42         (dolist (next (cddr pair))
  43           (should (not (equal prev next)))
  44           (should (string< prev next))
  45           (setq prev next))))))
  46
  47 (ert-deftest company-good-prefix ()
  48   (let ((company-minimum-prefix-length 5)
  49         company--explicit-action)
  50     (should (eq t (company--good-prefix-p "!@#$%")))
  51     (should (eq nil (company--good-prefix-p "abcd")))
  52     (should (eq nil (company--good-prefix-p 'stop)))
  53     (should (eq t (company--good-prefix-p '("foo" . 5))))
  54     (should (eq nil (company--good-prefix-p '("foo" . 4))))))
  55
  56 (ert-deftest company-multi-backend-with-lambdas ()
  57   (let ((company-backend
  58          (list (lambda (command &optional arg &rest ignore)
  59                  (case command
  60                    (prefix "z")
  61                    (candidates '("a" "b"))))
  62                (lambda (command &optional arg &rest ignore)
  63                  (case command
  64                    (prefix "z")
  65                    (candidates '("c" "d")))))))
  66     (should (equal (company-call-backend 'candidates "z") '("a" "b" "c" "d")))))
  67
  68 (ert-deftest company-begin-backend-failure-doesnt-break-company-backends ()
  69   (with-temp-buffer
  70     (insert "a")
  71     (company-mode)
  72     (should-error
  73      (company-begin-backend (lambda (command &rest ignore))))
  74     (let (company-frontends
  75           (company-backends
  76            (list (lambda (command &optional arg)
  77                    (case command
  78                      (prefix "a")
  79                      (candidates '("a" "ab" "ac")))))))
  80       (let (this-command)
  81         (company-call 'complete))
  82       (should (eq 3 company-candidates-length)))))
  83
  84 (ert-deftest company-require-match-explicit ()
  85   (with-temp-buffer
  86     (insert "ab")
  87     (company-mode)
  88     (let (company-frontends
  89           (company-require-match 'company-explicit-action-p)
  90           (company-backends
  91            (list (lambda (command &optional arg)
  92                    (case command
  93                      (prefix (buffer-substring (point-min) (point)))
  94                      (candidates '("abc" "abd")))))))
  95       (let (this-command)
  96         (company-complete))
  97       (let ((last-command-event ?e))
  98         (company-call 'self-insert-command 1))
  99       (should (eq 2 company-candidates-length))
 100       (should (eq 3 (point))))))
 101
 102 (ert-deftest company-dont-require-match-when-idle ()
 103   (with-temp-buffer
 104     (insert "ab")
 105     (company-mode)
 106     (let (company-frontends
 107           (company-require-match 'company-explicit-action-p)
 108           (company-backends
 109            (list (lambda (command &optional arg)
 110                    (case command
 111                      (prefix (buffer-substring (point-min) (point)))
 112                      (candidates '("abc" "abd")))))))
 113       (company-idle-begin (current-buffer) (selected-window)
 114                           (buffer-chars-modified-tick) (point))
 115       (let ((last-command-event ?e))
 116         (company-call 'self-insert-command 1))
 117       (should (eq nil company-candidates-length))
 118       (should (eq 4 (point))))))
 119
 120 (ert-deftest company-auto-complete-explicit ()
 121   (with-temp-buffer
 122     (insert "ab")
 123     (company-mode)
 124     (let (company-frontends
 125           (company-auto-complete 'company-explicit-action-p)
 126           (company-auto-complete-chars '(? ))
 127           (company-backends
 128            (list (lambda (command &optional arg)
 129                    (case command
 130                      (prefix (buffer-substring (point-min) (point)))
 131                      (candidates '("abcd" "abef")))))))
 132       (let (this-command)
 133         (company-complete))
 134       (let ((last-command-event ? ))
 135         (company-call 'self-insert-command 1))
 136       (should (string= "abcd " (buffer-string))))))
 137
 138 (ert-deftest company-no-auto-complete-when-idle ()
 139   (with-temp-buffer
 140     (insert "ab")
 141     (company-mode)
 142     (let (company-frontends
 143           (company-auto-complete 'company-explicit-action-p)
 144           (company-auto-complete-chars '(? ))
 145           (company-backends
 146            (list (lambda (command &optional arg)
 147                    (case command
 148                      (prefix (buffer-substring (point-min) (point)))
 149                      (candidates '("abcd" "abef")))))))
 150       (company-idle-begin (current-buffer) (selected-window)
 151                           (buffer-chars-modified-tick) (point))
 152       (let ((last-command-event ? ))
 153         (company-call 'self-insert-command 1))
 154       (should (string= "ab " (buffer-string))))))
 155
 156 (ert-deftest company-clears-explicit-action-when-no-matches ()
 157   (with-temp-buffer
 158     (company-mode)
 159     (let (company-frontends
 160           company-backends)
 161       (company-call 'manual-begin) ;; fails
 162       (should (null company-candidates))
 163       (should (null (company-explicit-action-p))))))
 164
 165 (ert-deftest company-ignore-case-replaces-prefix ()
 166   (with-temp-buffer
 167     (company-mode)
 168     (let (company-frontends
 169           company-end-of-buffer-workaround
 170           (company-backends
 171            (list (lambda (command &optional arg)
 172                    (case command
 173                      (prefix (buffer-substring (point-min) (point)))
 174                      (candidates '("abcd" "abef"))
 175                      (ignore-case t))))))
 176       (insert "A")
 177       (let (this-command)
 178         (company-complete))
 179       (should (string= "ab" (buffer-string)))
 180       (delete-char -2)
 181       (insert "A") ; hack, to keep it in one test
 182       (company-complete-selection)
 183       (should (string= "abcd" (buffer-string))))))
 184
 185 (ert-deftest company-ignore-case-with-keep-prefix ()
 186   (with-temp-buffer
 187     (insert "AB")
 188     (company-mode)
 189     (let (company-frontends
 190           (company-backends
 191            (list (lambda (command &optional arg)
 192                    (case command
 193                      (prefix (buffer-substring (point-min) (point)))
 194                      (candidates '("abcd" "abef"))
 195                      (ignore-case 'keep-prefix))))))
 196       (let (this-command)
 197         (company-complete))
 198       (company-complete-selection)
 199       (should (string= "ABcd" (buffer-string))))))
 200
 201 (ert-deftest company-non-prefix-completion ()
 202   (with-temp-buffer
 203     (insert "tc")
 204     (company-mode)
 205     (let (company-frontends
 206           company-end-of-buffer-workaround
 207           (company-backends
 208            (list (lambda (command &optional arg)
 209                    (case command
 210                      (prefix (buffer-substring (point-min) (point)))
 211                      (candidates '("tea-cup" "teal-color")))))))
 212       (let (this-command)
 213         (company-complete))
 214       (should (string= "tc" (buffer-string)))
 215       (company-complete-selection)
 216       (should (string= "tea-cup" (buffer-string))))))
 217
 218 (ert-deftest company-pseudo-tooltip-does-not-get-displaced ()
 219   :tags '(interactive)
 220   (with-temp-buffer
 221     (save-window-excursion
 222       (set-window-buffer nil (current-buffer))
 223       (save-excursion (insert " ff"))
 224       (company-mode)
 225       (let ((company-frontends '(company-pseudo-tooltip-frontend))
 226             (company-begin-commands '(self-insert-command))
 227             (company-backends
 228              (list (lambda (c &optional arg)
 229                      (case c (prefix "") (candidates '("a" "b" "c")))))))
 230         (let (this-command)
 231           (company-call 'complete))
 232         (company-call 'open-line 1)
 233         (should (eq 2 (overlay-start company-pseudo-tooltip-overlay)))))))
 234
 235 (ert-deftest company-pseudo-tooltip-show ()
 236   :tags '(interactive)
 237   (with-temp-buffer
 238     (save-window-excursion
 239     (set-window-buffer nil (current-buffer))
 240     (insert "aaaa\n  bb\nccccccc\nddd")
 241     (search-backward "bb")
 242     (let ((col (company--column))
 243           (company-candidates-length 2)
 244           (company-candidates '("123" "45")))
 245       (company-pseudo-tooltip-show (company--row) col 0)
 246       (let ((ov company-pseudo-tooltip-overlay))
 247         ;; With margins.
 248         (should (eq (overlay-get ov 'company-width) 5))
 249         ;; FIXME: Make it 2?
 250         (should (eq (overlay-get ov 'company-height) company-tooltip-limit))
 251         (should (eq (overlay-get ov 'company-column) col))
 252         (should (string= (overlay-get ov 'company-after)
 253                          "  123 \nc 45  c\nddd\n")))))))
 254
 255 (ert-deftest company-preview-show-with-annotations ()
 256   :tags '(interactive)
 257   (with-temp-buffer
 258     (save-window-excursion
 259       (set-window-buffer nil (current-buffer))
 260       (save-excursion (insert "\n"))
 261       (let ((company-candidates-length 1)
 262             (company-candidates '("123")))
 263         (company-preview-show-at-point (point))
 264         (let ((ov company-preview-overlay))
 265           (should (string= (overlay-get ov 'display) "123\n")))))))
 266
 267 (ert-deftest company-pseudo-tooltip-show-with-annotations ()
 268   :tags '(interactive)
 269   (with-temp-buffer
 270     (save-window-excursion
 271       (set-window-buffer nil (current-buffer))
 272       (insert " ")
 273       (save-excursion (insert "\n"))
 274       (let ((company-candidates-length 2)
 275             (company-backend (lambda (action &optional arg &rest _ignore)
 276                                (when (eq action 'annotation)
 277                                  (cdr (assoc arg '(("123" . "(4)")))))))
 278             (company-candidates '("123" "45")))
 279         (company-pseudo-tooltip-show-at-point (point))
 280         (let ((ov company-pseudo-tooltip-overlay))
 281           ;; With margins.
 282           (should (eq (overlay-get ov 'company-width) 8))
 283           (should (string= (overlay-get ov 'company-after)
 284                            " 123(4) \n 45     \n")))))))
 285
 286 (ert-deftest company-create-lines-shows-numbers ()
 287   (let ((company-show-numbers t)
 288         (company-candidates '("x" "y" "z"))
 289         (company-candidates-length 3))
 290     (should (equal '(" x 1 " " y 2 " " z 3 ")
 291                    (company--create-lines 0 999)))))
 292
 293 (ert-deftest company-column-with-composition ()
 294   (with-temp-buffer
 295     (insert "lambda ()")
 296     (compose-region 1 (1+ (length "lambda")) "\\")
 297     (should (= (company--column) 4))))
 298
 299 (ert-deftest company-column-with-line-prefix ()
 300   (with-temp-buffer
 301     (insert "foo")
 302     (put-text-property (point-min) (point) 'line-prefix "  ")
 303     (should (= (company--column) 5))))
 304
 305 (ert-deftest company-column-wth-line-prefix-on-empty-line ()
 306   (with-temp-buffer
 307     (insert "\n")
 308     (forward-char -1)
 309     (put-text-property (point-min) (point-max) 'line-prefix "  ")
 310     (should (= (company--column) 2))))
 311
 312 (ert-deftest company-plainify ()
 313   (let ((tab-width 8))
 314     (should (equal-including-properties
 315              (company-plainify "\tabc\td\t")
 316              (concat "        "
 317                      "abc     "
 318                      "d       "))))
 319   (should (equal-including-properties
 320            (company-plainify (propertize "foobar" 'line-prefix "-*-"))
 321            "-*-foobar")))
 322
 323 (ert-deftest company-modify-line ()
 324   (let ((str "-*-foobar"))
 325     (should (equal-including-properties
 326              (company-modify-line str "zz" 4)
 327              "-*-fzzbar"))
 328     (should (equal-including-properties
 329              (company-modify-line str "xx" 0)
 330              "xx-foobar"))
 331     (should (equal-including-properties
 332              (company-modify-line str "zz" 10)
 333              "-*-foobar zz"))))
 334
 335 (ert-deftest company-scrollbar-bounds ()
 336   (should (equal nil (company--scrollbar-bounds 0 3 3)))
 337   (should (equal nil (company--scrollbar-bounds 0 4 3)))
 338   (should (equal '(0 . 0) (company--scrollbar-bounds 0 1 2)))
 339   (should (equal '(1 . 1) (company--scrollbar-bounds 2 2 4)))
 340   (should (equal '(2 . 3) (company--scrollbar-bounds 7 4 12)))
 341   (should (equal '(1 . 2) (company--scrollbar-bounds 3 4 12)))
 342   (should (equal '(1 . 3) (company--scrollbar-bounds 4 5 11))))
 343
 344 ;;; Template
 345
 346 (ert-deftest company-template-removed-after-the-last-jump ()
 347   (with-temp-buffer
 348     (insert "{ }")
 349     (goto-char 2)
 350     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 351       (save-excursion
 352         (dotimes (i 2)
 353           (insert " ")
 354           (company-template-add-field tpl (point) "foo")))
 355       (company-call 'template-forward-field)
 356       (should (= 3 (point)))
 357       (company-call 'template-forward-field)
 358       (should (= 7 (point)))
 359       (company-call 'template-forward-field)
 360       (should (= 11 (point)))
 361       (should (zerop (length (overlay-get tpl 'company-template-fields))))
 362       (should (null (overlay-buffer tpl))))))
 363
 364 (ert-deftest company-template-removed-after-input-and-jump ()
 365   (with-temp-buffer
 366     (insert "{ }")
 367     (goto-char 2)
 368     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 369       (save-excursion
 370         (insert " ")
 371         (company-template-add-field tpl (point) "bar"))
 372       (company-call 'template-move-to-first tpl)
 373       (should (= 3 (point)))
 374       (dolist (c (string-to-list "tee"))
 375         (let ((last-command-event c))
 376           (company-call 'self-insert-command 1)))
 377       (should (string= "{ tee }" (buffer-string)))
 378       (should (overlay-buffer tpl))
 379       (company-call 'template-forward-field)
 380       (should (= 7 (point)))
 381       (should (null (overlay-buffer tpl))))))
 382
 383 (defun company-call (name &rest args)
 384   (let* ((maybe (intern (format "company-%s" name)))
 385          (command (if (fboundp maybe) maybe name)))
 386     (apply command args)
 387     (let ((this-command command))
 388       (run-hooks 'post-command-hook))))
 389
 390 (ert-deftest company-template-c-like-templatify ()
 391   (with-temp-buffer
 392     (let ((text "foo(int a, short b)"))
 393       (insert text)
 394       (company-template-c-like-templatify text)
 395       (should (equal "foo(arg0, arg1)" (buffer-string)))
 396       (should (looking-at "arg0"))
 397       (should (equal "int a"
 398                      (overlay-get (company-template-field-at) 'display))))))
 399
 400 (ert-deftest company-template-c-like-templatify-trims-after-closing-paren ()
 401   (with-temp-buffer
 402     (let ((text "foo(int a, short b)!@ #1334 a"))
 403       (insert text)
 404       (company-template-c-like-templatify text)
 405       (should (equal "foo(arg0, arg1)" (buffer-string)))
 406       (should (looking-at "arg0")))))
 407
 408 ;;; Elisp
 409
 410 (defmacro company-elisp-with-buffer (contents &rest body)
 411   (declare (indent 0))
 412   `(with-temp-buffer
 413      (insert ,contents)
 414      (setq major-mode 'emacs-lisp-mode)
 415      (re-search-backward "|")
 416      (replace-match "")
 417      (let ((company-elisp-detect-function-context t))
 418        ,@body)))
 419
 420 (ert-deftest company-elisp-candidates-predicate ()
 421   (company-elisp-with-buffer
 422     "(foo ba|)"
 423     (should (eq (company-elisp--candidates-predicate "ba")
 424                 'boundp))
 425     (should (eq (let (company-elisp-detect-function-context)
 426                   (company-elisp--candidates-predicate "ba"))
 427                 'company-elisp--predicate)))
 428   (company-elisp-with-buffer
 429     "(foo| )"
 430     (should (eq (company-elisp--candidates-predicate "foo")
 431                 'fboundp))
 432     (should (eq (let (company-elisp-detect-function-context)
 433                   (company-elisp--candidates-predicate "foo"))
 434                 'company-elisp--predicate)))
 435   (company-elisp-with-buffer
 436     "(foo 'b|)"
 437     (should (eq (company-elisp--candidates-predicate "b")
 438                 'company-elisp--predicate))))
 439
 440 (ert-deftest company-elisp-candidates-predicate-in-docstring ()
 441   (company-elisp-with-buffer
 442    "(def foo () \"Doo be doo `ide|"
 443    (should (eq 'company-elisp--predicate
 444                (company-elisp--candidates-predicate "ide")))))
 445
 446 ;; This one's also an integration test.
 447 (ert-deftest company-elisp-candidates-recognizes-binding-form ()
 448   (let ((company-elisp-detect-function-context t)
 449         (obarray [when what whelp])
 450         (what 1)
 451         (whelp 2)
 452         (wisp 3))
 453     (company-elisp-with-buffer
 454       "(let ((foo 7) (wh| )))"
 455       (should (equal '("what" "whelp")
 456                      (company-elisp-candidates "wh"))))
 457     (company-elisp-with-buffer
 458       "(cond ((null nil) (wh| )))"
 459       (should (equal '("when")
 460                      (company-elisp-candidates "wh"))))))
 461
 462 (ert-deftest company-elisp-candidates-predicate-binding-without-value ()
 463   (loop for (text prefix predicate) in '(("(let (foo|" "foo" boundp)
 464                                          ("(let (foo (bar|" "bar" boundp)
 465                                          ("(let (foo) (bar|" "bar" fboundp))
 466         do
 467         (eval `(company-elisp-with-buffer
 468                  ,text
 469                  (should (eq ',predicate
 470                              (company-elisp--candidates-predicate ,prefix)))))))
 471
 472 (ert-deftest company-elisp-finds-vars ()
 473   (let ((obarray [boo bar baz backquote])
 474         (boo t)
 475         (bar t)
 476         (baz t))
 477     (should (equal '("bar" "baz")
 478                    (company-elisp--globals "ba" 'boundp)))))
 479
 480 (ert-deftest company-elisp-finds-functions ()
 481   (let ((obarray [when what whelp])
 482         (what t)
 483         (whelp t))
 484     (should (equal '("when")
 485                    (company-elisp--globals "wh" 'fboundp)))))
 486
 487 (ert-deftest company-elisp-finds-things ()
 488   (let ((obarray [when what whelp])
 489         (what t)
 490         (whelp t))
 491     (should (equal '("what" "whelp" "when")
 492                    (sort (company-elisp--globals "wh" 'company-elisp--predicate)
 493                          'string<)))))
 494
 495 (ert-deftest company-elisp-locals-vars ()
 496   (company-elisp-with-buffer
 497     "(let ((foo 5) (bar 6))
 498        (cl-labels ((borg ()))
 499          (lambda (boo baz)
 500            b|)))"
 501     (should (equal '("bar" "baz" "boo")
 502                    (company-elisp--locals "b" nil)))))
 503
 504 (ert-deftest company-elisp-locals-single-var ()
 505   (company-elisp-with-buffer
 506     "(dotimes (itk 100)
 507        (dolist (item items)
 508          it|))"
 509     (should (equal '("itk" "item")
 510                    (company-elisp--locals "it" nil)))))
 511
 512 (ert-deftest company-elisp-locals-funs ()
 513   (company-elisp-with-buffer
 514     "(cl-labels ((foo ())
 515                  (fee ()))
 516        (let ((fun 4))
 517          (f| )))"
 518     (should (equal '("fee" "foo")
 519                    (sort (company-elisp--locals "f" t) 'string<)))))
 520
 521 (ert-deftest company-elisp-locals-skips-current-varlist ()
 522   (company-elisp-with-buffer
 523     "(let ((foo 1)
 524            (f| )))"
 525     (should (null (company-elisp--locals "f" nil)))))
 526
 527 (ert-deftest company-elisp-show-locals-first ()
 528   (company-elisp-with-buffer
 529     "(let ((floo 1)
 530            (flop 2)
 531            (flee 3))
 532        fl|)"
 533     (let ((obarray [float-pi]))
 534       (let (company-elisp-show-locals-first)
 535         (should (eq nil (company-elisp 'sorted))))
 536       (let ((company-elisp-show-locals-first t))
 537         (should (eq t (company-elisp 'sorted)))
 538         (should (equal '("flee" "floo" "flop" "float-pi")
 539                        (company-elisp-candidates "fl")))))))
 540
 541 (ert-deftest company-elisp-candidates-no-duplicates ()
 542   (company-elisp-with-buffer
 543     "(let ((float-pi 4))
 544        f|)"
 545     (let ((obarray [float-pi])
 546           (company-elisp-show-locals-first t))
 547       (should (equal '("float-pi") (company-elisp-candidates "f"))))))
 548
 549 (ert-deftest company-elisp-shouldnt-complete-defun-name ()
 550   (company-elisp-with-buffer
 551     "(defun foob|)"
 552     (should (null (company-elisp 'prefix)))))
 553
 554 (ert-deftest company-elisp-should-complete-def-call ()
 555   (company-elisp-with-buffer
 556     "(defu|"
 557     (should (equal "defu" (company-elisp 'prefix)))))
 558
 559 (ert-deftest company-elisp-should-complete-in-defvar ()
 560   ;; It will also complete the var name, at least for now.
 561   (company-elisp-with-buffer
 562     "(defvar abc de|"
 563     (should (equal "de" (company-elisp 'prefix)))))
 564
 565 (ert-deftest company-elisp-shouldnt-complete-in-defun-arglist ()
 566   (company-elisp-with-buffer
 567     "(defsubst foobar (ba|"
 568     (should (null (company-elisp 'prefix)))))
 569
 570 (ert-deftest company-elisp-prefix-in-defun-body ()
 571   (company-elisp-with-buffer
 572     "(defun foob ()|)"
 573     (should (equal "" (company-elisp 'prefix)))))
 574
 575 ;;; Clang
 576
 577 (ert-deftest company-clang-objc-templatify ()
 578   (with-temp-buffer
 579     (let ((text "createBookWithTitle:andAuthor:"))
 580       (insert text)
 581       (company-clang-objc-templatify text)
 582       (should (equal "createBookWithTitle:arg0 andAuthor:arg1" (buffer-string)))
 583       (should (looking-at "arg0"))
 584       (should (null (overlay-get (company-template-field-at) 'display))))))