code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.2.0
   8 ;; Package-Requires: ((emacs "24.1") (ivy "0.1.0"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; The overview back end is `ivy'.
  33 ;;
  34 ;; It can double as a quick `regex-builder', although only single
  35 ;; lines will be matched.
  36
  37 ;;; Code:
  38 (require 'ivy)
  39
  40 (defgroup swiper nil
  41   "`isearch' with an overview."
  42   :group 'matching
  43   :prefix "swiper-")
  44
  45 (defface swiper-match-face-1
  46   '((t (:inherit isearch-lazy-highlight-face)))
  47   "Face for `swiper' matches.")
  48
  49 (defface swiper-match-face-2
  50   '((t (:inherit isearch)))
  51   "Face for `swiper' matches.")
  52
  53 (defface swiper-match-face-3
  54   '((t (:inherit match)))
  55   "Face for `swiper' matches.")
  56
  57 (defface swiper-match-face-4
  58   '((t (:inherit isearch)))
  59   "Face for `swiper' matches.")
  60
  61 (defface swiper-line-face
  62   '((t (:inherit highlight)))
  63   "Face for current `swiper' line.")
  64
  65 (defcustom swiper-faces '(swiper-match-face-1
  66                           swiper-match-face-2
  67                           swiper-match-face-3
  68                           swiper-match-face-4)
  69   "List of `swiper' faces for group matches.")
  70
  71 (defcustom swiper-min-highlight 2
  72   "Only highlight matches for regexps at least this long."
  73   :type 'integer)
  74
  75 (defvar swiper-map
  76   (let ((map (make-sparse-keymap)))
  77     (define-key map (kbd "M-q") 'swiper-query-replace)
  78     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  79     map)
  80   "Keymap for swiper.")
  81
  82 (defun swiper-query-replace ()
  83   "Start `query-replace' with string to replace from last search string."
  84   (interactive)
  85   (if (null (window-minibuffer-p))
  86       (user-error "Should only be called in the minibuffer through `swiper-map'")
  87     (let* ((enable-recursive-minibuffers t)
  88            (from (ivy--regex ivy-text))
  89            (to (query-replace-read-to from "Query replace" t)))
  90       (delete-minibuffer-contents)
  91       (setq ivy--action
  92             (lambda ()
  93               (perform-replace from to
  94                                t t t)))
  95       (swiper--cleanup)
  96       (exit-minibuffer))))
  97
  98 (defun swiper-recenter-top-bottom (&optional arg)
  99   "Call (`recenter-top-bottom' ARG) in `swiper--window'."
 100   (interactive "P")
 101   (with-selected-window swiper--window
 102     (recenter-top-bottom arg)))
 103
 104 (defvar swiper--window nil
 105   "Store the current window.")
 106
 107 (defun swiper-font-lock-ensure ()
 108   "Ensure the entired buffer is highlighted."
 109   (unless (or (derived-mode-p 'magit-mode)
 110               (memq major-mode '(package-menu-mode
 111                                  gnus-summary-mode
 112                                  gnus-article-mode
 113                                  gnus-group-mode
 114                                  emms-playlist-mode erc-mode)))
 115     (if (fboundp 'font-lock-ensure)
 116         (font-lock-ensure)
 117       (font-lock-fontify-buffer))))
 118
 119 (defvar swiper--format-spec ""
 120   "Store the current candidates format spec.")
 121
 122 (defun swiper--candidates ()
 123   "Return a list of this buffer lines."
 124   (let ((n-lines (count-lines (point-min) (point-max))))
 125     (unless (zerop n-lines)
 126       (setq swiper--format-spec
 127             (format "%%-%dd %%s" (1+ (floor (log n-lines 10)))))
 128       (let ((line-number 0)
 129             candidates)
 130         (save-excursion
 131           (goto-char (point-min))
 132           (swiper-font-lock-ensure)
 133           (while (< (point) (point-max))
 134             (push (format swiper--format-spec
 135                           (cl-incf line-number)
 136                           (buffer-substring
 137                            (line-beginning-position)
 138                            (line-end-position)))
 139                   candidates)
 140             (zerop (forward-line 1)))
 141           (nreverse candidates))))))
 142
 143 (defvar swiper--opoint 1
 144   "The point when `swiper' starts.")
 145
 146 ;;;###autoload
 147 (defun swiper (&optional initial-input)
 148   "`isearch' with an overview.
 149 When non-nil, INITIAL-INPUT is the initial search pattern."
 150   (interactive)
 151   (swiper--ivy initial-input))
 152
 153 (defun swiper--init ()
 154   "Perform initialization common to both completion methods."
 155   (deactivate-mark)
 156   (setq swiper--opoint (point))
 157   (setq swiper--len 0)
 158   (setq swiper--anchor (line-number-at-pos))
 159   (setq swiper--window (selected-window)))
 160
 161 (defun swiper--ivy (&optional initial-input)
 162   "`isearch' with an overview using `ivy'.
 163 When non-nil, INITIAL-INPUT is the initial search pattern."
 164   (interactive)
 165   (ido-mode -1)
 166   (swiper--init)
 167   (let ((candidates (swiper--candidates))
 168         (preselect (format
 169                     swiper--format-spec
 170                     (line-number-at-pos)
 171                     (regexp-quote
 172                      (buffer-substring-no-properties
 173                       (line-beginning-position)
 174                       (line-end-position)))))
 175         res)
 176     (unwind-protect
 177          (setq res (ivy-read
 178                     (replace-regexp-in-string
 179                      "%s" "pattern: " swiper--format-spec)
 180                     candidates
 181                     initial-input
 182                     swiper-map
 183                     preselect
 184                     #'swiper--update-input-ivy))
 185       (ido-mode 1)
 186       (swiper--cleanup)
 187       (if (null ivy-exit)
 188           (goto-char swiper--opoint)
 189         (swiper--action res ivy-text)))))
 190
 191 (defun swiper--ensure-visible ()
 192   "Remove overlays hiding point."
 193   (let ((overlays (overlays-at (point)))
 194         ov expose)
 195     (while (setq ov (pop overlays))
 196       (if (and (invisible-p (overlay-get ov 'invisible))
 197                (setq expose (overlay-get ov 'isearch-open-invisible)))
 198           (funcall expose ov)))))
 199
 200 (defun swiper--cleanup ()
 201   "Clean up the overlays."
 202   (while swiper--overlays
 203     (delete-overlay (pop swiper--overlays)))
 204   (save-excursion
 205     (goto-char (point-min))
 206     (isearch-clean-overlays)))
 207
 208 (defvar swiper--overlays nil
 209   "Store overlays.")
 210
 211 (defvar swiper--anchor nil
 212   "A line number to which the search should be anchored.")
 213
 214 (defvar swiper--len 0
 215   "The last length of input for which an anchoring was made.")
 216
 217 (defun swiper--update-input-ivy ()
 218   "Called when `ivy' input is updated."
 219   (swiper--cleanup)
 220   (let* ((re (ivy--regex ivy-text))
 221          (str ivy--current)
 222          (num (if (string-match "^[0-9]+" str)
 223                   (string-to-number (match-string 0 str))
 224                 0)))
 225     (with-selected-window swiper--window
 226       (goto-char (point-min))
 227       (when (cl-plusp num)
 228         (goto-char (point-min))
 229         (forward-line (1- num))
 230         (isearch-range-invisible (line-beginning-position)
 231                                  (line-end-position))
 232         (unless (and (>= (point) (window-start))
 233                      (<= (point) (window-end swiper--window t)))
 234           (recenter)))
 235       (let ((ov (make-overlay
 236                  (line-beginning-position)
 237                  (1+ (line-end-position)))))
 238         (overlay-put ov 'face 'swiper-line-face)
 239         (overlay-put ov 'window swiper--window)
 240         (push ov swiper--overlays))
 241       (swiper--add-overlays
 242        re
 243        (window-start swiper--window)
 244        (window-end swiper--window t)))))
 245
 246 (defun swiper--add-overlays (re beg end)
 247   "Add overlays for RE regexp in current buffer between BEG and END."
 248   (when (>= (length re) swiper-min-highlight)
 249     (save-excursion
 250       (goto-char beg)
 251       ;; RE can become an invalid regexp
 252       (while (and (ignore-errors (re-search-forward re end t))
 253                   (> (- (match-end 0) (match-beginning 0)) 0))
 254         (let ((i 0))
 255           (while (<= i ivy--subexps)
 256             (when (match-beginning i)
 257               (let ((overlay (make-overlay (match-beginning i)
 258                                            (match-end i)))
 259                     (face
 260                      (cond ((zerop ivy--subexps)
 261                             (cl-caddr swiper-faces))
 262                            ((zerop i)
 263                             (car swiper-faces))
 264                            (t
 265                             (nth (1+ (mod (1- i) (1- (length swiper-faces))))
 266                                  swiper-faces)))))
 267                 (push overlay swiper--overlays)
 268                 (overlay-put overlay 'face face)
 269                 (overlay-put overlay 'window swiper--window)
 270                 (overlay-put overlay 'priority i)))
 271             (cl-incf i)))))))
 272
 273 (defun swiper--action (x input)
 274   "Goto line X and search for INPUT."
 275   (if (null x)
 276       (user-error "No candidates")
 277     (goto-char (point-min))
 278     (forward-line (1- (read x)))
 279     (re-search-forward
 280      (ivy--regex input) (line-end-position) t)
 281     (swiper--ensure-visible)
 282     (when (/= (point) swiper--opoint)
 283       (unless (and transient-mark-mode mark-active)
 284         (push-mark swiper--opoint t)
 285         (message "Mark saved where search started")))))
 286
 287 (provide 'swiper)
 288
 289 ;;; swiper.el ends here