code.delx.au - gnu-emacs-elpa/blob - counsel.el

   1 ;;; counsel.el --- Various completion functions using Ivy -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.1.0
   8 ;; Package-Requires: ((emacs "24.1") (swiper "0.4.0"))
   9 ;; Keywords: completion, matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; Just call one of the interactive functions in this file to complete
  29 ;; the corresponding thing using `ivy'.
  30 ;;
  31 ;; Currently available: Elisp symbols, Clojure symbols, Git files.
  32
  33 ;;; Code:
  34
  35 (require 'swiper)
  36
  37 ;;;###autoload
  38 (defun counsel-el ()
  39   "Elisp completion at point."
  40   (interactive)
  41   (counsel--generic
  42    (lambda (str) (all-completions str obarray))))
  43
  44 (defvar counsel-describe-map
  45   (let ((map (make-sparse-keymap)))
  46     (define-key map (kbd "C-.") #'counsel-find-symbol)
  47     (define-key map (kbd "C-,") #'counsel--info-lookup-symbol)
  48     map))
  49
  50 (defun counsel-find-symbol ()
  51   "Jump to the definition of the current symbol."
  52   (interactive)
  53   (ivy-set-action #'counsel--find-symbol)
  54   (ivy-done))
  55
  56 (defun counsel--info-lookup-symbol ()
  57   "Lookup the current symbol in the info docs."
  58   (interactive)
  59   (ivy-set-action #'counsel-info-lookup-symbol)
  60   (ivy-done))
  61
  62 (defun counsel--find-symbol (x)
  63   "Find symbol definition that corresponds to string X."
  64   (let ((full-name (get-text-property 0 'full-name x)))
  65     (if full-name
  66         (find-library full-name)
  67       (let ((sym (read x)))
  68         (cond ((boundp sym)
  69                (find-variable sym))
  70               ((fboundp sym)
  71                (find-function sym))
  72               ((or (featurep sym)
  73                    (locate-library
  74                     (prin1-to-string sym)))
  75                (find-library
  76                 (prin1-to-string sym)))
  77               (t
  78                (error "Couldn't fild definition of %s"
  79                       sym)))))))
  80
  81 (defvar counsel-describe-symbol-history nil
  82   "History for `counsel-describe-variable' and `counsel-describe-function'.")
  83
  84 (defun counsel-symbol-at-point ()
  85   "Return current symbol at point as a string."
  86   (let ((s (thing-at-point 'symbol)))
  87     (and (stringp s)
  88          (if (string-match "\\`[`']?\\(.*\\)'?\\'" s)
  89              (match-string 1 s)
  90            s))))
  91
  92 ;;;###autoload
  93 (defun counsel-describe-variable ()
  94   "Forward to `describe-variable'."
  95   (interactive)
  96   (let ((enable-recursive-minibuffers t))
  97     (ivy-read
  98      "Describe variable: "
  99      (let (cands)
 100        (mapatoms
 101         (lambda (vv)
 102           (when (or (get vv 'variable-documentation)
 103                     (and (boundp vv) (not (keywordp vv))))
 104             (push (symbol-name vv) cands))))
 105        cands)
 106      :keymap counsel-describe-map
 107      :preselect (counsel-symbol-at-point)
 108      :history 'counsel-describe-symbol-history
 109      :require-match t
 110      :sort t
 111      :action (lambda (x)
 112                (describe-variable
 113                 (intern x))))))
 114
 115 ;;;###autoload
 116 (defun counsel-describe-function ()
 117   "Forward to `describe-function'."
 118   (interactive)
 119   (let ((enable-recursive-minibuffers t))
 120     (ivy-read "Describe function: "
 121               (let (cands)
 122                 (mapatoms
 123                  (lambda (x)
 124                    (when (fboundp x)
 125                      (push (symbol-name x) cands))))
 126                 cands)
 127               :keymap counsel-describe-map
 128               :preselect (counsel-symbol-at-point)
 129               :history 'counsel-describe-symbol-history
 130               :require-match t
 131               :sort t
 132               :action (lambda (x)
 133                         (describe-function
 134                          (intern x))))))
 135
 136 (defvar info-lookup-mode)
 137 (declare-function info-lookup->completions "info-look")
 138 (declare-function info-lookup->mode-value "info-look")
 139 (declare-function info-lookup-select-mode "info-look")
 140 (declare-function info-lookup-change-mode "info-look")
 141 (declare-function info-lookup "info-look")
 142
 143 ;;;###autoload
 144 (defun counsel-info-lookup-symbol (symbol &optional mode)
 145   "Forward to (`info-describe-symbol' SYMBOL MODE) with ivy completion."
 146   (interactive
 147    (progn
 148      (require 'info-look)
 149      (let* ((topic 'symbol)
 150             (mode (cond (current-prefix-arg
 151                          (info-lookup-change-mode topic))
 152                         ((info-lookup->mode-value
 153                           topic (info-lookup-select-mode))
 154                          info-lookup-mode)
 155                         ((info-lookup-change-mode topic))))
 156             (completions (info-lookup->completions topic mode))
 157             (enable-recursive-minibuffers t)
 158             (value (ivy-read
 159                     "Describe symbol: "
 160                     (mapcar #'car completions)
 161                     :sort t)))
 162        (list value info-lookup-mode))))
 163   (require 'info-look)
 164   (info-lookup 'symbol symbol mode))
 165
 166 ;;;###autoload
 167 (defun counsel-unicode-char ()
 168   "Insert a Unicode character at point."
 169   (interactive)
 170   (let* ((minibuffer-allow-text-properties t)
 171          (char (ivy-read "Unicode name: "
 172                          (mapcar (lambda (x)
 173                                    (propertize
 174                                     (format "% -60s%c" (car x) (cdr x))
 175                                     'result (cdr x)))
 176                                  (ucs-names)))))
 177     (insert-char (get-text-property 0 'result char))))
 178
 179 (declare-function cider-sync-request:complete "ext:cider-client")
 180 ;;;###autoload
 181 (defun counsel-clj ()
 182   "Clojure completion at point."
 183   (interactive)
 184   (counsel--generic
 185    (lambda (str)
 186      (mapcar
 187       #'cl-caddr
 188       (cider-sync-request:complete str ":same")))))
 189
 190 ;;;###autoload
 191 (defun counsel-git ()
 192   "Find file in the current Git repository."
 193   (interactive)
 194   (let* ((default-directory (locate-dominating-file
 195                              default-directory ".git"))
 196          (cands (split-string
 197                  (shell-command-to-string
 198                   "git ls-files --full-name --")
 199                  "\n"
 200                  t))
 201          (action (lambda (x) (find-file x))))
 202     (ivy-read "Find file: " cands
 203               :action action)))
 204
 205 (defvar counsel--git-grep-dir nil
 206   "Store the base git directory.")
 207
 208 (defvar counsel--git-grep-count nil
 209   "Store the line count in current repository.")
 210
 211 (defun counsel-git-grep-function (string &optional _pred &rest _unused)
 212   "Grep in the current git repository for STRING."
 213   (if (and (> counsel--git-grep-count 20000)
 214            (< (length string) 3))
 215       (progn
 216         (setq ivy--full-length counsel--git-grep-count)
 217         (list ""
 218               (format "%d chars more" (- 3 (length ivy-text)))))
 219     (let* ((default-directory counsel--git-grep-dir)
 220            (cmd (format "git --no-pager grep --full-name -n --no-color -i -e %S"
 221                         (ivy--regex string t)))
 222            res)
 223       (if (<= counsel--git-grep-count 20000)
 224           (progn
 225             (setq res (shell-command-to-string cmd))
 226             (setq ivy--full-length nil)
 227             (split-string res "\n" t))
 228         (setq ivy--full-length -1)
 229         (counsel--gg-candidates (ivy--regex string))
 230         nil))))
 231
 232 (defvar counsel-git-grep-map
 233   (let ((map (make-sparse-keymap)))
 234     (define-key map (kbd "C-l") 'counsel-git-grep-recenter)
 235     map))
 236
 237 (defun counsel-git-grep-recenter ()
 238   (interactive)
 239   (with-selected-window (ivy-state-window ivy-last)
 240     (counsel-git-grep-action ivy--current)
 241     (recenter-top-bottom)))
 242
 243 (defun counsel-git-grep-action (x)
 244   (let ((lst (split-string x ":")))
 245     (find-file (expand-file-name (car lst) counsel--git-grep-dir))
 246     (goto-char (point-min))
 247     (forward-line (1- (string-to-number (cadr lst))))
 248     (unless (eq ivy-exit 'done)
 249       (setq swiper--window (selected-window))
 250       (swiper--cleanup)
 251       (swiper--add-overlays (ivy--regex ivy-text)))))
 252
 253 ;;;###autoload
 254 (defun counsel-git-grep (&optional initial-input)
 255   "Grep for a string in the current git repository."
 256   (interactive)
 257   (setq counsel--git-grep-dir
 258         (locate-dominating-file default-directory ".git"))
 259   (if (null counsel--git-grep-dir)
 260       (error "Not in a git repository")
 261     (setq counsel--git-grep-count (counsel--gg-count "" t))
 262     (ivy-read "pattern: " 'counsel-git-grep-function
 263               :initial-input initial-input
 264               :matcher #'counsel-git-grep-matcher
 265               :dynamic-collection (when (> counsel--git-grep-count 20000)
 266                                     'counsel-git-grep-function)
 267               :keymap counsel-git-grep-map
 268               :action #'counsel-git-grep-action
 269               :unwind #'swiper--cleanup)))
 270
 271 (defcustom counsel-find-file-at-point nil
 272   "When non-nil, add file-at-point to the list of candidates."
 273   :type 'boolean
 274   :group 'ivy)
 275
 276 (declare-function ffap-guesser "ffap")
 277
 278 ;;;###autoload
 279 (defun counsel-find-file ()
 280   "Forward to `find-file'."
 281   (interactive)
 282   (ivy-read "Find file: " 'read-file-name-internal
 283             :matcher #'counsel--find-file-matcher
 284             :action
 285             (lambda (x)
 286               (find-file (expand-file-name x ivy--directory)))
 287             :preselect (when counsel-find-file-at-point
 288                          (require 'ffap)
 289                          (ffap-guesser))))
 290
 291 (defcustom counsel-find-file-ignore-regexp nil
 292   "A regexp of files to ignore while in `counsel-find-file'.
 293 These files are un-ignored if `ivy-text' matches them.
 294 The common way to show all files is to start `ivy-text' with a dot.
 295 Possible value: \"\\(?:\\`[#.]\\)\\|\\(?:[#~]\\'\\)\"."
 296   :group 'ivy)
 297
 298 (defun counsel--find-file-matcher (regexp candidates)
 299   "Return REGEXP-matching CANDIDATES.
 300 Skip some dotfiles unless `ivy-text' requires them."
 301   (let ((res (cl-remove-if-not
 302               (lambda (x)
 303                 (string-match regexp x))
 304               candidates)))
 305     (if (or (null counsel-find-file-ignore-regexp)
 306             (string-match counsel-find-file-ignore-regexp ivy-text))
 307         res
 308       (cl-remove-if
 309        (lambda (x)
 310          (string-match counsel-find-file-ignore-regexp x))
 311        res))))
 312
 313 (defun counsel-git-grep-matcher (regexp candidates)
 314   (or (and (equal regexp ivy--old-re)
 315            ivy--old-cands)
 316       (prog1
 317           (setq ivy--old-cands
 318                 (cl-remove-if-not
 319                  (lambda (x)
 320                    (ignore-errors
 321                      (when (string-match "^[^:]+:[^:]+:" x)
 322                        (setq x (substring x (match-end 0)))
 323                        (if (stringp regexp)
 324                            (string-match regexp x)
 325                          (let ((res t))
 326                            (dolist (re regexp)
 327                              (setq res
 328                                    (and res
 329                                         (ignore-errors
 330                                           (if (cdr re)
 331                                               (string-match (car re) x)
 332                                             (not (string-match (car re) x)))))))
 333                            res)))))
 334                  candidates))
 335         (setq ivy--old-re regexp))))
 336
 337 (defun counsel-locate-function (str &rest _u)
 338   (if (< (length str) 3)
 339       (list ""
 340             (format "%d chars more" (- 3 (length ivy-text))))
 341     (split-string
 342      (shell-command-to-string (concat "locate -i -l 20 --regex " (ivy--regex str))) "\n" t)))
 343
 344 ;;;###autoload
 345 (defun counsel-locate ()
 346   "Call locate."
 347   (interactive)
 348   (let ((val (ivy-read "pattern: " 'counsel-locate-function)))
 349     (when val
 350       (find-file val))))
 351
 352 (defun counsel--generic (completion-fn)
 353   "Complete thing at point with COMPLETION-FN."
 354   (let* ((bnd (bounds-of-thing-at-point 'symbol))
 355          (str (if bnd
 356                   (buffer-substring-no-properties
 357                    (car bnd) (cdr bnd))
 358                 ""))
 359          (candidates (funcall completion-fn str))
 360          (ivy-height 7)
 361          (res (ivy-read (format "pattern (%s): " str)
 362                         candidates)))
 363     (when (stringp res)
 364       (when bnd
 365         (delete-region (car bnd) (cdr bnd)))
 366       (insert res))))
 367
 368 (defun counsel-directory-parent (dir)
 369   "Return the directory parent of directory DIR."
 370   (concat (file-name-nondirectory
 371            (directory-file-name dir)) "/"))
 372
 373 (defun counsel-string-compose (prefix str)
 374   "Make PREFIX the display prefix of STR though text properties."
 375   (let ((str (copy-sequence str)))
 376     (put-text-property
 377      0 1 'display
 378      (concat prefix (substring str 0 1))
 379      str)
 380     str))
 381
 382 ;;;###autoload
 383 (defun counsel-load-library ()
 384   "Load a selected the Emacs Lisp library.
 385 The libraries are offered from `load-path'."
 386   (interactive)
 387   (let ((dirs load-path)
 388         (suffix (concat (regexp-opt '(".el" ".el.gz") t) "\\'"))
 389         (cands (make-hash-table :test #'equal))
 390         short-name
 391         old-val
 392         dir-parent
 393         res)
 394     (dolist (dir dirs)
 395       (when (file-directory-p dir)
 396         (dolist (file (file-name-all-completions "" dir))
 397           (when (string-match suffix file)
 398             (unless (string-match "pkg.elc?$" file)
 399               (setq short-name (substring file 0 (match-beginning 0)))
 400               (if (setq old-val (gethash short-name cands))
 401                   (progn
 402                     ;; assume going up directory once will resolve name clash
 403                     (setq dir-parent (counsel-directory-parent (cdr old-val)))
 404                     (puthash short-name
 405                              (cons
 406                               (counsel-string-compose dir-parent (car old-val))
 407                               (cdr old-val))
 408                              cands)
 409                     (setq dir-parent (counsel-directory-parent dir))
 410                     (puthash (concat dir-parent short-name)
 411                              (cons
 412                               (propertize
 413                                (counsel-string-compose
 414                                 dir-parent short-name)
 415                                'full-name (expand-file-name file dir))
 416                               dir)
 417                              cands))
 418                 (puthash short-name
 419                          (cons (propertize
 420                                 short-name
 421                                 'full-name (expand-file-name file dir))
 422                                dir) cands)))))))
 423     (maphash (lambda (_k v) (push (car v) res)) cands)
 424     (ivy-read "Load library: " (nreverse res)
 425               :action (lambda (x)
 426                         (load-library
 427                          (get-text-property 0 'full-name x)))
 428               :keymap counsel-describe-map)))
 429
 430 (defun counsel--gg-candidates (regex)
 431   "Return git grep candidates for REGEX."
 432   (counsel--gg-count regex)
 433   (let* ((default-directory counsel--git-grep-dir)
 434          (counsel-gg-process " *counsel-gg*")
 435          (proc (get-process counsel-gg-process))
 436          (buff (get-buffer counsel-gg-process)))
 437     (when proc
 438       (delete-process proc))
 439     (when buff
 440       (kill-buffer buff))
 441     (setq proc (start-process-shell-command
 442                 counsel-gg-process
 443                 counsel-gg-process
 444                 (format "git --no-pager grep --full-name -n --no-color -i -e %S | head -n 200"
 445                         regex)))
 446     (set-process-sentinel
 447      proc
 448      #'counsel--gg-sentinel)))
 449
 450 (defun counsel--gg-sentinel (process event)
 451   (if (string= event "finished\n")
 452       (progn
 453         (with-current-buffer (process-buffer process)
 454           (setq ivy--all-candidates (split-string (buffer-string) "\n" t))
 455           (setq ivy--old-cands ivy--all-candidates))
 456         (unless (eq ivy--full-length -1)
 457           (ivy--insert-minibuffer
 458            (ivy--format ivy--all-candidates))))
 459     (if (string= event "exited abnormally with code 1\n")
 460         (message "Error"))))
 461
 462 (defun counsel--gg-count (regex &optional no-async)
 463   "Quickly and asynchronously count the amount of git grep REGEX matches.
 464 When NO-ASYNC is non-nil, do it synchronously."
 465   (let ((default-directory counsel--git-grep-dir)
 466         (cmd (format "git grep -i -c '%s' | sed 's/.*:\\(.*\\)/\\1/g' | awk '{s+=$1} END {print s}'"
 467                      regex))
 468         (counsel-ggc-process " *counsel-gg-count*"))
 469     (if no-async
 470         (string-to-number (shell-command-to-string cmd))
 471       (let ((proc (get-process counsel-ggc-process))
 472             (buff (get-buffer counsel-ggc-process)))
 473         (when proc
 474           (delete-process proc))
 475         (when buff
 476           (kill-buffer buff))
 477         (setq proc (start-process-shell-command
 478                     counsel-ggc-process
 479                     counsel-ggc-process
 480                     cmd))
 481         (set-process-sentinel
 482          proc
 483          #'(lambda (process event)
 484              (when (string= event "finished\n")
 485                (with-current-buffer (process-buffer process)
 486                  (setq ivy--full-length (string-to-number (buffer-string))))
 487                (ivy--insert-minibuffer
 488                 (ivy--format ivy--all-candidates)))))))))
 489
 490 (defun counsel--format-function-M-x (cands)
 491   "Join CANDS, a list of command names, with newlines.
 492 If a command is bound, add it's binding after it."
 493   (with-selected-window (ivy-state-window ivy-last)
 494     (mapconcat (lambda (x)
 495                  (let ((binding (substitute-command-keys (format "\\[%s]" x))))
 496                    (setq binding (replace-regexp-in-string "C-x 6" "<f2>" binding))
 497                    (if (string-match "^M-x" binding)
 498                        x
 499                      (format "%s (%s)" x
 500                              (propertize binding 'face 'font-lock-keyword-face)))))
 501                cands
 502                "\n")))
 503
 504 (defcustom counsel-M-x-initial-input "^"
 505   "Initial input for `counsel-M-x'."
 506   :group 'ivy)
 507
 508 ;;;###autoload
 509 (defun counsel-M-x (&optional initial-input)
 510   "Ivy version of `execute-extended-command'.
 511 Optional INITIAL-INPUT is the initial input in the minibuffer."
 512   (interactive)
 513   (setq initial-input (or initial-input counsel-M-x-initial-input))
 514   (let ((ivy-format-function #'counsel--format-function-M-x)
 515         (cands obarray)
 516         (pred 'commandp)
 517         (sort t))
 518     (when (or (featurep 'smex)
 519               (package-installed-p 'smex))
 520       (require 'smex)
 521       (smex-detect-new-commands)
 522       (smex-update)
 523       (setq cands smex-ido-cache)
 524       (setq pred nil)
 525       (setq sort nil))
 526     (ivy-read "M-x " cands
 527               :predicate pred
 528               :require-match t
 529               :history 'extended-command-history
 530               :action
 531               (lambda (cmd)
 532                 (execute-extended-command current-prefix-arg cmd))
 533               :sort sort
 534               :keymap counsel-describe-map
 535               :initial-input initial-input)))
 536
 537 (provide 'counsel)
 538
 539 ;;; counsel.el ends here