code.delx.au - gnu-emacs-elpa/blob - counsel.el

   1 ;;; counsel.el --- Various completion functions using Ivy -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.1.0
   8 ;; Package-Requires: ((emacs "24.1") (swiper "0.4.0"))
   9 ;; Keywords: completion, matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; Just call one of the interactive functions in this file to complete
  29 ;; the corresponding thing using `ivy'.
  30 ;;
  31 ;; Currently available: Elisp symbols, Clojure symbols, Git files.
  32
  33 ;;; Code:
  34
  35 (require 'swiper)
  36 (require 'etags)
  37
  38 ;;;###autoload
  39 (defun counsel-el ()
  40   "Elisp completion at point."
  41   (interactive)
  42   (let* ((bnd (unless (and (looking-at ")")
  43                            (eq (char-before) ?\())
  44                 (bounds-of-thing-at-point
  45                  'symbol)))
  46          (str (if bnd
  47                   (buffer-substring-no-properties
  48                    (car bnd)
  49                    (cdr bnd))
  50                 ""))
  51          (ivy-height 7)
  52          (funp (eq (char-before (car bnd)) ?\())
  53          symbol-names)
  54     (if bnd
  55         (progn
  56           (setq ivy-completion-beg
  57                 (move-marker (make-marker) (car bnd)))
  58           (setq ivy-completion-end
  59                 (move-marker (make-marker) (cdr bnd))))
  60       (setq ivy-completion-beg nil)
  61       (setq ivy-completion-end nil))
  62     (if (string= str "")
  63         (mapatoms
  64          (lambda (x)
  65            (when (symbolp x)
  66              (push (symbol-name x) symbol-names))))
  67       (setq symbol-names
  68             (all-completions str obarray
  69                              (and funp
  70                                   (lambda (x)
  71                                     (or (functionp x)
  72                                         (macrop x)
  73                                         (special-form-p x)))))))
  74     (ivy-read "Symbol name: " symbol-names
  75               :predicate (and funp #'functionp)
  76               :initial-input str
  77               :action #'ivy-completion-in-region-action)))
  78
  79 (declare-function slime-symbol-start-pos "ext:slime")
  80 (declare-function slime-symbol-end-pos "ext:slime")
  81 (declare-function slime-contextual-completions "ext:slime-c-p-c")
  82
  83 ;;;###autoload
  84 (defun counsel-cl ()
  85   "Common Lisp completion at point."
  86   (interactive)
  87   (setq ivy-completion-beg (slime-symbol-start-pos))
  88   (setq ivy-completion-end (slime-symbol-end-pos))
  89   (ivy-read "Symbol name: "
  90             (car (slime-contextual-completions
  91                   ivy-completion-beg
  92                   ivy-completion-end))
  93             :action #'ivy-completion-in-region-action))
  94
  95 (declare-function deferred:sync! "ext:deferred")
  96 (declare-function jedi:complete-request "ext:jedi-core")
  97 (declare-function jedi:ac-direct-matches "ext:jedi")
  98
  99 (defun counsel-jedi ()
 100   "Python completion at point."
 101   (interactive)
 102   (let ((bnd (bounds-of-thing-at-point 'symbol)))
 103     (if bnd
 104         (progn
 105           (setq ivy-completion-beg (car bnd))
 106           (setq ivy-completion-end (cdr bnd)))
 107       (setq ivy-completion-beg nil)
 108       (setq ivy-completion-end nil)))
 109   (deferred:sync!
 110    (jedi:complete-request))
 111   (ivy-read "Symbol name: " (jedi:ac-direct-matches)
 112             :action #'counsel--py-action))
 113
 114 (defun counsel--py-action (symbol)
 115   "Insert SYMBOL, erasing the previous one."
 116   (when (stringp symbol)
 117     (with-ivy-window
 118       (when ivy-completion-beg
 119         (delete-region
 120          ivy-completion-beg
 121          ivy-completion-end))
 122       (setq ivy-completion-beg
 123             (move-marker (make-marker) (point)))
 124       (insert symbol)
 125       (setq ivy-completion-end
 126             (move-marker (make-marker) (point)))
 127       (when (equal (get-text-property 0 'symbol symbol) "f")
 128         (insert "()")
 129         (setq ivy-completion-end
 130               (move-marker (make-marker) (point)))
 131         (backward-char 1)))))
 132
 133 (defvar counsel-describe-map
 134   (let ((map (make-sparse-keymap)))
 135     (define-key map (kbd "C-.") #'counsel-find-symbol)
 136     (define-key map (kbd "C-,") #'counsel--info-lookup-symbol)
 137     map))
 138
 139 (defun counsel-find-symbol ()
 140   "Jump to the definition of the current symbol."
 141   (interactive)
 142   (ivy-exit-with-action #'counsel--find-symbol))
 143
 144 (defun counsel--info-lookup-symbol ()
 145   "Lookup the current symbol in the info docs."
 146   (interactive)
 147   (ivy-exit-with-action #'counsel-info-lookup-symbol))
 148
 149 (defun counsel--find-symbol (x)
 150   "Find symbol definition that corresponds to string X."
 151   (with-no-warnings
 152     (ring-insert find-tag-marker-ring (point-marker)))
 153   (let ((full-name (get-text-property 0 'full-name x)))
 154     (if full-name
 155         (find-library full-name)
 156       (let ((sym (read x)))
 157         (cond ((and (eq (ivy-state-caller ivy-last)
 158                         'counsel-describe-variable)
 159                     (boundp sym))
 160                (find-variable sym))
 161               ((fboundp sym)
 162                (find-function sym))
 163               ((boundp sym)
 164                (find-variable sym))
 165               ((or (featurep sym)
 166                    (locate-library
 167                     (prin1-to-string sym)))
 168                (find-library
 169                 (prin1-to-string sym)))
 170               (t
 171                (error "Couldn't fild definition of %s"
 172                       sym)))))))
 173
 174 (defvar counsel-describe-symbol-history nil
 175   "History for `counsel-describe-variable' and `counsel-describe-function'.")
 176
 177 (defun counsel-symbol-at-point ()
 178   "Return current symbol at point as a string."
 179   (let ((s (thing-at-point 'symbol)))
 180     (and (stringp s)
 181          (if (string-match "\\`[`']?\\(.*?\\)'?\\'" s)
 182              (match-string 1 s)
 183            s))))
 184
 185 (defun counsel-variable-list ()
 186   "Return the list of all currently bound variables."
 187   (let (cands)
 188     (mapatoms
 189      (lambda (vv)
 190        (when (or (get vv 'variable-documentation)
 191                  (and (boundp vv) (not (keywordp vv))))
 192          (push (symbol-name vv) cands))))
 193     cands))
 194
 195 ;;;###autoload
 196 (defun counsel-describe-variable ()
 197   "Forward to `describe-variable'."
 198   (interactive)
 199   (let ((enable-recursive-minibuffers t))
 200     (ivy-read
 201      "Describe variable: "
 202      (counsel-variable-list)
 203      :keymap counsel-describe-map
 204      :preselect (counsel-symbol-at-point)
 205      :history 'counsel-describe-symbol-history
 206      :require-match t
 207      :sort t
 208      :action (lambda (x)
 209                (describe-variable
 210                 (intern x)))
 211      :caller 'counsel-describe-variable)))
 212
 213 (ivy-set-actions
 214  'counsel-describe-variable
 215  '(("i" counsel-info-lookup-symbol "info")
 216    ("d" counsel--find-symbol "definition")))
 217
 218 (ivy-set-actions
 219  'counsel-describe-function
 220  '(("i" counsel-info-lookup-symbol "info")
 221    ("d" counsel--find-symbol "definition")))
 222
 223 (ivy-set-actions
 224  'counsel-M-x
 225  '(("d" counsel--find-symbol "definition")))
 226
 227 ;;;###autoload
 228 (defun counsel-describe-function ()
 229   "Forward to `describe-function'."
 230   (interactive)
 231   (let ((enable-recursive-minibuffers t))
 232     (ivy-read "Describe function: "
 233               (let (cands)
 234                 (mapatoms
 235                  (lambda (x)
 236                    (when (fboundp x)
 237                      (push (symbol-name x) cands))))
 238                 cands)
 239               :keymap counsel-describe-map
 240               :preselect (counsel-symbol-at-point)
 241               :history 'counsel-describe-symbol-history
 242               :require-match t
 243               :sort t
 244               :action (lambda (x)
 245                         (describe-function
 246                          (intern x)))
 247               :caller 'counsel-describe-function)))
 248
 249 (defvar info-lookup-mode)
 250 (declare-function info-lookup->completions "info-look")
 251 (declare-function info-lookup->mode-value "info-look")
 252 (declare-function info-lookup-select-mode "info-look")
 253 (declare-function info-lookup-change-mode "info-look")
 254 (declare-function info-lookup "info-look")
 255
 256 ;;;###autoload
 257 (defun counsel-info-lookup-symbol (symbol &optional mode)
 258   "Forward to (`info-describe-symbol' SYMBOL MODE) with ivy completion."
 259   (interactive
 260    (progn
 261      (require 'info-look)
 262      (let* ((topic 'symbol)
 263             (mode (cond (current-prefix-arg
 264                          (info-lookup-change-mode topic))
 265                         ((info-lookup->mode-value
 266                           topic (info-lookup-select-mode))
 267                          info-lookup-mode)
 268                         ((info-lookup-change-mode topic))))
 269             (completions (info-lookup->completions topic mode))
 270             (enable-recursive-minibuffers t)
 271             (value (ivy-read
 272                     "Describe symbol: "
 273                     (mapcar #'car completions)
 274                     :sort t)))
 275        (list value info-lookup-mode))))
 276   (require 'info-look)
 277   (info-lookup 'symbol symbol mode))
 278
 279 (defvar counsel-unicode-char-history nil
 280   "History for `counsel-unicode-char'.")
 281
 282 ;;;###autoload
 283 (defun counsel-unicode-char ()
 284   "Insert a Unicode character at point."
 285   (interactive)
 286   (let ((minibuffer-allow-text-properties t))
 287     (setq ivy-completion-beg (point))
 288     (setq ivy-completion-end (point))
 289     (ivy-read "Unicode name: "
 290               (mapcar (lambda (x)
 291                         (propertize
 292                          (format "% -60s%c" (car x) (cdr x))
 293                          'result (cdr x)))
 294                       (ucs-names))
 295               :action (lambda (char)
 296                         (with-ivy-window
 297                           (delete-region ivy-completion-beg ivy-completion-end)
 298                           (setq ivy-completion-beg (point))
 299                           (insert-char (get-text-property 0 'result char))
 300                           (setq ivy-completion-end (point))))
 301               :history 'counsel-unicode-char-history)))
 302
 303 (declare-function cider-sync-request:complete "ext:cider-client")
 304 ;;;###autoload
 305 (defun counsel-clj ()
 306   "Clojure completion at point."
 307   (interactive)
 308   (counsel--generic
 309    (lambda (str)
 310      (mapcar
 311       #'cl-caddr
 312       (cider-sync-request:complete str ":same")))))
 313
 314 (defvar counsel--git-dir nil
 315   "Store the base git directory.")
 316
 317 ;;;###autoload
 318 (defun counsel-git ()
 319   "Find file in the current Git repository."
 320   (interactive)
 321   (setq counsel--git-dir (expand-file-name
 322                           (locate-dominating-file
 323                            default-directory ".git")))
 324   (let* ((default-directory counsel--git-dir)
 325          (cands (split-string
 326                  (shell-command-to-string
 327                   "git ls-files --full-name --")
 328                  "\n"
 329                  t)))
 330     (ivy-read "Find file: " cands
 331               :action #'counsel-git-action)))
 332
 333 (defun counsel-git-action (x)
 334   (with-ivy-window
 335     (let ((default-directory counsel--git-dir))
 336       (find-file x))))
 337
 338 (defvar counsel--git-grep-dir nil
 339   "Store the base git directory.")
 340
 341 (defvar counsel--git-grep-count nil
 342   "Store the line count in current repository.")
 343
 344 (defun counsel-more-chars (n)
 345   "Return two fake candidates prompting for at least N input."
 346   (list ""
 347         (format "%d chars more" (- n (length ivy-text)))))
 348
 349 (defvar counsel-git-grep-cmd "git --no-pager grep --full-name -n --no-color -i -e %S"
 350   "Store the command for `counsel-git-grep'.")
 351
 352 (defun counsel-git-grep-function (string &optional _pred &rest _unused)
 353   "Grep in the current git repository for STRING."
 354   (if (and (> counsel--git-grep-count 20000)
 355            (< (length string) 3))
 356       (counsel-more-chars 3)
 357     (let* ((default-directory counsel--git-grep-dir)
 358            (cmd (format counsel-git-grep-cmd
 359                         (setq ivy--old-re (ivy--regex string t)))))
 360       (if (<= counsel--git-grep-count 20000)
 361           (split-string (shell-command-to-string cmd) "\n" t)
 362         (counsel--gg-candidates (ivy--regex string))
 363         nil))))
 364
 365 (defvar counsel-git-grep-map
 366   (let ((map (make-sparse-keymap)))
 367     (define-key map (kbd "C-l") 'counsel-git-grep-recenter)
 368     (define-key map (kbd "M-q") 'counsel-git-grep-query-replace)
 369     map))
 370
 371 (defun counsel-git-grep-query-replace ()
 372   "Start `query-replace' with string to replace from last search string."
 373   (interactive)
 374   (if (null (window-minibuffer-p))
 375       (user-error
 376        "Should only be called in the minibuffer through `counsel-git-grep-map'")
 377     (let* ((enable-recursive-minibuffers t)
 378            (from (ivy--regex ivy-text))
 379            (to (query-replace-read-to from "Query replace" t)))
 380       (ivy-exit-with-action
 381        (lambda (_)
 382          (let (done-buffers)
 383            (dolist (cand ivy--old-cands)
 384              (when (string-match "\\`\\(.*?\\):\\([0-9]+\\):\\(.*\\)\\'" cand)
 385                (with-ivy-window
 386                  (let ((file-name (match-string-no-properties 1 cand)))
 387                    (setq file-name (expand-file-name file-name counsel--git-grep-dir))
 388                    (unless (member file-name done-buffers)
 389                      (push file-name done-buffers)
 390                      (find-file file-name)
 391                      (goto-char (point-min)))
 392                    (perform-replace from to t t nil)))))))))))
 393
 394 (defun counsel-git-grep-recenter ()
 395   (interactive)
 396   (with-ivy-window
 397     (counsel-git-grep-action ivy--current)
 398     (recenter-top-bottom)))
 399
 400 (defun counsel-git-grep-action (x)
 401   (when (string-match "\\`\\(.*?\\):\\([0-9]+\\):\\(.*\\)\\'" x)
 402     (with-ivy-window
 403       (let ((file-name (match-string-no-properties 1 x))
 404             (line-number (match-string-no-properties 2 x)))
 405         (find-file (expand-file-name file-name counsel--git-grep-dir))
 406         (goto-char (point-min))
 407         (forward-line (1- (string-to-number line-number)))
 408         (re-search-forward (ivy--regex ivy-text t) (line-end-position) t)
 409         (unless (eq ivy-exit 'done)
 410           (swiper--cleanup)
 411           (swiper--add-overlays (ivy--regex ivy-text)))))))
 412
 413 (defvar counsel-git-grep-history nil
 414   "History for `counsel-git-grep'.")
 415
 416 (defvar counsel-git-grep-cmd-history
 417   '("git --no-pager grep --full-name -n --no-color -i -e %S")
 418   "History for `counsel-git-grep' shell commands.")
 419
 420 ;;;###autoload
 421 (defun counsel-git-grep (&optional cmd initial-input)
 422   "Grep for a string in the current git repository.
 423 When CMD is a string, use it as a \"git grep\" command.
 424 When CMD is non-nil, prompt for a specific \"git grep\" command.
 425 INITIAL-INPUT can be given as the initial minibuffer input."
 426   (interactive "P")
 427   (cond
 428     ((stringp cmd)
 429      (setq counsel-git-grep-cmd cmd))
 430     (cmd
 431      (setq counsel-git-grep-cmd
 432            (ivy-read "cmd: " counsel-git-grep-cmd-history
 433                      :history 'counsel-git-grep-cmd-history))
 434      (setq counsel-git-grep-cmd-history
 435            (delete-dups counsel-git-grep-cmd-history)))
 436     (t
 437      (setq counsel-git-grep-cmd "git --no-pager grep --full-name -n --no-color -i -e %S")))
 438   (setq counsel--git-grep-dir
 439         (locate-dominating-file default-directory ".git"))
 440   (if (null counsel--git-grep-dir)
 441       (error "Not in a git repository")
 442     (setq counsel--git-grep-count (counsel--gg-count "" t))
 443     (ivy-read "git grep: " 'counsel-git-grep-function
 444               :initial-input initial-input
 445               :matcher #'counsel-git-grep-matcher
 446               :dynamic-collection (> counsel--git-grep-count 20000)
 447               :keymap counsel-git-grep-map
 448               :action #'counsel-git-grep-action
 449               :unwind #'swiper--cleanup
 450               :history 'counsel-git-grep-history
 451               :caller 'counsel-git-grep)))
 452
 453 (defcustom counsel-find-file-at-point nil
 454   "When non-nil, add file-at-point to the list of candidates."
 455   :type 'boolean
 456   :group 'ivy)
 457
 458 (declare-function ffap-guesser "ffap")
 459
 460 (defvar counsel-find-file-map (make-sparse-keymap))
 461
 462 ;;;###autoload
 463 (defun counsel-find-file (&optional initial-input)
 464   "Forward to `find-file'.
 465 When INITIAL-INPUT is non-nil, use it in the minibuffer during completion."
 466   (interactive)
 467   (ivy-read "Find file: " 'read-file-name-internal
 468             :matcher #'counsel--find-file-matcher
 469             :initial-input initial-input
 470             :action
 471             (lambda (x)
 472               (with-ivy-window
 473                 (find-file (expand-file-name x ivy--directory))))
 474             :preselect (when counsel-find-file-at-point
 475                          (require 'ffap)
 476                          (ffap-guesser))
 477             :require-match 'confirm-after-completion
 478             :history 'file-name-history
 479             :keymap counsel-find-file-map))
 480
 481 (defcustom counsel-find-file-ignore-regexp nil
 482   "A regexp of files to ignore while in `counsel-find-file'.
 483 These files are un-ignored if `ivy-text' matches them.
 484 The common way to show all files is to start `ivy-text' with a dot.
 485 Possible value: \"\\(?:\\`[#.]\\)\\|\\(?:[#~]\\'\\)\"."
 486   :group 'ivy)
 487
 488 (defun counsel--find-file-matcher (regexp candidates)
 489   "Return REGEXP-matching CANDIDATES.
 490 Skip some dotfiles unless `ivy-text' requires them."
 491   (let ((res (ivy--re-filter regexp candidates)))
 492     (if (or (null counsel-find-file-ignore-regexp)
 493             (string-match counsel-find-file-ignore-regexp ivy-text))
 494         res
 495       (cl-remove-if
 496        (lambda (x)
 497          (string-match counsel-find-file-ignore-regexp x))
 498        res))))
 499
 500 (defun counsel-git-grep-matcher (regexp candidates)
 501   (or (and (equal regexp ivy--old-re)
 502            ivy--old-cands)
 503       (prog1
 504           (setq ivy--old-cands
 505                 (cl-remove-if-not
 506                  (lambda (x)
 507                    (ignore-errors
 508                      (when (string-match "^[^:]+:[^:]+:" x)
 509                        (setq x (substring x (match-end 0)))
 510                        (if (stringp regexp)
 511                            (string-match regexp x)
 512                          (let ((res t))
 513                            (dolist (re regexp)
 514                              (setq res
 515                                    (and res
 516                                         (ignore-errors
 517                                           (if (cdr re)
 518                                               (string-match (car re) x)
 519                                             (not (string-match (car re) x)))))))
 520                            res)))))
 521                  candidates))
 522         (setq ivy--old-re regexp))))
 523
 524 (defvar counsel--async-time nil
 525   "Store the time when a new process was started.
 526 Or the time of the last minibuffer update.")
 527
 528 (defun counsel--async-command (cmd)
 529   (let* ((counsel--process " *counsel*")
 530          (proc (get-process counsel--process))
 531          (buff (get-buffer counsel--process)))
 532     (when proc
 533       (delete-process proc))
 534     (when buff
 535       (kill-buffer buff))
 536     (setq proc (start-process-shell-command
 537                 counsel--process
 538                 counsel--process
 539                 cmd))
 540     (setq counsel--async-time (current-time))
 541     (set-process-sentinel proc #'counsel--async-sentinel)
 542     (set-process-filter proc #'counsel--async-filter)))
 543
 544 (defun counsel--async-sentinel (process event)
 545   (if (string= event "finished\n")
 546       (progn
 547         (with-current-buffer (process-buffer process)
 548           (setq ivy--all-candidates
 549                 (ivy--sort-maybe
 550                  (split-string (buffer-string) "\n" t)))
 551           (if (null ivy--old-cands)
 552               (setq ivy--index
 553                     (or (ivy--preselect-index
 554                          (ivy-state-preselect ivy-last)
 555                          ivy--all-candidates)
 556                         0))
 557             (ivy--recompute-index
 558              ivy-text
 559              (funcall ivy--regex-function ivy-text)
 560              ivy--all-candidates))
 561           (setq ivy--old-cands ivy--all-candidates))
 562         (ivy--exhibit))
 563     (if (string= event "exited abnormally with code 1\n")
 564         (progn
 565           (setq ivy--all-candidates '("Error"))
 566           (setq ivy--old-cands ivy--all-candidates)
 567           (ivy--exhibit)))))
 568
 569 (defun counsel--async-filter (process str)
 570   "Receive from PROCESS the output STR.
 571 Update the minibuffer with the amount of lines collected every
 572 0.5 seconds since the last update."
 573   (with-current-buffer (process-buffer process)
 574     (insert str))
 575   (let (size)
 576     (when (time-less-p
 577            ;; 0.5s
 578            '(0 0 500000 0)
 579            (time-since counsel--async-time))
 580       (with-current-buffer (process-buffer process)
 581         (goto-char (point-min))
 582         (setq size (- (buffer-size) (forward-line (buffer-size)))))
 583       (ivy--insert-minibuffer
 584        (format "\ncollected: %d" size))
 585       (setq counsel--async-time (current-time)))))
 586
 587 (defun counsel-locate-action-extern (x)
 588   "Use xdg-open shell command on X."
 589   (call-process shell-file-name nil
 590                 nil nil
 591                 shell-command-switch
 592                 (format "%s %s"
 593                         (if (eq system-type 'darwin)
 594                                     "open"
 595                                   "xdg-open")
 596                         (shell-quote-argument x))))
 597
 598 (declare-function dired-jump "dired-x")
 599 (defun counsel-locate-action-dired (x)
 600   "Use `dired-jump' on X."
 601   (dired-jump nil x))
 602
 603 (defvar counsel-locate-history nil
 604   "History for `counsel-locate'.")
 605
 606 (defcustom counsel-locate-options (if (eq system-type 'darwin)
 607                                       '("-i")
 608                                     '("-i" "--regex"))
 609   "Command line options for `locate`."
 610   :group 'ivy
 611   :type  '(repeat string))
 612
 613 (ivy-set-actions
 614  'counsel-locate
 615  '(("x" counsel-locate-action-extern "xdg-open")
 616    ("d" counsel-locate-action-dired "dired")))
 617
 618 (defun counsel-unquote-regex-parens (str)
 619   (replace-regexp-in-string
 620    "\\\\)" ")"
 621    (replace-regexp-in-string
 622     "\\\\(" "("
 623     str)))
 624
 625 (defun counsel-locate-function (str &rest _u)
 626   (if (< (length str) 3)
 627       (counsel-more-chars 3)
 628     (counsel--async-command
 629      (format "locate %s '%s'"
 630              (mapconcat #'identity counsel-locate-options " ")
 631              (counsel-unquote-regex-parens
 632               (ivy--regex str))))
 633     '("" "working...")))
 634
 635 (defun counsel-delete-process ()
 636   (let ((process (get-process " *counsel*")))
 637     (when process
 638       (delete-process process))))
 639
 640 ;;;###autoload
 641 (defun counsel-locate (&optional initial-input)
 642   "Call the \"locate\" shell command.
 643 INITIAL-INPUT can be given as the initial minibuffer input."
 644   (interactive)
 645   (ivy-read "Locate: " #'counsel-locate-function
 646             :initial-input initial-input
 647             :dynamic-collection t
 648             :history 'counsel-locate-history
 649             :action (lambda (file)
 650                       (with-ivy-window
 651                         (when file
 652                           (find-file file))))
 653             :unwind #'counsel-delete-process))
 654
 655 (defun counsel--generic (completion-fn)
 656   "Complete thing at point with COMPLETION-FN."
 657   (let* ((bnd (bounds-of-thing-at-point 'symbol))
 658          (str (if bnd
 659                   (buffer-substring-no-properties
 660                    (car bnd) (cdr bnd))
 661                 ""))
 662          (candidates (funcall completion-fn str))
 663          (ivy-height 7)
 664          (res (ivy-read (format "pattern (%s): " str)
 665                         candidates)))
 666     (when (stringp res)
 667       (when bnd
 668         (delete-region (car bnd) (cdr bnd)))
 669       (insert res))))
 670
 671 (defun counsel-directory-parent (dir)
 672   "Return the directory parent of directory DIR."
 673   (concat (file-name-nondirectory
 674            (directory-file-name dir)) "/"))
 675
 676 (defun counsel-string-compose (prefix str)
 677   "Make PREFIX the display prefix of STR though text properties."
 678   (let ((str (copy-sequence str)))
 679     (put-text-property
 680      0 1 'display
 681      (concat prefix (substring str 0 1))
 682      str)
 683     str))
 684
 685 ;;;###autoload
 686 (defun counsel-load-library ()
 687   "Load a selected the Emacs Lisp library.
 688 The libraries are offered from `load-path'."
 689   (interactive)
 690   (let ((dirs load-path)
 691         (suffix (concat (regexp-opt '(".el" ".el.gz") t) "\\'"))
 692         (cands (make-hash-table :test #'equal))
 693         short-name
 694         old-val
 695         dir-parent
 696         res)
 697     (dolist (dir dirs)
 698       (when (file-directory-p dir)
 699         (dolist (file (file-name-all-completions "" dir))
 700           (when (string-match suffix file)
 701             (unless (string-match "pkg.elc?$" file)
 702               (setq short-name (substring file 0 (match-beginning 0)))
 703               (if (setq old-val (gethash short-name cands))
 704                   (progn
 705                     ;; assume going up directory once will resolve name clash
 706                     (setq dir-parent (counsel-directory-parent (cdr old-val)))
 707                     (puthash short-name
 708                              (cons
 709                               (counsel-string-compose dir-parent (car old-val))
 710                               (cdr old-val))
 711                              cands)
 712                     (setq dir-parent (counsel-directory-parent dir))
 713                     (puthash (concat dir-parent short-name)
 714                              (cons
 715                               (propertize
 716                                (counsel-string-compose
 717                                 dir-parent short-name)
 718                                'full-name (expand-file-name file dir))
 719                               dir)
 720                              cands))
 721                 (puthash short-name
 722                          (cons (propertize
 723                                 short-name
 724                                 'full-name (expand-file-name file dir))
 725                                dir) cands)))))))
 726     (maphash (lambda (_k v) (push (car v) res)) cands)
 727     (ivy-read "Load library: " (nreverse res)
 728               :action (lambda (x)
 729                         (load-library
 730                          (get-text-property 0 'full-name x)))
 731               :keymap counsel-describe-map)))
 732
 733 (defvar counsel-gg-state nil
 734   "The current state of candidates / count sync.")
 735
 736 (defun counsel--gg-candidates (regex)
 737   "Return git grep candidates for REGEX."
 738   (setq counsel-gg-state -2)
 739   (counsel--gg-count regex)
 740   (let* ((default-directory counsel--git-grep-dir)
 741          (counsel-gg-process " *counsel-gg*")
 742          (proc (get-process counsel-gg-process))
 743          (buff (get-buffer counsel-gg-process)))
 744     (when proc
 745       (delete-process proc))
 746     (when buff
 747       (kill-buffer buff))
 748     (setq proc (start-process-shell-command
 749                 counsel-gg-process
 750                 counsel-gg-process
 751                 (concat
 752                  (format counsel-git-grep-cmd regex)
 753                  " | head -n 200")))
 754     (set-process-sentinel
 755      proc
 756      #'counsel--gg-sentinel)))
 757
 758 (defun counsel--gg-sentinel (process event)
 759   (if (string= event "finished\n")
 760       (progn
 761         (with-current-buffer (process-buffer process)
 762           (setq ivy--all-candidates
 763                 (or (split-string (buffer-string) "\n" t)
 764                     '("")))
 765           (setq ivy--old-cands ivy--all-candidates))
 766         (when (= 0 (cl-incf counsel-gg-state))
 767           (ivy--exhibit)))
 768     (if (string= event "exited abnormally with code 1\n")
 769         (progn
 770           (setq ivy--all-candidates '("Error"))
 771           (setq ivy--old-cands ivy--all-candidates)
 772           (ivy--exhibit)))))
 773
 774 (defun counsel--gg-count (regex &optional no-async)
 775   "Quickly and asynchronously count the amount of git grep REGEX matches.
 776 When NO-ASYNC is non-nil, do it synchronously."
 777   (let ((default-directory counsel--git-grep-dir)
 778         (cmd
 779          (concat
 780           (format
 781            (replace-regexp-in-string
 782             "--full-name" "-c"
 783             counsel-git-grep-cmd)
 784            ;; "git grep -i -c '%s'"
 785            (replace-regexp-in-string
 786             "-" "\\\\-"
 787             (replace-regexp-in-string "'" "''" regex)))
 788           " | sed 's/.*:\\(.*\\)/\\1/g' | awk '{s+=$1} END {print s}'"))
 789         (counsel-ggc-process " *counsel-gg-count*"))
 790     (if no-async
 791         (string-to-number (shell-command-to-string cmd))
 792       (let ((proc (get-process counsel-ggc-process))
 793             (buff (get-buffer counsel-ggc-process)))
 794         (when proc
 795           (delete-process proc))
 796         (when buff
 797           (kill-buffer buff))
 798         (setq proc (start-process-shell-command
 799                     counsel-ggc-process
 800                     counsel-ggc-process
 801                     cmd))
 802         (set-process-sentinel
 803          proc
 804          #'(lambda (process event)
 805              (when (string= event "finished\n")
 806                (with-current-buffer (process-buffer process)
 807                  (setq ivy--full-length (string-to-number (buffer-string))))
 808                (when (= 0 (cl-incf counsel-gg-state))
 809                  (ivy--exhibit)))))))))
 810
 811 (defun counsel--M-x-transformer (cand-pair)
 812   "Add a binding to CAND-PAIR cdr if the car is bound in the current window.
 813 CAND-PAIR is (command-name . extra-info)."
 814   (let* ((command-name (car cand-pair))
 815          (extra-info (cdr cand-pair))
 816          (binding (substitute-command-keys (format "\\[%s]" command-name))))
 817     (setq binding (replace-regexp-in-string "C-x 6" "<f2>" binding))
 818     (if (string-match "^M-x" binding)
 819         cand-pair
 820       (cons command-name
 821             (if extra-info
 822                 (format " %s (%s)" extra-info (propertize binding 'face 'font-lock-keyword-face))
 823               (format " (%s)" (propertize binding 'face 'font-lock-keyword-face)))))))
 824
 825 (defvar smex-initialized-p)
 826 (defvar smex-ido-cache)
 827 (declare-function smex-initialize "ext:smex")
 828 (declare-function smex-detect-new-commands "ext:smex")
 829 (declare-function smex-update "ext:smex")
 830 (declare-function smex-rank "ext:smex")
 831
 832 (defun counsel--M-x-prompt ()
 833   "M-x plus the string representation of `current-prefix-arg'."
 834   (if (not current-prefix-arg)
 835       "M-x "
 836     (concat
 837      (if (eq current-prefix-arg '-)
 838          "- "
 839        (if (integerp current-prefix-arg)
 840            (format "%d " current-prefix-arg)
 841          (if (= (car current-prefix-arg) 4)
 842              "C-u "
 843            (format "%d " (car current-prefix-arg)))))
 844      "M-x ")))
 845
 846 ;;;###autoload
 847 (defun counsel-M-x (&optional initial-input)
 848   "Ivy version of `execute-extended-command'.
 849 Optional INITIAL-INPUT is the initial input in the minibuffer."
 850   (interactive)
 851   (unless initial-input
 852     (setq initial-input (cdr (assoc this-command
 853                                     ivy-initial-inputs-alist))))
 854   (let* ((store ivy-format-function)
 855          (ivy-format-function
 856           (lambda (cand-pairs)
 857             (funcall
 858              store
 859              (with-ivy-window
 860                (mapcar #'counsel--M-x-transformer cand-pairs)))))
 861          (cands obarray)
 862          (pred 'commandp)
 863          (sort t))
 864     (when (require 'smex nil 'noerror)
 865       (unless smex-initialized-p
 866         (smex-initialize))
 867       (smex-detect-new-commands)
 868       (smex-update)
 869       (setq cands smex-ido-cache)
 870       (setq pred nil)
 871       (setq sort nil))
 872     (ivy-read (counsel--M-x-prompt) cands
 873               :predicate pred
 874               :require-match t
 875               :history 'extended-command-history
 876               :action
 877               (lambda (cmd)
 878                 (when (featurep 'smex)
 879                   (smex-rank (intern cmd)))
 880                 (let ((prefix-arg current-prefix-arg)
 881                       (ivy-format-function store)
 882                       (this-command (intern cmd)))
 883                   (command-execute (intern cmd) 'record)))
 884               :sort sort
 885               :keymap counsel-describe-map
 886               :initial-input initial-input
 887               :caller 'counsel-M-x)))
 888
 889 (declare-function powerline-reset "ext:powerline")
 890
 891 (defun counsel--load-theme-action (x)
 892   "Disable current themes and load theme X."
 893   (condition-case nil
 894       (progn
 895         (mapc #'disable-theme custom-enabled-themes)
 896         (load-theme (intern x))
 897         (when (fboundp 'powerline-reset)
 898           (powerline-reset)))
 899     (error "Problem loading theme %s" x)))
 900
 901 ;;;###autoload
 902 (defun counsel-load-theme ()
 903   "Forward to `load-theme'.
 904 Usable with `ivy-resume', `ivy-next-line-and-call' and
 905 `ivy-previous-line-and-call'."
 906   (interactive)
 907   (ivy-read "Load custom theme: "
 908             (mapcar 'symbol-name
 909                     (custom-available-themes))
 910             :action #'counsel--load-theme-action))
 911
 912 (defvar rhythmbox-library)
 913 (declare-function rhythmbox-load-library "ext:helm-rhythmbox")
 914 (declare-function dbus-call-method "dbus")
 915 (declare-function rhythmbox-song-uri "ext:helm-rhythmbox")
 916 (declare-function helm-rhythmbox-candidates "ext:helm-rhythmbox")
 917
 918 (defun counsel-rhythmbox-enqueue-song (song)
 919   "Let Rhythmbox enqueue SONG."
 920   (let ((service "org.gnome.Rhythmbox3")
 921         (path "/org/gnome/Rhythmbox3/PlayQueue")
 922         (interface "org.gnome.Rhythmbox3.PlayQueue"))
 923     (dbus-call-method :session service path interface
 924                       "AddToQueue" (rhythmbox-song-uri song))))
 925
 926 (defvar counsel-rhythmbox-history nil
 927   "History for `counsel-rhythmbox'.")
 928
 929 ;;;###autoload
 930 (defun counsel-rhythmbox ()
 931   "Choose a song from the Rhythmbox library to play or enqueue."
 932   (interactive)
 933   (unless (require 'helm-rhythmbox nil t)
 934     (error "Please install `helm-rhythmbox'"))
 935   (unless rhythmbox-library
 936     (rhythmbox-load-library)
 937     (while (null rhythmbox-library)
 938       (sit-for 0.1)))
 939   (ivy-read "Rhythmbox: "
 940             (helm-rhythmbox-candidates)
 941             :history 'counsel-rhythmbox-history
 942             :action
 943             '(1
 944               ("p" helm-rhythmbox-play-song "Play song")
 945               ("e" counsel-rhythmbox-enqueue-song "Enqueue song"))
 946             :caller 'counsel-rhythmbox))
 947
 948 (defvar counsel-org-tags nil
 949   "Store the current list of tags.")
 950
 951 (defvar org-outline-regexp)
 952 (defvar org-indent-mode)
 953 (defvar org-indent-indentation-per-level)
 954 (defvar org-tags-column)
 955 (declare-function org-get-tags-string "org")
 956 (declare-function org-move-to-column "org-compat")
 957
 958 (defun counsel-org-change-tags (tags)
 959   (let ((current (org-get-tags-string))
 960         (col (current-column))
 961         level)
 962     ;; Insert new tags at the correct column
 963     (beginning-of-line 1)
 964     (setq level (or (and (looking-at org-outline-regexp)
 965                          (- (match-end 0) (point) 1))
 966                     1))
 967     (cond
 968       ((and (equal current "") (equal tags "")))
 969       ((re-search-forward
 970         (concat "\\([ \t]*" (regexp-quote current) "\\)[ \t]*$")
 971         (point-at-eol) t)
 972        (if (equal tags "")
 973            (delete-region
 974             (match-beginning 0)
 975             (match-end 0))
 976          (goto-char (match-beginning 0))
 977          (let* ((c0 (current-column))
 978                 ;; compute offset for the case of org-indent-mode active
 979                 (di (if (bound-and-true-p org-indent-mode)
 980                         (* (1- org-indent-indentation-per-level) (1- level))
 981                       0))
 982                 (p0 (if (equal (char-before) ?*) (1+ (point)) (point)))
 983                 (tc (+ org-tags-column (if (> org-tags-column 0) (- di) di)))
 984                 (c1 (max (1+ c0) (if (> tc 0) tc (- (- tc) (string-width tags)))))
 985                 (rpl (concat (make-string (max 0 (- c1 c0)) ?\ ) tags)))
 986            (replace-match rpl t t)
 987            (and c0 indent-tabs-mode (tabify p0 (point)))
 988            tags)))
 989       (t (error "Tags alignment failed")))
 990     (org-move-to-column col)))
 991
 992 (defun counsel-org--set-tags ()
 993   (counsel-org-change-tags
 994    (if counsel-org-tags
 995        (format ":%s:"
 996                (mapconcat #'identity counsel-org-tags ":"))
 997      "")))
 998
 999 (defvar org-agenda-bulk-marked-entries)
1000
1001 (declare-function org-get-at-bol "org")
1002 (declare-function org-agenda-error "org-agenda")
1003
1004 (defun counsel-org-tag-action (x)
1005   (if (member x counsel-org-tags)
1006       (progn
1007         (setq counsel-org-tags (delete x counsel-org-tags)))
1008     (unless (equal x "")
1009       (setq counsel-org-tags (append counsel-org-tags (list x)))
1010       (unless (member x ivy--all-candidates)
1011         (setq ivy--all-candidates (append ivy--all-candidates (list x))))))
1012   (let ((prompt (counsel-org-tag-prompt)))
1013     (setf (ivy-state-prompt ivy-last) prompt)
1014     (setq ivy--prompt (concat "%-4d " prompt)))
1015   (cond ((memq this-command '(ivy-done
1016                               ivy-alt-done
1017                               ivy-immediate-done))
1018          (if (eq major-mode 'org-agenda-mode)
1019              (if (null org-agenda-bulk-marked-entries)
1020                  (let ((hdmarker (or (org-get-at-bol 'org-hd-marker)
1021                                      (org-agenda-error))))
1022                    (with-current-buffer (marker-buffer hdmarker)
1023                      (goto-char hdmarker)
1024                      (counsel-org--set-tags)))
1025                (let ((add-tags (copy-sequence counsel-org-tags)))
1026                  (dolist (m org-agenda-bulk-marked-entries)
1027                    (with-current-buffer (marker-buffer m)
1028                      (save-excursion
1029                        (goto-char m)
1030                        (setq counsel-org-tags
1031                              (delete-dups
1032                               (append (split-string (org-get-tags-string) ":" t)
1033                                       add-tags)))
1034                        (counsel-org--set-tags))))))
1035            (counsel-org--set-tags)))
1036         ((eq this-command 'ivy-call)
1037          (delete-minibuffer-contents))))
1038
1039 (defun counsel-org-tag-prompt ()
1040   (format "Tags (%s): "
1041           (mapconcat #'identity counsel-org-tags ", ")))
1042
1043 (defvar org-setting-tags)
1044 (defvar org-last-tags-completion-table)
1045 (defvar org-tag-persistent-alist)
1046 (defvar org-tag-alist)
1047 (defvar org-complete-tags-always-offer-all-agenda-tags)
1048
1049 (declare-function org-at-heading-p "org")
1050 (declare-function org-back-to-heading "org")
1051 (declare-function org-get-buffer-tags "org")
1052 (declare-function org-global-tags-completion-table "org")
1053 (declare-function org-agenda-files "org")
1054 (declare-function org-agenda-set-tags "org-agenda")
1055
1056 ;;;###autoload
1057 (defun counsel-org-tag ()
1058   "Add or remove tags in org-mode."
1059   (interactive)
1060   (save-excursion
1061     (if (eq major-mode 'org-agenda-mode)
1062         (if org-agenda-bulk-marked-entries
1063             (setq counsel-org-tags nil)
1064           (let ((hdmarker (or (org-get-at-bol 'org-hd-marker)
1065                               (org-agenda-error))))
1066             (with-current-buffer (marker-buffer hdmarker)
1067               (goto-char hdmarker)
1068               (setq counsel-org-tags
1069                     (split-string (org-get-tags-string) ":" t)))))
1070       (unless (org-at-heading-p)
1071         (org-back-to-heading t))
1072       (setq counsel-org-tags (split-string (org-get-tags-string) ":" t)))
1073     (let ((org-setting-tags t)
1074           (org-last-tags-completion-table
1075            (append org-tag-persistent-alist
1076                    (or org-tag-alist (org-get-buffer-tags))
1077                    (and
1078                     (or org-complete-tags-always-offer-all-agenda-tags
1079                         (eq major-mode 'org-agenda-mode))
1080                     (org-global-tags-completion-table
1081                      (org-agenda-files))))))
1082       (ivy-read (counsel-org-tag-prompt)
1083                 (lambda (str &rest _unused)
1084                   (delete-dups
1085                    (all-completions str 'org-tags-completion-function)))
1086                 :history 'org-tags-history
1087                 :action 'counsel-org-tag-action))))
1088
1089 ;;;###autoload
1090 (defun counsel-org-tag-agenda ()
1091   "Set tags for the current agenda item."
1092   (interactive)
1093   (let ((store (symbol-function 'org-set-tags)))
1094     (unwind-protect
1095          (progn
1096            (fset 'org-set-tags
1097                  (symbol-function 'counsel-org-tag))
1098            (org-agenda-set-tags nil nil))
1099       (fset 'org-set-tags store))))
1100
1101 (defcustom counsel-ag-base-command "ag --vimgrep %S"
1102   "Format string to use in `cousel-ag-function' to construct the
1103 command. %S will be replaced by the regex string. The default is
1104 \"ag --vimgrep %S\"."
1105   :type 'stringp
1106   :group 'ivy)
1107
1108 (defun counsel-ag-function (string &optional _pred &rest _unused)
1109   "Grep in the current directory for STRING."
1110   (if (< (length string) 3)
1111       (counsel-more-chars 3)
1112     (let ((default-directory counsel--git-grep-dir)
1113           (regex (counsel-unquote-regex-parens
1114                   (setq ivy--old-re
1115                         (ivy--regex string)))))
1116       (counsel--async-command
1117        (format counsel-ag-base-command regex))
1118       nil)))
1119
1120 ;;;###autoload
1121 (defun counsel-ag (&optional initial-input initial-directory)
1122   "Grep for a string in the current directory using ag.
1123 INITIAL-INPUT can be given as the initial minibuffer input."
1124   (interactive)
1125   (setq counsel--git-grep-dir (or initial-directory default-directory))
1126   (ivy-read "ag: " 'counsel-ag-function
1127             :initial-input initial-input
1128             :dynamic-collection t
1129             :history 'counsel-git-grep-history
1130             :action #'counsel-git-grep-action
1131             :unwind (lambda ()
1132                       (counsel-delete-process)
1133                       (swiper--cleanup))))
1134
1135 ;;;###autoload
1136 (defun counsel-grep ()
1137   "Grep for a string in the current file."
1138   (interactive)
1139   (setq counsel--git-grep-dir (buffer-file-name))
1140   (ivy-read "grep: " 'counsel-grep-function
1141             :dynamic-collection t
1142             :preselect (format "%d:%s"
1143                                (line-number-at-pos)
1144                                (buffer-substring-no-properties
1145                                 (line-beginning-position)
1146                                 (line-end-position)))
1147             :history 'counsel-git-grep-history
1148             :update-fn (lambda ()
1149                          (counsel-grep-action ivy--current))
1150             :action #'counsel-grep-action
1151             :unwind (lambda ()
1152                       (counsel-delete-process)
1153                       (swiper--cleanup))
1154             :caller 'counsel-grep))
1155
1156 (defun counsel-grep-function (string &optional _pred &rest _unused)
1157   "Grep in the current directory for STRING."
1158   (if (< (length string) 3)
1159       (counsel-more-chars 3)
1160     (let ((regex (counsel-unquote-regex-parens
1161                   (setq ivy--old-re
1162                         (ivy--regex string)))))
1163       (counsel--async-command
1164        (format "grep -nP --ignore-case '%s' %s" regex counsel--git-grep-dir))
1165       nil)))
1166
1167 (defun counsel-grep-action (x)
1168   (when (string-match "\\`\\([0-9]+\\):\\(.*\\)\\'" x)
1169     (with-ivy-window
1170       (let ((file-name counsel--git-grep-dir)
1171             (line-number (match-string-no-properties 1 x)))
1172         (find-file file-name)
1173         (goto-char (point-min))
1174         (forward-line (1- (string-to-number line-number)))
1175         (re-search-forward (ivy--regex ivy-text t) (line-end-position) t)
1176         (unless (eq ivy-exit 'done)
1177           (swiper--cleanup)
1178           (swiper--add-overlays (ivy--regex ivy-text)))))))
1179
1180 (defun counsel-recoll-function (string &optional _pred &rest _unused)
1181   "Grep in the current directory for STRING."
1182   (if (< (length string) 3)
1183       (counsel-more-chars 3)
1184     (counsel--async-command
1185      (format "recoll -t -b '%s'" string))
1186     nil))
1187
1188 ;; This command uses the recollq command line tool that comes together
1189 ;; with the recoll (the document indexing database) source:
1190 ;;     http://www.lesbonscomptes.com/recoll/download.html
1191 ;; You need to build it yourself (together with recoll):
1192 ;;     cd ./query && make && sudo cp recollq /usr/local/bin
1193 ;; You can try the GUI version of recoll with:
1194 ;;     sudo apt-get install recoll
1195 ;; Unfortunately, that does not install recollq.
1196 (defun counsel-recoll (&optional initial-input)
1197   "Search for a string in the recoll database.
1198 You'll be given a list of files that match.
1199 Selecting a file will launch `swiper' for that file.
1200 INITIAL-INPUT can be given as the initial minibuffer input."
1201   (interactive)
1202   (ivy-read "recoll: " 'counsel-recoll-function
1203             :initial-input initial-input
1204             :dynamic-collection t
1205             :history 'counsel-git-grep-history
1206             :action (lambda (x)
1207                       (when (string-match "file://\\(.*\\)\\'" x)
1208                         (let ((file-name (match-string 1 x)))
1209                           (find-file file-name)
1210                           (unless (string-match "pdf$" x)
1211                             (swiper ivy-text)))))))
1212
1213 (defvar tmm-km-list nil)
1214 (declare-function tmm-get-keymap "tmm")
1215 (declare-function tmm--completion-table "tmm")
1216 (declare-function tmm-get-keybind "tmm")
1217
1218 (defun counsel-tmm-prompt (menu)
1219   "Select and call an item from the MENU keymap."
1220   (let (out
1221         choice
1222         chosen-string)
1223     (setq tmm-km-list nil)
1224     (map-keymap (lambda (k v) (tmm-get-keymap (cons k v))) menu)
1225     (setq tmm-km-list (nreverse tmm-km-list))
1226     (setq out (ivy-read "Menu bar: " (tmm--completion-table tmm-km-list)
1227                         :require-match t
1228                         :sort nil))
1229     (setq choice (cdr (assoc out tmm-km-list)))
1230     (setq chosen-string (car choice))
1231     (setq choice (cdr choice))
1232     (cond ((keymapp choice)
1233            (counsel-tmm-prompt choice))
1234           ((and choice chosen-string)
1235            (setq last-command-event chosen-string)
1236            (call-interactively choice)))))
1237
1238 (defun counsel-tmm ()
1239   "Text-mode emulation of looking and choosing from a menubar."
1240   (interactive)
1241   (require 'tmm)
1242   (run-hooks 'menu-bar-update-hook)
1243   (counsel-tmm-prompt (tmm-get-keybind [menu-bar])))
1244
1245 (defcustom counsel-yank-pop-truncate nil
1246   "When non-nil, truncate the display of long strings."
1247   :group 'ivy)
1248
1249 ;;;###autoload
1250 (defun counsel-yank-pop ()
1251   "Ivy replacement for `yank-pop'."
1252   (interactive)
1253   (if (eq last-command 'yank)
1254       (progn
1255         (setq ivy-completion-end (point))
1256         (setq ivy-completion-beg
1257               (save-excursion
1258                 (search-backward (car kill-ring))
1259                 (point))))
1260     (setq ivy-completion-beg (point))
1261     (setq ivy-completion-end (point)))
1262   (let ((candidates (cl-remove-if
1263                      (lambda (s)
1264                        (or (< (length s) 3)
1265                            (string-match "\\`[\n[:blank:]]+\\'" s)))
1266                      (delete-dups kill-ring))))
1267     (when counsel-yank-pop-truncate
1268       (setq candidates
1269             (mapcar (lambda (s)
1270                       (if (string-match "\\`\\(.*\n.*\n.*\n.*\\)\n" s)
1271                           (progn
1272                             (let ((s (copy-sequence s)))
1273                               (put-text-property
1274                                (match-end 1)
1275                                (length s)
1276                                'display
1277                                " [...]"
1278                                s)
1279                               s))
1280                         s))
1281                     candidates)))
1282     (ivy-read "kill-ring: " candidates
1283               :action 'counsel-yank-pop-action)))
1284
1285 (defun counsel-yank-pop-action (s)
1286   "Insert S into the buffer, overwriting the previous yank."
1287   (with-ivy-window
1288     (delete-region ivy-completion-beg
1289                    ivy-completion-end)
1290     (insert (substring-no-properties s))
1291     (setq ivy-completion-end (point))))
1292
1293 (defvar imenu-auto-rescan)
1294 (declare-function imenu--subalist-p "imenu")
1295 (declare-function imenu--make-index-alist "imenu")
1296
1297 (defun counsel-imenu-get-candidates-from (alist &optional prefix)
1298   "Create a list of (key . value) from ALIST.
1299 PREFIX is used to create the key."
1300   (cl-mapcan (lambda (elm)
1301                (if (imenu--subalist-p elm)
1302                    (counsel-imenu-get-candidates-from
1303                     (cl-loop for (e . v) in (cdr elm) collect
1304                          (cons e (if (integerp v) (copy-marker v) v)))
1305                     (concat prefix (if prefix ".") (car elm)))
1306                  (list
1307                   (cons (concat prefix (if prefix ".") (car elm))
1308                         (if (overlayp (cdr elm))
1309                             (overlay-start (cdr elm))
1310                           (cdr elm))))))
1311              alist))
1312
1313 ;;;###autoload
1314 (defun counsel-imenu ()
1315   "Jump to a buffer position indexed by imenu."
1316   (interactive)
1317   (unless (featurep 'imenu)
1318     (require 'imenu nil t))
1319   (let* ((imenu-auto-rescan t)
1320          (items (imenu--make-index-alist t))
1321          (items (delete (assoc "*Rescan*" items) items)))
1322     (ivy-read "imenu items:" (counsel-imenu-get-candidates-from items)
1323               :action (lambda (pos)
1324                         (with-ivy-window
1325                           (goto-char pos))))))
1326
1327 (provide 'counsel)
1328
1329 ;;; counsel.el ends here