code.delx.au - gnu-emacs-elpa/blob - company-tests.el

   1 ;;; company-tests.el --- company-mode tests
   2
   3 ;; Copyright (C) 2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'ert)
  30 (require 'company)
  31 (require 'company-keywords)
  32 (require 'company-elisp)
  33 (require 'company-clang)
  34
  35 ;;; Core
  36
  37 (ert-deftest company-sorted-keywords ()
  38   "Test that keywords in `company-keywords-alist' are in alphabetical order."
  39   (dolist (pair company-keywords-alist)
  40     (when (consp (cdr pair))
  41       (let ((prev (cadr pair)))
  42         (dolist (next (cddr pair))
  43           (should (not (equal prev next)))
  44           (should (string< prev next))
  45           (setq prev next))))))
  46
  47 (ert-deftest company-good-prefix ()
  48   (let ((company-minimum-prefix-length 5)
  49         company--explicit-action)
  50     (should (eq t (company--good-prefix-p "!@#$%")))
  51     (should (eq nil (company--good-prefix-p "abcd")))
  52     (should (eq nil (company--good-prefix-p 'stop)))
  53     (should (eq t (company--good-prefix-p '("foo" . 5))))
  54     (should (eq nil (company--good-prefix-p '("foo" . 4))))))
  55
  56 (ert-deftest company-multi-backend-with-lambdas ()
  57   (let ((company-backend
  58          (list (lambda (command &optional arg &rest ignore)
  59                  (case command
  60                    (prefix "z")
  61                    (candidates '("a" "b"))))
  62                (lambda (command &optional arg &rest ignore)
  63                  (case command
  64                    (prefix "z")
  65                    (candidates '("c" "d")))))))
  66     (should (equal (company-call-backend 'candidates "z") '("a" "b" "c" "d")))))
  67
  68 (ert-deftest company-begin-backend-failure-doesnt-break-company-backends ()
  69   (with-temp-buffer
  70     (insert "a")
  71     (company-mode)
  72     (should-error
  73      (company-begin-backend (lambda (command &rest ignore))))
  74     (let (company-frontends
  75           (company-backends
  76            (list (lambda (command &optional arg)
  77                    (case command
  78                      (prefix "a")
  79                      (candidates '("a" "ab" "ac")))))))
  80       (let (this-command)
  81         (company-call 'complete))
  82       (should (eq 3 company-candidates-length)))))
  83
  84 (ert-deftest company-require-match-explicit ()
  85   (with-temp-buffer
  86     (insert "ab")
  87     (company-mode)
  88     (let (company-frontends
  89           (company-require-match 'company-explicit-action-p)
  90           (company-backends
  91            (list (lambda (command &optional arg)
  92                    (case command
  93                      (prefix (buffer-substring (point-min) (point)))
  94                      (candidates '("abc" "abd")))))))
  95       (let (this-command)
  96         (company-complete))
  97       (let ((last-command-event ?e))
  98         (company-call 'self-insert-command 1))
  99       (should (eq 2 company-candidates-length))
 100       (should (eq 3 (point))))))
 101
 102 (ert-deftest company-dont-require-match-when-idle ()
 103   (with-temp-buffer
 104     (insert "ab")
 105     (company-mode)
 106     (let (company-frontends
 107           (company-require-match 'company-explicit-action-p)
 108           (company-backends
 109            (list (lambda (command &optional arg)
 110                    (case command
 111                      (prefix (buffer-substring (point-min) (point)))
 112                      (candidates '("abc" "abd")))))))
 113       (company-idle-begin (current-buffer) (selected-window)
 114                           (buffer-chars-modified-tick) (point))
 115       (let ((last-command-event ?e))
 116         (company-call 'self-insert-command 1))
 117       (should (eq nil company-candidates-length))
 118       (should (eq 4 (point))))))
 119
 120 (ert-deftest company-auto-complete-explicit ()
 121   (with-temp-buffer
 122     (insert "ab")
 123     (company-mode)
 124     (let (company-frontends
 125           (company-auto-complete 'company-explicit-action-p)
 126           (company-auto-complete-chars '(? ))
 127           (company-backends
 128            (list (lambda (command &optional arg)
 129                    (case command
 130                      (prefix (buffer-substring (point-min) (point)))
 131                      (candidates '("abcd" "abef")))))))
 132       (let (this-command)
 133         (company-complete))
 134       (let ((last-command-event ? ))
 135         (company-call 'self-insert-command 1))
 136       (should (string= "abcd " (buffer-string))))))
 137
 138 (ert-deftest company-no-auto-complete-when-idle ()
 139   (with-temp-buffer
 140     (insert "ab")
 141     (company-mode)
 142     (let (company-frontends
 143           (company-auto-complete 'company-explicit-action-p)
 144           (company-auto-complete-chars '(? ))
 145           (company-backends
 146            (list (lambda (command &optional arg)
 147                    (case command
 148                      (prefix (buffer-substring (point-min) (point)))
 149                      (candidates '("abcd" "abef")))))))
 150       (company-idle-begin (current-buffer) (selected-window)
 151                           (buffer-chars-modified-tick) (point))
 152       (let ((last-command-event ? ))
 153         (company-call 'self-insert-command 1))
 154       (should (string= "ab " (buffer-string))))))
 155
 156 (ert-deftest company-clears-explicit-action-when-no-matches ()
 157   (with-temp-buffer
 158     (company-mode)
 159     (let (company-frontends
 160           company-backends)
 161       (company-call 'manual-begin) ;; fails
 162       (should (null company-candidates))
 163       (should (null (company-explicit-action-p))))))
 164
 165 (ert-deftest company-ignore-case-replaces-prefix ()
 166   (with-temp-buffer
 167     (company-mode)
 168     (let (company-frontends
 169           company-end-of-buffer-workaround
 170           (company-backends
 171            (list (lambda (command &optional arg)
 172                    (case command
 173                      (prefix (buffer-substring (point-min) (point)))
 174                      (candidates '("abcd" "abef"))
 175                      (ignore-case t))))))
 176       (insert "A")
 177       (let (this-command)
 178         (company-complete))
 179       (should (string= "ab" (buffer-string)))
 180       (delete-char -2)
 181       (insert "A") ; hack, to keep it in one test
 182       (company-complete-selection)
 183       (should (string= "abcd" (buffer-string))))))
 184
 185 (ert-deftest company-ignore-case-with-keep-prefix ()
 186   (with-temp-buffer
 187     (insert "AB")
 188     (company-mode)
 189     (let (company-frontends
 190           (company-backends
 191            (list (lambda (command &optional arg)
 192                    (case command
 193                      (prefix (buffer-substring (point-min) (point)))
 194                      (candidates '("abcd" "abef"))
 195                      (ignore-case 'keep-prefix))))))
 196       (let (this-command)
 197         (company-complete))
 198       (company-complete-selection)
 199       (should (string= "ABcd" (buffer-string))))))
 200
 201 (ert-deftest company-non-prefix-completion ()
 202   (with-temp-buffer
 203     (insert "tc")
 204     (company-mode)
 205     (let (company-frontends
 206           company-end-of-buffer-workaround
 207           (company-backends
 208            (list (lambda (command &optional arg)
 209                    (case command
 210                      (prefix (buffer-substring (point-min) (point)))
 211                      (candidates '("tea-cup" "teal-color")))))))
 212       (let (this-command)
 213         (company-complete))
 214       (should (string= "tc" (buffer-string)))
 215       (company-complete-selection)
 216       (should (string= "tea-cup" (buffer-string))))))
 217
 218 (ert-deftest company-pseudo-tooltip-does-not-get-displaced ()
 219   :tags '(interactive)
 220   (with-temp-buffer
 221     (save-window-excursion
 222       (set-window-buffer nil (current-buffer))
 223       (save-excursion (insert " ff"))
 224       (company-mode)
 225       (let ((company-frontends '(company-pseudo-tooltip-frontend))
 226             (company-begin-commands '(self-insert-command))
 227             (company-backends
 228              (list (lambda (c &optional arg)
 229                      (case c (prefix "") (candidates '("a" "b" "c")))))))
 230         (let (this-command)
 231           (company-call 'complete))
 232         (company-call 'open-line 1)
 233         (should (eq 2 (overlay-start company-pseudo-tooltip-overlay)))))))
 234
 235 (ert-deftest company-pseudo-tooltip-overlay-show ()
 236   :tags '(interactive)
 237   (with-temp-buffer
 238     (save-window-excursion
 239     (set-window-buffer nil (current-buffer))
 240     (insert "aaaa\n  bb\nccccccc\nddd")
 241     (search-backward "bb")
 242     (let ((col (company--column))
 243           (company-candidates-length 2)
 244           (company-candidates '("123" "45")))
 245       (company-pseudo-tooltip-show (company--row) col 0)
 246       (let ((ov company-pseudo-tooltip-overlay))
 247         ;; With margins.
 248         (should (eq (overlay-get ov 'company-width) 5))
 249         ;; FIXME: Make it 2?
 250         (should (eq (overlay-get ov 'company-height) company-tooltip-limit))
 251         (should (eq (overlay-get ov 'company-column) col))
 252         (should (string= (overlay-get ov 'company-after)
 253                          "  123 \nc 45  c\nddd\n")))))))
 254
 255 (ert-deftest company-create-lines-shows-numbers ()
 256   (let ((company-show-numbers t)
 257         (company-candidates '("x" "y" "z"))
 258         (company-candidates-length 3))
 259     (should (equal '(" x 1 " " y 2 " " z 3 ")
 260                    (company--create-lines 0 999)))))
 261
 262 (ert-deftest company-column-with-composition ()
 263   (with-temp-buffer
 264     (insert "lambda ()")
 265     (compose-region 1 (1+ (length "lambda")) "\\")
 266     (should (= (company--column) 4))))
 267
 268 (ert-deftest company-column-with-line-prefix ()
 269   (with-temp-buffer
 270     (insert "foo")
 271     (put-text-property (point-min) (point) 'line-prefix "  ")
 272     (should (= (company--column) 5))))
 273
 274 (ert-deftest company-column-wth-line-prefix-on-empty-line ()
 275   (with-temp-buffer
 276     (insert "\n")
 277     (forward-char -1)
 278     (put-text-property (point-min) (point-max) 'line-prefix "  ")
 279     (should (= (company--column) 2))))
 280
 281 (ert-deftest company-plainify ()
 282   (let ((tab-width 8))
 283     (should (equal-including-properties
 284              (company-plainify "\tabc\td\t")
 285              (concat "        "
 286                      "abc     "
 287                      "d       "))))
 288   (should (equal-including-properties
 289            (company-plainify (propertize "foobar" 'line-prefix "-*-"))
 290            "-*-foobar")))
 291
 292 (ert-deftest company-modify-line ()
 293   (let ((str "-*-foobar"))
 294     (should (equal-including-properties
 295              (company-modify-line str "zz" 4)
 296              "-*-fzzbar"))
 297     (should (equal-including-properties
 298              (company-modify-line str "xx" 0)
 299              "xx-foobar"))
 300     (should (equal-including-properties
 301              (company-modify-line str "zz" 10)
 302              "-*-foobar zz"))))
 303
 304 ;;; Template
 305
 306 (ert-deftest company-template-removed-after-the-last-jump ()
 307   (with-temp-buffer
 308     (insert "{ }")
 309     (goto-char 2)
 310     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 311       (save-excursion
 312         (dotimes (i 2)
 313           (insert " ")
 314           (company-template-add-field tpl (point) "foo")))
 315       (company-call 'template-forward-field)
 316       (should (= 3 (point)))
 317       (company-call 'template-forward-field)
 318       (should (= 7 (point)))
 319       (company-call 'template-forward-field)
 320       (should (= 11 (point)))
 321       (should (zerop (length (overlay-get tpl 'company-template-fields))))
 322       (should (null (overlay-buffer tpl))))))
 323
 324 (ert-deftest company-template-removed-after-input-and-jump ()
 325   (with-temp-buffer
 326     (insert "{ }")
 327     (goto-char 2)
 328     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 329       (save-excursion
 330         (insert " ")
 331         (company-template-add-field tpl (point) "bar"))
 332       (company-call 'template-move-to-first tpl)
 333       (should (= 3 (point)))
 334       (dolist (c (string-to-list "tee"))
 335         (let ((last-command-event c))
 336           (company-call 'self-insert-command 1)))
 337       (should (string= "{ tee }" (buffer-string)))
 338       (should (overlay-buffer tpl))
 339       (company-call 'template-forward-field)
 340       (should (= 7 (point)))
 341       (should (null (overlay-buffer tpl))))))
 342
 343 (defun company-call (name &rest args)
 344   (let* ((maybe (intern (format "company-%s" name)))
 345          (command (if (fboundp maybe) maybe name)))
 346     (apply command args)
 347     (let ((this-command command))
 348       (run-hooks 'post-command-hook))))
 349
 350 (ert-deftest company-template-c-like-templatify ()
 351   (with-temp-buffer
 352     (let ((text "foo(int a, short b)"))
 353       (insert text)
 354       (company-template-c-like-templatify text)
 355       (should (equal "foo(arg0, arg1)" (buffer-string)))
 356       (should (looking-at "arg0"))
 357       (should (equal "int a"
 358                      (overlay-get (company-template-field-at) 'display))))))
 359
 360 (ert-deftest company-template-c-like-templatify-trims-after-closing-paren ()
 361   (with-temp-buffer
 362     (let ((text "foo(int a, short b)!@ #1334 a"))
 363       (insert text)
 364       (company-template-c-like-templatify text)
 365       (should (equal "foo(arg0, arg1)" (buffer-string)))
 366       (should (looking-at "arg0")))))
 367
 368 ;;; Elisp
 369
 370 (defmacro company-elisp-with-buffer (contents &rest body)
 371   (declare (indent 0))
 372   `(with-temp-buffer
 373      (insert ,contents)
 374      (setq major-mode 'emacs-lisp-mode)
 375      (re-search-backward "|")
 376      (replace-match "")
 377      (let ((company-elisp-detect-function-context t))
 378        ,@body)))
 379
 380 (ert-deftest company-elisp-candidates-predicate ()
 381   (company-elisp-with-buffer
 382     "(foo ba|)"
 383     (should (eq (company-elisp--candidates-predicate "ba")
 384                 'boundp))
 385     (should (eq (let (company-elisp-detect-function-context)
 386                   (company-elisp--candidates-predicate "ba"))
 387                 'company-elisp--predicate)))
 388   (company-elisp-with-buffer
 389     "(foo| )"
 390     (should (eq (company-elisp--candidates-predicate "foo")
 391                 'fboundp))
 392     (should (eq (let (company-elisp-detect-function-context)
 393                   (company-elisp--candidates-predicate "foo"))
 394                 'company-elisp--predicate)))
 395   (company-elisp-with-buffer
 396     "(foo 'b|)"
 397     (should (eq (company-elisp--candidates-predicate "b")
 398                 'company-elisp--predicate))))
 399
 400 (ert-deftest company-elisp-candidates-predicate-in-docstring ()
 401   (company-elisp-with-buffer
 402    "(def foo () \"Doo be doo `ide|"
 403    (should (eq 'company-elisp--predicate
 404                (company-elisp--candidates-predicate "ide")))))
 405
 406 ;; This one's also an integration test.
 407 (ert-deftest company-elisp-candidates-recognizes-binding-form ()
 408   (let ((company-elisp-detect-function-context t)
 409         (obarray [when what whelp])
 410         (what 1)
 411         (whelp 2)
 412         (wisp 3))
 413     (company-elisp-with-buffer
 414       "(let ((foo 7) (wh| )))"
 415       (should (equal '("what" "whelp")
 416                      (company-elisp-candidates "wh"))))
 417     (company-elisp-with-buffer
 418       "(cond ((null nil) (wh| )))"
 419       (should (equal '("when")
 420                      (company-elisp-candidates "wh"))))))
 421
 422 (ert-deftest company-elisp-candidates-predicate-binding-without-value ()
 423   (loop for (text prefix predicate) in '(("(let (foo|" "foo" boundp)
 424                                          ("(let (foo (bar|" "bar" boundp)
 425                                          ("(let (foo) (bar|" "bar" fboundp))
 426         do
 427         (eval `(company-elisp-with-buffer
 428                  ,text
 429                  (should (eq ',predicate
 430                              (company-elisp--candidates-predicate ,prefix)))))))
 431
 432 (ert-deftest company-elisp-finds-vars ()
 433   (let ((obarray [boo bar baz backquote])
 434         (boo t)
 435         (bar t)
 436         (baz t))
 437     (should (equal '("bar" "baz")
 438                    (company-elisp--globals "ba" 'boundp)))))
 439
 440 (ert-deftest company-elisp-finds-functions ()
 441   (let ((obarray [when what whelp])
 442         (what t)
 443         (whelp t))
 444     (should (equal '("when")
 445                    (company-elisp--globals "wh" 'fboundp)))))
 446
 447 (ert-deftest company-elisp-finds-things ()
 448   (let ((obarray [when what whelp])
 449         (what t)
 450         (whelp t))
 451     (should (equal '("what" "whelp" "when")
 452                    (sort (company-elisp--globals "wh" 'company-elisp--predicate)
 453                          'string<)))))
 454
 455 (ert-deftest company-elisp-locals-vars ()
 456   (company-elisp-with-buffer
 457     "(let ((foo 5) (bar 6))
 458        (cl-labels ((borg ()))
 459          (lambda (boo baz)
 460            b|)))"
 461     (should (equal '("bar" "baz" "boo")
 462                    (company-elisp--locals "b" nil)))))
 463
 464 (ert-deftest company-elisp-locals-single-var ()
 465   (company-elisp-with-buffer
 466     "(dotimes (itk 100)
 467        (dolist (item items)
 468          it|))"
 469     (should (equal '("itk" "item")
 470                    (company-elisp--locals "it" nil)))))
 471
 472 (ert-deftest company-elisp-locals-funs ()
 473   (company-elisp-with-buffer
 474     "(cl-labels ((foo ())
 475                  (fee ()))
 476        (let ((fun 4))
 477          (f| )))"
 478     (should (equal '("fee" "foo")
 479                    (sort (company-elisp--locals "f" t) 'string<)))))
 480
 481 (ert-deftest company-elisp-locals-skips-current-varlist ()
 482   (company-elisp-with-buffer
 483     "(let ((foo 1)
 484            (f| )))"
 485     (should (null (company-elisp--locals "f" nil)))))
 486
 487 (ert-deftest company-elisp-show-locals-first ()
 488   (company-elisp-with-buffer
 489     "(let ((floo 1)
 490            (flop 2)
 491            (flee 3))
 492        fl|)"
 493     (let ((obarray [float-pi]))
 494       (let (company-elisp-show-locals-first)
 495         (should (eq nil (company-elisp 'sorted))))
 496       (let ((company-elisp-show-locals-first t))
 497         (should (eq t (company-elisp 'sorted)))
 498         (should (equal '("flee" "floo" "flop" "float-pi")
 499                        (company-elisp-candidates "fl")))))))
 500
 501 (ert-deftest company-elisp-candidates-no-duplicates ()
 502   (company-elisp-with-buffer
 503     "(let ((float-pi 4))
 504        f|)"
 505     (let ((obarray [float-pi])
 506           (company-elisp-show-locals-first t))
 507       (should (equal '("float-pi") (company-elisp-candidates "f"))))))
 508
 509 (ert-deftest company-elisp-shouldnt-complete-defun-name ()
 510   (company-elisp-with-buffer
 511     "(defun foob|)"
 512     (should (null (company-elisp 'prefix)))))
 513
 514 (ert-deftest company-elisp-should-complete-def-call ()
 515   (company-elisp-with-buffer
 516     "(defu|"
 517     (should (equal "defu" (company-elisp 'prefix)))))
 518
 519 (ert-deftest company-elisp-should-complete-in-defvar ()
 520   ;; It will also complete the var name, at least for now.
 521   (company-elisp-with-buffer
 522     "(defvar abc de|"
 523     (should (equal "de" (company-elisp 'prefix)))))
 524
 525 (ert-deftest company-elisp-shouldnt-complete-in-defun-arglist ()
 526   (company-elisp-with-buffer
 527     "(defsubst foobar (ba|"
 528     (should (null (company-elisp 'prefix)))))
 529
 530 (ert-deftest company-elisp-prefix-in-defun-body ()
 531   (company-elisp-with-buffer
 532     "(defun foob ()|)"
 533     (should (equal "" (company-elisp 'prefix)))))
 534
 535 ;;; Clang
 536
 537 (ert-deftest company-clang-objc-templatify ()
 538   (with-temp-buffer
 539     (let ((text "createBookWithTitle:andAuthor:"))
 540       (insert text)
 541       (company-clang-objc-templatify text)
 542       (should (equal "createBookWithTitle:arg0 andAuthor:arg1" (buffer-string)))
 543       (should (looking-at "arg0"))
 544       (should (null (overlay-get (company-template-field-at) 'display))))))