code.delx.au - gnu-emacs-elpa/blob - company-tests.el

   1 ;;; company-tests.el --- company-mode tests
   2
   3 ;; Copyright (C) 2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'ert)
  30 (require 'company)
  31 (require 'company-keywords)
  32 (require 'company-elisp)
  33 (require 'company-clang)
  34
  35 ;;; Core
  36
  37 (ert-deftest company-sorted-keywords ()
  38   "Test that keywords in `company-keywords-alist' are in alphabetical order."
  39   (dolist (pair company-keywords-alist)
  40     (when (consp (cdr pair))
  41       (let ((prev (cadr pair)))
  42         (dolist (next (cddr pair))
  43           (should (not (equal prev next)))
  44           (should (string< prev next))
  45           (setq prev next))))))
  46
  47 (ert-deftest company-good-prefix ()
  48   (let ((company-minimum-prefix-length 5)
  49         company--explicit-action)
  50     (should (eq t (company--good-prefix-p "!@#$%")))
  51     (should (eq nil (company--good-prefix-p "abcd")))
  52     (should (eq nil (company--good-prefix-p 'stop)))
  53     (should (eq t (company--good-prefix-p '("foo" . 5))))
  54     (should (eq nil (company--good-prefix-p '("foo" . 4))))))
  55
  56 (ert-deftest company-multi-backend-with-lambdas ()
  57   (let ((company-backend
  58          (list (lambda (command &optional arg &rest ignore)
  59                  (case command
  60                    (prefix "z")
  61                    (candidates '("a" "b"))))
  62                (lambda (command &optional arg &rest ignore)
  63                  (case command
  64                    (prefix "z")
  65                    (candidates '("c" "d")))))))
  66     (should (equal (company-call-backend 'candidates "z") '("a" "b" "c" "d")))))
  67
  68 (ert-deftest company-begin-backend-failure-doesnt-break-company-backends ()
  69   (with-temp-buffer
  70     (insert "a")
  71     (company-mode)
  72     (should-error
  73      (company-begin-backend (lambda (command &rest ignore))))
  74     (let (company-frontends
  75           (company-backends
  76            (list (lambda (command &optional arg)
  77                    (case command
  78                      (prefix "a")
  79                      (candidates '("a" "ab" "ac")))))))
  80       (let (this-command)
  81         (company-call 'complete))
  82       (should (eq 3 company-candidates-length)))))
  83
  84 (ert-deftest company-require-match-explicit ()
  85   (with-temp-buffer
  86     (insert "ab")
  87     (company-mode)
  88     (let (company-frontends
  89           (company-require-match 'company-explicit-action-p)
  90           (company-backends
  91            (list (lambda (command &optional arg)
  92                    (case command
  93                      (prefix (buffer-substring (point-min) (point)))
  94                      (candidates '("abc" "abd")))))))
  95       (let (this-command)
  96         (company-complete))
  97       (let ((last-command-event ?e))
  98         (company-call 'self-insert-command 1))
  99       (should (eq 2 company-candidates-length))
 100       (should (eq 3 (point))))))
 101
 102 (ert-deftest company-dont-require-match-when-idle ()
 103   (with-temp-buffer
 104     (insert "ab")
 105     (company-mode)
 106     (let (company-frontends
 107           (company-require-match 'company-explicit-action-p)
 108           (company-backends
 109            (list (lambda (command &optional arg)
 110                    (case command
 111                      (prefix (buffer-substring (point-min) (point)))
 112                      (candidates '("abc" "abd")))))))
 113       (company-idle-begin (current-buffer) (selected-window)
 114                           (buffer-chars-modified-tick) (point))
 115       (let ((last-command-event ?e))
 116         (company-call 'self-insert-command 1))
 117       (should (eq nil company-candidates-length))
 118       (should (eq 4 (point))))))
 119
 120 (ert-deftest company-auto-complete-explicit ()
 121   (with-temp-buffer
 122     (insert "ab")
 123     (company-mode)
 124     (let (company-frontends
 125           (company-auto-complete 'company-explicit-action-p)
 126           (company-auto-complete-chars '(? ))
 127           (company-backends
 128            (list (lambda (command &optional arg)
 129                    (case command
 130                      (prefix (buffer-substring (point-min) (point)))
 131                      (candidates '("abcd" "abef")))))))
 132       (let (this-command)
 133         (company-complete))
 134       (let ((last-command-event ? ))
 135         (company-call 'self-insert-command 1))
 136       (should (string= "abcd " (buffer-string))))))
 137
 138 (ert-deftest company-no-auto-complete-when-idle ()
 139   (with-temp-buffer
 140     (insert "ab")
 141     (company-mode)
 142     (let (company-frontends
 143           (company-auto-complete 'company-explicit-action-p)
 144           (company-auto-complete-chars '(? ))
 145           (company-backends
 146            (list (lambda (command &optional arg)
 147                    (case command
 148                      (prefix (buffer-substring (point-min) (point)))
 149                      (candidates '("abcd" "abef")))))))
 150       (company-idle-begin (current-buffer) (selected-window)
 151                           (buffer-chars-modified-tick) (point))
 152       (let ((last-command-event ? ))
 153         (company-call 'self-insert-command 1))
 154       (should (string= "ab " (buffer-string))))))
 155
 156 (ert-deftest company-clears-explicit-action-when-no-matches ()
 157   (with-temp-buffer
 158     (company-mode)
 159     (let (company-frontends
 160           company-backends)
 161       (company-call 'manual-begin) ;; fails
 162       (should (null company-candidates))
 163       (should (null (company-explicit-action-p))))))
 164
 165 (ert-deftest company-pseudo-tooltip-does-not-get-displaced ()
 166   :tags '(interactive)
 167   (with-temp-buffer
 168     (save-window-excursion
 169       (set-window-buffer nil (current-buffer))
 170       (save-excursion (insert " ff"))
 171       (company-mode)
 172       (let ((company-frontends '(company-pseudo-tooltip-frontend))
 173             (company-begin-commands '(self-insert-command))
 174             (company-backends
 175              (list (lambda (c &optional arg)
 176                      (case c (prefix "") (candidates '("a" "b" "c")))))))
 177         (let (this-command)
 178           (company-call 'complete))
 179         (company-call 'open-line 1)
 180         (should (eq 2 (overlay-start company-pseudo-tooltip-overlay)))))))
 181
 182 (ert-deftest company-pseudo-tooltip-overlay-show ()
 183   :tags '(interactive)
 184   (with-temp-buffer
 185     (save-window-excursion
 186     (set-window-buffer nil (current-buffer))
 187     (insert "aaaa\n bb\nccccc\nddd")
 188     (search-backward "bb")
 189     (let ((col (company--column))
 190           (company-candidates-length 2)
 191           (company-candidates '("123" "45")))
 192       (company-pseudo-tooltip-show (company--row) col 0)
 193       (let ((ov company-pseudo-tooltip-overlay))
 194         (should (eq (overlay-get ov 'company-width) 3))
 195         ;; FIXME: Make it 2?
 196         (should (eq (overlay-get ov 'company-height) company-tooltip-limit))
 197         (should (eq (overlay-get ov 'company-column) col))
 198         (should (string= (overlay-get ov 'company-before)
 199                          " 123\nc45 c\nddd\n")))))))
 200
 201 (ert-deftest company-column-with-composition ()
 202   (with-temp-buffer
 203     (insert "lambda ()")
 204     (compose-region 1 (1+ (length "lambda")) "\\")
 205     (should (= (company--column) 4))))
 206
 207 (ert-deftest company-column-with-line-prefix ()
 208   (with-temp-buffer
 209     (insert "foo")
 210     (put-text-property (point-min) (point) 'line-prefix "  ")
 211     (should (= (company--column) 5))))
 212
 213 (ert-deftest company-modify-line-with-line-prefix ()
 214   (let ((str (propertize "foobar" 'line-prefix "-*-")))
 215     (should (string= (company-modify-line str "zz" 4)
 216                      "fzzbar"))
 217     (should (string= (company-modify-line str "zzxx" 0)
 218                      "zzxxoobar"))
 219     (should (string= (company-modify-line str "zzxx" 0)
 220                      "zzxxoobar"))
 221     (should (string= (company-modify-line str "zz" 10)
 222                      "foobar zz"))))
 223
 224 ;;; Template
 225
 226 (ert-deftest company-template-removed-after-the-last-jump ()
 227   (with-temp-buffer
 228     (insert "{ }")
 229     (goto-char 2)
 230     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 231       (save-excursion
 232         (dotimes (i 2)
 233           (insert " ")
 234           (company-template-add-field tpl (point) "foo")))
 235       (company-call 'template-forward-field)
 236       (should (= 3 (point)))
 237       (company-call 'template-forward-field)
 238       (should (= 7 (point)))
 239       (company-call 'template-forward-field)
 240       (should (= 11 (point)))
 241       (should (zerop (length (overlay-get tpl 'company-template-fields))))
 242       (should (null (overlay-buffer tpl))))))
 243
 244 (ert-deftest company-template-removed-after-input-and-jump ()
 245   (with-temp-buffer
 246     (insert "{ }")
 247     (goto-char 2)
 248     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 249       (save-excursion
 250         (insert " ")
 251         (company-template-add-field tpl (point) "bar"))
 252       (company-call 'template-move-to-first tpl)
 253       (should (= 3 (point)))
 254       (dolist (c (string-to-list "tee"))
 255         (let ((last-command-event c))
 256           (company-call 'self-insert-command 1)))
 257       (should (string= "{ tee }" (buffer-string)))
 258       (should (overlay-buffer tpl))
 259       (company-call 'template-forward-field)
 260       (should (= 7 (point)))
 261       (should (null (overlay-buffer tpl))))))
 262
 263 (defun company-call (name &rest args)
 264   (let* ((maybe (intern (format "company-%s" name)))
 265          (command (if (fboundp maybe) maybe name)))
 266     (apply command args)
 267     (let ((this-command command))
 268       (run-hooks 'post-command-hook))))
 269
 270 (ert-deftest company-template-c-like-templatify ()
 271   (with-temp-buffer
 272     (let ((text "foo(int a, short b)"))
 273       (insert text)
 274       (company-template-c-like-templatify text)
 275       (should (equal "foo(arg0, arg1)" (buffer-string)))
 276       (should (looking-at "arg0"))
 277       (should (equal "int a"
 278                      (overlay-get (company-template-field-at) 'display))))))
 279
 280 ;;; Elisp
 281
 282 (defmacro company-elisp-with-buffer (contents &rest body)
 283   (declare (indent 0))
 284   `(with-temp-buffer
 285      (insert ,contents)
 286      (setq major-mode 'emacs-lisp-mode)
 287      (re-search-backward "|")
 288      (replace-match "")
 289      (let ((company-elisp-detect-function-context t))
 290        ,@body)))
 291
 292 (ert-deftest company-elisp-candidates-predicate ()
 293   (company-elisp-with-buffer
 294     "(foo ba|)"
 295     (should (eq (company-elisp--candidates-predicate "ba")
 296                 'boundp))
 297     (should (eq (let (company-elisp-detect-function-context)
 298                   (company-elisp--candidates-predicate "ba"))
 299                 'company-elisp--predicate)))
 300   (company-elisp-with-buffer
 301     "(foo| )"
 302     (should (eq (company-elisp--candidates-predicate "foo")
 303                 'fboundp))
 304     (should (eq (let (company-elisp-detect-function-context)
 305                   (company-elisp--candidates-predicate "foo"))
 306                 'company-elisp--predicate)))
 307   (company-elisp-with-buffer
 308     "(foo 'b|)"
 309     (should (eq (company-elisp--candidates-predicate "b")
 310                 'company-elisp--predicate))))
 311
 312 (ert-deftest company-elisp-candidates-predicate-in-docstring ()
 313   (company-elisp-with-buffer
 314    "(def foo () \"Doo be doo `ide|"
 315    (should (eq 'company-elisp--predicate
 316                (company-elisp--candidates-predicate "ide")))))
 317
 318 ;; This one's also an integration test.
 319 (ert-deftest company-elisp-candidates-recognizes-binding-form ()
 320   (let ((company-elisp-detect-function-context t)
 321         (obarray [when what whelp])
 322         (what 1)
 323         (whelp 2)
 324         (wisp 3))
 325     (company-elisp-with-buffer
 326       "(let ((foo 7) (wh| )))"
 327       (should (equal '("what" "whelp")
 328                      (company-elisp-candidates "wh"))))
 329     (company-elisp-with-buffer
 330       "(cond ((null nil) (wh| )))"
 331       (should (equal '("when")
 332                      (company-elisp-candidates "wh"))))))
 333
 334 (ert-deftest company-elisp-candidates-predicate-binding-without-value ()
 335   (loop for (text prefix predicate) in '(("(let (foo|" "foo" boundp)
 336                                          ("(let (foo (bar|" "bar" boundp)
 337                                          ("(let (foo) (bar|" "bar" fboundp))
 338         do
 339         (eval `(company-elisp-with-buffer
 340                  ,text
 341                  (should (eq ',predicate
 342                              (company-elisp--candidates-predicate ,prefix)))))))
 343
 344 (ert-deftest company-elisp-finds-vars ()
 345   (let ((obarray [boo bar baz backquote])
 346         (boo t)
 347         (bar t)
 348         (baz t))
 349     (should (equal '("bar" "baz")
 350                    (company-elisp--globals "ba" 'boundp)))))
 351
 352 (ert-deftest company-elisp-finds-functions ()
 353   (let ((obarray [when what whelp])
 354         (what t)
 355         (whelp t))
 356     (should (equal '("when")
 357                    (company-elisp--globals "wh" 'fboundp)))))
 358
 359 (ert-deftest company-elisp-finds-things ()
 360   (let ((obarray [when what whelp])
 361         (what t)
 362         (whelp t))
 363     (should (equal '("what" "whelp" "when")
 364                    (sort (company-elisp--globals "wh" 'company-elisp--predicate)
 365                          'string<)))))
 366
 367 (ert-deftest company-elisp-locals-vars ()
 368   (company-elisp-with-buffer
 369     "(let ((foo 5) (bar 6))
 370        (cl-labels ((borg ()))
 371          (lambda (boo baz)
 372            b|)))"
 373     (should (equal '("bar" "baz" "boo")
 374                    (company-elisp--locals "b" nil)))))
 375
 376 (ert-deftest company-elisp-locals-single-var ()
 377   (company-elisp-with-buffer
 378     "(dotimes (itk 100)
 379        (dolist (item items)
 380          it|))"
 381     (should (equal '("itk" "item")
 382                    (company-elisp--locals "it" nil)))))
 383
 384 (ert-deftest company-elisp-locals-funs ()
 385   (company-elisp-with-buffer
 386     "(cl-labels ((foo ())
 387                  (fee ()))
 388        (let ((fun 4))
 389          (f| )))"
 390     (should (equal '("fee" "foo")
 391                    (sort (company-elisp--locals "f" t) 'string<)))))
 392
 393 (ert-deftest company-elisp-locals-skips-current-varlist ()
 394   (company-elisp-with-buffer
 395     "(let ((foo 1)
 396            (f| )))"
 397     (should (null (company-elisp--locals "f" nil)))))
 398
 399 (ert-deftest company-elisp-show-locals-first ()
 400   (company-elisp-with-buffer
 401     "(let ((floo 1)
 402            (flop 2)
 403            (flee 3))
 404        fl|)"
 405     (let ((obarray [float-pi]))
 406       (let (company-elisp-show-locals-first)
 407         (should (eq nil (company-elisp 'sorted))))
 408       (let ((company-elisp-show-locals-first t))
 409         (should (eq t (company-elisp 'sorted)))
 410         (should (equal '("flee" "floo" "flop" "float-pi")
 411                        (company-elisp-candidates "fl")))))))
 412
 413 (ert-deftest company-elisp-candidates-no-duplicates ()
 414   (company-elisp-with-buffer
 415     "(let ((float-pi 4))
 416        f|)"
 417     (let ((obarray [float-pi])
 418           (company-elisp-show-locals-first t))
 419       (should (equal '("float-pi") (company-elisp-candidates "f"))))))
 420
 421 (ert-deftest company-elisp-shouldnt-complete-defun-name ()
 422   (company-elisp-with-buffer
 423     "(defun foob|)"
 424     (should (null (company-elisp 'prefix)))))
 425
 426 (ert-deftest company-elisp-should-complete-def-call ()
 427   (company-elisp-with-buffer
 428     "(defu|"
 429     (should (equal "defu" (company-elisp 'prefix)))))
 430
 431 (ert-deftest company-elisp-should-complete-in-defvar ()
 432   ;; It will also complete the var name, at least for now.
 433   (company-elisp-with-buffer
 434     "(defvar abc de|"
 435     (should (equal "de" (company-elisp 'prefix)))))
 436
 437 (ert-deftest company-elisp-shouldnt-complete-in-defun-arglist ()
 438   (company-elisp-with-buffer
 439     "(defsubst foobar (ba|"
 440     (should (null (company-elisp 'prefix)))))
 441
 442 (ert-deftest company-elisp-prefix-in-defun-body ()
 443   (company-elisp-with-buffer
 444     "(defun foob ()|)"
 445     (should (equal "" (company-elisp 'prefix)))))
 446
 447 ;;; Clang
 448
 449 (ert-deftest company-clang-objc-templatify ()
 450   (with-temp-buffer
 451     (let ((text "createBookWithTitle:andAuthor:"))
 452       (insert text)
 453       (company-clang-objc-templatify text)
 454       (should (equal "createBookWithTitle:arg0 andAuthor:arg1" (buffer-string)))
 455       (should (looking-at "arg0"))
 456       (should (null (overlay-get (company-template-field-at) 'display))))))