code.delx.au - gnu-emacs-elpa/blob - context-coloring.el

   1 ;;; context-coloring.el --- Highlight by scope  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2014-2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Jackson Ray Hamilton <jackson@jacksonrayhamilton.com>
   6 ;; Version: 6.3.0
   7 ;; Keywords: convenience faces tools
   8 ;; Package-Requires: ((emacs "24") (js2-mode "20150126"))
   9 ;; URL: https://github.com/jacksonrayhamilton/context-coloring
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This program is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Highlights code by scope.  Top-level scopes are one color, second-level
  29 ;; scopes are another color, and so on.  Variables retain the color of the scope
  30 ;; in which they are defined.  A variable defined in an outer scope referenced
  31 ;; by an inner scope is colored the same as the outer scope.
  32
  33 ;; By default, comments and strings are still highlighted syntactically.
  34
  35 ;;; Code:
  36
  37 (require 'js2-mode)
  38
  39
  40 ;;; Utilities
  41
  42 (defun context-coloring-join (strings delimiter)
  43   "Join a list of STRINGS with the string DELIMITER."
  44   (mapconcat 'identity strings delimiter))
  45
  46 (defsubst context-coloring-trim-right (string)
  47   "Remove leading whitespace from STRING."
  48   (if (string-match "[ \t\n\r]+\\'" string)
  49       (replace-match "" t t string)
  50     string))
  51
  52 (defsubst context-coloring-trim-left (string)
  53   "Remove trailing whitespace from STRING."
  54   (if (string-match "\\`[ \t\n\r]+" string)
  55       (replace-match "" t t string)
  56     string))
  57
  58 (defsubst context-coloring-trim (string)
  59   "Remove leading and trailing whitespace from STRING."
  60   (context-coloring-trim-left (context-coloring-trim-right string)))
  61
  62
  63 ;;; Faces
  64
  65 (defun context-coloring-defface (level tty light dark)
  66   "Define a face for LEVEL with colors for TTY, LIGHT and DARK
  67 backgrounds."
  68   (let ((face (intern (format "context-coloring-level-%s-face" level)))
  69         (doc (format "Context coloring face, level %s." level)))
  70     (custom-declare-face
  71      face
  72      `((((type tty)) (:foreground ,tty))
  73        (((background light)) (:foreground ,light))
  74        (((background dark)) (:foreground ,dark)))
  75      doc
  76      :group 'context-coloring)))
  77
  78 (defun context-coloring-defface-neutral (level)
  79   "Define a face for LEVEL with the default neutral colors."
  80   (context-coloring-defface level nil "#3f3f3f" "#cdcdcd"))
  81
  82 (context-coloring-defface 0 nil       "#000000" "#ffffff")
  83 (context-coloring-defface 1 "yellow"  "#008b8b" "#00ffff")
  84 (context-coloring-defface 2 "green"   "#0000ff" "#87cefa")
  85 (context-coloring-defface 3 "cyan"    "#483d8b" "#b0c4de")
  86 (context-coloring-defface 4 "blue"    "#a020f0" "#eedd82")
  87 (context-coloring-defface 5 "magenta" "#a0522d" "#98fb98")
  88 (context-coloring-defface 6 "red"     "#228b22" "#7fffd4")
  89 (context-coloring-defface-neutral 7)
  90
  91 (defvar context-coloring-maximum-face nil
  92   "Index of the highest face available for coloring.")
  93
  94 (defvar context-coloring-original-maximum-face nil
  95   "Fallback value for `context-coloring-maximum-face' when all
  96   themes have been disabled.")
  97
  98 (setq context-coloring-maximum-face 7)
  99
 100 (setq context-coloring-original-maximum-face
 101       context-coloring-maximum-face)
 102
 103 ;; Theme authors can have up to 26 levels: 1 (0th) for globals, 24 (1st-24th)
 104 ;; for nested levels, and 1 (25th) for infinity.
 105 (dotimes (number 18)
 106   (context-coloring-defface-neutral (+ number context-coloring-maximum-face 1)))
 107
 108
 109 ;;; Face functions
 110
 111 (defsubst context-coloring-level-face (level)
 112   "Return the symbol for a face with LEVEL."
 113   ;; `concat' is faster than `format' here.
 114   (intern-soft
 115    (concat "context-coloring-level-" (number-to-string level) "-face")))
 116
 117 (defsubst context-coloring-bounded-level-face (level)
 118   "Return the symbol for a face with LEVEL, bounded by
 119 `context-coloring-maximum-face'."
 120   (context-coloring-level-face (min level context-coloring-maximum-face)))
 121
 122
 123 ;;; Colorization utilities
 124
 125 (defsubst context-coloring-colorize-region (start end level)
 126   "Color characters from the 1-indexed START point (inclusive) to
 127 the END point (exclusive) with the face corresponding to LEVEL."
 128   (add-text-properties
 129    start
 130    end
 131    `(face ,(context-coloring-bounded-level-face level))))
 132
 133 (make-obsolete-variable
 134  'context-coloring-comments-and-strings
 135  "use `context-coloring-syntactic-comments' and
 136  `context-coloring-syntactic-strings' instead."
 137  "6.1.0")
 138
 139 (defcustom context-coloring-syntactic-comments t
 140   "If non-nil, also color comments using `font-lock'."
 141   :group 'context-coloring)
 142
 143 (defcustom context-coloring-syntactic-strings t
 144   "If non-nil, also color strings using `font-lock'."
 145   :group 'context-coloring)
 146
 147 (defun context-coloring-font-lock-syntactic-comment-function (state)
 148   "Tell `font-lock' to color a comment but not a string."
 149   (if (nth 3 state) nil font-lock-comment-face))
 150
 151 (defun context-coloring-font-lock-syntactic-string-function (state)
 152   "Tell `font-lock' to color a string but not a comment."
 153   (if (nth 3 state) font-lock-string-face nil))
 154
 155 (defsubst context-coloring-maybe-colorize-comments-and-strings (&optional min max)
 156   "Color the current buffer's comments or strings if
 157 `context-coloring-syntactic-comments' or
 158 `context-coloring-syntactic-strings' are non-nil."
 159   (when (or context-coloring-syntactic-comments
 160             context-coloring-syntactic-strings)
 161     (let ((min (or min (point-min)))
 162           (max (or max (point-max)))
 163           (font-lock-syntactic-face-function
 164            (cond
 165             ((and context-coloring-syntactic-comments
 166                   (not context-coloring-syntactic-strings))
 167              'context-coloring-font-lock-syntactic-comment-function)
 168             ((and context-coloring-syntactic-strings
 169                   (not context-coloring-syntactic-comments))
 170              'context-coloring-font-lock-syntactic-string-function)
 171             (t
 172              font-lock-syntactic-face-function))))
 173       (save-excursion
 174         (font-lock-fontify-syntactically-region min max)
 175         ;; TODO: Make configurable at the dispatch level.
 176         (when (eq major-mode 'emacs-lisp-mode)
 177           (font-lock-fontify-keywords-region min max))))))
 178
 179
 180 ;;; js2-mode colorization
 181
 182 (defvar-local context-coloring-js2-scope-level-hash-table nil
 183   "Associate `js2-scope' structures and with their scope
 184   levels.")
 185
 186 (defcustom context-coloring-js-block-scopes nil
 187   "If non-nil, also color block scopes in the scope hierarchy in JavaScript.
 188
 189 The block-scoped `let' and `const' are introduced in ES6.  Enable
 190 this for ES6 code; disable it elsewhere.
 191
 192 Supported modes: `js2-mode'"
 193   :group 'context-coloring)
 194
 195 (defsubst context-coloring-js2-scope-level (scope)
 196   "Return the level of SCOPE."
 197   (cond ((gethash scope context-coloring-js2-scope-level-hash-table))
 198         (t
 199          (let ((level 0)
 200                (current-scope scope)
 201                enclosing-scope)
 202            (while (and current-scope
 203                        (js2-node-parent current-scope)
 204                        (setq enclosing-scope
 205                              (js2-node-get-enclosing-scope current-scope)))
 206              (when (or context-coloring-js-block-scopes
 207                        (let ((type (js2-scope-type current-scope)))
 208                          (or (= type js2-SCRIPT)
 209                              (= type js2-FUNCTION)
 210                              (= type js2-CATCH))))
 211                (setq level (+ level 1)))
 212              (setq current-scope enclosing-scope))
 213            (puthash scope level context-coloring-js2-scope-level-hash-table)))))
 214
 215 (defsubst context-coloring-js2-local-name-node-p (node)
 216   "Determine if NODE is a `js2-name-node' representing a local
 217 variable."
 218   (and (js2-name-node-p node)
 219        (let ((parent (js2-node-parent node)))
 220          (not (or (and (js2-object-prop-node-p parent)
 221                        (eq node (js2-object-prop-node-left parent)))
 222                   (and (js2-prop-get-node-p parent)
 223                        ;; For nested property lookup, the node on the left is a
 224                        ;; `js2-prop-get-node', so this always works.
 225                        (eq node (js2-prop-get-node-right parent))))))))
 226
 227 (defvar-local context-coloring-point-max nil
 228   "Cached value of `point-max'.")
 229
 230 (defsubst context-coloring-js2-colorize-node (node level)
 231   "Color NODE with the color for LEVEL."
 232   (let ((start (js2-node-abs-pos node)))
 233     (context-coloring-colorize-region
 234      start
 235      (min
 236       ;; End
 237       (+ start (js2-node-len node))
 238       ;; Somes nodes (like the ast when there is an unterminated multiline
 239       ;; comment) will stretch to the value of `point-max'.
 240       context-coloring-point-max)
 241      level)))
 242
 243 (defun context-coloring-js2-colorize ()
 244   "Color the current buffer using the abstract syntax tree
 245 generated by `js2-mode'."
 246   ;; Reset the hash table; the old one could be obsolete.
 247   (setq context-coloring-js2-scope-level-hash-table (make-hash-table :test 'eq))
 248   (setq context-coloring-point-max (point-max))
 249   (with-silent-modifications
 250     (js2-visit-ast
 251      js2-mode-ast
 252      (lambda (node end-p)
 253        (when (null end-p)
 254          (cond
 255           ((js2-scope-p node)
 256            (context-coloring-js2-colorize-node
 257             node
 258             (context-coloring-js2-scope-level node)))
 259           ((context-coloring-js2-local-name-node-p node)
 260            (let* ((enclosing-scope (js2-node-get-enclosing-scope node))
 261                   (defining-scope (js2-get-defining-scope
 262                                    enclosing-scope
 263                                    (js2-name-node-name node))))
 264              ;; The tree seems to be walked lexically, so an entire scope will
 265              ;; be colored, including its name nodes, before they are reached.
 266              ;; Coloring the nodes defined in that scope would be redundant, so
 267              ;; don't do it.
 268              (when (not (eq defining-scope enclosing-scope))
 269                (context-coloring-js2-colorize-node
 270                 node
 271                 (context-coloring-js2-scope-level defining-scope))))))
 272          ;; The `t' indicates to search children.
 273          t)))
 274     (context-coloring-maybe-colorize-comments-and-strings)))
 275
 276
 277 ;;; Emacs Lisp colorization
 278
 279 (defsubst context-coloring-forward-sws ()
 280   "Move forward through whitespace and comments."
 281   (while (forward-comment 1)))
 282
 283 (defsubst context-coloring-get-syntax-code ()
 284   (syntax-class
 285    ;; Faster version of `syntax-after':
 286    (aref (syntax-table) (char-after (point)))))
 287
 288 (defsubst context-coloring-exact-regexp (word)
 289   "Create a regexp that matches exactly WORD."
 290   (concat "\\`" (regexp-quote word) "\\'"))
 291
 292 (defsubst context-coloring-exact-or-regexp (words)
 293   "Create a regexp that matches any exact word in WORDS."
 294   (context-coloring-join
 295    (mapcar 'context-coloring-exact-regexp words) "\\|"))
 296
 297 (defconst context-coloring-elisp-defun-regexp
 298   (context-coloring-exact-or-regexp
 299    '("defun" "defun*" "defsubst" "defmacro"
 300      "cl-defun" "cl-defsubst" "cl-defmacro")))
 301
 302 (defconst context-coloring-elisp-arglist-arg-regexp
 303   "\\`[^&:]")
 304
 305 (defconst context-coloring-ignored-word-regexp
 306   (context-coloring-join (list "\\`[-+]?[0-9]"
 307                                "\\`[&:].+"
 308                                (context-coloring-exact-or-regexp
 309                                 '("t" "nil" "." "?")))
 310                          "\\|"))
 311
 312 (defconst context-coloring-WORD-CODE 2)
 313 (defconst context-coloring-SYMBOL-CODE 3)
 314 (defconst context-coloring-OPEN-PARENTHESIS-CODE 4)
 315 (defconst context-coloring-CLOSE-PARENTHESIS-CODE 5)
 316 (defconst context-coloring-EXPRESSION-PREFIX-CODE 6)
 317 (defconst context-coloring-STRING-QUOTE-CODE 7)
 318 (defconst context-coloring-ESCAPE-CODE 9)
 319 (defconst context-coloring-COMMENT-START-CODE 11)
 320 (defconst context-coloring-COMMENT-END-CODE 12)
 321
 322 (defconst context-coloring-OCTOTHORPE-CHAR (string-to-char "#"))
 323 (defconst context-coloring-APOSTROPHE-CHAR (string-to-char "'"))
 324 (defconst context-coloring-OPEN-PARENTHESIS-CHAR (string-to-char "("))
 325 (defconst context-coloring-COMMA-CHAR (string-to-char ","))
 326 (defconst context-coloring-AT-CHAR (string-to-char "@"))
 327 (defconst context-coloring-BACKTICK-CHAR (string-to-char "`"))
 328
 329 (defvar context-coloring-parse-interruptable-p t
 330   "Set this to nil to force parse to continue until finished.")
 331
 332 (defconst context-coloring-elisp-sexps-per-pause 1000
 333   "Pause after this many iterations to check for user input.
 334 If user input is pending, stop the parse.  This makes for a
 335 smoother user experience for large files.
 336
 337 As of this writing, emacs lisp colorization seems to run at about
 338 60,000 iterations per second.  A default value of 1000 should
 339 provide visually \"instant\" updates at 60 frames per second.")
 340
 341 (defvar context-coloring-elisp-sexp-count 0)
 342
 343 (defsubst context-coloring-elisp-increment-sexp-count ()
 344   (setq context-coloring-elisp-sexp-count
 345         (1+ context-coloring-elisp-sexp-count))
 346   (when (and (zerop (% context-coloring-elisp-sexp-count
 347                        context-coloring-elisp-sexps-per-pause))
 348              context-coloring-parse-interruptable-p
 349              (input-pending-p))
 350     (throw 'interrupted t)))
 351
 352 (defvar context-coloring-elisp-scope-stack '())
 353
 354 (defsubst context-coloring-elisp-make-scope (level)
 355   (list
 356    :level level
 357    :variables '()))
 358
 359 (defsubst context-coloring-elisp-scope-get-level (scope)
 360   (plist-get scope :level))
 361
 362 (defsubst context-coloring-elisp-scope-add-variable (scope variable)
 363   (plist-put scope :variables (cons variable (plist-get scope :variables))))
 364
 365 (defsubst context-coloring-elisp-scope-has-variable (scope variable)
 366   (member variable (plist-get scope :variables)))
 367
 368 (defsubst context-coloring-elisp-get-variable-level (variable)
 369   (let* ((scope-stack context-coloring-elisp-scope-stack)
 370          scope
 371          level)
 372     (while (and scope-stack (not level))
 373       (setq scope (car scope-stack))
 374       (cond
 375        ((context-coloring-elisp-scope-has-variable scope variable)
 376         (setq level (context-coloring-elisp-scope-get-level scope)))
 377        (t
 378         (setq scope-stack (cdr scope-stack)))))
 379     ;; Assume a global variable.
 380     (or level 0)))
 381
 382 (defsubst context-coloring-elisp-current-scope-level ()
 383   (cond
 384    ((car context-coloring-elisp-scope-stack)
 385     (context-coloring-elisp-scope-get-level (car context-coloring-elisp-scope-stack)))
 386    (t
 387     0)))
 388
 389 (defsubst context-coloring-elisp-push-scope ()
 390   (push (context-coloring-elisp-make-scope
 391          (1+ (context-coloring-elisp-current-scope-level)))
 392         context-coloring-elisp-scope-stack))
 393
 394 (defsubst context-coloring-elisp-pop-scope ()
 395   (pop context-coloring-elisp-scope-stack))
 396
 397 (defsubst context-coloring-elisp-add-variable (variable)
 398   (context-coloring-elisp-scope-add-variable
 399    (car context-coloring-elisp-scope-stack)
 400    variable))
 401
 402 (defsubst context-coloring-elisp-parse-arg (callback)
 403   (let* ((arg-string (buffer-substring-no-properties
 404                       (point)
 405                       (progn (forward-sexp)
 406                              (point)))))
 407     (when (string-match-p
 408            context-coloring-elisp-arglist-arg-regexp
 409            arg-string)
 410       (funcall callback arg-string))))
 411
 412 ;; TODO: These seem to spiral into an infinite loop sometimes.
 413 (defun context-coloring-elisp-parse-let-varlist (type)
 414   (let ((varlist '())
 415         syntax-code)
 416     ;; Enter.
 417     (forward-char)
 418     (while (/= (setq syntax-code (context-coloring-get-syntax-code))
 419                context-coloring-CLOSE-PARENTHESIS-CODE)
 420       (cond
 421        ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 422         (forward-char)
 423         (context-coloring-forward-sws)
 424         (setq syntax-code (context-coloring-get-syntax-code))
 425         (when (or (= syntax-code context-coloring-WORD-CODE)
 426                   (= syntax-code context-coloring-SYMBOL-CODE))
 427           (context-coloring-elisp-parse-arg
 428            (lambda (var)
 429              (push var varlist)))
 430           (context-coloring-forward-sws)
 431           (setq syntax-code (context-coloring-get-syntax-code))
 432           (when (/= syntax-code context-coloring-CLOSE-PARENTHESIS-CODE)
 433             (context-coloring-elisp-colorize-sexp)))
 434         (context-coloring-forward-sws)
 435         ;; Skip past the closing parenthesis.
 436         (forward-char))
 437        ((or (= syntax-code context-coloring-WORD-CODE)
 438             (= syntax-code context-coloring-SYMBOL-CODE))
 439         (context-coloring-elisp-parse-arg
 440          (lambda (var)
 441            (push var varlist)))))
 442       (when (eq type 'let*)
 443         (context-coloring-elisp-add-variable (pop varlist)))
 444       (context-coloring-forward-sws))
 445     (when (eq type 'let)
 446       (while varlist
 447         (context-coloring-elisp-add-variable (pop varlist))))
 448     ;; Exit.
 449     (forward-char)))
 450
 451 (defun context-coloring-elisp-parse-arglist ()
 452   (let (syntax-code)
 453     ;; Enter.
 454     (forward-char)
 455     (while (/= (setq syntax-code (context-coloring-get-syntax-code))
 456                context-coloring-CLOSE-PARENTHESIS-CODE)
 457       (cond
 458        ((or (= syntax-code context-coloring-WORD-CODE)
 459             (= syntax-code context-coloring-SYMBOL-CODE))
 460         (context-coloring-elisp-parse-arg
 461          (lambda (arg)
 462            (context-coloring-elisp-add-variable arg))))
 463        (t
 464         (forward-sexp)))
 465       (context-coloring-forward-sws))
 466     ;; Exit.
 467     (forward-char)))
 468
 469 (defun context-coloring-elisp-colorize-defun-like (&optional anonymous-p
 470                                                              let-type)
 471   (let ((start (point))
 472         end
 473         stop
 474         syntax-code
 475         defun-name-pos
 476         defun-name-end)
 477     (context-coloring-elisp-push-scope)
 478     ;; Color the whole sexp.
 479     (forward-sexp)
 480     (setq end (point))
 481     (context-coloring-colorize-region
 482      start
 483      end
 484      (context-coloring-elisp-current-scope-level))
 485     (goto-char start)
 486     ;; Skip past the "defun".
 487     (skip-syntax-forward "^w_")
 488     (forward-sexp)
 489     (context-coloring-forward-sws)
 490     (setq stop nil)
 491     (unless anonymous-p
 492       ;; Check for the defun's name.
 493       (setq syntax-code (context-coloring-get-syntax-code))
 494       (cond
 495        ((or (= syntax-code context-coloring-WORD-CODE)
 496             (= syntax-code context-coloring-SYMBOL-CODE))
 497         ;; Color the defun's name with the top-level color.
 498         (setq defun-name-pos (point))
 499         (forward-sexp)
 500         (setq defun-name-end (point))
 501         (context-coloring-colorize-region defun-name-pos defun-name-end 0)
 502         (context-coloring-forward-sws))
 503        (t
 504         (setq stop t))))
 505     (cond
 506      (stop
 507       ;; Skip it.
 508       (goto-char start)
 509       (forward-sexp))
 510      (t
 511       (setq syntax-code (context-coloring-get-syntax-code))
 512       (cond
 513        ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 514         (cond
 515          (let-type
 516           (context-coloring-elisp-parse-let-varlist let-type))
 517          (t
 518           (context-coloring-elisp-parse-arglist)))
 519         ;; Colorize the rest of the function.
 520         (context-coloring-elisp-colorize-region (point) (1- end))
 521         ;; Exit the defun.
 522         (forward-char))
 523        (t
 524         ;; Skip it.
 525         (goto-char start)
 526         (forward-sexp)))))
 527     (context-coloring-elisp-pop-scope)
 528     (context-coloring-elisp-colorize-comments-and-strings-in-region start end)))
 529
 530 (defun context-coloring-elisp-colorize-defun ()
 531   (context-coloring-elisp-colorize-defun-like))
 532
 533 (defun context-coloring-elisp-colorize-lambda ()
 534   (context-coloring-elisp-colorize-defun-like t))
 535
 536 (defun context-coloring-elisp-colorize-let ()
 537   (context-coloring-elisp-colorize-defun-like t 'let))
 538
 539 (defun context-coloring-elisp-colorize-let* ()
 540   (context-coloring-elisp-colorize-defun-like t 'let*))
 541
 542 (defun context-coloring-elisp-colorize-parenthesized-sexp ()
 543   (context-coloring-elisp-increment-sexp-count)
 544   (let* ((start (point))
 545          (end (progn (forward-sexp)
 546                      (point)))
 547          (syntax-code (progn (goto-char start)
 548                              (forward-char)
 549                              (context-coloring-forward-sws)
 550                              (context-coloring-get-syntax-code))))
 551     ;; Figure out if the sexp is a special form.
 552     (cond
 553      ((when (or (= syntax-code context-coloring-WORD-CODE)
 554                 (= syntax-code context-coloring-SYMBOL-CODE))
 555         (let ((name-string (buffer-substring-no-properties
 556                             (point)
 557                             (progn (forward-sexp)
 558                                    (point)))))
 559           (cond
 560            ((string-match-p context-coloring-elisp-defun-regexp name-string)
 561             (goto-char start)
 562             (context-coloring-elisp-colorize-defun)
 563             t)
 564            ((string-equal "let" name-string)
 565             (goto-char start)
 566             (context-coloring-elisp-colorize-let)
 567             t)
 568            ((string-equal "let*" name-string)
 569             (goto-char start)
 570             (context-coloring-elisp-colorize-let*)
 571             t)
 572            ((string-equal "lambda" name-string)
 573             (goto-char start)
 574             (context-coloring-elisp-colorize-lambda)
 575             t)
 576            (t
 577             nil)))))
 578      ;; Not a special form; just colorize the remaining region.
 579      (t
 580       (context-coloring-colorize-region
 581        start
 582        end
 583        (context-coloring-elisp-current-scope-level))
 584       (context-coloring-elisp-colorize-region (point) (1- end))
 585       (forward-char)))))
 586
 587 (defun context-coloring-elisp-colorize-symbol ()
 588   (context-coloring-elisp-increment-sexp-count)
 589   (let* ((symbol-pos (point))
 590          (symbol-end (progn (forward-sexp)
 591                             (point)))
 592          (symbol-string (buffer-substring-no-properties
 593                          symbol-pos
 594                          symbol-end)))
 595     (cond
 596      ((string-match-p context-coloring-ignored-word-regexp symbol-string))
 597      (t
 598       (context-coloring-colorize-region
 599        symbol-pos
 600        symbol-end
 601        (context-coloring-elisp-get-variable-level
 602         symbol-string))))))
 603
 604 (defun context-coloring-elisp-colorize-expression-prefix ()
 605   (context-coloring-elisp-increment-sexp-count)
 606   (let ((char (char-after))
 607         (start (point))
 608         (end (progn (forward-sexp)
 609                     (point))))
 610     (cond
 611      ((or (= char context-coloring-APOSTROPHE-CHAR)
 612           (= char context-coloring-OCTOTHORPE-CHAR))
 613       (context-coloring-elisp-colorize-comments-and-strings-in-region start end))
 614      ((= char context-coloring-BACKTICK-CHAR)
 615       (goto-char start)
 616       (while (> end (progn (forward-char)
 617                            (point)))
 618         (setq char (char-after))
 619         (when (= char context-coloring-COMMA-CHAR)
 620           (forward-char)
 621           (when (= (char-after) context-coloring-AT-CHAR)
 622             ;; If we don't do this "@" could be interpreted as a symbol.
 623             (forward-char))
 624           (context-coloring-forward-sws)
 625           (context-coloring-elisp-colorize-sexp)))
 626       (context-coloring-elisp-colorize-comments-and-strings-in-region start end)))))
 627
 628 (defun context-coloring-elisp-colorize-comment ()
 629   (context-coloring-elisp-increment-sexp-count)
 630   (let ((start (point)))
 631     (context-coloring-forward-sws)
 632     (context-coloring-maybe-colorize-comments-and-strings
 633      start
 634      (point))))
 635
 636 (defun context-coloring-elisp-colorize-string ()
 637   (context-coloring-elisp-increment-sexp-count)
 638   (let ((start (point)))
 639     (forward-sexp)
 640     (context-coloring-maybe-colorize-comments-and-strings
 641      start
 642      (point))))
 643
 644 (defun context-coloring-elisp-colorize-sexp ()
 645   (let ((syntax-code (context-coloring-get-syntax-code)))
 646     (cond
 647      ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 648       (context-coloring-elisp-colorize-parenthesized-sexp))
 649      ((or (= syntax-code context-coloring-WORD-CODE)
 650           (= syntax-code context-coloring-SYMBOL-CODE))
 651       (context-coloring-elisp-colorize-symbol))
 652      ((= syntax-code context-coloring-EXPRESSION-PREFIX-CODE)
 653       (context-coloring-elisp-colorize-expression-prefix))
 654      ((= syntax-code context-coloring-STRING-QUOTE-CODE)
 655       (context-coloring-elisp-colorize-string))
 656      ((= syntax-code context-coloring-ESCAPE-CODE)
 657       (forward-char 2))
 658      (t
 659       (forward-char)))))
 660
 661 (defun context-coloring-elisp-colorize-comments-and-strings-in-region (start end)
 662   (let (syntax-code)
 663     (goto-char start)
 664     (while (> end (progn (skip-syntax-forward "^<\"\\" end)
 665                          (point)))
 666       (setq syntax-code (context-coloring-get-syntax-code))
 667       (cond
 668        ((= syntax-code context-coloring-STRING-QUOTE-CODE)
 669         (context-coloring-elisp-colorize-string))
 670        ((= syntax-code context-coloring-COMMENT-START-CODE)
 671         (context-coloring-elisp-colorize-comment))
 672        ((= syntax-code context-coloring-ESCAPE-CODE)
 673         (forward-char 2))
 674        (t
 675         (forward-char))))))
 676
 677 (defun context-coloring-elisp-colorize-region (start end)
 678   (let (syntax-code)
 679     (goto-char start)
 680     (while (> end (progn (skip-syntax-forward "^()w_'<\"\\" end)
 681                          (point)))
 682       (setq syntax-code (context-coloring-get-syntax-code))
 683       (cond
 684        ((= syntax-code context-coloring-OPEN-PARENTHESIS-CODE)
 685         (context-coloring-elisp-colorize-parenthesized-sexp))
 686        ((or (= syntax-code context-coloring-WORD-CODE)
 687             (= syntax-code context-coloring-SYMBOL-CODE))
 688         (context-coloring-elisp-colorize-symbol))
 689        ((= syntax-code context-coloring-EXPRESSION-PREFIX-CODE)
 690         (context-coloring-elisp-colorize-expression-prefix))
 691        ((= syntax-code context-coloring-STRING-QUOTE-CODE)
 692         (context-coloring-elisp-colorize-string))
 693        ((= syntax-code context-coloring-COMMENT-START-CODE)
 694         (context-coloring-elisp-colorize-comment))
 695        ((= syntax-code context-coloring-ESCAPE-CODE)
 696         (forward-char 2))
 697        (t
 698         (forward-char))))))
 699
 700 (defun context-coloring-elisp-colorize (start end)
 701   (setq context-coloring-elisp-sexp-count 0)
 702   (setq context-coloring-elisp-scope-stack '())
 703   (let ((inhibit-point-motion-hooks t)
 704         (case-fold-search nil)
 705         ;; This is a recursive-descent parser, so give it a big stack.
 706         (max-lisp-eval-depth (max max-lisp-eval-depth 3000))
 707         (max-specpdl-size (max max-specpdl-size 3000)))
 708     (context-coloring-elisp-colorize-region start end)))
 709
 710 (defun context-coloring-elisp-colorize-changed-region (start end)
 711   (with-silent-modifications
 712     (save-excursion
 713       (let ((start (progn (goto-char start)
 714                           (beginning-of-defun)
 715                           (point)))
 716             (end (progn (goto-char end)
 717                         (end-of-defun)
 718                         (point))))
 719         (context-coloring-elisp-colorize start end)))))
 720
 721 (defun context-coloring-elisp-colorize-buffer ()
 722   (interactive)
 723   (with-silent-modifications
 724     (save-excursion
 725       (context-coloring-elisp-colorize (point-min) (point-max)))))
 726
 727
 728 ;;; Shell command scopification / colorization
 729
 730 (defun context-coloring-apply-tokens (tokens)
 731   "Process a string of TOKENS to apply context-based coloring to
 732 the current buffer.  Tokens are 3 integers: start, end, level.  A
 733 new token occurrs after every 3rd element, and the elements are
 734 separated by commas."
 735   (let* ((tokens (mapcar 'string-to-number (split-string tokens ","))))
 736     (while tokens
 737       (context-coloring-colorize-region
 738        (pop tokens)
 739        (pop tokens)
 740        (pop tokens))))
 741   (context-coloring-maybe-colorize-comments-and-strings))
 742
 743 (defun context-coloring-parse-array (array)
 744   "Parse ARRAY as a flat JSON array of numbers and use the tokens
 745 to colorize the buffer."
 746   (let* ((braceless (substring-no-properties (context-coloring-trim array) 1 -1)))
 747     (when (> (length braceless) 0)
 748       (with-silent-modifications
 749         (context-coloring-apply-tokens braceless)))))
 750
 751 (defvar-local context-coloring-scopifier-process nil
 752   "The single scopifier process that can be running.")
 753
 754 (defun context-coloring-kill-scopifier ()
 755   "Kill the currently-running scopifier process."
 756   (when (not (null context-coloring-scopifier-process))
 757     (delete-process context-coloring-scopifier-process)
 758     (setq context-coloring-scopifier-process nil)))
 759
 760 (defun context-coloring-scopify-shell-command (command callback)
 761   "Invoke a scopifier via COMMAND, read its response
 762 asynchronously and invoke CALLBACK with its output."
 763
 764   ;; Prior running tokenization is implicitly obsolete if this function is
 765   ;; called.
 766   (context-coloring-kill-scopifier)
 767
 768   ;; Start the process.
 769   (setq context-coloring-scopifier-process
 770         (start-process-shell-command "scopifier" nil command))
 771
 772   (let ((output ""))
 773
 774     ;; The process may produce output in multiple chunks.  This filter
 775     ;; accumulates the chunks into a message.
 776     (set-process-filter
 777      context-coloring-scopifier-process
 778      (lambda (_process chunk)
 779        (setq output (concat output chunk))))
 780
 781     ;; When the process's message is complete, this sentinel parses it as JSON
 782     ;; and applies the tokens to the buffer.
 783     (set-process-sentinel
 784      context-coloring-scopifier-process
 785      (lambda (_process event)
 786        (when (equal "finished\n" event)
 787          (funcall callback output))))))
 788
 789 (defun context-coloring-send-buffer-to-scopifier ()
 790   "Give the scopifier process its input so it can begin
 791 scopifying."
 792   (process-send-region
 793    context-coloring-scopifier-process
 794    (point-min) (point-max))
 795   (process-send-eof
 796    context-coloring-scopifier-process))
 797
 798 (defun context-coloring-scopify-and-colorize (command &optional callback)
 799   "Invoke a scopifier via COMMAND with the current buffer's contents,
 800 read the scopifier's response asynchronously and apply a parsed
 801 list of tokens to `context-coloring-apply-tokens'.
 802
 803 Invoke CALLBACK when complete."
 804   (let ((buffer (current-buffer)))
 805     (context-coloring-scopify-shell-command
 806      command
 807      (lambda (output)
 808        (with-current-buffer buffer
 809          (context-coloring-parse-array output))
 810        (setq context-coloring-scopifier-process nil)
 811        (when callback (funcall callback)))))
 812   (context-coloring-send-buffer-to-scopifier))
 813
 814
 815 ;;; Dispatch
 816
 817 (defvar context-coloring-dispatch-hash-table (make-hash-table :test 'eq)
 818   "Map dispatch strategy names to their corresponding property
 819   lists, which contain details about the strategies.")
 820
 821 (defvar context-coloring-mode-hash-table (make-hash-table :test 'eq)
 822   "Map major mode names to dispatch property lists.")
 823
 824 (defun context-coloring-get-dispatch-for-mode (mode)
 825   "Return the dispatch for MODE (or a derivative mode)."
 826   (let ((parent mode)
 827         dispatch)
 828     (while (and parent
 829                 (not (setq dispatch (gethash parent context-coloring-mode-hash-table)))
 830                 (setq parent (get parent 'derived-mode-parent))))
 831     dispatch))
 832
 833 (defun context-coloring-define-dispatch (symbol &rest properties)
 834   "Define a new dispatch named SYMBOL with PROPERTIES.
 835
 836 A \"dispatch\" is a property list describing a strategy for
 837 coloring a buffer.  There are two possible strategies: Parse and
 838 color in a single function (`:colorizer') or parse with a shell
 839 command that returns scope data (`:command').  In the latter
 840 case, the scope data will be used to automatically color the
 841 buffer.
 842
 843 PROPERTIES must include `:modes' and one of `:colorizer',
 844 `:scopifier' or `:command'.
 845
 846 `:modes' - List of major modes this dispatch is valid for.
 847
 848 `:colorizer' - Symbol referring to a function that parses and
 849 colors the buffer.
 850
 851 `:executable' - Optional name of an executable required by
 852 `:command'.
 853
 854 `:command' - Shell command to execute with the current buffer
 855 sent via stdin, and with a flat JSON array of start, end and
 856 level data returned via stdout.
 857
 858 `:version' - Minimum required version that should be printed when
 859 executing `:command' with a \"--version\" flag.  The version
 860 should be numeric, e.g. \"2\", \"19700101\", \"1.2.3\",
 861 \"v1.2.3\" etc.
 862
 863 `:setup' - Arbitrary code to set up this dispatch when
 864 `context-coloring-mode' is enabled.
 865
 866 `:teardown' - Arbitrary code to tear down this dispatch when
 867 `context-coloring-mode' is disabled."
 868   (let ((modes (plist-get properties :modes))
 869         (colorizer (plist-get properties :colorizer))
 870         (command (plist-get properties :command)))
 871     (when (null modes)
 872       (error "No mode defined for dispatch"))
 873     (when (not (or colorizer
 874                    command))
 875       (error "No colorizer or command defined for dispatch"))
 876     (puthash symbol properties context-coloring-dispatch-hash-table)
 877     (dolist (mode modes)
 878       (puthash mode properties context-coloring-mode-hash-table))))
 879
 880
 881 ;;; Colorization
 882
 883 (defvar context-coloring-colorize-hook nil
 884   "Hooks to run after coloring a buffer.")
 885
 886 (defun context-coloring-colorize (&optional callback)
 887   "Color the current buffer by function context.
 888
 889 Invoke CALLBACK when complete; see `context-coloring-dispatch'."
 890   (interactive)
 891   (context-coloring-dispatch
 892    (lambda ()
 893      (when callback (funcall callback))
 894      (run-hooks 'context-coloring-colorize-hook))))
 895
 896 (defvar-local context-coloring-changed nil
 897   "Indication that the buffer has changed recently, which implies
 898 that it should be colored again by
 899 `context-coloring-colorize-idle-timer' if that timer is being
 900 used.")
 901
 902 (defun context-coloring-change-function (_start _end _length)
 903   "Register a change so that a buffer can be colorized soon."
 904   ;; Tokenization is obsolete if there was a change.
 905   (context-coloring-kill-scopifier)
 906   (setq context-coloring-changed t))
 907
 908 (defun context-coloring-maybe-colorize (buffer)
 909   "Colorize the current buffer if it has changed."
 910   (when (and (eq buffer (current-buffer))
 911              context-coloring-changed)
 912     (setq context-coloring-changed nil)
 913     (context-coloring-colorize)))
 914
 915
 916 ;;; Versioning
 917
 918 (defun context-coloring-parse-version (string)
 919   "Extract segments of a version STRING into a list.  \"v1.0.0\"
 920 produces (1 0 0), \"19700101\" produces (19700101), etc."
 921   (let (version)
 922     (while (string-match "[0-9]+" string)
 923       (setq version (append version
 924                             (list (string-to-number (match-string 0 string)))))
 925       (setq string (substring string (match-end 0))))
 926     version))
 927
 928 (defun context-coloring-check-version (expected actual)
 929   "Check that version EXPECTED is less than or equal to ACTUAL."
 930   (let ((expected (context-coloring-parse-version expected))
 931         (actual (context-coloring-parse-version actual))
 932         (continue t)
 933         (acceptable t))
 934     (while (and continue expected)
 935       (let ((an-expected (car expected))
 936             (an-actual (car actual)))
 937         (cond
 938          ((> an-actual an-expected)
 939           (setq acceptable t)
 940           (setq continue nil))
 941          ((< an-actual an-expected)
 942           (setq acceptable nil)
 943           (setq continue nil))))
 944       (setq expected (cdr expected))
 945       (setq actual (cdr actual)))
 946     acceptable))
 947
 948 (defvar context-coloring-check-scopifier-version-hook nil
 949   "Hooks to run after checking the scopifier version.")
 950
 951 (defun context-coloring-check-scopifier-version (&optional callback)
 952   "Asynchronously invoke CALLBACK with a predicate indicating
 953 whether the current scopifier version satisfies the minimum
 954 version number required for the current major mode."
 955   (let ((dispatch (context-coloring-get-dispatch-for-mode major-mode)))
 956     (when dispatch
 957       (let ((version (plist-get dispatch :version))
 958             (command (plist-get dispatch :command)))
 959         (context-coloring-scopify-shell-command
 960          (context-coloring-join (list command "--version") " ")
 961          (lambda (output)
 962            (if (context-coloring-check-version version output)
 963                (progn
 964                  (when callback (funcall callback t)))
 965              (when callback (funcall callback nil)))
 966            (run-hooks 'context-coloring-check-scopifier-version-hook)))))))
 967
 968
 969 ;;; Themes
 970
 971 (defvar context-coloring-theme-hash-table (make-hash-table :test 'eq)
 972   "Map theme names to theme properties.")
 973
 974 (defun context-coloring-theme-p (theme)
 975   "Return t if THEME is defined, nil otherwise."
 976   (and (gethash theme context-coloring-theme-hash-table)))
 977
 978 (defconst context-coloring-level-face-regexp
 979   "context-coloring-level-\\([[:digit:]]+\\)-face"
 980   "Extract a level from a face.")
 981
 982 (defvar context-coloring-originally-set-theme-hash-table
 983   (make-hash-table :test 'eq)
 984   "Cache custom themes who originally set their own
 985   `context-coloring-level-N-face' faces.")
 986
 987 (defun context-coloring-theme-originally-set-p (theme)
 988   "Return t if there is a `context-coloring-level-N-face'
 989 originally set for THEME, nil otherwise."
 990   (let (originally-set)
 991     (cond
 992      ;; `setq' might return a non-nil value for the sake of this `cond'.
 993      ((setq
 994        originally-set
 995        (gethash
 996         theme
 997         context-coloring-originally-set-theme-hash-table))
 998       (eq originally-set 'yes))
 999      (t
1000       (let* ((settings (get theme 'theme-settings))
1001              (tail settings)
1002              found)
1003         (while (and tail (not found))
1004           (and (eq (nth 0 (car tail)) 'theme-face)
1005                (string-match
1006                 context-coloring-level-face-regexp
1007                 (symbol-name (nth 1 (car tail))))
1008                (setq found t))
1009           (setq tail (cdr tail)))
1010         found)))))
1011
1012 (defun context-coloring-cache-originally-set (theme originally-set)
1013   "Remember if THEME had colors originally set for it.  If
1014 ORIGINALLY-SET is non-nil, it did, otherwise it didn't."
1015   ;; Caching whether a theme was originally set is kind of dirty, but we have to
1016   ;; do it to remember the past state of the theme.  There are probably some
1017   ;; edge cases where caching will be an issue, but they are probably rare.
1018   (puthash
1019    theme
1020    (if originally-set 'yes 'no)
1021    context-coloring-originally-set-theme-hash-table))
1022
1023 (defun context-coloring-warn-theme-originally-set (theme)
1024   "Warn the user that the colors for THEME are already originally
1025 set."
1026   (warn "Context coloring colors for theme `%s' are already defined" theme))
1027
1028 (defun context-coloring-theme-highest-level (theme)
1029   "Return the highest level N of a face like
1030 `context-coloring-level-N-face' set for THEME, or `-1' if there
1031 is none."
1032   (let* ((settings (get theme 'theme-settings))
1033          (tail settings)
1034          face-string
1035          number
1036          (found -1))
1037     (while tail
1038       (and (eq (nth 0 (car tail)) 'theme-face)
1039            (setq face-string (symbol-name (nth 1 (car tail))))
1040            (string-match
1041             context-coloring-level-face-regexp
1042             face-string)
1043            (setq number (string-to-number
1044                          (substring face-string
1045                                     (match-beginning 1)
1046                                     (match-end 1))))
1047            (> number found)
1048            (setq found number))
1049       (setq tail (cdr tail)))
1050     found))
1051
1052 (defun context-coloring-apply-theme (theme)
1053   "Apply THEME's properties to its respective custom theme,
1054 which must already exist and which *should* already be enabled."
1055   (let* ((properties (gethash theme context-coloring-theme-hash-table))
1056          (colors (plist-get properties :colors))
1057          (level -1))
1058     ;; Only clobber when we have to.
1059     (when (custom-theme-enabled-p theme)
1060       (setq context-coloring-maximum-face (- (length colors) 1)))
1061     (apply
1062      'custom-theme-set-faces
1063      theme
1064      (mapcar
1065       (lambda (color)
1066         (setq level (+ level 1))
1067         `(,(context-coloring-level-face level) ((t (:foreground ,color)))))
1068       colors))))
1069
1070 (defun context-coloring-define-theme (theme &rest properties)
1071   "Define a context theme named THEME for coloring scope levels.
1072
1073 PROPERTIES is a property list specifiying the following details:
1074
1075 `:aliases': List of symbols of other custom themes that these
1076 colors are applicable to.
1077
1078 `:colors': List of colors that this context theme uses.
1079
1080 `:override': If non-nil, this context theme is intentionally
1081 overriding colors set by a custom theme.  Don't set this non-nil
1082 unless there is a custom theme you want to use which sets
1083 `context-coloring-level-N-face' faces that you want to replace.
1084
1085 `:recede': If non-nil, this context theme should not apply its
1086 colors if a custom theme already sets
1087 `context-coloring-level-N-face' faces.  This option is
1088 optimistic; set this non-nil if you would rather confer the duty
1089 of picking colors to a custom theme author (if / when he ever
1090 gets around to it).
1091
1092 By default, context themes will always override custom themes,
1093 even if those custom themes set `context-coloring-level-N-face'
1094 faces.  If a context theme does override a custom theme, a
1095 warning will be raised, at which point you may want to enable the
1096 `:override' option, or just delete your context theme and opt to
1097 use your custom theme's author's colors instead.
1098
1099 Context themes only work for the custom theme with the highest
1100 precedence, i.e. the car of `custom-enabled-themes'."
1101   (let ((aliases (plist-get properties :aliases))
1102         (override (plist-get properties :override))
1103         (recede (plist-get properties :recede)))
1104     (dolist (name (append `(,theme) aliases))
1105       (puthash name properties context-coloring-theme-hash-table)
1106       (when (custom-theme-p name)
1107         (let ((originally-set (context-coloring-theme-originally-set-p name)))
1108           (context-coloring-cache-originally-set name originally-set)
1109           ;; In the particular case when you innocently define colors that a
1110           ;; custom theme originally set, warn.  Arguably this only has to be
1111           ;; done at enable time, but it is probably more useful to do it at
1112           ;; definition time for prompter feedback.
1113           (when (and originally-set
1114                      (not recede)
1115                      (not override))
1116             (context-coloring-warn-theme-originally-set name))
1117           ;; Set (or overwrite) colors.
1118           (when (not (and originally-set
1119                           recede))
1120             (context-coloring-apply-theme name)))))))
1121
1122 (defun context-coloring-enable-theme (theme)
1123   "Apply THEME if its colors are not already set, else just set
1124 `context-coloring-maximum-face' to the correct value for THEME."
1125   (let* ((properties (gethash theme context-coloring-theme-hash-table))
1126          (recede (plist-get properties :recede))
1127          (override (plist-get properties :override)))
1128     (cond
1129      (recede
1130       (let ((highest-level (context-coloring-theme-highest-level theme)))
1131         (cond
1132          ;; This can be true whether originally set by a custom theme or by a
1133          ;; context theme.
1134          ((> highest-level -1)
1135           (setq context-coloring-maximum-face highest-level))
1136          ;; It is possible that the corresponding custom theme did not exist at
1137          ;; the time of defining this context theme, and in that case the above
1138          ;; condition proves the custom theme did not originally set any faces,
1139          ;; so we have license to apply the context theme for the first time
1140          ;; here.
1141          (t
1142           (context-coloring-apply-theme theme)))))
1143      (t
1144       (let ((originally-set (context-coloring-theme-originally-set-p theme)))
1145         ;; Cache now in case the context theme was defined after the custom
1146         ;; theme.
1147         (context-coloring-cache-originally-set theme originally-set)
1148         (when (and originally-set
1149                    (not override))
1150           (context-coloring-warn-theme-originally-set theme))
1151         (context-coloring-apply-theme theme))))))
1152
1153 (defadvice enable-theme (after context-coloring-enable-theme (theme) activate)
1154   "Enable colors for context themes just-in-time."
1155   (when (and (not (eq theme 'user)) ; Called internally by `enable-theme'.
1156              (custom-theme-p theme) ; Guard against non-existent themes.
1157              (context-coloring-theme-p theme))
1158     (when (= (length custom-enabled-themes) 1)
1159       ;; Cache because we can't reliably figure it out in reverse.
1160       (setq context-coloring-original-maximum-face
1161             context-coloring-maximum-face))
1162     (context-coloring-enable-theme theme)))
1163
1164 (defadvice disable-theme (after context-coloring-disable-theme (theme) activate)
1165   "Update `context-coloring-maximum-face'."
1166   (when (custom-theme-p theme) ; Guard against non-existent themes.
1167     (let ((enabled-theme (car custom-enabled-themes)))
1168       (if (context-coloring-theme-p enabled-theme)
1169           (progn
1170             (context-coloring-enable-theme enabled-theme))
1171         ;; Assume we are back to no theme; act as if nothing ever happened.
1172         ;; This is still prone to intervention, but rather extraordinarily.
1173         (setq context-coloring-maximum-face
1174               context-coloring-original-maximum-face)))))
1175
1176 (context-coloring-define-theme
1177  'ample
1178  :recede t
1179  :colors '("#bdbdb3"
1180            "#baba36"
1181            "#6aaf50"
1182            "#5180b3"
1183            "#ab75c3"
1184            "#cd7542"
1185            "#df9522"
1186            "#454545"))
1187
1188 (context-coloring-define-theme
1189  'anti-zenburn
1190  :recede t
1191  :colors '("#232333"
1192            "#6c1f1c"
1193            "#401440"
1194            "#0f2050"
1195            "#205070"
1196            "#336c6c"
1197            "#23733c"
1198            "#6b400c"
1199            "#603a60"
1200            "#2f4070"
1201            "#235c5c"))
1202
1203 (context-coloring-define-theme
1204  'grandshell
1205  :recede t
1206  :colors '("#bebebe"
1207            "#5af2ee"
1208            "#b2baf6"
1209            "#f09fff"
1210            "#efc334"
1211            "#f6df92"
1212            "#acfb5a"
1213            "#888888"))
1214
1215 (context-coloring-define-theme
1216  'leuven
1217  :recede t
1218  :colors '("#333333"
1219            "#0000ff"
1220            "#6434a3"
1221            "#ba36a5"
1222            "#d0372d"
1223            "#036a07"
1224            "#006699"
1225            "#006fe0"
1226            "#808080"))
1227
1228 (context-coloring-define-theme
1229  'monokai
1230  :recede t
1231  :colors '("#f8f8f2"
1232            "#66d9ef"
1233            "#a1efe4"
1234            "#a6e22e"
1235            "#e6db74"
1236            "#fd971f"
1237            "#f92672"
1238            "#fd5ff0"
1239            "#ae81ff"))
1240
1241 (context-coloring-define-theme
1242  'solarized
1243  :recede t
1244  :aliases '(solarized-light
1245             solarized-dark
1246             sanityinc-solarized-light
1247             sanityinc-solarized-dark)
1248  :colors '("#839496"
1249            "#268bd2"
1250            "#2aa198"
1251            "#859900"
1252            "#b58900"
1253            "#cb4b16"
1254            "#dc322f"
1255            "#d33682"
1256            "#6c71c4"
1257            "#69b7f0"
1258            "#69cabf"
1259            "#b4c342"
1260            "#deb542"
1261            "#f2804f"
1262            "#ff6e64"
1263            "#f771ac"
1264            "#9ea0e5"))
1265
1266 (context-coloring-define-theme
1267  'spacegray
1268  :recede t
1269  :colors '("#ffffff"
1270            "#89aaeb"
1271            "#c189eb"
1272            "#bf616a"
1273            "#dca432"
1274            "#ebcb8b"
1275            "#b4eb89"
1276            "#89ebca"))
1277
1278 (context-coloring-define-theme
1279  'tango
1280  :recede t
1281  :colors '("#2e3436"
1282            "#346604"
1283            "#204a87"
1284            "#5c3566"
1285            "#a40000"
1286            "#b35000"
1287            "#c4a000"
1288            "#8ae234"
1289            "#8cc4ff"
1290            "#ad7fa8"
1291            "#ef2929"
1292            "#fcaf3e"
1293            "#fce94f"))
1294
1295 (context-coloring-define-theme
1296  'zenburn
1297  :recede t
1298  :colors '("#dcdccc"
1299            "#93e0e3"
1300            "#bfebbf"
1301            "#f0dfaf"
1302            "#dfaf8f"
1303            "#cc9393"
1304            "#dc8cc3"
1305            "#94bff3"
1306            "#9fc59f"
1307            "#d0bf8f"
1308            "#dca3a3"))
1309
1310
1311 ;;; Change detection
1312
1313 (defvar-local context-coloring-colorize-idle-timer nil
1314   "The currently-running idle timer.")
1315
1316 (defcustom context-coloring-delay 0.25
1317   "Delay between a buffer update and colorization.
1318
1319 Increase this if your machine is high-performing.  Decrease it if
1320 it ain't.
1321
1322 Supported modes: `js-mode', `js3-mode', `emacs-lisp-mode'"
1323   :group 'context-coloring)
1324
1325 (defun context-coloring-setup-idle-change-detection ()
1326   "Setup idle change detection."
1327   (add-hook
1328    'after-change-functions 'context-coloring-change-function nil t)
1329   (add-hook
1330    'kill-buffer-hook 'context-coloring-teardown-idle-change-detection nil t)
1331   (setq context-coloring-colorize-idle-timer
1332         (run-with-idle-timer
1333          context-coloring-delay
1334          t
1335          'context-coloring-maybe-colorize
1336          (current-buffer))))
1337
1338 (defun context-coloring-teardown-idle-change-detection ()
1339   "Teardown idle change detection."
1340   (context-coloring-kill-scopifier)
1341   (when context-coloring-colorize-idle-timer
1342     (cancel-timer context-coloring-colorize-idle-timer))
1343   (remove-hook
1344    'kill-buffer-hook 'context-coloring-teardown-idle-change-detection t)
1345   (remove-hook
1346    'after-change-functions 'context-coloring-change-function t))
1347
1348
1349 ;;; Built-in dispatches
1350
1351 (context-coloring-define-dispatch
1352  'javascript-node
1353  :modes '(js-mode js3-mode)
1354  :executable "scopifier"
1355  :command "scopifier"
1356  :version "v1.1.1")
1357
1358 (context-coloring-define-dispatch
1359  'javascript-js2
1360  :modes '(js2-mode)
1361  :colorizer 'context-coloring-js2-colorize
1362  :setup
1363  (lambda ()
1364    (add-hook 'js2-post-parse-callbacks 'context-coloring-colorize nil t))
1365  :teardown
1366  (lambda ()
1367    (remove-hook 'js2-post-parse-callbacks 'context-coloring-colorize t)))
1368
1369 (context-coloring-define-dispatch
1370  'emacs-lisp
1371  :modes '(emacs-lisp-mode)
1372  :colorizer 'context-coloring-elisp-colorize-buffer
1373  :setup 'context-coloring-setup-idle-change-detection
1374  :teardown 'context-coloring-teardown-idle-change-detection)
1375
1376 (defun context-coloring-dispatch (&optional callback)
1377   "Determine the optimal track for scopification / coloring of
1378 the current buffer, then execute it.
1379
1380 Invoke CALLBACK when complete.  It is invoked synchronously for
1381 elisp tracks, and asynchronously for shell command tracks."
1382   (let* ((dispatch (context-coloring-get-dispatch-for-mode major-mode))
1383          (colorizer (plist-get dispatch :colorizer))
1384          (command (plist-get dispatch :command))
1385          interrupted-p)
1386     (cond
1387      (colorizer
1388       (setq interrupted-p
1389             (catch 'interrupted
1390               (funcall colorizer)))
1391       (cond
1392        (interrupted-p
1393         (setq context-coloring-changed t))
1394        (t
1395         (when callback (funcall callback)))))
1396      (command
1397       (context-coloring-scopify-and-colorize command callback)))))
1398
1399
1400 ;;; Minor mode
1401
1402 ;;;###autoload
1403 (define-minor-mode context-coloring-mode
1404   "Context-based code coloring, inspired by Douglas Crockford."
1405   nil " Context" nil
1406   (if (not context-coloring-mode)
1407       (progn
1408         (let ((dispatch (context-coloring-get-dispatch-for-mode major-mode)))
1409           (when dispatch
1410             (let ((command (plist-get dispatch :command))
1411                   (teardown (plist-get dispatch :teardown)))
1412               (when command
1413                 (context-coloring-teardown-idle-change-detection))
1414               (when teardown
1415                 (funcall teardown)))))
1416         (font-lock-mode)
1417         (jit-lock-mode t))
1418
1419     ;; Font lock is incompatible with this mode; the converse is also true.
1420     (font-lock-mode 0)
1421     (jit-lock-mode nil)
1422
1423     ;; ...but we do use font-lock functions here.
1424     (font-lock-set-defaults)
1425
1426     ;; Safely change the valye of this function as necessary.
1427     (make-local-variable 'font-lock-syntactic-face-function)
1428
1429     (let ((dispatch (context-coloring-get-dispatch-for-mode major-mode)))
1430       (if dispatch
1431           (progn
1432             (let ((command (plist-get dispatch :command))
1433                   (version (plist-get dispatch :version))
1434                   (executable (plist-get dispatch :executable))
1435                   (setup (plist-get dispatch :setup))
1436                   (colorize-initially-p t))
1437               (when command
1438                 ;; Shell commands recolor on change, idly.
1439                 (cond
1440                  ((and executable
1441                        (null (executable-find executable)))
1442                   (message "Executable \"%s\" not found" executable)
1443                   (setq colorize-initially-p nil))
1444                  (version
1445                   (context-coloring-check-scopifier-version
1446                    (lambda (sufficient-p)
1447                      (if sufficient-p
1448                          (progn
1449                            (context-coloring-setup-idle-change-detection)
1450                            (context-coloring-colorize))
1451                        (message "Update to the minimum version of \"%s\" (%s)"
1452                                 executable version))))
1453                   (setq colorize-initially-p nil))
1454                  (t
1455                   (context-coloring-setup-idle-change-detection))))
1456               (when setup
1457                 (funcall setup))
1458               ;; Colorize once initially.
1459               (when colorize-initially-p
1460                 (let ((context-coloring-parse-interruptable-p nil))
1461                   (context-coloring-colorize)))))
1462         (when (null dispatch)
1463           (message "Context coloring is not available for this major mode"))))))
1464
1465 (provide 'context-coloring)
1466
1467 ;;; context-coloring.el ends here