code.delx.au - gnu-emacs-elpa/blob - packages/company/company-template.el

   1 ;;; company-template.el
   2
   3 ;; Copyright (C) 2009, 2010, 2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Code:
  23
  24 (require 'cl-lib)
  25
  26 (defface company-template-field
  27   '((((background dark)) (:background "yellow" :foreground "black"))
  28     (((background light)) (:background "orange" :foreground "black")))
  29   "Face used for editable text in template fields."
  30   :group 'company)
  31
  32 (defvar company-template-nav-map
  33   (let ((keymap (make-sparse-keymap)))
  34     (define-key keymap [tab] 'company-template-forward-field)
  35     (define-key keymap (kbd "TAB") 'company-template-forward-field)
  36     keymap))
  37
  38 (defvar-local company-template--buffer-templates nil)
  39
  40 ;; interactive ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  41
  42 (defun company-template-templates-at (pos)
  43   (let (os)
  44     (dolist (o (overlays-at pos))
  45       ;; FIXME: Always return the whole list of templates?
  46       ;; We remove templates not at point after every command.
  47       (when (memq o company-template--buffer-templates)
  48         (push o os)))
  49     os))
  50
  51 (defun company-template-move-to-first (templ)
  52   (interactive)
  53   (goto-char (overlay-start templ))
  54   (company-template-forward-field))
  55
  56 (defun company-template-forward-field ()
  57   (interactive)
  58   (let* ((start (point))
  59          (templates (company-template-templates-at (point)))
  60          (minimum (apply 'max (mapcar 'overlay-end templates)))
  61          (fields (cl-loop for templ in templates
  62                           append (overlay-get templ 'company-template-fields))))
  63     (dolist (pos (mapcar 'overlay-start fields))
  64       (and pos
  65            (> pos (point))
  66            (< pos minimum)
  67            (setq minimum pos)))
  68     (push-mark)
  69     (goto-char minimum)
  70     (company-template-remove-field (company-template-field-at start))))
  71
  72 (defun company-template-field-at (&optional point)
  73   (cl-loop for ovl in (overlays-at (or point (point)))
  74            when (overlay-get ovl 'company-template-parent)
  75            return ovl))
  76
  77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  78
  79 (defun company-template-declare-template (beg end)
  80   (let ((ov (make-overlay beg end)))
  81     ;; (overlay-put ov 'face 'highlight)
  82     (overlay-put ov 'keymap company-template-nav-map)
  83     (overlay-put ov 'priority 101)
  84     (overlay-put ov 'evaporate t)
  85     (push ov company-template--buffer-templates)
  86     (add-hook 'post-command-hook 'company-template-post-command nil t)
  87     ov))
  88
  89 (defun company-template-remove-template (templ)
  90   (mapc 'company-template-remove-field
  91         (overlay-get templ 'company-template-fields))
  92   (setq company-template--buffer-templates
  93         (delq templ company-template--buffer-templates))
  94   (delete-overlay templ))
  95
  96 (defun company-template-add-field (templ pos text &optional display)
  97   "Add new field to template TEMPL at POS, inserting TEXT.
  98 When DISPLAY is non-nil, set the respective property on the overlay.
  99 Leave point at the end of the field."
 100   (cl-assert templ)
 101   (goto-char pos)
 102   (insert text)
 103   (when (> (point) (overlay-end templ))
 104     (move-overlay templ (overlay-start templ) (point)))
 105   (let ((ov (make-overlay pos (+ pos (length text))))
 106         (siblings (overlay-get templ 'company-template-fields)))
 107     ;; (overlay-put ov 'evaporate t)
 108     (overlay-put ov 'intangible t)
 109     (overlay-put ov 'face 'company-template-field)
 110     (when display
 111       (overlay-put ov 'display display))
 112     (overlay-put ov 'company-template-parent templ)
 113     (overlay-put ov 'insert-in-front-hooks '(company-template-insert-hook))
 114     (push ov siblings)
 115     (overlay-put templ 'company-template-fields siblings)))
 116
 117 (defun company-template-remove-field (ovl &optional clear)
 118   (when (overlayp ovl)
 119     (when (overlay-buffer ovl)
 120       (when clear
 121         (delete-region (overlay-start ovl) (overlay-end ovl)))
 122       (delete-overlay ovl))
 123     (let* ((templ (overlay-get ovl 'company-template-parent))
 124            (siblings (overlay-get templ 'company-template-fields)))
 125       (setq siblings (delq ovl siblings))
 126       (overlay-put templ 'company-template-fields siblings))))
 127
 128 (defun company-template-clean-up (&optional pos)
 129   "Clean up all templates that don't contain POS."
 130   (let ((local-ovs (overlays-at (or pos (point)))))
 131     (dolist (templ company-template--buffer-templates)
 132       (unless (memq templ local-ovs)
 133         (company-template-remove-template templ)))))
 134
 135 ;; hooks ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 136
 137 (defun company-template-insert-hook (ovl after-p &rest _ignore)
 138   "Called when a snippet input prompt is modified."
 139   (unless after-p
 140     (company-template-remove-field ovl t)))
 141
 142 (defun company-template-post-command ()
 143   (company-template-clean-up)
 144   (unless company-template--buffer-templates
 145     (remove-hook 'post-command-hook 'company-template-post-command t)))
 146
 147 ;; common ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 148
 149 (defun company-template-c-like-templatify (call)
 150   (let* ((end (point-marker))
 151          (beg (- (point) (length call)))
 152          (cnt 0)
 153          (templ (company-template-declare-template beg end))
 154          paren-open paren-close)
 155     (with-syntax-table (make-syntax-table (syntax-table))
 156       (modify-syntax-entry ?< "(")
 157       (modify-syntax-entry ?> ")")
 158       (when (search-backward ")" beg t)
 159         (setq paren-close (point-marker))
 160         (forward-char 1)
 161         (delete-region (point) end)
 162         (backward-sexp)
 163         (forward-char 1)
 164         (setq paren-open (point-marker)))
 165       (when (search-backward ">" beg t)
 166         (let ((angle-close (point-marker)))
 167           (forward-char 1)
 168           (backward-sexp)
 169           (forward-char)
 170           (setq cnt (company-template--c-like-args templ angle-close
 171                                                    cnt))))
 172       (when paren-open
 173         (goto-char paren-open)
 174         (company-template--c-like-args templ paren-close cnt)))
 175     (if (overlay-get templ 'company-template-fields)
 176         (company-template-move-to-first templ)
 177       (company-template-remove-template templ)
 178       (goto-char end))))
 179
 180 (defun company-template--c-like-args (templ end counter)
 181   (let ((last-pos (point)))
 182     (while (re-search-forward "\\([^,]+\\),?" end 'move)
 183       (when (zerop (car (parse-partial-sexp last-pos (point))))
 184         (let ((sig (buffer-substring-no-properties last-pos (match-end 1))))
 185           (save-excursion
 186             (company-template-add-field templ last-pos
 187                                         (format "arg%d" counter) sig)
 188             (delete-region (point) (+ (point) (length sig))))
 189           (skip-chars-forward " ")
 190           (setq last-pos (point))
 191           (cl-incf counter)))))
 192   counter)
 193
 194 (provide 'company-template)
 195 ;;; company-template.el ends here