code.delx.au - gnu-emacs-elpa/blob - packages/spinner/spinner.el

   1 ;;; spinner.el --- Add spinners and progress-bars to the mode-line for ongoing operations -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; Version: 1.7
   7 ;; URL: https://github.com/Malabarba/spinner.el
   8 ;; Keywords: processes mode-line
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; 1 Usage
  26 ;; ═══════
  27 ;;
  28 ;;   First of all, don’t forget to add `(spinner "VERSION")' to your
  29 ;;   package’s dependencies.
  30 ;;
  31 ;;
  32 ;; 1.1 Major-modes
  33 ;; ───────────────
  34 ;;
  35 ;;   1. Just call `(spinner-start)' and a spinner will be added to the
  36 ;;      mode-line.
  37 ;;   2. Call `(spinner-stop)' on the same buffer when you want to remove
  38 ;;      it.
  39 ;;
  40 ;;   The default spinner is a line drawing that rotates. You can pass an
  41 ;;   argument to `spinner-start' to specify which spinner you want. All
  42 ;;   possibilities are listed in the `spinner-types' variable, but here are
  43 ;;   a few examples for you to try:
  44 ;;
  45 ;;   • `(spinner-start 'vertical-breathing 10)'
  46 ;;   • `(spinner-start 'minibox)'
  47 ;;   • `(spinner-start 'moon)'
  48 ;;   • `(spinner-start 'triangle)'
  49 ;;
  50 ;;   You can also define your own as a vector of strings (see the examples
  51 ;;   in `spinner-types').
  52 ;;
  53 ;;
  54 ;; 1.2 Minor-modes
  55 ;; ───────────────
  56 ;;
  57 ;;   Minor-modes can create a spinner with `spinner-create' and then add it
  58 ;;   to their mode-line lighter. They can then start the spinner by setting
  59 ;;   a variable and calling `spinner-start-timer'. Finally, they can stop
  60 ;;   the spinner (and the timer) by just setting the same variable to nil.
  61 ;;
  62 ;;   Here’s an example for a minor-mode named `foo'. Assuming that
  63 ;;   `foo--lighter' is used as the mode-line lighter, the following code
  64 ;;   will add an *inactive* global spinner to the mode-line.
  65 ;;   ┌────
  66 ;;   │ (defvar foo--spinner (spinner-create 'rotating-line))
  67 ;;   │ (defconst foo--lighter
  68 ;;   │   '(" foo" (:eval (spinner-print foo--spinner))))
  69 ;;   └────
  70 ;;
  71 ;;   1. To activate the spinner, just call `(spinner-start foo--spinner)'.
  72 ;;      It will show up on the mode-line and start animating.
  73 ;;   2. To get rid of it, call `(spinner-stop foo--spinner)'. It will then
  74 ;;      disappear again.
  75 ;;
  76 ;;   Some minor-modes will need spinners to be buffer-local. To achieve
  77 ;;   that, just make the `foo--spinner' variable buffer-local and use the
  78 ;;   third argument of the `spinner-create' function. The snippet below is an
  79 ;;   example.
  80 ;;
  81 ;;   ┌────
  82 ;;   │ (defvar-local foo--spinner nil)
  83 ;;   │ (defconst foo--lighter
  84 ;;   │   '(" foo" (:eval (spinner-print foo--spinner))))
  85 ;;   │ (defun foo--start-spinner ()
  86 ;;   │   "Create and start a spinner on this buffer."
  87 ;;   │   (unless foo--spinner
  88 ;;   │     (setq foo--spinner (spinner-create 'moon t)))
  89 ;;   │   (spinner-start foo--spinner))
  90 ;;   └────
  91 ;;
  92 ;;   1. To activate the spinner, just call `(foo--start-spinner)'.
  93 ;;   2. To get rid of it, call `(spinner-stop foo--spinner)'.
  94 ;;
  95 ;;   This will use the `moon' spinner, but you can use any of the names
  96 ;;   defined in the `spinner-types' variable or even define your own.
  97
  98 \f
  99 ;;; Code:
 100 (eval-when-compile
 101   (require 'cl))
 102
 103 (defconst spinner-types
 104   '((3-line-clock . ["┤" "┘" "┴" "└" "├" "┌" "┬" "┐"])
 105     (2-line-clock . ["┘" "└" "┌" "┐"])
 106     (flipping-line . ["_" "\\" "|" "/"])
 107     (rotating-line . ["-" "\\" "|" "/"])
 108     (progress-bar . ["[    ]" "[=   ]" "[==  ]" "[=== ]" "[====]" "[ ===]" "[  ==]" "[   =]"])
 109     (progress-bar-filled . ["|    |" "|█   |" "|██  |" "|███ |" "|████|" "| ███|" "|  ██|" "|   █|"])
 110     (vertical-breathing . ["▁" "▂" "▃" "▄" "▅" "▆" "▇" "█" "▇" "▆" "▅" "▄" "▃" "▂" "▁" " "])
 111     (vertical-rising . ["▁" "▄" "█" "▀" "▔"])
 112     (horizontal-breathing . [" " "▏" "▎" "▍" "▌" "▋" "▊" "▉" "▉" "▊" "▋" "▌" "▍" "▎" "▏"])
 113     (horizontal-breathing-long
 114      . ["  " "▎ " "▌ " "▊ " "█ " "█▎" "█▌" "█▊" "██" "█▊" "█▌" "█▎" "█ " "▊ " "▋ " "▌ " "▍ " "▎ " "▏ "])
 115     (horizontal-moving . ["  " "▌ " "█ " "▐▌" " █" " ▐"])
 116     (minibox . ["▖" "▘" "▝" "▗"])
 117     (triangle . ["◢" "◣" "◤" "◥"])
 118     (box-in-box . ["◰" "◳" "◲" "◱"])
 119     (box-in-circle . ["◴" "◷" "◶" "◵"])
 120     (half-circle . ["◐" "◓" "◑" "◒"])
 121     (moon . ["🌑" "🌘" "🌖" "🌕" "🌔" "🌒"]))
 122   "Predefined alist of spinners.
 123 Each car is a symbol identifying the spinner, and each cdr is a
 124 vector, the spinner itself.")
 125
 126 (defun spinner-make-progress-bar (width &optional char)
 127   "Return a vector of strings of the given WIDTH.
 128 The vector is a valid spinner type and is similar to the
 129 `progress-bar' spinner, except without the sorrounding brackets.
 130 CHAR is the character to use for the moving bar (defaults to =)."
 131   (let ((whole-string (concat (make-string (1- width) ?\s)
 132                               (make-string 4 (or char ?=))
 133                               (make-string width ?\s))))
 134     (thread-last (mapcar (lambda (n) (substring whole-string n (+ n width)))
 135                          (number-sequence (+ width 3) 0 -1))
 136       (apply #'vector))))
 137
 138 (defvar spinner-current nil
 139   "Spinner curently being displayed on the `mode-line-process'.")
 140 (make-variable-buffer-local 'spinner-current)
 141
 142 (defconst spinner--mode-line-construct
 143   '(:eval (spinner-print spinner-current))
 144   "Construct used to display a spinner in `mode-line-process'.")
 145 (put 'spinner--mode-line-construct 'risky-local-variable t)
 146
 147 (defvar spinner-frames-per-second 10
 148   "Default speed at which spinners spin, in frames per second.
 149 Each spinner can override this value.")
 150
 151 \f
 152 ;;; The spinner object.
 153 (defun spinner--type-to-frames (type)
 154   "Return a vector of frames corresponding to TYPE.
 155 The list of possible built-in spinner types is given by the
 156 `spinner-types' variable, but you can also use your own (see
 157 below).
 158
 159 If TYPE is nil, the frames of this spinner are given by the first
 160 element of `spinner-types'.
 161 If TYPE is a symbol, it specifies an element of `spinner-types'.
 162 If TYPE is 'random, use a random element of `spinner-types'.
 163 If TYPE is a list, it should be a list of symbols, and a random
 164 one is chosen as the spinner type.
 165 If TYPE is a vector, it should be a vector of strings and these
 166 are used as the spinner's frames.  This allows you to make your
 167 own spinner animations."
 168   (cond
 169    ((vectorp type) type)
 170    ((not type) (cdr (car spinner-types)))
 171    ((eq type 'random)
 172     (cdr (elt spinner-types
 173               (random (length spinner-types)))))
 174    ((listp type)
 175     (cdr (assq (elt type (random (length type)))
 176                spinner-types)))
 177    ((symbolp type) (cdr (assq type spinner-types)))
 178    (t (error "Unknown spinner type: %s" type))))
 179
 180 (defstruct (spinner
 181             (:copier nil)
 182             (:conc-name spinner--)
 183             (:constructor make-spinner (&optional type buffer-local frames-per-second delay-before-start)))
 184   (frames (spinner--type-to-frames type))
 185   (counter 0)
 186   (fps (or frames-per-second spinner-frames-per-second))
 187   (timer (timer-create) :read-only)
 188   (active-p nil)
 189   (buffer (when buffer-local
 190             (if (bufferp buffer-local)
 191                 buffer-local
 192               (current-buffer))))
 193   (delay (or delay-before-start 0)))
 194
 195 ;;;###autoload
 196 (defun spinner-create (&optional type buffer-local fps delay)
 197   "Create a spinner of the given TYPE.
 198 The possible TYPEs are described in `spinner--type-to-frames'.
 199
 200 FPS, if given, is the number of desired frames per second.
 201 Default is `spinner-frames-per-second'.
 202
 203 If BUFFER-LOCAL is non-nil, the spinner will be automatically
 204 deactivated if the buffer is killed.  If BUFFER-LOCAL is a
 205 buffer, use that instead of current buffer.
 206
 207 When started, in order to function properly, the spinner runs a
 208 timer which periodically calls `force-mode-line-update' in the
 209 curent buffer.  If BUFFER-LOCAL was set at creation time, then
 210 `force-mode-line-update' is called in that buffer instead.  When
 211 the spinner is stopped, the timer is deactivated.
 212
 213 DELAY, if given, is the number of seconds to wait after starting
 214 the spinner before actually displaying it. It is safe to cancel
 215 the spinner before this time, in which case it won't display at
 216 all."
 217   (make-spinner type buffer-local fps delay))
 218
 219 (defun spinner-print (spinner)
 220   "Return a string of the current frame of SPINNER.
 221 If SPINNER is nil, just return nil.
 222 Designed to be used in the mode-line with:
 223     (:eval (spinner-print some-spinner))"
 224   (when (and spinner (spinner--active-p spinner))
 225     (let ((frame (spinner--counter spinner)))
 226       (when (>= frame 0)
 227         (elt (spinner--frames spinner) frame)))))
 228
 229 (defun spinner--timer-function (spinner)
 230   "Function called to update SPINNER.
 231 If SPINNER is no longer active, or if its buffer has been killed,
 232 stop the SPINNER's timer."
 233   (let ((buffer (spinner--buffer spinner)))
 234     (if (or (not (spinner--active-p spinner))
 235             (and buffer (not (buffer-live-p buffer))))
 236         (spinner-stop spinner)
 237       ;; Increment
 238       (callf (lambda (x) (if (< x 0)
 239                         (1+ x)
 240                       (% (1+ x) (length (spinner--frames spinner)))))
 241           (spinner--counter spinner))
 242       ;; Update mode-line.
 243       (if (buffer-live-p buffer)
 244           (with-current-buffer buffer
 245             (force-mode-line-update))
 246         (force-mode-line-update)))))
 247
 248 (defun spinner--start-timer (spinner)
 249   "Start a SPINNER's timer."
 250   (let ((old-timer (spinner--timer spinner)))
 251     (when (timerp old-timer)
 252       (cancel-timer old-timer))
 253
 254     (setf (spinner--active-p spinner) t)
 255
 256     (unless (ignore-errors (> (spinner--fps spinner) 0))
 257       (error "A spinner's FPS must be a positive number"))
 258     (setf (spinner--counter spinner) (round (- (* (or (spinner--delay spinner) 0)
 259                                            (spinner--fps spinner)))))
 260     ;; Create timer.
 261     (let* ((repeat (/ 1.0 (spinner--fps spinner)))
 262            (time (timer-next-integral-multiple-of-time (current-time) repeat))
 263            ;; Create the timer as a lex variable so it can cancel itself.
 264            (timer (spinner--timer spinner)))
 265       (timer-set-time timer time repeat)
 266       (timer-set-function timer #'spinner--timer-function (list spinner))
 267       (timer-activate timer)
 268       ;; Return a stopping function.
 269       (lambda () (spinner-stop spinner)))))
 270
 271 \f
 272 ;;; The main functions
 273 ;;;###autoload
 274 (defun spinner-start (&optional type-or-object fps delay)
 275   "Start a mode-line spinner of given TYPE-OR-OBJECT.
 276 If TYPE-OR-OBJECT is an object created with `make-spinner',
 277 simply activate it.  This method is designed for minor modes, so
 278 they can use the spinner as part of their lighter by doing:
 279     '(:eval (spinner-print THE-SPINNER))
 280 To stop this spinner, call `spinner-stop' on it.
 281
 282 If TYPE-OR-OBJECT is anything else, a buffer-local spinner is
 283 created with this type, and it is displayed in the
 284 `mode-line-process' of the buffer it was created it.  Both
 285 TYPE-OR-OBJECT and FPS are passed to `make-spinner' (which see).
 286 To stop this spinner, call `spinner-stop' in the same buffer.
 287
 288 Either way, the return value is a function which can be called
 289 anywhere to stop this spinner.  You can also call `spinner-stop'
 290 in the same buffer where the spinner was created.
 291
 292 FPS, if given, is the number of desired frames per second.
 293 Default is `spinner-frames-per-second'.
 294
 295 DELAY, if given, is the number of seconds to wait until actually
 296 displaying the spinner. It is safe to cancel the spinner before
 297 this time, in which case it won't display at all."
 298   (unless (spinner-p type-or-object)
 299     ;; Choose type.
 300     (if (spinner-p spinner-current)
 301         (setf (spinner--frames spinner-current) (spinner--type-to-frames type-or-object))
 302       (setq spinner-current (make-spinner type-or-object (current-buffer) fps delay)))
 303     (setq type-or-object spinner-current)
 304     ;; Maybe add to mode-line.
 305     (unless (memq 'spinner--mode-line-construct mode-line-process)
 306       (setq mode-line-process
 307             (list (or mode-line-process "")
 308                   'spinner--mode-line-construct))))
 309
 310   ;; Create timer.
 311   (when fps (setf (spinner--fps type-or-object) fps))
 312   (when delay (setf (spinner--delay type-or-object) delay))
 313   (spinner--start-timer type-or-object))
 314
 315 (defun spinner-start-print (spinner)
 316   "Like `spinner-print', but also start SPINNER if it's not active."
 317   (unless (spinner--active-p spinner)
 318     (spinner-start spinner))
 319   (spinner-print spinner))
 320
 321 (defun spinner-stop (&optional spinner)
 322   "Stop SPINNER, defaulting to the current buffer's spinner.
 323 It is always safe to call this function, even if there is no
 324 active spinner."
 325   (let ((spinner (or spinner spinner-current)))
 326     (when (spinner-p spinner)
 327       (let ((timer (spinner--timer spinner)))
 328         (when (timerp timer)
 329           (cancel-timer timer)))
 330       (setf (spinner--active-p spinner) nil)
 331       (force-mode-line-update))))
 332
 333 (provide 'spinner)
 334
 335 ;;; spinner.el ends here