code.delx.au - gnu-emacs-elpa/blob - context-coloring.el

   1 ;;; context-coloring.el --- Highlight by scope  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2014-2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Jackson Ray Hamilton <jackson@jacksonrayhamilton.com>
   6 ;; Version: 6.2.1
   7 ;; Keywords: convenience faces tools
   8 ;; Package-Requires: ((emacs "24") (js2-mode "20150126"))
   9 ;; URL: https://github.com/jacksonrayhamilton/context-coloring
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This program is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Highlights code by scope.  Top-level scopes are one color, second-level
  29 ;; scopes are another color, and so on.  Variables retain the color of the scope
  30 ;; in which they are defined.  A variable defined in an outer scope referenced
  31 ;; by an inner scope is colored the same as the outer scope.
  32
  33 ;; By default, comments and strings are still highlighted syntactically.
  34
  35 ;; To use with js2-mode, add the following to your init file:
  36
  37 ;; (require 'context-coloring)
  38 ;; (add-hook 'js2-mode-hook 'context-coloring-mode)
  39
  40 ;; To use with js-mode or js3-mode, install Node.js 0.10+ and the scopifier
  41 ;; executable:
  42
  43 ;; $ npm install -g scopifier
  44
  45 ;;; Code:
  46
  47 (require 'js2-mode)
  48
  49
  50 ;;; Local variables
  51
  52 (defvar-local context-coloring-buffer nil
  53   "Reference to this buffer (for timers).")
  54
  55
  56 ;;; Utilities
  57
  58 (defun context-coloring-join (strings delimiter)
  59   "Join a list of STRINGS with the string DELIMITER."
  60   (mapconcat 'identity strings delimiter))
  61
  62 (defsubst context-coloring-trim-right (string)
  63   "Remove leading whitespace from STRING."
  64   (if (string-match "[ \t\n\r]+\\'" string)
  65       (replace-match "" t t string)
  66     string))
  67
  68 (defsubst context-coloring-trim-left (string)
  69   "Remove trailing whitespace from STRING."
  70   (if (string-match "\\`[ \t\n\r]+" string)
  71       (replace-match "" t t string)
  72     string))
  73
  74 (defsubst context-coloring-trim (string)
  75   "Remove leading and trailing whitespace from STRING."
  76   (context-coloring-trim-left (context-coloring-trim-right string)))
  77
  78
  79 ;;; Faces
  80
  81 (defun context-coloring-defface (level tty light dark)
  82   "Define a face for LEVEL with colors for TTY, LIGHT and DARK
  83 backgrounds."
  84   (let ((face (intern (format "context-coloring-level-%s-face" level)))
  85         (doc (format "Context coloring face, level %s." level)))
  86     (custom-declare-face
  87      face
  88      `((((type tty)) (:foreground ,tty))
  89        (((background light)) (:foreground ,light))
  90        (((background dark)) (:foreground ,dark)))
  91      doc
  92      :group 'context-coloring)))
  93
  94 (defun context-coloring-defface-neutral (level)
  95   "Define a face for LEVEL with the default neutral colors."
  96   (context-coloring-defface level nil "#3f3f3f" "#cdcdcd"))
  97
  98 (context-coloring-defface 0 nil       "#000000" "#ffffff")
  99 (context-coloring-defface 1 "yellow"  "#008b8b" "#00ffff")
 100 (context-coloring-defface 2 "green"   "#0000ff" "#87cefa")
 101 (context-coloring-defface 3 "cyan"    "#483d8b" "#b0c4de")
 102 (context-coloring-defface 4 "blue"    "#a020f0" "#eedd82")
 103 (context-coloring-defface 5 "magenta" "#a0522d" "#98fb98")
 104 (context-coloring-defface 6 "red"     "#228b22" "#7fffd4")
 105 (context-coloring-defface-neutral 7)
 106
 107 (defvar context-coloring-maximum-face nil
 108   "Index of the highest face available for coloring.")
 109
 110 (defvar context-coloring-original-maximum-face nil
 111   "Fallback value for `context-coloring-maximum-face' when all
 112   themes have been disabled.")
 113
 114 (setq context-coloring-maximum-face 7)
 115
 116 (setq context-coloring-original-maximum-face
 117       context-coloring-maximum-face)
 118
 119 ;; Theme authors can have up to 26 levels: 1 (0th) for globals, 24 (1st-24th)
 120 ;; for nested levels, and 1 (25th) for infinity.
 121 (dotimes (number 18)
 122   (context-coloring-defface-neutral (+ number context-coloring-maximum-face 1)))
 123
 124
 125 ;;; Face functions
 126
 127 (defsubst context-coloring-level-face (level)
 128   "Return the symbol for a face with LEVEL."
 129   ;; `concat' is faster than `format' here.
 130   (intern-soft
 131    (concat "context-coloring-level-" (number-to-string level) "-face")))
 132
 133 (defsubst context-coloring-bounded-level-face (level)
 134   "Return the symbol for a face with LEVEL, bounded by
 135 `context-coloring-maximum-face'."
 136   (context-coloring-level-face (min level context-coloring-maximum-face)))
 137
 138
 139 ;;; Colorization utilities
 140
 141 (defsubst context-coloring-colorize-region (start end level)
 142   "Color characters from the 1-indexed START point (inclusive) to
 143 the END point (exclusive) with the face corresponding to LEVEL."
 144   (add-text-properties
 145    start
 146    end
 147    `(face ,(context-coloring-bounded-level-face level))))
 148
 149 (defcustom context-coloring-comments-and-strings nil
 150   "If non-nil, also color comments and strings using `font-lock'."
 151   :group 'context-coloring)
 152
 153 (make-obsolete-variable
 154  'context-coloring-comments-and-strings
 155  "use `context-coloring-syntactic-comments' and
 156  `context-coloring-syntactic-strings' instead."
 157  "6.1.0")
 158
 159 (defcustom context-coloring-syntactic-comments t
 160   "If non-nil, also color comments using `font-lock'."
 161   :group 'context-coloring)
 162
 163 (defcustom context-coloring-syntactic-strings t
 164   "If non-nil, also color strings using `font-lock'."
 165   :group 'context-coloring)
 166
 167 (defun context-coloring-font-lock-syntactic-comment-function (state)
 168   "Tell `font-lock' to color a comment but not a string."
 169   (if (nth 3 state) nil font-lock-comment-face))
 170
 171 (defun context-coloring-font-lock-syntactic-string-function (state)
 172   "Tell `font-lock' to color a string but not a comment."
 173   (if (nth 3 state) font-lock-string-face nil))
 174
 175 (defsubst context-coloring-maybe-colorize-comments-and-strings ()
 176   "Color the current buffer's comments and strings if
 177 `context-coloring-comments-and-strings' is non-nil."
 178   (when (or context-coloring-comments-and-strings
 179             context-coloring-syntactic-comments
 180             context-coloring-syntactic-strings)
 181     (let ((old-function font-lock-syntactic-face-function)
 182           saved-function-p)
 183       (cond
 184        ((and context-coloring-syntactic-comments
 185              (not context-coloring-syntactic-strings))
 186         (setq font-lock-syntactic-face-function
 187               'context-coloring-font-lock-syntactic-comment-function)
 188         (setq saved-function-p t))
 189        ((and context-coloring-syntactic-strings
 190              (not context-coloring-syntactic-comments))
 191         (setq font-lock-syntactic-face-function
 192               'context-coloring-font-lock-syntactic-string-function)
 193         (setq saved-function-p t)))
 194       (save-excursion
 195         (font-lock-fontify-syntactically-region (point-min) (point-max)))
 196       (when saved-function-p
 197         (setq font-lock-syntactic-face-function old-function)))))
 198
 199
 200 ;;; js2-mode colorization
 201
 202 (defvar-local context-coloring-js2-scope-level-hash-table nil
 203   "Associate `js2-scope' structures and with their scope
 204   levels.")
 205
 206 (defcustom context-coloring-js-block-scopes nil
 207   "If non-nil, also color block scopes in the scope hierarchy in JavaScript.
 208
 209 The block-scoped `let' and `const' are introduced in ES6.  Enable
 210 this for ES6 code; disable it elsewhere.
 211
 212 Supported modes: `js2-mode'"
 213   :group 'context-coloring)
 214
 215 (defsubst context-coloring-js2-scope-level (scope)
 216   "Return the level of SCOPE."
 217   (cond ((gethash scope context-coloring-js2-scope-level-hash-table))
 218         (t
 219          (let ((level 0)
 220                (current-scope scope)
 221                enclosing-scope)
 222            (while (and current-scope
 223                        (js2-node-parent current-scope)
 224                        (setq enclosing-scope
 225                              (js2-node-get-enclosing-scope current-scope)))
 226              (when (or context-coloring-js-block-scopes
 227                        (let ((type (js2-scope-type current-scope)))
 228                          (or (= type js2-SCRIPT)
 229                              (= type js2-FUNCTION)
 230                              (= type js2-CATCH))))
 231                (setq level (+ level 1)))
 232              (setq current-scope enclosing-scope))
 233            (puthash scope level context-coloring-js2-scope-level-hash-table)))))
 234
 235 (defsubst context-coloring-js2-local-name-node-p (node)
 236   "Determine if NODE is a `js2-name-node' representing a local
 237 variable."
 238   (and (js2-name-node-p node)
 239        (let ((parent (js2-node-parent node)))
 240          (not (or (and (js2-object-prop-node-p parent)
 241                        (eq node (js2-object-prop-node-left parent)))
 242                   (and (js2-prop-get-node-p parent)
 243                        ;; For nested property lookup, the node on the left is a
 244                        ;; `js2-prop-get-node', so this always works.
 245                        (eq node (js2-prop-get-node-right parent))))))))
 246
 247 (defvar-local context-coloring-point-max nil
 248   "Cached value of `point-max'.")
 249
 250 (defsubst context-coloring-js2-colorize-node (node level)
 251   "Color NODE with the color for LEVEL."
 252   (let ((start (js2-node-abs-pos node)))
 253     (context-coloring-colorize-region
 254      start
 255      (min
 256       ;; End
 257       (+ start (js2-node-len node))
 258       ;; Somes nodes (like the ast when there is an unterminated multiline
 259       ;; comment) will stretch to the value of `point-max'.
 260       context-coloring-point-max)
 261      level)))
 262
 263 (defun context-coloring-js2-colorize ()
 264   "Color the current buffer using the abstract syntax tree
 265 generated by `js2-mode'."
 266   ;; Reset the hash table; the old one could be obsolete.
 267   (setq context-coloring-js2-scope-level-hash-table (make-hash-table :test 'eq))
 268   (setq context-coloring-point-max (point-max))
 269   (with-silent-modifications
 270     (js2-visit-ast
 271      js2-mode-ast
 272      (lambda (node end-p)
 273        (when (null end-p)
 274          (cond
 275           ((js2-scope-p node)
 276            (context-coloring-js2-colorize-node
 277             node
 278             (context-coloring-js2-scope-level node)))
 279           ((context-coloring-js2-local-name-node-p node)
 280            (let* ((enclosing-scope (js2-node-get-enclosing-scope node))
 281                   (defining-scope (js2-get-defining-scope
 282                                    enclosing-scope
 283                                    (js2-name-node-name node))))
 284              ;; The tree seems to be walked lexically, so an entire scope will
 285              ;; be colored, including its name nodes, before they are reached.
 286              ;; Coloring the nodes defined in that scope would be redundant, so
 287              ;; don't do it.
 288              (when (not (eq defining-scope enclosing-scope))
 289                (context-coloring-js2-colorize-node
 290                 node
 291                 (context-coloring-js2-scope-level defining-scope))))))
 292          ;; The `t' indicates to search children.
 293          t)))
 294     (context-coloring-maybe-colorize-comments-and-strings)))
 295
 296
 297 ;;; Emacs Lisp colorization
 298
 299 (defun context-coloring-make-scope (depth level)
 300   (list
 301    :depth depth
 302    :level level
 303    :variables (make-hash-table)))
 304
 305 (defun context-coloring-scope-get-depth (scope)
 306   (plist-get scope :depth))
 307
 308 (defun context-coloring-scope-get-level (scope)
 309   (plist-get scope :level))
 310
 311 (defun context-coloring-scope-add-variable (scope variable)
 312   (puthash variable t (plist-get scope :variables)))
 313
 314 (defun context-coloring-scope-get-variable (scope variable)
 315   (gethash variable (plist-get scope :variables)))
 316
 317 (defun context-coloring-get-variable-level (scope-stack variable)
 318   (let* (scope
 319          level)
 320     (while (and scope-stack (not level))
 321       (setq scope (car scope-stack))
 322       (cond
 323        ((context-coloring-scope-get-variable scope variable)
 324         (setq level (context-coloring-scope-get-level scope)))
 325        (t
 326         (setq scope-stack (cdr scope-stack)))))
 327     ;; Assume global
 328     (or level 0)))
 329
 330 (defun context-coloring-make-backtick (end enabled)
 331   (list
 332    :end end
 333    :enabled enabled))
 334
 335 (defun context-coloring-backtick-get-end (backtick)
 336   (plist-get backtick :end))
 337
 338 (defun context-coloring-backtick-get-enabled (backtick)
 339   (plist-get backtick :enabled))
 340
 341 (defun context-coloring-backtick-enabled-p (backtick-stack)
 342   (context-coloring-backtick-get-enabled (car backtick-stack)))
 343
 344 (defun context-coloring-make-let-value (end)
 345   (list
 346    :end end))
 347
 348 (defun context-coloring-let-value-get-end (let-value)
 349   (plist-get let-value :end))
 350
 351 (defun context-coloring-emacs-lisp-identifier-syntax-p (syntax-code)
 352   (or (= 2 syntax-code)
 353       (= 3 syntax-code)))
 354
 355 (defun context-coloring-forward-sws ()
 356   "Move forward through whitespace and comments."
 357   (while (forward-comment 1)))
 358
 359 (defun context-coloring-at-open-parenthesis ()
 360   (= 4 (logand #xFFFF (car (syntax-after (point))))))
 361
 362 (defun context-coloring-emacs-lisp-colorize ()
 363   "Color the current buffer by parsing emacs lisp sexps."
 364   (with-silent-modifications
 365     (save-excursion
 366       ;; TODO: Can probably make this lazy to the nearest defun
 367       (goto-char (point-min))
 368       (let* ((inhibit-point-motion-hooks t)
 369              (end (point-max))
 370              (last-ppss-pos (point))
 371              (ppss (syntax-ppss))
 372              (scope-stack `(,(context-coloring-make-scope -1 0))) ; -1 never matches a depth
 373              (backtick-stack `(,(context-coloring-make-backtick -1 nil)))
 374              (let-value-stack `(,(context-coloring-make-let-value -1)))
 375              one-word-found-p
 376              in-defun-p
 377              in-lambda-p
 378              in-let*-p
 379              defun-arglist
 380              defun-arg
 381              let-varlist
 382              let-var
 383              variable
 384              variable-end
 385              variable-string
 386              variable-scope-level
 387              token-pos
 388              token-syntax
 389              token-syntax-code
 390              token-char
 391              child-0-pos
 392              child-0-end
 393              child-0-syntax
 394              child-0-syntax-code
 395              child-0-string
 396              child-1-pos
 397              child-1-end
 398              child-1-syntax
 399              child-1-syntax-code
 400              child-2-end)
 401         (while (> end (progn (skip-syntax-forward "^()w_'" end)
 402                              (point)))
 403           (setq token-pos (point))
 404           (setq token-syntax (syntax-after token-pos))
 405           (setq ppss (parse-partial-sexp last-ppss-pos token-pos nil nil ppss))
 406           (setq last-ppss-pos token-pos)
 407           ;; `skip-syntax-forward' leaves the point at the delimiter, move past
 408           ;; it.
 409           (setq token-syntax-code (logand #xFFFF (car token-syntax)))
 410           (setq token-char (string-to-char (buffer-substring-no-properties
 411                                             token-pos
 412                                             (1+ token-pos))))
 413           (cond
 414
 415            ;; Resolve invalid state
 416            ((cond
 417              ;; Inside string?
 418              ((nth 3 ppss)
 419               (skip-syntax-forward "^\"" end)
 420               (forward-char)
 421               t)
 422              ;; Inside comment?
 423              ((nth 4 ppss)
 424               (skip-syntax-forward "^>" end) ; comment ender
 425               t)))
 426
 427            ;; Expression prefix
 428            ;; Has to come first in case of commas
 429            ((= 6 token-syntax-code)
 430             (forward-char)
 431             (cond
 432              ;; Just outright skip top-level symbols
 433              ((not (or (cadr backtick-stack)
 434                        (= token-char 96))) ; 96 = '`'
 435               (goto-char (scan-sexps (point) 1)))
 436              ((or (= token-char 96)  ; 96 = '`'
 437                   (= token-char 44)) ; 44 = ','
 438               ;; Have to manage backticks
 439               (setq backtick-stack (cons (context-coloring-make-backtick
 440                                           (scan-sexps (point) 1) ; End of the backtick
 441                                           (= token-char 96)) ; 96 = '`'
 442                                          backtick-stack)))))
 443
 444            ;; End backtick
 445            ((and (cadr backtick-stack)
 446                  (>= (point) (context-coloring-backtick-get-end (car backtick-stack))))
 447             (setq backtick-stack (cdr backtick-stack)))
 448
 449            ;; Restricted by backtick
 450            ((and (cadr backtick-stack)
 451                  (context-coloring-backtick-enabled-p backtick-stack))
 452             (forward-char))
 453
 454            ;; Opening delimiter
 455            ((= 4 token-syntax-code)
 456             (forward-char)
 457             ;; Lookahead for scopes / function calls
 458             (context-coloring-forward-sws)
 459             (setq child-0-pos (point))
 460             (setq child-0-syntax (syntax-after child-0-pos))
 461             (setq child-0-syntax-code (logand #xFFFF (car child-0-syntax)))
 462             (cond
 463              ;; Word
 464              ((context-coloring-emacs-lisp-identifier-syntax-p child-0-syntax-code)
 465               (setq one-word-found-p t)
 466               (setq child-0-end (scan-sexps child-0-pos 1))
 467               (setq child-0-string (buffer-substring-no-properties child-0-pos child-0-end))
 468               (cond
 469                ((string-match-p "\\`defun\\'\\|\\`defmacro\\'" child-0-string)
 470                 (setq in-defun-p t))
 471                ((string-match-p "\\`lambda\\'" child-0-string)
 472                 (setq in-lambda-p t))
 473                ((string-match-p "\\`let\\*\\'" child-0-string)
 474                 (setq in-let*-p t)))))
 475             (when (or in-defun-p
 476                       in-lambda-p
 477                       in-let*-p)
 478               (setq scope-stack (cons (context-coloring-make-scope
 479                                        (nth 0 ppss)
 480                                        (1+ (context-coloring-scope-get-level
 481                                             (car scope-stack))))
 482                                       scope-stack)))
 483             ;; TODO: Probably redundant and wasteful
 484             (context-coloring-colorize-region token-pos
 485                                               (scan-sexps token-pos 1)
 486                                               (context-coloring-scope-get-level
 487                                                (car scope-stack)))
 488             (cond
 489              ((or in-defun-p
 490                   in-lambda-p)
 491               (goto-char child-0-end)
 492               (when in-defun-p
 493                 ;; Lookahead for defun name
 494                 (context-coloring-forward-sws)
 495                 (setq child-1-pos (point))
 496                 (setq child-1-syntax (syntax-after child-1-pos))
 497                 (setq child-1-syntax-code (logand #xFFFF (car child-1-syntax)))
 498                 (cond
 499                  ;; Word
 500                  ((context-coloring-emacs-lisp-identifier-syntax-p child-1-syntax-code)
 501                   (setq child-1-end (scan-sexps child-1-pos 1))
 502                   ;; defuns are global so use level 0
 503                   (context-coloring-colorize-region child-1-pos child-1-end 0)
 504                   (goto-char child-1-end))))
 505               ;; Lookahead for parameters
 506               (context-coloring-forward-sws)
 507               (when (context-coloring-at-open-parenthesis)
 508                 ;; Actually it should be `child-1-end' for `lambda'.
 509                 (setq child-2-end (scan-sexps (point) 1))
 510                 (setq defun-arglist (read (buffer-substring-no-properties
 511                                            (point)
 512                                            child-2-end)))
 513                 (while defun-arglist
 514                   (setq defun-arg (car defun-arglist))
 515                   (when (and (symbolp defun-arg)
 516                              (string-match-p "\\`[^&:]" (symbol-name defun-arg)))
 517                     (context-coloring-scope-add-variable
 518                      (car scope-stack)
 519                      defun-arg))
 520                   (setq defun-arglist (cdr defun-arglist)))
 521                 (goto-char child-2-end))
 522               ;; Cleanup
 523               (setq in-defun-p nil)
 524               (setq in-lambda-p nil))
 525              (in-let*-p
 526               (goto-char child-0-end)
 527               ;; Lookahead for bindings
 528               (context-coloring-forward-sws)
 529               (setq child-1-pos (point))
 530               (setq child-1-syntax (syntax-after child-1-pos))
 531               (setq child-1-syntax-code (logand #xFFFF (car child-1-syntax)))
 532               (when (= 4 child-1-syntax-code)
 533                 (setq child-1-end (scan-sexps (point) 1))
 534                 (setq let-varlist (read (buffer-substring-no-properties
 535                                          (point)
 536                                          child-1-end)))
 537                 (while let-varlist
 538                   (setq let-var (car let-varlist))
 539                   (cond
 540                    ((symbolp let-var)
 541                     (context-coloring-scope-add-variable
 542                      (car scope-stack)
 543                      let-var))
 544                    ((listp let-var)
 545                     (context-coloring-scope-add-variable
 546                      (car scope-stack)
 547                      (car let-var))
 548                     ;; TODO: Recurse or use stack to eval var value
 549                     ))
 550                   (setq let-varlist (cdr let-varlist)))
 551                 (goto-char child-1-end))
 552               ;; Cleanup
 553               (setq in-let*-p nil))
 554              (t
 555               (goto-char (cond
 556                           ;; If there was a word, continue parsing after it.
 557                           (one-word-found-p
 558                            (1+ child-0-end))
 559                           (t
 560                            (1+ token-pos))))))
 561             ;; Cleanup
 562             (setq one-word-found-p nil))
 563
 564            ;; Word (variable)
 565            ((context-coloring-emacs-lisp-identifier-syntax-p token-syntax-code)
 566             (setq variable-end (scan-sexps (point) 1))
 567             (setq variable-string (buffer-substring-no-properties
 568                                    token-pos
 569                                    variable-end))
 570             (cond
 571              ;; Ignore constants such as numbers, keywords, t, nil. These can't
 572              ;; be rebound, so they should be treated like syntax.
 573              ((string-match-p "\\`[-+]?[0-9]\\|\\`t\\'\\|\\`nil\\'" variable-string))
 574              ((keywordp (read variable-string)))
 575              (t
 576               (setq variable (intern variable-string))
 577               (setq variable-scope-level
 578                     (context-coloring-get-variable-level scope-stack variable))
 579               (when (/= variable-scope-level (context-coloring-scope-get-level
 580                                               (car scope-stack)))
 581                 (context-coloring-colorize-region
 582                  token-pos
 583                  variable-end
 584                  variable-scope-level))))
 585             (goto-char variable-end))
 586
 587            ;; Closing delimiter
 588            ((= 5 token-syntax-code)
 589             (forward-char)
 590             ;; End scope
 591             (setq ppss (parse-partial-sexp last-ppss-pos (point) nil nil ppss))
 592             (setq last-ppss-pos (point))
 593             (when (= (nth 0 ppss) (context-coloring-scope-get-depth (car scope-stack)))
 594               (setq scope-stack (cdr scope-stack))))
 595
 596            ))))
 597     (context-coloring-maybe-colorize-comments-and-strings)))
 598
 599
 600 ;;; Shell command scopification / colorization
 601
 602 (defun context-coloring-apply-tokens (tokens)
 603   "Process a vector of TOKENS to apply context-based coloring to
 604 the current buffer.  Tokens are 3 integers: start, end, level.
 605 The vector is flat, with a new token occurring after every 3rd
 606 element."
 607   (with-silent-modifications
 608     (let ((i 0)
 609           (len (length tokens)))
 610       (while (< i len)
 611         (context-coloring-colorize-region
 612          (elt tokens i)
 613          (elt tokens (+ i 1))
 614          (elt tokens (+ i 2)))
 615         (setq i (+ i 3))))
 616     (context-coloring-maybe-colorize-comments-and-strings)))
 617
 618 (defun context-coloring-parse-array (array)
 619   "Parse ARRAY as a flat JSON array of numbers."
 620   (let ((braceless (substring (context-coloring-trim array) 1 -1)))
 621     (cond
 622      ((> (length braceless) 0)
 623       (vconcat
 624        (mapcar 'string-to-number (split-string braceless ","))))
 625      (t
 626       (vector)))))
 627
 628 (defvar-local context-coloring-scopifier-process nil
 629   "The single scopifier process that can be running.")
 630
 631 (defun context-coloring-kill-scopifier ()
 632   "Kill the currently-running scopifier process."
 633   (when (not (null context-coloring-scopifier-process))
 634     (delete-process context-coloring-scopifier-process)
 635     (setq context-coloring-scopifier-process nil)))
 636
 637 (defun context-coloring-scopify-shell-command (command callback)
 638   "Invoke a scopifier via COMMAND, read its response
 639 asynchronously and invoke CALLBACK with its output."
 640
 641   ;; Prior running tokenization is implicitly obsolete if this function is
 642   ;; called.
 643   (context-coloring-kill-scopifier)
 644
 645   ;; Start the process.
 646   (setq context-coloring-scopifier-process
 647         (start-process-shell-command "scopifier" nil command))
 648
 649   (let ((output ""))
 650
 651     ;; The process may produce output in multiple chunks.  This filter
 652     ;; accumulates the chunks into a message.
 653     (set-process-filter
 654      context-coloring-scopifier-process
 655      (lambda (_process chunk)
 656        (setq output (concat output chunk))))
 657
 658     ;; When the process's message is complete, this sentinel parses it as JSON
 659     ;; and applies the tokens to the buffer.
 660     (set-process-sentinel
 661      context-coloring-scopifier-process
 662      (lambda (_process event)
 663        (when (equal "finished\n" event)
 664          (funcall callback output))))))
 665
 666 (defun context-coloring-send-buffer-to-scopifier ()
 667   "Give the scopifier process its input so it can begin
 668 scopifying."
 669   (process-send-region
 670    context-coloring-scopifier-process
 671    (point-min) (point-max))
 672   (process-send-eof
 673    context-coloring-scopifier-process))
 674
 675 (defun context-coloring-scopify-and-colorize (command &optional callback)
 676   "Invoke a scopifier via COMMAND with the current buffer's contents,
 677 read the scopifier's response asynchronously and apply a parsed
 678 list of tokens to `context-coloring-apply-tokens'.
 679
 680 Invoke CALLBACK when complete."
 681   (let ((buffer context-coloring-buffer))
 682     (context-coloring-scopify-shell-command
 683      command
 684      (lambda (output)
 685        (let ((tokens (context-coloring-parse-array output)))
 686          (with-current-buffer buffer
 687            (context-coloring-apply-tokens tokens))
 688          (setq context-coloring-scopifier-process nil)
 689          (when callback (funcall callback))))))
 690   (context-coloring-send-buffer-to-scopifier))
 691
 692
 693 ;;; Dispatch
 694
 695 (defvar context-coloring-dispatch-hash-table (make-hash-table :test 'eq)
 696   "Map dispatch strategy names to their corresponding property
 697   lists, which contain details about the strategies.")
 698
 699 (defvar context-coloring-mode-hash-table (make-hash-table :test 'eq)
 700   "Map major mode names to dispatch property lists.")
 701
 702 (defun context-coloring-define-dispatch (symbol &rest properties)
 703   "Define a new dispatch named SYMBOL with PROPERTIES.
 704
 705 A \"dispatch\" is a property list describing a strategy for
 706 coloring a buffer.  There are three possible strategies: Parse
 707 and color in a single function (`:colorizer'), parse in a
 708 function that returns scope data (`:scopifier'), or parse with a
 709 shell command that returns scope data (`:command').  In the
 710 latter two cases, the scope data will be used to automatically
 711 color the buffer.
 712
 713 PROPERTIES must include `:modes' and one of `:colorizer',
 714 `:scopifier' or `:command'.
 715
 716 `:modes' - List of major modes this dispatch is valid for.
 717
 718 `:colorizer' - Symbol referring to a function that parses and
 719 colors the buffer.
 720
 721 `:scopifier' - Symbol referring to a function that parses the
 722 buffer a returns a flat vector of start, end and level data.
 723
 724 `:executable' - Optional name of an executable required by
 725 `:command'.
 726
 727 `:command' - Shell command to execute with the current buffer
 728 sent via stdin, and with a flat JSON array of start, end and
 729 level data returned via stdout.
 730
 731 `:version' - Minimum required version that should be printed when
 732 executing `:command' with a \"--version\" flag.  The version
 733 should be numeric, e.g. \"2\", \"19700101\", \"1.2.3\",
 734 \"v1.2.3\" etc.
 735
 736 `:setup' - Arbitrary code to set up this dispatch when
 737 `context-coloring-mode' is enabled.
 738
 739 `:teardown' - Arbitrary code to tear down this dispatch when
 740 `context-coloring-mode' is disabled."
 741   (let ((modes (plist-get properties :modes))
 742         (colorizer (plist-get properties :colorizer))
 743         (scopifier (plist-get properties :scopifier))
 744         (command (plist-get properties :command)))
 745     (when (null modes)
 746       (error "No mode defined for dispatch"))
 747     (when (not (or colorizer
 748                    scopifier
 749                    command))
 750       (error "No colorizer, scopifier or command defined for dispatch"))
 751     (puthash symbol properties context-coloring-dispatch-hash-table)
 752     (dolist (mode modes)
 753       (when (null (gethash mode context-coloring-mode-hash-table))
 754         (puthash mode properties context-coloring-mode-hash-table)))))
 755
 756 (context-coloring-define-dispatch
 757  'javascript-node
 758  :modes '(js-mode js3-mode)
 759  :executable "scopifier"
 760  :command "scopifier"
 761  :version "v1.1.1")
 762
 763 (context-coloring-define-dispatch
 764  'javascript-js2
 765  :modes '(js2-mode)
 766  :colorizer 'context-coloring-js2-colorize
 767  :setup
 768  (lambda ()
 769    (add-hook 'js2-post-parse-callbacks 'context-coloring-colorize nil t))
 770  :teardown
 771  (lambda ()
 772    (remove-hook 'js2-post-parse-callbacks 'context-coloring-colorize t)))
 773
 774 (context-coloring-define-dispatch
 775  'emacs-lisp
 776  :modes '(emacs-lisp-mode)
 777  :colorizer 'context-coloring-emacs-lisp-colorize)
 778
 779 (defun context-coloring-dispatch (&optional callback)
 780   "Determine the optimal track for scopification / coloring of
 781 the current buffer, then execute it.
 782
 783 Invoke CALLBACK when complete.  It is invoked synchronously for
 784 elisp tracks, and asynchronously for shell command tracks."
 785   (let ((dispatch (gethash major-mode context-coloring-mode-hash-table))
 786         colorizer
 787         scopifier
 788         command)
 789     (cond
 790      ((setq colorizer (plist-get dispatch :colorizer))
 791       (funcall colorizer)
 792       (when callback (funcall callback)))
 793      ((setq scopifier (plist-get dispatch :scopifier))
 794       (context-coloring-apply-tokens (funcall scopifier))
 795       (when callback (funcall callback)))
 796      ((setq command (plist-get dispatch :command))
 797       (context-coloring-scopify-and-colorize command callback)))))
 798
 799
 800 ;;; Colorization
 801
 802 (defvar context-coloring-colorize-hook nil
 803   "Hooks to run after coloring a buffer.")
 804
 805 (defun context-coloring-colorize (&optional callback)
 806   "Color the current buffer by function context.
 807
 808 Invoke CALLBACK when complete; see `context-coloring-dispatch'."
 809   (interactive)
 810   (context-coloring-dispatch
 811    (lambda ()
 812      (when callback (funcall callback))
 813      (run-hooks 'context-coloring-colorize-hook))))
 814
 815 (defvar-local context-coloring-changed nil
 816   "Indication that the buffer has changed recently, which implies
 817 that it should be colored again by
 818 `context-coloring-colorize-idle-timer' if that timer is being
 819 used.")
 820
 821 (defun context-coloring-change-function (_start _end _length)
 822   "Register a change so that a buffer can be colorized soon."
 823   ;; Tokenization is obsolete if there was a change.
 824   (context-coloring-kill-scopifier)
 825   (setq context-coloring-changed t))
 826
 827 (defun context-coloring-maybe-colorize ()
 828   "Colorize the current buffer if it has changed."
 829   (when (and (eq context-coloring-buffer (window-buffer (selected-window)))
 830              context-coloring-changed)
 831     (setq context-coloring-changed nil)
 832     (context-coloring-colorize)))
 833
 834
 835 ;;; Versioning
 836
 837 (defun context-coloring-parse-version (string)
 838   "Extract segments of a version STRING into a list.  \"v1.0.0\"
 839 produces (1 0 0), \"19700101\" produces (19700101), etc."
 840   (let (version)
 841     (while (string-match "[0-9]+" string)
 842       (setq version (append version
 843                             (list (string-to-number (match-string 0 string)))))
 844       (setq string (substring string (match-end 0))))
 845     version))
 846
 847 (defun context-coloring-check-version (expected actual)
 848   "Check that version EXPECTED is less than or equal to ACTUAL."
 849   (let ((expected (context-coloring-parse-version expected))
 850         (actual (context-coloring-parse-version actual))
 851         (continue t)
 852         (acceptable t))
 853     (while (and continue expected)
 854       (let ((an-expected (car expected))
 855             (an-actual (car actual)))
 856         (cond
 857          ((> an-actual an-expected)
 858           (setq acceptable t)
 859           (setq continue nil))
 860          ((< an-actual an-expected)
 861           (setq acceptable nil)
 862           (setq continue nil))))
 863       (setq expected (cdr expected))
 864       (setq actual (cdr actual)))
 865     acceptable))
 866
 867 (defvar context-coloring-check-scopifier-version-hook nil
 868   "Hooks to run after checking the scopifier version.")
 869
 870 (defun context-coloring-check-scopifier-version (&optional callback)
 871   "Asynchronously invoke CALLBACK with a predicate indicating
 872 whether the current scopifier version satisfies the minimum
 873 version number required for the current major mode."
 874   (let ((dispatch (gethash major-mode context-coloring-mode-hash-table)))
 875     (when dispatch
 876       (let ((version (plist-get dispatch :version))
 877             (command (plist-get dispatch :command)))
 878         (context-coloring-scopify-shell-command
 879          (context-coloring-join (list command "--version") " ")
 880          (lambda (output)
 881            (if (context-coloring-check-version version output)
 882                (progn
 883                  (when callback (funcall callback t)))
 884              (when callback (funcall callback nil)))
 885            (run-hooks 'context-coloring-check-scopifier-version-hook)))))))
 886
 887
 888 ;;; Themes
 889
 890 (defvar context-coloring-theme-hash-table (make-hash-table :test 'eq)
 891   "Map theme names to theme properties.")
 892
 893 (defun context-coloring-theme-p (theme)
 894   "Return t if THEME is defined, nil otherwise."
 895   (and (gethash theme context-coloring-theme-hash-table)))
 896
 897 (defconst context-coloring-level-face-regexp
 898   "context-coloring-level-\\([[:digit:]]+\\)-face"
 899   "Extract a level from a face.")
 900
 901 (defvar context-coloring-originally-set-theme-hash-table
 902   (make-hash-table :test 'eq)
 903   "Cache custom themes who originally set their own
 904   `context-coloring-level-N-face' faces.")
 905
 906 (defun context-coloring-theme-originally-set-p (theme)
 907   "Return t if there is a `context-coloring-level-N-face'
 908 originally set for THEME, nil otherwise."
 909   (let (originally-set)
 910     (cond
 911      ;; `setq' might return a non-nil value for the sake of this `cond'.
 912      ((setq
 913        originally-set
 914        (gethash
 915         theme
 916         context-coloring-originally-set-theme-hash-table))
 917       (eq originally-set 'yes))
 918      (t
 919       (let* ((settings (get theme 'theme-settings))
 920              (tail settings)
 921              found)
 922         (while (and tail (not found))
 923           (and (eq (nth 0 (car tail)) 'theme-face)
 924                (string-match
 925                 context-coloring-level-face-regexp
 926                 (symbol-name (nth 1 (car tail))))
 927                (setq found t))
 928           (setq tail (cdr tail)))
 929         found)))))
 930
 931 (defun context-coloring-cache-originally-set (theme originally-set)
 932   "Remember if THEME had colors originally set for it.  If
 933 ORIGINALLY-SET is non-nil, it did, otherwise it didn't."
 934   ;; Caching whether a theme was originally set is kind of dirty, but we have to
 935   ;; do it to remember the past state of the theme.  There are probably some
 936   ;; edge cases where caching will be an issue, but they are probably rare.
 937   (puthash
 938    theme
 939    (if originally-set 'yes 'no)
 940    context-coloring-originally-set-theme-hash-table))
 941
 942 (defun context-coloring-warn-theme-originally-set (theme)
 943   "Warn the user that the colors for THEME are already originally
 944 set."
 945   (warn "Context coloring colors for theme `%s' are already defined" theme))
 946
 947 (defun context-coloring-theme-highest-level (theme)
 948   "Return the highest level N of a face like
 949 `context-coloring-level-N-face' set for THEME, or `-1' if there
 950 is none."
 951   (let* ((settings (get theme 'theme-settings))
 952          (tail settings)
 953          face-string
 954          number
 955          (found -1))
 956     (while tail
 957       (and (eq (nth 0 (car tail)) 'theme-face)
 958            (setq face-string (symbol-name (nth 1 (car tail))))
 959            (string-match
 960             context-coloring-level-face-regexp
 961             face-string)
 962            (setq number (string-to-number
 963                          (substring face-string
 964                                     (match-beginning 1)
 965                                     (match-end 1))))
 966            (> number found)
 967            (setq found number))
 968       (setq tail (cdr tail)))
 969     found))
 970
 971 (defun context-coloring-apply-theme (theme)
 972   "Apply THEME's properties to its respective custom theme,
 973 which must already exist and which *should* already be enabled."
 974   (let* ((properties (gethash theme context-coloring-theme-hash-table))
 975          (colors (plist-get properties :colors))
 976          (level -1))
 977     ;; Only clobber when we have to.
 978     (when (custom-theme-enabled-p theme)
 979       (setq context-coloring-maximum-face (- (length colors) 1)))
 980     (apply
 981      'custom-theme-set-faces
 982      theme
 983      (mapcar
 984       (lambda (color)
 985         (setq level (+ level 1))
 986         `(,(context-coloring-level-face level) ((t (:foreground ,color)))))
 987       colors))))
 988
 989 (defun context-coloring-define-theme (theme &rest properties)
 990   "Define a context theme named THEME for coloring scope levels.
 991
 992 PROPERTIES is a property list specifiying the following details:
 993
 994 `:aliases': List of symbols of other custom themes that these
 995 colors are applicable to.
 996
 997 `:colors': List of colors that this context theme uses.
 998
 999 `:override': If non-nil, this context theme is intentionally
1000 overriding colors set by a custom theme.  Don't set this non-nil
1001 unless there is a custom theme you want to use which sets
1002 `context-coloring-level-N-face' faces that you want to replace.
1003
1004 `:recede': If non-nil, this context theme should not apply its
1005 colors if a custom theme already sets
1006 `context-coloring-level-N-face' faces.  This option is
1007 optimistic; set this non-nil if you would rather confer the duty
1008 of picking colors to a custom theme author (if / when he ever
1009 gets around to it).
1010
1011 By default, context themes will always override custom themes,
1012 even if those custom themes set `context-coloring-level-N-face'
1013 faces.  If a context theme does override a custom theme, a
1014 warning will be raised, at which point you may want to enable the
1015 `:override' option, or just delete your context theme and opt to
1016 use your custom theme's author's colors instead.
1017
1018 Context themes only work for the custom theme with the highest
1019 precedence, i.e. the car of `custom-enabled-themes'."
1020   (let ((aliases (plist-get properties :aliases))
1021         (override (plist-get properties :override))
1022         (recede (plist-get properties :recede)))
1023     (dolist (name (append `(,theme) aliases))
1024       (puthash name properties context-coloring-theme-hash-table)
1025       (when (custom-theme-p name)
1026         (let ((originally-set (context-coloring-theme-originally-set-p name)))
1027           (context-coloring-cache-originally-set name originally-set)
1028           ;; In the particular case when you innocently define colors that a
1029           ;; custom theme originally set, warn.  Arguably this only has to be
1030           ;; done at enable time, but it is probably more useful to do it at
1031           ;; definition time for prompter feedback.
1032           (when (and originally-set
1033                      (not recede)
1034                      (not override))
1035             (context-coloring-warn-theme-originally-set name))
1036           ;; Set (or overwrite) colors.
1037           (when (not (and originally-set
1038                           recede))
1039             (context-coloring-apply-theme name)))))))
1040
1041 (defun context-coloring-enable-theme (theme)
1042   "Apply THEME if its colors are not already set, else just set
1043 `context-coloring-maximum-face' to the correct value for THEME."
1044   (let* ((properties (gethash theme context-coloring-theme-hash-table))
1045          (recede (plist-get properties :recede))
1046          (override (plist-get properties :override)))
1047     (cond
1048      (recede
1049       (let ((highest-level (context-coloring-theme-highest-level theme)))
1050         (cond
1051          ;; This can be true whether originally set by a custom theme or by a
1052          ;; context theme.
1053          ((> highest-level -1)
1054           (setq context-coloring-maximum-face highest-level))
1055          ;; It is possible that the corresponding custom theme did not exist at
1056          ;; the time of defining this context theme, and in that case the above
1057          ;; condition proves the custom theme did not originally set any faces,
1058          ;; so we have license to apply the context theme for the first time
1059          ;; here.
1060          (t
1061           (context-coloring-apply-theme theme)))))
1062      (t
1063       (let ((originally-set (context-coloring-theme-originally-set-p theme)))
1064         ;; Cache now in case the context theme was defined after the custom
1065         ;; theme.
1066         (context-coloring-cache-originally-set theme originally-set)
1067         (when (and originally-set
1068                    (not override))
1069           (context-coloring-warn-theme-originally-set theme))
1070         (context-coloring-apply-theme theme))))))
1071
1072 (defadvice enable-theme (after context-coloring-enable-theme (theme) activate)
1073   "Enable colors for context themes just-in-time."
1074   (when (and (not (eq theme 'user)) ; Called internally by `enable-theme'.
1075              (custom-theme-p theme) ; Guard against non-existent themes.
1076              (context-coloring-theme-p theme))
1077     (when (= (length custom-enabled-themes) 1)
1078       ;; Cache because we can't reliably figure it out in reverse.
1079       (setq context-coloring-original-maximum-face
1080             context-coloring-maximum-face))
1081     (context-coloring-enable-theme theme)))
1082
1083 (defadvice disable-theme (after context-coloring-disable-theme (theme) activate)
1084   "Update `context-coloring-maximum-face'."
1085   (when (custom-theme-p theme) ; Guard against non-existent themes.
1086     (let ((enabled-theme (car custom-enabled-themes)))
1087       (if (context-coloring-theme-p enabled-theme)
1088           (progn
1089             (context-coloring-enable-theme enabled-theme))
1090         ;; Assume we are back to no theme; act as if nothing ever happened.
1091         ;; This is still prone to intervention, but rather extraordinarily.
1092         (setq context-coloring-maximum-face
1093               context-coloring-original-maximum-face)))))
1094
1095 (context-coloring-define-theme
1096  'ample
1097  :recede t
1098  :colors '("#bdbdb3"
1099            "#baba36"
1100            "#6aaf50"
1101            "#5180b3"
1102            "#ab75c3"
1103            "#cd7542"
1104            "#df9522"
1105            "#454545"))
1106
1107 (context-coloring-define-theme
1108  'anti-zenburn
1109  :recede t
1110  :colors '("#232333"
1111            "#6c1f1c"
1112            "#401440"
1113            "#0f2050"
1114            "#205070"
1115            "#336c6c"
1116            "#23733c"
1117            "#6b400c"
1118            "#603a60"
1119            "#2f4070"
1120            "#235c5c"))
1121
1122 (context-coloring-define-theme
1123  'grandshell
1124  :recede t
1125  :colors '("#bebebe"
1126            "#5af2ee"
1127            "#b2baf6"
1128            "#f09fff"
1129            "#efc334"
1130            "#f6df92"
1131            "#acfb5a"
1132            "#888888"))
1133
1134 (context-coloring-define-theme
1135  'leuven
1136  :recede t
1137  :colors '("#333333"
1138            "#0000ff"
1139            "#6434a3"
1140            "#ba36a5"
1141            "#d0372d"
1142            "#036a07"
1143            "#006699"
1144            "#006fe0"
1145            "#808080"))
1146
1147 (context-coloring-define-theme
1148  'monokai
1149  :recede t
1150  :colors '("#f8f8f2"
1151            "#66d9ef"
1152            "#a1efe4"
1153            "#a6e22e"
1154            "#e6db74"
1155            "#fd971f"
1156            "#f92672"
1157            "#fd5ff0"
1158            "#ae81ff"))
1159
1160 (context-coloring-define-theme
1161  'solarized
1162  :recede t
1163  :aliases '(solarized-light
1164             solarized-dark
1165             sanityinc-solarized-light
1166             sanityinc-solarized-dark)
1167  :colors '("#839496"
1168            "#268bd2"
1169            "#2aa198"
1170            "#859900"
1171            "#b58900"
1172            "#cb4b16"
1173            "#dc322f"
1174            "#d33682"
1175            "#6c71c4"
1176            "#69b7f0"
1177            "#69cabf"
1178            "#b4c342"
1179            "#deb542"
1180            "#f2804f"
1181            "#ff6e64"
1182            "#f771ac"
1183            "#9ea0e5"))
1184
1185 (context-coloring-define-theme
1186  'spacegray
1187  :recede t
1188  :colors '("#ffffff"
1189            "#89aaeb"
1190            "#c189eb"
1191            "#bf616a"
1192            "#dca432"
1193            "#ebcb8b"
1194            "#b4eb89"
1195            "#89ebca"))
1196
1197 (context-coloring-define-theme
1198  'tango
1199  :recede t
1200  :colors '("#2e3436"
1201            "#346604"
1202            "#204a87"
1203            "#5c3566"
1204            "#a40000"
1205            "#b35000"
1206            "#c4a000"
1207            "#8ae234"
1208            "#8cc4ff"
1209            "#ad7fa8"
1210            "#ef2929"
1211            "#fcaf3e"
1212            "#fce94f"))
1213
1214 (context-coloring-define-theme
1215  'zenburn
1216  :recede t
1217  :colors '("#dcdccc"
1218            "#93e0e3"
1219            "#bfebbf"
1220            "#f0dfaf"
1221            "#dfaf8f"
1222            "#cc9393"
1223            "#dc8cc3"
1224            "#94bff3"
1225            "#9fc59f"
1226            "#d0bf8f"
1227            "#dca3a3"))
1228
1229
1230 ;;; Minor mode
1231
1232 (defvar-local context-coloring-colorize-idle-timer nil
1233   "The currently-running idle timer.")
1234
1235 (defcustom context-coloring-delay 0.25
1236   "Delay between a buffer update and colorization.
1237
1238 Increase this if your machine is high-performing.  Decrease it if
1239 it ain't.
1240
1241 Supported modes: `js-mode', `js3-mode'"
1242   :group 'context-coloring)
1243
1244 (defun context-coloring-setup-idle-change-detection ()
1245   "Setup idle change detection."
1246   (add-hook
1247    'after-change-functions 'context-coloring-change-function nil t)
1248   (setq context-coloring-colorize-idle-timer
1249         (run-with-idle-timer
1250          context-coloring-delay
1251          t
1252          'context-coloring-maybe-colorize)))
1253
1254 ;;;###autoload
1255 (define-minor-mode context-coloring-mode
1256   "Context-based code coloring, inspired by Douglas Crockford."
1257   nil " Context" nil
1258   (if (not context-coloring-mode)
1259       (progn
1260         (context-coloring-kill-scopifier)
1261         (when context-coloring-colorize-idle-timer
1262           (cancel-timer context-coloring-colorize-idle-timer))
1263         (let ((dispatch (gethash major-mode context-coloring-mode-hash-table)))
1264           (when dispatch
1265             (let ((command (plist-get dispatch :command))
1266                   (teardown (plist-get dispatch :teardown)))
1267               (when command
1268                 (remove-hook
1269                  'after-change-functions 'context-coloring-change-function t))
1270               (when teardown
1271                 (funcall teardown)))))
1272         (font-lock-mode)
1273         (jit-lock-mode t))
1274
1275     ;; Remember this buffer.  This value should not be dynamically-bound.
1276     (setq context-coloring-buffer (current-buffer))
1277
1278     ;; Font lock is incompatible with this mode; the converse is also true.
1279     (font-lock-mode 0)
1280     (jit-lock-mode nil)
1281
1282     ;; Safely change the valye of this function as necessary.
1283     (make-local-variable 'font-lock-syntactic-face-function)
1284
1285     (let ((dispatch (gethash major-mode context-coloring-mode-hash-table)))
1286       (if dispatch
1287           (progn
1288             (let ((command (plist-get dispatch :command))
1289                   (version (plist-get dispatch :version))
1290                   (executable (plist-get dispatch :executable))
1291                   (setup (plist-get dispatch :setup))
1292                   (colorize-initially-p t))
1293               (when command
1294                 ;; Shell commands recolor on change, idly.
1295                 (cond
1296                  ((and executable
1297                        (null (executable-find executable)))
1298                   (message "Executable \"%s\" not found" executable)
1299                   (setq colorize-initially-p nil))
1300                  (version
1301                   (context-coloring-check-scopifier-version
1302                    (lambda (sufficient-p)
1303                      (if sufficient-p
1304                          (progn
1305                            (context-coloring-setup-idle-change-detection)
1306                            (context-coloring-colorize))
1307                        (message "Update to the minimum version of \"%s\" (%s)"
1308                                 executable version))))
1309                   (setq colorize-initially-p nil))
1310                  (t
1311                   (context-coloring-setup-idle-change-detection))))
1312               (when setup
1313                 (funcall setup))
1314               ;; Colorize once initially.
1315               (when colorize-initially-p
1316                 (context-coloring-colorize))))
1317         (when (null dispatch)
1318           (message "Context coloring is not available for this major mode"))))))
1319
1320 (provide 'context-coloring)
1321
1322 ;;; context-coloring.el ends here