code.delx.au - gnu-emacs-elpa/blob - packages/context-coloring/test/context-coloring-test.el

   1 ;;; context-coloring-test.el --- Tests for context coloring  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2014-2015  Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; This program is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; Tests for context coloring.
  23
  24 ;; Use with `make test'.
  25
  26 ;;; Code:
  27
  28 (require 'cl-lib)
  29 (require 'context-coloring)
  30 (require 'ert)
  31 (require 'js2-mode)
  32
  33
  34 ;;; Test running utilities
  35
  36 (defconst context-coloring-test-path
  37   (file-name-directory (or load-file-name buffer-file-name))
  38   "This file's directory.")
  39
  40 (defun context-coloring-test-read-file (path)
  41   "Return the file's contents from PATH as a string."
  42   (with-temp-buffer
  43     (insert-file-contents (expand-file-name path context-coloring-test-path))
  44     (buffer-string)))
  45
  46 (defmacro context-coloring-test-with-fixture (fixture &rest body)
  47   "With relative FIXTURE, evaluate BODY in a temporary buffer."
  48   `(with-temp-buffer
  49      (progn
  50        (insert (context-coloring-test-read-file ,fixture))
  51        ,@body)))
  52
  53
  54 ;;; Test defining utilities
  55
  56 (cl-defmacro context-coloring-test-define-deftest (name
  57                                                    &key mode
  58                                                    &key extension
  59                                                    &key no-fixture
  60                                                    &key enable-context-coloring-mode
  61                                                    &key before-each
  62                                                    &key after-each)
  63   "Define a deftest defmacro for tests prefixed with NAME.  MODE
  64 is called to set up tests' environments.  EXTENSION denotes the
  65 suffix for tests' fixture files.  If NO-FIXTURE is non-nil, don't
  66 use a fixture.  If ENABLE-CONTEXT-COLORING-MODE is non-nil,
  67 `context-coloring-mode' is activated before tests.  Functions
  68 BEFORE-EACH and AFTER-EACH run before the major mode is activated
  69 before each test, and after each test, even if an error is
  70 signaled."
  71   (declare (indent defun))
  72   (let ((macro-name (intern (format "context-coloring-test-deftest%s"
  73                                     (cond
  74                                      ;; No name means no dash.
  75                                      ((eq name nil) "")
  76                                      (t (format "-%s" name)))))))
  77     `(cl-defmacro ,macro-name (name
  78                                body
  79                                &key fixture
  80                                &key before
  81                                &key after)
  82        (declare (indent defun))
  83        ;; Commas in nested backquotes are not evaluated.  Binding the variables
  84        ;; here is probably the cleanest workaround.
  85        (let ((mode ,mode)
  86              (before-each ',before-each)
  87              (after-each ',after-each)
  88              (test-name (intern (format ,(format "%s-%%s"
  89                                                  (cond
  90                                                   (name)
  91                                                   (t "generic"))) name)))
  92              (fixture (cond
  93                        (fixture (format "./fixtures/%s" fixture))
  94                        (,no-fixture "./fixtures/empty")
  95                        (t (format ,(format "./fixtures/%%s.%s" extension) name)))))
  96          ,@`((let ((enable-context-coloring-mode ,enable-context-coloring-mode))
  97                `(ert-deftest ,test-name ()
  98                   (context-coloring-test-with-fixture
  99                    ,fixture
 100                    (when ,before-each (funcall ,before-each))
 101                    (,mode)
 102                    (when ,before (funcall ,before))
 103                    (when ,enable-context-coloring-mode (context-coloring-mode))
 104                    (unwind-protect
 105                        (progn
 106                          (funcall ,body))
 107                      (when ,after (funcall ,after))
 108                      (when ,after-each (funcall ,after-each)))))))))))
 109
 110 (context-coloring-test-define-deftest nil
 111   :mode #'fundamental-mode
 112   :no-fixture t)
 113
 114 (context-coloring-test-define-deftest javascript
 115   :mode #'js2-mode
 116   :extension "js"
 117   :enable-context-coloring-mode t
 118   :before-each (lambda ()
 119                  (setq js2-mode-show-parse-errors nil)
 120                  (setq js2-mode-show-strict-warnings nil)))
 121
 122 (context-coloring-test-define-deftest emacs-lisp
 123   :mode #'emacs-lisp-mode
 124   :extension "el"
 125   :enable-context-coloring-mode t)
 126
 127 (context-coloring-test-define-deftest eval-expression
 128   :mode #'fundamental-mode
 129   :no-fixture t)
 130
 131
 132 ;;; Assertion functions
 133
 134 (defun context-coloring-test-get-last-message ()
 135   "Get the last message in the current messages bufffer."
 136   (let ((messages (split-string
 137                    (buffer-substring-no-properties
 138                     (point-min)
 139                     (point-max))
 140                    "\n")))
 141     (car (nthcdr (- (length messages) 2) messages))))
 142
 143 (defun context-coloring-test-assert-message (expected buffer)
 144   "Assert that message EXPECTED is at the end of BUFFER."
 145   (when (null (get-buffer buffer))
 146     (ert-fail
 147      (format
 148       (concat
 149        "Expected buffer `%s' to have message \"%s\", "
 150        "but the buffer did not have any messages.")
 151       buffer expected)))
 152   (with-current-buffer buffer
 153     (let ((message (context-coloring-test-get-last-message)))
 154       (when (not (equal message expected))
 155         (ert-fail
 156          (format
 157           (concat
 158            "Expected buffer `%s' to have message \"%s\", "
 159            "but instead it was \"%s\"")
 160           buffer expected
 161           message))))))
 162
 163 (defun context-coloring-test-assert-not-message (expected buffer)
 164   "Assert that message EXPECTED is not at the end of BUFFER."
 165   (when (get-buffer buffer)
 166     (with-current-buffer buffer
 167       (let ((message (context-coloring-test-get-last-message)))
 168         (when (equal message expected)
 169           (ert-fail
 170            (format
 171             (concat
 172              "Expected buffer `%s' not to have message \"%s\", "
 173              "but it did")
 174             buffer expected)))))))
 175
 176 (defun context-coloring-test-assert-error (body error-message)
 177   "Assert that BODY signals ERROR-MESSAGE."
 178   (let ((error-signaled-p nil))
 179     (condition-case err
 180         (progn
 181           (funcall body))
 182       (error
 183        (setq error-signaled-p t)
 184        (when (not (string-equal (cadr err) error-message))
 185          (ert-fail (format (concat "Expected the error \"%s\" to be thrown, "
 186                                    "but instead it was \"%s\".")
 187                            error-message
 188                            (cadr err))))))
 189     (when (not error-signaled-p)
 190       (ert-fail "Expected an error to be thrown, but there wasn't."))))
 191
 192
 193 ;;; Miscellaneous tests
 194
 195 (defmacro context-coloring-test-define-derived-mode (name)
 196   "Define a derived mode exclusively for any test with NAME."
 197   (let ((name (intern (format "context-coloring-test-%s-mode" name))))
 198     `(define-derived-mode ,name fundamental-mode "Testing")))
 199
 200 (defvar context-coloring-test-caused-p nil
 201   "If non-nil, coloring was caused.")
 202
 203 (defmacro context-coloring-test-assert-causes-coloring (&rest body)
 204   "Assert that BODY causes coloring."
 205   `(progn
 206      ;; Gross, but I want this to pass on 24.3.
 207      (ad-add-advice #'context-coloring-colorize
 208                     '(assert-causes-coloring
 209                       nil t
 210                       (advice . (lambda ()
 211                                   (setq context-coloring-test-caused-p t))))
 212                     'after
 213                     0)
 214      (ad-activate #'context-coloring-colorize)
 215      ,@body
 216      (when (not context-coloring-test-caused-p)
 217        (ert-fail "Expected to have colorized, but it didn't."))))
 218
 219 (defun context-coloring-test-cleanup-assert-causes-coloring ()
 220   "Undo `context-coloring-test-assert-causes-coloring'."
 221   (ad-unadvise #'context-coloring-colorize)
 222   (setq context-coloring-test-caused-p nil))
 223
 224 (context-coloring-test-define-derived-mode mode-startup)
 225
 226 (context-coloring-test-deftest mode-startup
 227   (lambda ()
 228     (context-coloring-define-dispatch
 229      'mode-startup
 230      :modes '(context-coloring-test-mode-startup-mode)
 231      :colorizer #'ignore)
 232     (context-coloring-test-mode-startup-mode)
 233     (context-coloring-test-assert-causes-coloring
 234      (context-coloring-mode)))
 235   :after (lambda ()
 236            (context-coloring-test-cleanup-assert-causes-coloring)))
 237
 238 (context-coloring-test-define-derived-mode change-detection)
 239
 240 (context-coloring-test-deftest change-detection
 241   (lambda ()
 242     (context-coloring-define-dispatch
 243      'idle-change
 244      :modes '(context-coloring-test-change-detection-mode)
 245      :colorizer #'ignore
 246      :setup #'context-coloring-setup-idle-change-detection
 247      :teardown #'context-coloring-teardown-idle-change-detection)
 248     (context-coloring-test-change-detection-mode)
 249     (context-coloring-mode)
 250     (context-coloring-test-assert-causes-coloring
 251      (insert " ")
 252      ;; Simply cannot figure out how to trigger an idle timer; would much rather
 253      ;; test that.  But (current-idle-time) always returns nil in these tests.
 254      (context-coloring-maybe-colorize-with-buffer (current-buffer))))
 255   :after (lambda ()
 256            (context-coloring-test-cleanup-assert-causes-coloring)))
 257
 258 (context-coloring-test-deftest unsupported-mode
 259   (lambda ()
 260     (context-coloring-mode)
 261     (context-coloring-test-assert-message
 262      "Context coloring is unavailable here"
 263      "*Messages*")))
 264
 265 (context-coloring-test-deftest derived-mode
 266   (lambda ()
 267     (lisp-interaction-mode)
 268     (context-coloring-mode)
 269     (context-coloring-test-assert-not-message
 270      "Context coloring is unavailable here"
 271      "*Messages*")))
 272
 273 (context-coloring-test-deftest unavailable-message-ignored
 274   (lambda ()
 275     (minibuffer-with-setup-hook
 276         (lambda ()
 277           (context-coloring-mode)
 278           (context-coloring-test-assert-not-message
 279            "Context coloring is unavailable here"
 280            "*Messages*"))
 281       (execute-kbd-macro
 282        (vconcat
 283         [?\C-u]
 284         [?\M-!])))))
 285
 286 (context-coloring-test-define-derived-mode define-dispatch-error)
 287
 288 (context-coloring-test-deftest define-dispatch-error
 289   (lambda ()
 290     (context-coloring-test-assert-error
 291      (lambda ()
 292        (context-coloring-define-dispatch
 293         'define-dispatch-no-modes))
 294      "No mode or predicate defined for dispatch")
 295     (context-coloring-test-assert-error
 296      (lambda ()
 297        (context-coloring-define-dispatch
 298         'define-dispatch-no-strategy
 299         :modes '(context-coloring-test-define-dispatch-error-mode)))
 300      "No colorizer defined for dispatch")))
 301
 302 (context-coloring-test-define-derived-mode disable-mode)
 303
 304 (context-coloring-test-deftest disable-mode
 305   (lambda ()
 306     (let (torn-down)
 307       (context-coloring-define-dispatch
 308        'disable-mode
 309        :modes '(context-coloring-test-disable-mode-mode)
 310        :colorizer #'ignore
 311        :teardown (lambda ()
 312                    (setq torn-down t)))
 313       (context-coloring-test-disable-mode-mode)
 314       (context-coloring-mode)
 315       (context-coloring-mode -1)
 316       (when (not torn-down)
 317         (ert-fail "Expected teardown function to have been called, but it wasn't.")))))
 318
 319 (defun context-coloring-test-assert-maximum-face (expected)
 320   "Assert that `context-coloring-maximum-face' is EXPECTED."
 321   (when (not (= context-coloring-maximum-face expected))
 322     (ert-fail (format "Expected maximum face to be %s, but it was %s"
 323                       expected context-coloring-maximum-face))))
 324
 325 (deftheme context-coloring-test-custom-theme)
 326
 327 (context-coloring-test-define-derived-mode custom-theme)
 328
 329 (context-coloring-test-deftest custom-theme
 330   (lambda ()
 331     (custom-theme-set-faces
 332      'context-coloring-test-custom-theme
 333      '(context-coloring-level-0-face ((t :foreground "#aaaaaa")))
 334      '(context-coloring-level-1-face ((t :foreground "#bbbbbb"))))
 335     (custom-set-faces
 336      '(context-coloring-level-0-face ((t :foreground "#aaaaaa"))))
 337     (enable-theme 'context-coloring-test-custom-theme)
 338     (context-coloring-define-dispatch
 339      'theme
 340      :modes '(context-coloring-test-custom-theme-mode)
 341      :colorizer #'ignore)
 342     (context-coloring-test-custom-theme-mode)
 343     (context-coloring-colorize)
 344     (context-coloring-test-assert-maximum-face 1)
 345     ;; This theme should now be ignored in favor of the `user' theme.
 346     (custom-theme-reset-faces
 347      'context-coloring-test-custom-theme
 348      '(context-coloring-level-0-face nil)
 349      '(context-coloring-level-1-face nil))
 350     (context-coloring-colorize)
 351     ;; Maximum face for `user'.
 352     (context-coloring-test-assert-maximum-face 0)
 353     ;; Now `user' should be ignored too.
 354     (custom-reset-faces
 355      '(context-coloring-level-0-face nil))
 356     (context-coloring-colorize)
 357     ;; Expect the package's defaults.
 358     (context-coloring-test-assert-maximum-face
 359      context-coloring-default-maximum-face))
 360   :after (lambda ()
 361            (custom-reset-faces
 362             '(context-coloring-level-0-face nil))
 363            (disable-theme 'context-coloring-test-custom-theme)))
 364
 365
 366 ;;; Coloring tests
 367
 368 (defun context-coloring-test-assert-position-level (position level)
 369   "Assert that POSITION has LEVEL."
 370   (let ((face (get-text-property position 'face))
 371         actual-level)
 372     (when (not (and face
 373                     (let* ((face-string (symbol-name face))
 374                            (matches (string-match
 375                                      context-coloring-level-face-regexp
 376                                      face-string)))
 377                       (when matches
 378                         (setq actual-level (string-to-number
 379                                             (substring face-string
 380                                                        (match-beginning 1)
 381                                                        (match-end 1))))
 382                         (= level actual-level)))))
 383       (ert-fail (format (concat "Expected level at position %s, "
 384                                 "which is \"%s\", to be %s; "
 385                                 "but it was %s")
 386                         position
 387                         (buffer-substring-no-properties position (1+ position)) level
 388                         actual-level)))))
 389
 390 (defun context-coloring-test-assert-position-face (position face-regexp)
 391   "Assert that the face at POSITION satisfies FACE-REGEXP."
 392   (let ((face (get-text-property position 'face)))
 393     (when (or
 394            ;; Pass a non-string to do an `equal' check (against a symbol or nil).
 395            (unless (stringp face-regexp)
 396              (not (equal face-regexp face)))
 397            ;; Otherwise do the matching.
 398            (when (stringp face-regexp)
 399              (not (string-match-p face-regexp (symbol-name face)))))
 400       (ert-fail (format (concat "Expected face at position %s, "
 401                                 "which is \"%s\", to be %s; "
 402                                 "but it was %s")
 403                         position
 404                         (buffer-substring-no-properties position (1+ position)) face-regexp
 405                         face)))))
 406
 407 (defun context-coloring-test-assert-position-comment (position)
 408   "Assert that the face at POSITION is a comment."
 409   (context-coloring-test-assert-position-face
 410    position "\\`font-lock-comment\\(-delimiter\\)?-face\\'"))
 411
 412 (defun context-coloring-test-assert-position-constant-comment (position)
 413   "Assert that the face at POSITION is a constant comment."
 414   (context-coloring-test-assert-position-face position '(font-lock-constant-face
 415                                                          font-lock-comment-face)))
 416
 417 (defun context-coloring-test-assert-position-string (position)
 418   "Assert that the face at POSITION is a string."
 419   (context-coloring-test-assert-position-face position 'font-lock-string-face))
 420
 421 (defun context-coloring-test-assert-position-nil (position)
 422   "Assert that the face at POSITION is nil."
 423   (context-coloring-test-assert-position-face position nil))
 424
 425 (defun context-coloring-test-assert-coloring (map)
 426   "Assert that the current buffer's coloring will match MAP.
 427
 428 MAP's newlines should correspond to the current fixture.
 429
 430 The following characters appearing in MAP assert coloring for
 431 corresponding points in the fixture:
 432
 433 0-9: Level equals number.
 434 C: Face is constant comment.
 435 c: Face is comment.
 436 n: Face is nil.
 437 s: Face is string.
 438
 439 Any other characters are discarded.  Characters \"x\" and any
 440 other non-letters are guaranteed to always be discarded."
 441   ;; Omit the superfluous, formatting-related leading newline.  Can't use
 442   ;; `save-excursion' here because if an assertion fails it will cause future
 443   ;; tests to get messed up.
 444   (goto-char (point-min))
 445   (let* ((map (substring map 1))
 446          (index 0)
 447          char-string
 448          char)
 449     (while (< index (length map))
 450       (setq char-string (substring map index (1+ index)))
 451       (setq char (string-to-char char-string))
 452       (cond
 453        ;; Newline
 454        ((= char 10)
 455         (forward-line)
 456         (beginning-of-line))
 457        ;; Number
 458        ((and (>= char 48)
 459              (<= char 57))
 460         (context-coloring-test-assert-position-level
 461          (point) (string-to-number char-string))
 462         (forward-char))
 463        ;; 'C' = Constant comment
 464        ((= char 67)
 465         (context-coloring-test-assert-position-constant-comment (point))
 466         (forward-char))
 467        ;; 'c' = Comment
 468        ((= char 99)
 469         (context-coloring-test-assert-position-comment (point))
 470         (forward-char))
 471        ;; 'n' = nil
 472        ((= char 110)
 473         (context-coloring-test-assert-position-nil (point))
 474         (forward-char))
 475        ;; 's' = String
 476        ((= char 115)
 477         (context-coloring-test-assert-position-string (point))
 478         (forward-char))
 479        (t
 480         (forward-char)))
 481       (setq index (1+ index)))))
 482
 483 (context-coloring-test-deftest-javascript function-scopes
 484   (lambda ()
 485     (context-coloring-test-assert-coloring "
 486 000 0 0 11111111 11 110
 487 11111111 011 1
 488     111 1 1 22222222 22 221
 489     22222222 122 22
 490 1")))
 491
 492 (context-coloring-test-deftest-javascript global
 493   (lambda ()
 494     (context-coloring-test-assert-coloring "
 495 (xxxxxxxx () {
 496     111 1 1 00000001xxx11
 497 }());")))
 498
 499 (context-coloring-test-deftest-javascript block-scopes
 500   (lambda ()
 501     (context-coloring-test-assert-coloring "
 502 (xxxxxxxx () {
 503     11 111 2
 504         222 12
 505         222 22
 506     2
 507 }());"))
 508   :before (lambda ()
 509             (setq context-coloring-javascript-block-scopes t))
 510   :after (lambda ()
 511            (setq context-coloring-javascript-block-scopes nil)))
 512
 513 (context-coloring-test-deftest-javascript catch
 514   (lambda ()
 515     (context-coloring-test-assert-coloring "
 516 (xxxxxxxx () {
 517     111 11 22222 222 2
 518         222 1 2 22
 519         222 22 33333 333 3
 520             333 1 3 33
 521         3
 522     2
 523 }());")))
 524
 525 (context-coloring-test-deftest-javascript key-names
 526   (lambda ()
 527     (context-coloring-test-assert-coloring "
 528 (xxxxxxxx () {
 529     111111 1
 530         11 11
 531         1 1 1
 532     11
 533 }());")))
 534
 535 (context-coloring-test-deftest-javascript property-lookup
 536   (lambda ()
 537     (context-coloring-test-assert-coloring "
 538 (xxxxxxxx () {
 539     0000001111111
 540     0000001 111111
 541     00000011111111111
 542 }());")))
 543
 544 (context-coloring-test-deftest-javascript key-values
 545   (lambda ()
 546     (context-coloring-test-assert-coloring "
 547 (xxxxxxxx () {
 548     xxx x;
 549     (xxxxxxxx () {
 550         xxxxxx {
 551             x: 1
 552         };
 553     }());
 554 }());")))
 555
 556 (context-coloring-test-deftest-javascript syntactic-comments-and-strings
 557   (lambda ()
 558     (context-coloring-test-assert-coloring "
 559 0000 00
 560 ccccccc
 561 cccccccccc
 562 ssssssssssss0"))
 563   :fixture "comments-and-strings.js")
 564
 565 (context-coloring-test-deftest-javascript syntactic-comments
 566   (lambda ()
 567     (context-coloring-test-assert-coloring "
 568 0000 00
 569 ccccccc
 570 cccccccccc
 571 0000000000000"))
 572   :fixture "comments-and-strings.js"
 573   :before (lambda ()
 574             (setq context-coloring-syntactic-strings nil))
 575   :after (lambda ()
 576            (setq context-coloring-syntactic-strings t)))
 577
 578 (context-coloring-test-deftest-javascript syntactic-strings
 579   (lambda ()
 580     (context-coloring-test-assert-coloring "
 581 0000 00
 582 0000000
 583 0000000000
 584 ssssssssssss0"))
 585   :fixture "comments-and-strings.js"
 586   :before (lambda ()
 587             (setq context-coloring-syntactic-comments nil))
 588   :after (lambda ()
 589            (setq context-coloring-syntactic-comments t)))
 590
 591 (context-coloring-test-deftest-javascript unterminated-comment
 592   ;; As long as `add-text-properties' doesn't signal an error, this test passes.
 593   (lambda ()))
 594
 595 (context-coloring-test-deftest-emacs-lisp defun
 596   (lambda ()
 597     (context-coloring-test-assert-coloring "
 598 111111 000 1111 111 111111111 1111
 599   11 111 111 111 000011
 600
 601 0000 0 0 00
 602
 603 111111 01
 604 111111 111
 605 111111 0 1sss11")))
 606
 607 (context-coloring-test-deftest-emacs-lisp defadvice
 608   (lambda ()
 609     (context-coloring-test-assert-coloring "
 610 1111111111 0 1111111 111111 11111 111 111111111
 611   2222 222 122
 612     22 1 2221")))
 613
 614 (context-coloring-test-deftest-emacs-lisp lambda
 615   (lambda ()
 616     (context-coloring-test-assert-coloring "
 617 00000000 1111111 1111
 618            11111111 11 2222222 2222
 619                          222 22 12 2221 111 0 00")))
 620
 621 (context-coloring-test-deftest-emacs-lisp quote
 622   (lambda ()
 623     (context-coloring-test-assert-coloring "
 624 (xxxxx 0000000 00 00000)
 625 (xxx () (xxxxxxxxx (,0000)))
 626
 627 (xxxxx x (x)
 628   (xx (xx x 111
 629       111111 1 111 111
 630       111111 1 1111111111 11 111 1 111 1 00001 10000 11 00001 1 10000
 631                  sss ccc
 632                  1111
 633
 634 (xxxxxx '(sss cc
 635           sss cc
 636           ))
 637
 638 (xxxxxx () 111111 11111)")))
 639
 640 (context-coloring-test-deftest-emacs-lisp splice
 641   (lambda ()
 642     (context-coloring-test-assert-coloring "
 643 (xxxxxx ()
 644   111111 00001 100001)")))
 645
 646 (context-coloring-test-deftest-emacs-lisp comment
 647   (lambda ()
 648     ;; Just check that the comment isn't parsed syntactically.
 649     (context-coloring-test-assert-coloring "
 650 (xxxxx x ()
 651   (xx (x xxxxx-xxxx xx)   cccccccccc
 652       11 00000-0000 11))) cccccccccc")))
 653
 654 (context-coloring-test-deftest-emacs-lisp string
 655   (lambda ()
 656     (context-coloring-test-assert-coloring "
 657 (xxxxx x (x)
 658   (xxxxxx x x sss 1 0 sssss 0 1 sssssss11")))
 659
 660 (context-coloring-test-deftest-emacs-lisp ignored
 661   (lambda ()
 662     (context-coloring-test-assert-coloring "
 663 (xxxxx x ()
 664   (x x 1 11 11 111 111 11 11 11 1 111 (1 1 1)))")))
 665
 666 (context-coloring-test-deftest-emacs-lisp sexp
 667   (lambda ()
 668     (context-coloring-test-assert-coloring "
 669 (xxx ()
 670   `,@sss
 671   `,@11
 672   `,@11)")))
 673
 674 (context-coloring-test-deftest-emacs-lisp let
 675   (lambda ()
 676     (context-coloring-test-assert-coloring "
 677 1111 11
 678       11 01
 679       11 00001
 680       11 2222 22
 681                22 02
 682                22 000022
 683            2222 2 2 2 00002211
 684   1111 1 1 1 000011
 685
 686 1111 cc ccccccc
 687     1sss11")))
 688
 689 (context-coloring-test-deftest-emacs-lisp let*
 690   (lambda ()
 691     (context-coloring-test-assert-coloring "
 692 11111 11
 693        11 11
 694        11 000011
 695   1111 1 1 1 0 0 00001
 696   22222 22
 697          22 12
 698          22 00002
 699          22 02
 700          22 222
 701     2222 1 1 2 2 2 000022
 702   1111 1 1 1 0 0 000011")))
 703
 704 (context-coloring-test-deftest-emacs-lisp cond
 705   (lambda ()
 706     (context-coloring-test-assert-coloring "
 707 (xxx (x)
 708   11111
 709    11 11
 710    10000 11
 711    1111 1 00001 11
 712    11 11111 1 000011
 713    cc c
 714    sss1)")))
 715
 716 (context-coloring-test-deftest-emacs-lisp condition-case
 717   (lambda ()
 718     (context-coloring-test-assert-coloring "
 719 1111111111-1111 111
 720     111111 000 00001
 721   111111 111 00001
 722   1111111 111111 111 000011
 723
 724 (111111111-1111-111111-11111 111
 725     cc c
 726     (xxx () 222)
 727   (11111 (xxx () 222))
 728   sss)")))
 729
 730 (context-coloring-test-deftest-emacs-lisp dolist
 731   (lambda ()
 732     (context-coloring-test-assert-coloring "
 733 1111111 111111
 734   2222222 2222 1111 2222222
 735     3333333 33 33 222 1111 2222223321")))
 736
 737 (defun context-coloring-test-insert-unread-space ()
 738   "Simulate the insertion of a space as if by a user."
 739   (setq unread-command-events (cons '(t . 32)
 740                                     unread-command-events)))
 741
 742 (defun context-coloring-test-remove-faces ()
 743   "Remove all faces in the current buffer."
 744   (remove-text-properties (point-min) (point-max) '(face nil)))
 745
 746 (context-coloring-test-deftest-emacs-lisp iteration
 747   (lambda ()
 748     (let ((context-coloring-elisp-sexps-per-pause 2))
 749       (context-coloring-colorize)
 750       (context-coloring-test-assert-coloring "
 751 cc `CC' `CC'
 752 (xxxxx x ())")
 753       (context-coloring-test-remove-faces)
 754       (context-coloring-test-insert-unread-space)
 755       (context-coloring-colorize)
 756       ;; Coloring is interrupted after the first "sexp" (the comment in this
 757       ;; case).
 758       (context-coloring-test-assert-coloring "
 759 cc `CC' `CC'
 760 nnnnnn n nnn"))))
 761
 762 (context-coloring-test-deftest-emacs-lisp changed
 763   (lambda ()
 764     (context-coloring-test-remove-faces)
 765     ;; Goto line 3.
 766     (goto-char (point-min))
 767     (forward-line (1- 3))
 768     (insert " ")
 769     ;; Mock `pos-visible-in-window-p' because in batch mode `get-buffer-window'
 770     ;; returns nil.  Emacs must not have a window in that environment.
 771     (cl-letf (((symbol-function 'pos-visible-in-window-p)
 772                (let ((calls 0))
 773                  (lambda ()
 774                    (prog1
 775                        ;; First and third calls start from center.  Second and
 776                        ;; fourth calls are made immediately after moving past
 777                        ;; the first defun in either direction "off screen".
 778                        (cond
 779                         ((= calls 0) t)
 780                         ((= calls 1) nil)
 781                         ((= calls 2) t)
 782                         ((= calls 4) nil))
 783                      (setq calls (1+ calls)))))))
 784       (context-coloring-colorize))
 785     (context-coloring-test-assert-coloring "
 786 nnnn  n nnn nnnnnnnn
 787 0000
 788
 789 0000
 790 nnnnn n nnn nnnnnnnn")))
 791
 792 (context-coloring-test-deftest-emacs-lisp unbalanced-parenthesis
 793   (lambda ()
 794     (context-coloring-test-assert-coloring "
 795 1111 111
 796 nnnn nn")))
 797
 798 (context-coloring-test-deftest-eval-expression let
 799   (lambda ()
 800     (minibuffer-with-setup-hook
 801         (lambda ()
 802           ;; Perform the test in a hook as it's the only way I know of examining
 803           ;; the minibuffer's contents.  The contents are implicitly submitted,
 804           ;; so we have to ignore the errors in the arbitrary test subject code.
 805           (insert "(ignore-errors (let (a) (message a free)))")
 806           (context-coloring-colorize)
 807           (context-coloring-test-assert-coloring "
 808 xxxx: 0000000-000000 1111 111 11111111 1 0000110"))
 809       ;; Simulate user input because `call-interactively' is blocking and
 810       ;; doesn't seem to run the hook.
 811       (execute-kbd-macro
 812        (vconcat
 813         [?\C-u] ;; Don't output the result of the arbitrary test subject code.
 814         [?\M-:])))))
 815
 816 (provide 'context-coloring-test)
 817
 818 ;;; context-coloring-test.el ends here