code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.6.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (delete-minibuffer-contents)
 109       (ivy-set-action (lambda (_)
 110                         (with-ivy-window
 111                           (move-beginning-of-line 1)
 112                           (perform-replace from to
 113                                            t t nil))))
 114       (swiper--cleanup)
 115       (exit-minibuffer))))
 116
 117 (defvar avy-background)
 118 (defvar avy-all-windows)
 119 (defvar avy-style)
 120 (defvar avy-keys)
 121 (declare-function avy--regex-candidates "ext:avy")
 122 (declare-function avy--process "ext:avy")
 123 (declare-function avy--overlay-post "ext:avy")
 124 (declare-function avy-action-goto "ext:avy")
 125 (declare-function avy--done "ext:avy")
 126 (declare-function avy--make-backgrounds "ext:avy")
 127 (declare-function avy-window-list "ext:avy")
 128 (declare-function avy-read "ext:avy")
 129 (declare-function avy-read-de-bruijn "ext:avy")
 130 (declare-function avy-tree "ext:avy")
 131 (declare-function avy-push-mark "ext:avy")
 132 (declare-function avy--remove-leading-chars "ext:avy")
 133
 134 ;;;###autoload
 135 (defun swiper-avy ()
 136   "Jump to one of the current swiper candidates."
 137   (interactive)
 138   (unless (string= ivy-text "")
 139     (let* ((avy-all-windows nil)
 140            (candidates (append
 141                         (with-ivy-window
 142                           (avy--regex-candidates
 143                            (ivy--regex ivy-text)))
 144                         (save-excursion
 145                           (save-restriction
 146                             (narrow-to-region (window-start) (window-end))
 147                             (goto-char (point-min))
 148                             (forward-line)
 149                             (let ((cands))
 150                               (while (< (point) (point-max))
 151                                 (push (cons (1+ (point))
 152                                             (selected-window))
 153                                       cands)
 154                                 (forward-line))
 155                               cands)))))
 156            (candidate (unwind-protect
 157                           (prog2
 158                               (avy--make-backgrounds
 159                                (append (avy-window-list)
 160                                        (list  (ivy-state-window ivy-last))))
 161                               (if (eq avy-style 'de-bruijn)
 162                                   (avy-read-de-bruijn
 163                                    candidates avy-keys)
 164                                 (avy-read (avy-tree candidates avy-keys)
 165                                           #'avy--overlay-post
 166                                           #'avy--remove-leading-chars))
 167                             (avy-push-mark))
 168                         (avy--done))))
 169       (if (window-minibuffer-p (cdr candidate))
 170           (progn
 171             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 172             (ivy--exhibit)
 173             (ivy-done)
 174             (ivy-call))
 175         (ivy-quit-and-run
 176          (avy-action-goto (caar candidate)))))))
 177
 178 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 179 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 180
 181 ;;;###autoload
 182 (defun swiper-mc ()
 183   (interactive)
 184   (unless (require 'multiple-cursors nil t)
 185     (error "multiple-cursors isn't installed"))
 186   (let ((cands (nreverse ivy--old-cands)))
 187     (unless (string= ivy-text "")
 188       (ivy-set-action
 189        (lambda (_)
 190          (let (cand)
 191            (while (setq cand (pop cands))
 192              (swiper--action cand)
 193              (when cands
 194                (mc/create-fake-cursor-at-point))))
 195          (multiple-cursors-mode 1)))
 196       (setq ivy-exit 'done)
 197       (exit-minibuffer))))
 198
 199 (defun swiper-recenter-top-bottom (&optional arg)
 200   "Call (`recenter-top-bottom' ARG)."
 201   (interactive "P")
 202   (with-ivy-window
 203     (recenter-top-bottom arg)))
 204
 205 (defun swiper-font-lock-ensure ()
 206   "Ensure the entired buffer is highlighted."
 207   (unless (or (derived-mode-p 'magit-mode)
 208               (bound-and-true-p magit-blame-mode)
 209               (memq major-mode '(package-menu-mode
 210                                  gnus-summary-mode
 211                                  gnus-article-mode
 212                                  gnus-group-mode
 213                                  emms-playlist-mode
 214                                  emms-stream-mode
 215                                  erc-mode
 216                                  org-agenda-mode
 217                                  dired-mode
 218                                  jabber-chat-mode
 219                                  elfeed-search-mode
 220                                  elfeed-show-mode
 221                                  fundamental-mode
 222                                  Man-mode
 223                                  woman-mode
 224                                  mu4e-view-mode
 225                                  mu4e-headers-mode
 226                                  help-mode
 227                                  debbugs-gnu-mode
 228                                  w3m-mode)))
 229     (unless (> (buffer-size) 100000)
 230       (if (fboundp 'font-lock-ensure)
 231           (font-lock-ensure)
 232         (with-no-warnings (font-lock-fontify-buffer))))))
 233
 234 (defvar swiper--format-spec ""
 235   "Store the current candidates format spec.")
 236
 237 (defvar swiper--width nil
 238   "Store the amount of digits needed for the longest line nubmer.")
 239
 240 (defvar swiper-use-visual-line nil
 241   "When non-nil, use `line-move' instead of `forward-line'.")
 242
 243 (defun swiper--candidates ()
 244   "Return a list of this buffer lines."
 245   (setq swiper-use-visual-line
 246         (and (not (eq major-mode 'org-mode))
 247              visual-line-mode
 248              (< (buffer-size) 20000)))
 249   (let ((n-lines (count-lines (point-min) (point-max))))
 250     (unless (zerop n-lines)
 251       (setq swiper--width (1+ (floor (log n-lines 10))))
 252       (setq swiper--format-spec
 253             (format "%%-%dd " swiper--width))
 254       (let ((line-number 0)
 255             (advancer (if swiper-use-visual-line
 256                           (lambda (arg) (line-move arg t))
 257                         #'forward-line))
 258             candidates)
 259         (save-excursion
 260           (goto-char (point-min))
 261           (swiper-font-lock-ensure)
 262           (while (< (point) (point-max))
 263             (let ((str (concat " " (buffer-substring
 264                                     (point)
 265                                     (if swiper-use-visual-line
 266                                         (save-excursion
 267                                           (end-of-visual-line)
 268                                           (point))
 269                                       (line-end-position))))))
 270               (put-text-property 0 1 'display
 271                                  (format swiper--format-spec
 272                                          (cl-incf line-number))
 273                                  str)
 274               (push str candidates))
 275             (funcall advancer 1))
 276           (nreverse candidates))))))
 277
 278 (defvar swiper--opoint 1
 279   "The point when `swiper' starts.")
 280
 281 ;;;###autoload
 282 (defun swiper (&optional initial-input)
 283   "`isearch' with an overview.
 284 When non-nil, INITIAL-INPUT is the initial search pattern."
 285   (interactive)
 286   (swiper--ivy initial-input))
 287
 288 (defvar swiper--anchor nil
 289   "A line number to which the search should be anchored.")
 290
 291 (defvar swiper--len 0
 292   "The last length of input for which an anchoring was made.")
 293
 294 (defun swiper--init ()
 295   "Perform initialization common to both completion methods."
 296   (setq swiper--opoint (point))
 297   (setq swiper--len 0)
 298   (setq swiper--anchor (line-number-at-pos)))
 299
 300 (defun swiper--re-builder (str)
 301   "Transform STR into a swiper regex.
 302 This is the regex used in the minibuffer, since the candidates
 303 there have line numbers. In the buffer, `ivy--regex' should be used."
 304   (cond
 305     ((equal str "")
 306      "")
 307     ((equal str "^")
 308      (setq ivy--subexps 0)
 309      ".")
 310     ((string-match "^\\^" str)
 311      (setq ivy--old-re "")
 312      (let ((re (ivy--regex-plus (substring str 1))))
 313        (if (zerop ivy--subexps)
 314            (prog1 (format "^ ?\\(%s\\)" re)
 315              (setq ivy--subexps 1))
 316          (format "^ %s" re))))
 317     (t
 318      (ivy--regex-plus str))))
 319
 320 (defvar swiper-history nil
 321   "History for `swiper'.")
 322
 323 (defvar swiper-invocation-face nil
 324   "The face at the point of invocation of `swiper'.")
 325
 326 (defun swiper--ivy (&optional initial-input)
 327   "`isearch' with an overview using `ivy'.
 328 When non-nil, INITIAL-INPUT is the initial search pattern."
 329   (interactive)
 330   (swiper--init)
 331   (setq swiper-invocation-face
 332         (plist-get (text-properties-at (point)) 'face))
 333   (let ((candidates (swiper--candidates))
 334         (preselect (buffer-substring-no-properties
 335                     (line-beginning-position)
 336                     (line-end-position)))
 337         (minibuffer-allow-text-properties t))
 338     (unwind-protect
 339         (ivy-read
 340          "Swiper: "
 341          candidates
 342          :initial-input initial-input
 343          :keymap swiper-map
 344          :preselect preselect
 345          :require-match t
 346          :update-fn #'swiper--update-input-ivy
 347          :unwind #'swiper--cleanup
 348          :action #'swiper--action
 349          :re-builder #'swiper--re-builder
 350          :history 'swiper-history
 351          :caller 'swiper)
 352       (when (null ivy-exit)
 353         (goto-char swiper--opoint)))))
 354
 355 (defun swiper-toggle-face-matching ()
 356   "Toggle matching only the candidates with `swiper-invocation-face'."
 357   (interactive)
 358   (setf (ivy-state-matcher ivy-last)
 359         (if (ivy-state-matcher ivy-last)
 360             nil
 361           #'swiper--face-matcher))
 362   (setq ivy--old-re nil))
 363
 364 (defun swiper--face-matcher (regexp candidates)
 365   "Return REGEXP-matching CANDIDATES.
 366 Matched candidates should have `swiper-invocation-face'."
 367   (cl-remove-if-not
 368    (lambda (x)
 369      (and
 370       (string-match regexp x)
 371       (let ((s (match-string 0 x))
 372             (i 0))
 373         (while (and (< i (length s))
 374                     (text-property-any
 375                      i (1+ i)
 376                      'face swiper-invocation-face
 377                      s))
 378           (cl-incf i))
 379         (eq i (length s)))))
 380    candidates))
 381
 382 (defun swiper--ensure-visible ()
 383   "Remove overlays hiding point."
 384   (let ((overlays (overlays-at (point)))
 385         ov expose)
 386     (while (setq ov (pop overlays))
 387       (if (and (invisible-p (overlay-get ov 'invisible))
 388                (setq expose (overlay-get ov 'isearch-open-invisible)))
 389           (funcall expose ov)))))
 390
 391 (defvar swiper--overlays nil
 392   "Store overlays.")
 393
 394 (defun swiper--cleanup ()
 395   "Clean up the overlays."
 396   (while swiper--overlays
 397     (delete-overlay (pop swiper--overlays)))
 398   (save-excursion
 399     (goto-char (point-min))
 400     (isearch-clean-overlays)))
 401
 402 (defun swiper--update-input-ivy ()
 403   "Called when `ivy' input is updated."
 404   (with-ivy-window
 405     (swiper--cleanup)
 406     (when (> (length ivy--current) 0)
 407       (let* ((re (funcall ivy--regex-function ivy-text))
 408              (re (if (stringp re) re (caar re)))
 409              (str (get-text-property 0 'display ivy--current))
 410              (num (if (string-match "^[0-9]+" str)
 411                       (string-to-number (match-string 0 str))
 412                     0)))
 413         (goto-char (point-min))
 414         (when (cl-plusp num)
 415           (goto-char (point-min))
 416           (if swiper-use-visual-line
 417               (line-move (1- num))
 418             (forward-line (1- num)))
 419           (if (and (equal ivy-text "")
 420                    (>= swiper--opoint (line-beginning-position))
 421                    (<= swiper--opoint (line-end-position)))
 422               (goto-char swiper--opoint)
 423             (re-search-forward re (line-end-position) t))
 424           (isearch-range-invisible (line-beginning-position)
 425                                    (line-end-position))
 426           (unless (and (>= (point) (window-start))
 427                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 428             (recenter)))
 429         (swiper--add-overlays re)))))
 430
 431 (defun swiper--add-overlays (re &optional beg end wnd)
 432   "Add overlays for RE regexp in visible part of the current buffer.
 433 BEG and END, when specified, are the point bounds.
 434 WND, when specified is the window."
 435   (setq wnd (or wnd (ivy-state-window ivy-last)))
 436   (let ((ov (if visual-line-mode
 437                 (make-overlay
 438                  (save-excursion
 439                    (beginning-of-visual-line)
 440                    (point))
 441                  (save-excursion
 442                    (end-of-visual-line)
 443                    (point)))
 444               (make-overlay
 445                (line-beginning-position)
 446                (1+ (line-end-position))))))
 447     (overlay-put ov 'face 'swiper-line-face)
 448     (overlay-put ov 'window wnd)
 449     (push ov swiper--overlays)
 450     (let* ((wh (window-height))
 451            (beg (or beg (save-excursion
 452                           (forward-line (- wh))
 453                           (point))))
 454            (end (or end (save-excursion
 455                           (forward-line wh)
 456                           (point)))))
 457       (when (>= (length re) swiper-min-highlight)
 458         (save-excursion
 459           (goto-char beg)
 460           ;; RE can become an invalid regexp
 461           (while (and (ignore-errors (re-search-forward re end t))
 462                       (> (- (match-end 0) (match-beginning 0)) 0))
 463             (let ((i 0))
 464               (while (<= i ivy--subexps)
 465                 (when (match-beginning i)
 466                   (let ((overlay (make-overlay (match-beginning i)
 467                                                (match-end i)))
 468                         (face
 469                          (cond ((zerop ivy--subexps)
 470                                 (cadr swiper-faces))
 471                                ((zerop i)
 472                                 (car swiper-faces))
 473                                (t
 474                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 475                                      swiper-faces)))))
 476                     (push overlay swiper--overlays)
 477                     (overlay-put overlay 'face face)
 478                     (overlay-put overlay 'window wnd)
 479                     (overlay-put overlay 'priority i)))
 480                 (cl-incf i)))))))))
 481
 482 (defun swiper--action (x)
 483   "Goto line X."
 484   (if (null x)
 485       (user-error "No candidates")
 486     (with-ivy-window
 487       (unless (equal (current-buffer)
 488                      (ivy-state-buffer ivy-last))
 489         (switch-to-buffer (ivy-state-buffer ivy-last)))
 490       (goto-char (point-min))
 491       (funcall (if swiper-use-visual-line
 492                    #'line-move
 493                  #'forward-line)
 494                (1- (read (get-text-property 0 'display x))))
 495       (re-search-forward
 496        (ivy--regex ivy-text) (line-end-position) t)
 497       (swiper--ensure-visible)
 498       (when (/= (point) swiper--opoint)
 499         (unless (and transient-mark-mode mark-active)
 500           (push-mark swiper--opoint t)
 501           (message "Mark saved where search started"))))))
 502
 503 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 504 (defun swiper-from-isearch ()
 505   "Invoke `swiper' from isearch."
 506   (interactive)
 507   (let ((query (if isearch-regexp
 508                    isearch-string
 509                  (regexp-quote isearch-string))))
 510     (isearch-exit)
 511     (swiper query)))
 512
 513 (defvar swiper-multi-buffers nil
 514   "Store the current list of buffers.")
 515
 516 (defvar swiper-multi-candidates nil
 517   "Store the list of candidates for `swiper-multi'.")
 518
 519 (defun swiper-multi-prompt ()
 520   (format "Buffers (%s): "
 521           (mapconcat #'identity swiper-multi-buffers ", ")))
 522
 523 (defun swiper-multi ()
 524   "Select one or more buffers.
 525 Run `swiper' for those buffers."
 526   (interactive)
 527   (setq swiper-multi-buffers nil)
 528   (setq swiper-multi-candidates nil)
 529   (ivy-read (swiper-multi-prompt)
 530             'internal-complete-buffer
 531             :action 'swiper-multi-action-1)
 532   (ivy-read "Swiper: " swiper-multi-candidates
 533             :action 'swiper-multi-action-2
 534             :unwind #'swiper--cleanup
 535             :caller 'swiper-multi))
 536
 537 (defun swiper-multi-action-1 (x)
 538   (if (member x swiper-multi-buffers)
 539       (progn
 540         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 541     (unless (equal x "")
 542       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 543   (let ((prompt (swiper-multi-prompt)))
 544     (setf (ivy-state-prompt ivy-last) prompt)
 545     (setq ivy--prompt (concat "%-4d " prompt)))
 546   (cond ((memq this-command '(ivy-done
 547                               ivy-alt-done
 548                               ivy-immediate-done))
 549          (let ((ww (window-width)))
 550            (dolist (buf swiper-multi-buffers)
 551              (with-current-buffer buf
 552                (setq swiper-multi-candidates
 553                      (append
 554                       (mapcar
 555                        (lambda (s)
 556                          (setq s (concat s " "))
 557                          (let ((len (length s)))
 558                            (put-text-property
 559                             (1- len) len 'display
 560                             (concat
 561                              (make-string
 562                               (max
 563                                (- ww
 564                                   (string-width s)
 565                                   (length (buffer-name))
 566                                   1)
 567                                0)
 568                               ?\ )
 569                              (buffer-name))
 570                             s)
 571                            s))
 572                        (swiper--candidates))
 573                       swiper-multi-candidates))))))
 574         ((eq this-command 'ivy-call)
 575          (delete-minibuffer-contents))))
 576
 577 (defun swiper-multi-action-2 (x)
 578   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 579     (with-ivy-window
 580       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 581         (switch-to-buffer (match-string 1 buf-space))
 582         (goto-char (point-min))
 583         (forward-line (1- (read x)))
 584         (re-search-forward
 585          (ivy--regex ivy-text)
 586          (line-end-position) t)
 587         (unless (eq ivy-exit 'done)
 588           (swiper--cleanup)
 589           (swiper--add-overlays (ivy--regex ivy-text)))))))
 590
 591 (provide 'swiper)
 592
 593 ;;; swiper.el ends here