code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.5.1
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (defface swiper-minibuffer-match-face-1
  65   '((((class color) (background light))
  66      :background "#d3d3d3")
  67     (((class color) (background dark))
  68      :background "#555555"))
  69   "The background face for `swiper' minibuffer matches."
  70   :group 'function-args-faces)
  71
  72 (defface swiper-minibuffer-match-face-2
  73   '((((class color) (background light))
  74      :background "#e99ce8" :weight bold)
  75     (((class color) (background dark))
  76      :background "#777777" :weight bold))
  77   "Face for `swiper' minibuffer matches modulo 1.")
  78
  79 (defface swiper-minibuffer-match-face-3
  80   '((((class color) (background light))
  81      :background "#bbbbff" :weight bold)
  82     (((class color) (background dark))
  83      :background "#7777ff" :weight bold))
  84   "Face for `swiper' minibuffer matches modulo 2.")
  85
  86 (defface swiper-minibuffer-match-face-4
  87   '((((class color) (background light))
  88      :background "#ffbbff" :weight bold)
  89     (((class color) (background dark))
  90      :background "#8a498a" :weight bold))
  91   "Face for `swiper' minibuffer matches modulo 3.")
  92
  93 (defface swiper-line-face
  94   '((t (:inherit highlight)))
  95   "Face for current `swiper' line.")
  96
  97 (defcustom swiper-faces '(swiper-match-face-1
  98                           swiper-match-face-2
  99                           swiper-match-face-3
 100                           swiper-match-face-4)
 101   "List of `swiper' faces for group matches.")
 102
 103 (defcustom swiper-min-highlight 2
 104   "Only highlight matches for regexps at least this long."
 105   :type 'integer)
 106
 107 (defvar swiper-map
 108   (let ((map (make-sparse-keymap)))
 109     (define-key map (kbd "M-q") 'swiper-query-replace)
 110     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
 111     (define-key map (kbd "C-'") 'swiper-avy)
 112     map)
 113   "Keymap for swiper.")
 114
 115 (defun swiper-query-replace ()
 116   "Start `query-replace' with string to replace from last search string."
 117   (interactive)
 118   (if (null (window-minibuffer-p))
 119       (user-error "Should only be called in the minibuffer through `swiper-map'")
 120     (let* ((enable-recursive-minibuffers t)
 121            (from (ivy--regex ivy-text))
 122            (to (query-replace-read-to from "Query replace" t)))
 123       (delete-minibuffer-contents)
 124       (ivy-set-action (lambda (_)
 125                         (with-ivy-window
 126                           (move-beginning-of-line 1)
 127                           (perform-replace from to
 128                                            t t nil))))
 129       (swiper--cleanup)
 130       (exit-minibuffer))))
 131
 132 (defvar avy-background)
 133 (defvar avy-all-windows)
 134 (declare-function avy--regex-candidates "ext:avy")
 135 (declare-function avy--process "ext:avy")
 136 (declare-function avy--overlay-post "ext:avy")
 137 (declare-function avy-action-goto "ext:avy")
 138
 139 ;;;###autoload
 140 (defun swiper-avy ()
 141   "Jump to one of the current swiper candidates."
 142   (interactive)
 143   (unless (string= ivy-text "")
 144     (let* ((avy-all-windows nil)
 145            (candidates (append
 146                         (with-ivy-window
 147                           (avy--regex-candidates
 148                            (ivy--regex ivy-text)))
 149                         (save-excursion
 150                           (save-restriction
 151                             (narrow-to-region (window-start) (window-end))
 152                             (goto-char (point-min))
 153                             (forward-line)
 154                             (let ((cands))
 155                               (while (< (point) (point-max))
 156                                 (push (cons (1+ (point))
 157                                             (selected-window))
 158                                       cands)
 159                                 (forward-line))
 160                               cands)))))
 161            (candidate (unwind-protect
 162                           (prog2
 163                               (avy--make-backgrounds
 164                                (append (avy-window-list)
 165                                        (list  (ivy-state-window ivy-last))))
 166                               (if (eq avy-style 'de-bruijn)
 167                                   (avy-read-de-bruijn
 168                                    candidates avy-keys)
 169                                 (avy-read (avy-tree candidates avy-keys)
 170                                           #'avy--overlay-post
 171                                           #'avy--remove-leading-chars))
 172                             (avy-push-mark))
 173                         (avy--done))))
 174       (if (window-minibuffer-p (cdr candidate))
 175           (progn
 176             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 177             (ivy--exhibit)
 178             (ivy-done)
 179             (ivy-call))
 180         (ivy-quit-and-run
 181          (avy-action-goto (caar candidate)))))))
 182
 183 (defun swiper-recenter-top-bottom (&optional arg)
 184   "Call (`recenter-top-bottom' ARG)."
 185   (interactive "P")
 186   (with-ivy-window
 187     (recenter-top-bottom arg)))
 188
 189 (defun swiper-font-lock-ensure ()
 190   "Ensure the entired buffer is highlighted."
 191   (unless (or (derived-mode-p 'magit-mode)
 192               (bound-and-true-p magit-blame-mode)
 193               (memq major-mode '(package-menu-mode
 194                                  gnus-summary-mode
 195                                  gnus-article-mode
 196                                  gnus-group-mode
 197                                  emms-playlist-mode erc-mode
 198                                  org-agenda-mode
 199                                  dired-mode
 200                                  jabber-chat-mode
 201                                  elfeed-search-mode
 202                                  fundamental-mode
 203                                  Man-mode
 204                                  woman-mode
 205                                  mu4e-view-mode
 206                                  mu4e-headers-mode)))
 207     (unless (> (buffer-size) 100000)
 208       (if (fboundp 'font-lock-ensure)
 209           (font-lock-ensure)
 210         (with-no-warnings (font-lock-fontify-buffer))))))
 211
 212 (defvar swiper--format-spec ""
 213   "Store the current candidates format spec.")
 214
 215 (defvar swiper--width nil
 216   "Store the amount of digits needed for the longest line nubmer.")
 217
 218 (defun swiper--candidates ()
 219   "Return a list of this buffer lines."
 220   (let ((n-lines (count-lines (point-min) (point-max))))
 221     (unless (zerop n-lines)
 222       (setq swiper--width (1+ (floor (log n-lines 10))))
 223       (setq swiper--format-spec
 224             (format "%%-%dd " swiper--width))
 225       (let ((line-number 0)
 226             (advancer (if (and visual-line-mode
 227                                (< (buffer-size) 20000))
 228                           (lambda (arg) (line-move arg t))
 229                         #'forward-line))
 230             candidates)
 231         (save-excursion
 232           (goto-char (point-min))
 233           (swiper-font-lock-ensure)
 234           (while (< (point) (point-max))
 235             (let ((str (concat " " (buffer-substring
 236                                     (point)
 237                                     (if visual-line-mode
 238                                         (save-excursion
 239                                           (end-of-visual-line)
 240                                           (point))
 241                                       (line-end-position))))))
 242               (put-text-property 0 1 'display
 243                                  (format swiper--format-spec
 244                                          (cl-incf line-number))
 245                                  str)
 246               (push str candidates))
 247             (funcall advancer 1))
 248           (nreverse candidates))))))
 249
 250 (defvar swiper--opoint 1
 251   "The point when `swiper' starts.")
 252
 253 ;;;###autoload
 254 (defun swiper (&optional initial-input)
 255   "`isearch' with an overview.
 256 When non-nil, INITIAL-INPUT is the initial search pattern."
 257   (interactive)
 258   (swiper--ivy initial-input))
 259
 260 (defvar swiper--anchor nil
 261   "A line number to which the search should be anchored.")
 262
 263 (defvar swiper--len 0
 264   "The last length of input for which an anchoring was made.")
 265
 266 (defun swiper--init ()
 267   "Perform initialization common to both completion methods."
 268   (setq swiper--opoint (point))
 269   (setq swiper--len 0)
 270   (setq swiper--anchor (line-number-at-pos)))
 271
 272 (defun swiper--re-builder (str)
 273   "Transform STR into a swiper regex.
 274 This is the regex used in the minibuffer, since the candidates
 275 there have line numbers. In the buffer, `ivy--regex' should be used."
 276   (cond
 277     ((equal str "")
 278      "")
 279     ((equal str "^")
 280      ".")
 281     ((string-match "^\\^" str)
 282      (setq ivy--old-re "")
 283      (let ((re (ivy--regex-plus (substring str 1))))
 284        (format "^[0-9][0-9 ]\\{%d\\}%s"
 285                swiper--width
 286                (if (zerop ivy--subexps)
 287                    (prog1 (format "\\(%s\\)" re)
 288                      (setq ivy--subexps 1))
 289                  re))))
 290     (t
 291      (ivy--regex-plus str))))
 292
 293 (defvar swiper-history nil
 294   "History for `swiper'.")
 295
 296 (defun swiper--ivy (&optional initial-input)
 297   "`isearch' with an overview using `ivy'.
 298 When non-nil, INITIAL-INPUT is the initial search pattern."
 299   (interactive)
 300   (swiper--init)
 301   (let ((candidates (swiper--candidates))
 302         (preselect (buffer-substring-no-properties
 303                     (line-beginning-position)
 304                     (line-end-position)))
 305         (minibuffer-allow-text-properties t)
 306         res)
 307     (unwind-protect
 308          (setq res (ivy-read
 309                     "Swiper: "
 310                     candidates
 311                     :initial-input initial-input
 312                     :keymap swiper-map
 313                     :preselect preselect
 314                     :require-match t
 315                     :update-fn #'swiper--update-input-ivy
 316                     :unwind #'swiper--cleanup
 317                     :re-builder #'swiper--re-builder
 318                     :history 'swiper-history))
 319       (if (null ivy-exit)
 320           (goto-char swiper--opoint)
 321         (swiper--action res ivy-text)))))
 322
 323 (defun swiper--ensure-visible ()
 324   "Remove overlays hiding point."
 325   (let ((overlays (overlays-at (point)))
 326         ov expose)
 327     (while (setq ov (pop overlays))
 328       (if (and (invisible-p (overlay-get ov 'invisible))
 329                (setq expose (overlay-get ov 'isearch-open-invisible)))
 330           (funcall expose ov)))))
 331
 332 (defvar swiper--overlays nil
 333   "Store overlays.")
 334
 335 (defun swiper--cleanup ()
 336   "Clean up the overlays."
 337   (while swiper--overlays
 338     (delete-overlay (pop swiper--overlays)))
 339   (save-excursion
 340     (goto-char (point-min))
 341     (isearch-clean-overlays)))
 342
 343 (defun swiper--update-input-ivy ()
 344   "Called when `ivy' input is updated."
 345   (with-ivy-window
 346     (swiper--cleanup)
 347     (when (> (length ivy--current) 0)
 348       (let* ((re (funcall ivy--regex-function ivy-text))
 349              (re (if (stringp re) re (caar re)))
 350              (str (get-text-property 0 'display ivy--current))
 351              (num (if (string-match "^[0-9]+" str)
 352                       (string-to-number (match-string 0 str))
 353                     0)))
 354         (goto-char (point-min))
 355         (when (cl-plusp num)
 356           (goto-char (point-min))
 357           (if visual-line-mode
 358               (line-move (1- num))
 359             (forward-line (1- num)))
 360           (if (and (equal ivy-text "")
 361                    (>= swiper--opoint (line-beginning-position))
 362                    (<= swiper--opoint (line-end-position)))
 363               (goto-char swiper--opoint)
 364             (re-search-forward re (line-end-position) t))
 365           (isearch-range-invisible (line-beginning-position)
 366                                    (line-end-position))
 367           (unless (and (>= (point) (window-start))
 368                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 369             (recenter)))
 370         (swiper--add-overlays re)))))
 371
 372 (defun swiper--add-overlays (re &optional beg end)
 373   "Add overlays for RE regexp in visible part of the current buffer.
 374 BEG and END, when specified, are the point bounds."
 375   (let ((ov (if visual-line-mode
 376                 (make-overlay
 377                  (save-excursion
 378                    (beginning-of-visual-line)
 379                    (point))
 380                  (save-excursion
 381                    (end-of-visual-line)
 382                    (point)))
 383               (make-overlay
 384                (line-beginning-position)
 385                (1+ (line-end-position))))))
 386     (overlay-put ov 'face 'swiper-line-face)
 387     (overlay-put ov 'window (ivy-state-window ivy-last))
 388     (push ov swiper--overlays)
 389     (let* ((wh (window-height))
 390            (beg (or beg (save-excursion
 391                           (forward-line (- wh))
 392                           (point))))
 393            (end (or end (save-excursion
 394                           (forward-line wh)
 395                           (point)))))
 396       (when (>= (length re) swiper-min-highlight)
 397         (save-excursion
 398           (goto-char beg)
 399           ;; RE can become an invalid regexp
 400           (while (and (ignore-errors (re-search-forward re end t))
 401                       (> (- (match-end 0) (match-beginning 0)) 0))
 402             (let ((i 0))
 403               (while (<= i ivy--subexps)
 404                 (when (match-beginning i)
 405                   (let ((overlay (make-overlay (match-beginning i)
 406                                                (match-end i)))
 407                         (face
 408                          (cond ((zerop ivy--subexps)
 409                                 (cadr swiper-faces))
 410                                ((zerop i)
 411                                 (car swiper-faces))
 412                                (t
 413                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 414                                      swiper-faces)))))
 415                     (push overlay swiper--overlays)
 416                     (overlay-put overlay 'face face)
 417                     (overlay-put overlay 'window (ivy-state-window ivy-last))
 418                     (overlay-put overlay 'priority i)))
 419                 (cl-incf i)))))))))
 420
 421 (defun swiper--action (x input)
 422   "Goto line X and search for INPUT."
 423   (if (null x)
 424       (user-error "No candidates")
 425     (goto-char (point-min))
 426     (funcall (if visual-line-mode
 427                  #'line-move
 428                #'forward-line)
 429              (1- (read (get-text-property 0 'display x))))
 430     (re-search-forward
 431      (ivy--regex input) (line-end-position) t)
 432     (swiper--ensure-visible)
 433     (when (/= (point) swiper--opoint)
 434       (unless (and transient-mark-mode mark-active)
 435         (push-mark swiper--opoint t)
 436         (message "Mark saved where search started")))))
 437
 438 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 439 (defun swiper-from-isearch ()
 440   "Invoke `swiper' from isearch."
 441   (interactive)
 442   (let ((query (if isearch-regexp
 443                    isearch-string
 444                  (regexp-quote isearch-string))))
 445     (isearch-exit)
 446     (swiper query)))
 447
 448 (defvar swiper-multi-buffers nil
 449   "Store the current list of buffers.")
 450
 451 (defvar swiper-multi-candidates nil
 452   "Store the list of candidates for `swiper-multi'.")
 453
 454 (defun swiper-multi-prompt ()
 455   (format "Buffers (%s): "
 456           (mapconcat #'identity swiper-multi-buffers ", ")))
 457
 458 (defun swiper-multi ()
 459   "Select one or more buffers.
 460 Run `swiper' for those buffers."
 461   (interactive)
 462   (setq swiper-multi-buffers nil)
 463   (setq swiper-multi-candidates nil)
 464   (ivy-read (swiper-multi-prompt)
 465             'internal-complete-buffer
 466             :action 'swiper-multi-action-1)
 467   (ivy-read "Swiper: " swiper-multi-candidates
 468             :action 'swiper-multi-action-2
 469             :unwind #'swiper--cleanup))
 470
 471 (defun swiper-multi-action-1 (x)
 472   (if (member x swiper-multi-buffers)
 473       (progn
 474         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 475     (unless (equal x "")
 476       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 477   (let ((prompt (swiper-multi-prompt)))
 478     (setf (ivy-state-prompt ivy-last) prompt)
 479     (setq ivy--prompt (concat "%-4d " prompt)))
 480   (cond ((memq this-command '(ivy-done
 481                               ivy-alt-done
 482                               ivy-immediate-done))
 483          (let ((ww (window-width)))
 484            (dolist (buf swiper-multi-buffers)
 485              (with-current-buffer buf
 486                (setq swiper-multi-candidates
 487                      (append
 488                       (mapcar
 489                        (lambda (s)
 490                          (setq s (concat s " "))
 491                          (let ((len (length s)))
 492                            (put-text-property
 493                             (1- len) len 'display
 494                             (concat
 495                              (make-string
 496                               (max
 497                                (- ww
 498                                   (string-width s)
 499                                   (length (buffer-name))
 500                                   1)
 501                                0)
 502                               ?\ )
 503                              (buffer-name))
 504                             s)
 505                            s))
 506                        (swiper--candidates))
 507                       swiper-multi-candidates))))))
 508         ((eq this-command 'ivy-call)
 509          (delete-minibuffer-contents))))
 510
 511 (defun swiper-multi-action-2 (x)
 512   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 513     (with-ivy-window
 514       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 515         (switch-to-buffer (match-string 1 buf-space))
 516         (goto-char (point-min))
 517         (forward-line (1- (read x)))
 518         (re-search-forward
 519          (ivy--regex ivy-text)
 520          (line-end-position) t)
 521         (unless (eq ivy-exit 'done)
 522           (swiper--cleanup)
 523           (swiper--add-overlays (ivy--regex ivy-text)))))))
 524
 525 (provide 'swiper)
 526
 527 ;;; swiper.el ends here