code.delx.au - gnu-emacs-elpa/blob - packages/swiper/swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (swiper--cleanup)
 109       (ivy-exit-with-action
 110        (lambda (_)
 111          (with-ivy-window
 112            (move-beginning-of-line 1)
 113            (perform-replace from to
 114                             t t nil)))))))
 115
 116 (defvar avy-background)
 117 (defvar avy-all-windows)
 118 (defvar avy-style)
 119 (defvar avy-keys)
 120 (declare-function avy--regex-candidates "ext:avy")
 121 (declare-function avy--process "ext:avy")
 122 (declare-function avy--overlay-post "ext:avy")
 123 (declare-function avy-action-goto "ext:avy")
 124 (declare-function avy--done "ext:avy")
 125 (declare-function avy--make-backgrounds "ext:avy")
 126 (declare-function avy-window-list "ext:avy")
 127 (declare-function avy-read "ext:avy")
 128 (declare-function avy-read-de-bruijn "ext:avy")
 129 (declare-function avy-tree "ext:avy")
 130 (declare-function avy-push-mark "ext:avy")
 131 (declare-function avy--remove-leading-chars "ext:avy")
 132
 133 ;;;###autoload
 134 (defun swiper-avy ()
 135   "Jump to one of the current swiper candidates."
 136   (interactive)
 137   (unless (string= ivy-text "")
 138     (let* ((avy-all-windows nil)
 139            (candidates (append
 140                         (with-ivy-window
 141                           (avy--regex-candidates
 142                            (ivy--regex ivy-text)))
 143                         (save-excursion
 144                           (save-restriction
 145                             (narrow-to-region (window-start) (window-end))
 146                             (goto-char (point-min))
 147                             (forward-line)
 148                             (let ((cands))
 149                               (while (< (point) (point-max))
 150                                 (push (cons (1+ (point))
 151                                             (selected-window))
 152                                       cands)
 153                                 (forward-line))
 154                               cands)))))
 155            (candidate (unwind-protect
 156                           (prog2
 157                               (avy--make-backgrounds
 158                                (append (avy-window-list)
 159                                        (list  (ivy-state-window ivy-last))))
 160                               (if (eq avy-style 'de-bruijn)
 161                                   (avy-read-de-bruijn
 162                                    candidates avy-keys)
 163                                 (avy-read (avy-tree candidates avy-keys)
 164                                           #'avy--overlay-post
 165                                           #'avy--remove-leading-chars))
 166                             (avy-push-mark))
 167                         (avy--done))))
 168       (if (window-minibuffer-p (cdr candidate))
 169           (progn
 170             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 171             (ivy--exhibit)
 172             (ivy-done)
 173             (ivy-call))
 174         (ivy-quit-and-run
 175          (avy-action-goto (caar candidate)))))))
 176
 177 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 178 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 179
 180 ;;;###autoload
 181 (defun swiper-mc ()
 182   (interactive)
 183   (unless (require 'multiple-cursors nil t)
 184     (error "multiple-cursors isn't installed"))
 185   (let ((cands (nreverse ivy--old-cands)))
 186     (unless (string= ivy-text "")
 187       (ivy-exit-with-action
 188        (lambda (_)
 189          (let (cand)
 190            (while (setq cand (pop cands))
 191              (swiper--action cand)
 192              (when cands
 193                (mc/create-fake-cursor-at-point))))
 194          (multiple-cursors-mode 1))))))
 195
 196 (defun swiper-recenter-top-bottom (&optional arg)
 197   "Call (`recenter-top-bottom' ARG)."
 198   (interactive "P")
 199   (with-ivy-window
 200     (recenter-top-bottom arg)))
 201
 202 (defun swiper-font-lock-ensure ()
 203   "Ensure the entired buffer is highlighted."
 204   (unless (or (derived-mode-p 'magit-mode)
 205               (bound-and-true-p magit-blame-mode)
 206               (memq major-mode '(package-menu-mode
 207                                  gnus-summary-mode
 208                                  gnus-article-mode
 209                                  gnus-group-mode
 210                                  emms-playlist-mode
 211                                  emms-stream-mode
 212                                  erc-mode
 213                                  org-agenda-mode
 214                                  dired-mode
 215                                  jabber-chat-mode
 216                                  elfeed-search-mode
 217                                  elfeed-show-mode
 218                                  fundamental-mode
 219                                  Man-mode
 220                                  woman-mode
 221                                  mu4e-view-mode
 222                                  mu4e-headers-mode
 223                                  help-mode
 224                                  debbugs-gnu-mode
 225                                  occur-mode
 226                                  occur-edit-mode
 227                                  bongo-mode
 228                                  eww-mode
 229                                  twittering-mode
 230                                  vc-dir-mode
 231                                  w3m-mode)))
 232     (unless (> (buffer-size) 100000)
 233       (if (fboundp 'font-lock-ensure)
 234           (font-lock-ensure)
 235         (with-no-warnings (font-lock-fontify-buffer))))))
 236
 237 (defvar swiper--format-spec ""
 238   "Store the current candidates format spec.")
 239
 240 (defvar swiper--width nil
 241   "Store the amount of digits needed for the longest line nubmer.")
 242
 243 (defvar swiper-use-visual-line nil
 244   "When non-nil, use `line-move' instead of `forward-line'.")
 245
 246 (declare-function outline-show-all "outline")
 247
 248 (defun swiper--candidates (&optional numbers-width)
 249   "Return a list of this buffer lines.
 250
 251 NUMBERS-WIDTH, when specified, is used for line numbers width
 252 spec, instead of calculating it as the log of the buffer line
 253 count."
 254   (if (and visual-line-mode
 255            ;; super-slow otherwise
 256            (< (buffer-size) 20000))
 257       (progn
 258         (when (eq major-mode 'org-mode)
 259           (require 'outline)
 260           (if (fboundp 'outline-show-all)
 261               (outline-show-all)
 262             (with-no-warnings
 263               (show-all))))
 264         (setq swiper-use-visual-line t))
 265     (setq swiper-use-visual-line nil))
 266   (let ((n-lines (count-lines (point-min) (point-max))))
 267     (unless (zerop n-lines)
 268       (setq swiper--width (or numbers-width
 269                               (1+ (floor (log n-lines 10)))))
 270       (setq swiper--format-spec
 271             (format "%%-%dd " swiper--width))
 272       (let ((line-number 0)
 273             (advancer (if swiper-use-visual-line
 274                           (lambda (arg) (line-move arg t))
 275                         #'forward-line))
 276             candidates)
 277         (save-excursion
 278           (goto-char (point-min))
 279           (swiper-font-lock-ensure)
 280           (while (< (point) (point-max))
 281             (let ((str (concat
 282                         " "
 283                         (replace-regexp-in-string
 284                          "\t" "    "
 285                          (if swiper-use-visual-line
 286                              (buffer-substring
 287                               (save-excursion
 288                                 (beginning-of-visual-line)
 289                                 (point))
 290                               (save-excursion
 291                                 (end-of-visual-line)
 292                                 (point)))
 293                            (buffer-substring
 294                             (point)
 295                             (line-end-position)))))))
 296               (when (eq major-mode 'twittering-mode)
 297                 (remove-text-properties 0 (length str) '(field) str))
 298               (put-text-property 0 1 'display
 299                                  (format swiper--format-spec
 300                                          (cl-incf line-number))
 301                                  str)
 302               (push str candidates))
 303             (funcall advancer 1))
 304           (nreverse candidates))))))
 305
 306 (defvar swiper--opoint 1
 307   "The point when `swiper' starts.")
 308
 309 ;;;###autoload
 310 (defun swiper (&optional initial-input)
 311   "`isearch' with an overview.
 312 When non-nil, INITIAL-INPUT is the initial search pattern."
 313   (interactive)
 314   (swiper--ivy initial-input))
 315
 316 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 317
 318 (defun swiper--init ()
 319   "Perform initialization common to both completion methods."
 320   (setq swiper--opoint (point))
 321   (when (bound-and-true-p evil-jumper-mode)
 322     (evil-jumper--set-jump)))
 323
 324 (defun swiper--re-builder (str)
 325   "Transform STR into a swiper regex.
 326 This is the regex used in the minibuffer, since the candidates
 327 there have line numbers. In the buffer, `ivy--regex' should be used."
 328   (cond
 329     ((equal str "")
 330      "")
 331     ((equal str "^")
 332      (setq ivy--subexps 0)
 333      ".")
 334     ((string-match "^\\^" str)
 335      (setq ivy--old-re "")
 336      (let ((re (ivy--regex-plus (substring str 1))))
 337        (if (zerop ivy--subexps)
 338            (prog1 (format "^ ?\\(%s\\)" re)
 339              (setq ivy--subexps 1))
 340          (format "^ %s" re))))
 341     (t
 342      (ivy--regex-plus str))))
 343
 344 (defvar swiper-history nil
 345   "History for `swiper'.")
 346
 347 (defvar swiper-invocation-face nil
 348   "The face at the point of invocation of `swiper'.")
 349
 350 (defun swiper--ivy (&optional initial-input)
 351   "`isearch' with an overview using `ivy'.
 352 When non-nil, INITIAL-INPUT is the initial search pattern."
 353   (interactive)
 354   (swiper--init)
 355   (setq swiper-invocation-face
 356         (plist-get (text-properties-at (point)) 'face))
 357   (let ((candidates (swiper--candidates))
 358         (preselect
 359          (if swiper-use-visual-line
 360              (count-screen-lines
 361               (point-min)
 362               (save-excursion (beginning-of-visual-line) (point)))
 363            (1- (line-number-at-pos))))
 364         (minibuffer-allow-text-properties t)
 365         res)
 366     (unwind-protect
 367          (setq res
 368                (ivy-read
 369                 "Swiper: "
 370                 candidates
 371                 :initial-input initial-input
 372                 :keymap swiper-map
 373                 :preselect preselect
 374                 :require-match t
 375                 :update-fn #'swiper--update-input-ivy
 376                 :unwind #'swiper--cleanup
 377                 :action #'swiper--action
 378                 :re-builder #'swiper--re-builder
 379                 :history 'swiper-history
 380                 :caller 'swiper))
 381       (unless res
 382         (goto-char swiper--opoint)))))
 383
 384 (defun swiper-toggle-face-matching ()
 385   "Toggle matching only the candidates with `swiper-invocation-face'."
 386   (interactive)
 387   (setf (ivy-state-matcher ivy-last)
 388         (if (ivy-state-matcher ivy-last)
 389             nil
 390           #'swiper--face-matcher))
 391   (setq ivy--old-re nil))
 392
 393 (defun swiper--face-matcher (regexp candidates)
 394   "Return REGEXP-matching CANDIDATES.
 395 Matched candidates should have `swiper-invocation-face'."
 396   (cl-remove-if-not
 397    (lambda (x)
 398      (and
 399       (string-match regexp x)
 400       (let ((s (match-string 0 x))
 401             (i 0))
 402         (while (and (< i (length s))
 403                     (text-property-any
 404                      i (1+ i)
 405                      'face swiper-invocation-face
 406                      s))
 407           (cl-incf i))
 408         (eq i (length s)))))
 409    candidates))
 410
 411 (defun swiper--ensure-visible ()
 412   "Remove overlays hiding point."
 413   (let ((overlays (overlays-at (point)))
 414         ov expose)
 415     (while (setq ov (pop overlays))
 416       (if (and (invisible-p (overlay-get ov 'invisible))
 417                (setq expose (overlay-get ov 'isearch-open-invisible)))
 418           (funcall expose ov)))))
 419
 420 (defvar swiper--overlays nil
 421   "Store overlays.")
 422
 423 (defun swiper--cleanup ()
 424   "Clean up the overlays."
 425   (while swiper--overlays
 426     (delete-overlay (pop swiper--overlays)))
 427   (save-excursion
 428     (goto-char (point-min))
 429     (isearch-clean-overlays)))
 430
 431 (defun swiper--update-input-ivy ()
 432   "Called when `ivy' input is updated."
 433   (with-ivy-window
 434     (swiper--cleanup)
 435     (when (> (length ivy--current) 0)
 436       (let* ((re (funcall ivy--regex-function ivy-text))
 437              (re (if (stringp re) re (caar re)))
 438              (str (get-text-property 0 'display ivy--current))
 439              (num (if (string-match "^[0-9]+" str)
 440                       (string-to-number (match-string 0 str))
 441                     0)))
 442         (unless (eq this-command 'ivy-yank-word)
 443           (goto-char (point-min))
 444           (when (cl-plusp num)
 445             (goto-char (point-min))
 446             (if swiper-use-visual-line
 447                 (line-move (1- num))
 448               (forward-line (1- num)))
 449             (if (and (equal ivy-text "")
 450                      (>= swiper--opoint (line-beginning-position))
 451                      (<= swiper--opoint (line-end-position)))
 452                 (goto-char swiper--opoint)
 453               (re-search-forward re (line-end-position) t))
 454             (isearch-range-invisible (line-beginning-position)
 455                                      (line-end-position))
 456             (unless (and (>= (point) (window-start))
 457                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 458               (recenter))))
 459         (swiper--add-overlays re)))))
 460
 461 (defun swiper--add-overlays (re &optional beg end wnd)
 462   "Add overlays for RE regexp in visible part of the current buffer.
 463 BEG and END, when specified, are the point bounds.
 464 WND, when specified is the window."
 465   (setq wnd (or wnd (ivy-state-window ivy-last)))
 466   (let ((ov (if visual-line-mode
 467                 (make-overlay
 468                  (save-excursion
 469                    (beginning-of-visual-line)
 470                    (point))
 471                  (save-excursion
 472                    (end-of-visual-line)
 473                    (point)))
 474               (make-overlay
 475                (line-beginning-position)
 476                (1+ (line-end-position))))))
 477     (overlay-put ov 'face 'swiper-line-face)
 478     (overlay-put ov 'window wnd)
 479     (push ov swiper--overlays)
 480     (let* ((wh (window-height))
 481            (beg (or beg (save-excursion
 482                           (forward-line (- wh))
 483                           (point))))
 484            (end (or end (save-excursion
 485                           (forward-line wh)
 486                           (point)))))
 487       (when (>= (length re) swiper-min-highlight)
 488         (save-excursion
 489           (goto-char beg)
 490           ;; RE can become an invalid regexp
 491           (while (and (ignore-errors (re-search-forward re end t))
 492                       (> (- (match-end 0) (match-beginning 0)) 0))
 493             (let ((i 0))
 494               (while (<= i ivy--subexps)
 495                 (when (match-beginning i)
 496                   (let ((overlay (make-overlay (match-beginning i)
 497                                                (match-end i)))
 498                         (face
 499                          (cond ((zerop ivy--subexps)
 500                                 (cadr swiper-faces))
 501                                ((zerop i)
 502                                 (car swiper-faces))
 503                                (t
 504                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 505                                      swiper-faces)))))
 506                     (push overlay swiper--overlays)
 507                     (overlay-put overlay 'face face)
 508                     (overlay-put overlay 'window wnd)
 509                     (overlay-put overlay 'priority i)))
 510                 (cl-incf i)))))))))
 511
 512 (defun swiper--action (x)
 513   "Goto line X."
 514   (if (null x)
 515       (user-error "No candidates")
 516     (with-ivy-window
 517       (unless (equal (current-buffer)
 518                      (ivy-state-buffer ivy-last))
 519         (switch-to-buffer (ivy-state-buffer ivy-last)))
 520       (goto-char (point-min))
 521       (funcall (if swiper-use-visual-line
 522                    #'line-move
 523                  #'forward-line)
 524                (1- (read (get-text-property 0 'display x))))
 525       (re-search-forward
 526        (ivy--regex ivy-text) (line-end-position) t)
 527       (swiper--ensure-visible)
 528       (when (/= (point) swiper--opoint)
 529         (unless (and transient-mark-mode mark-active)
 530           (when (eq ivy-exit 'done)
 531             (push-mark swiper--opoint t)
 532             (message "Mark saved where search started")))))))
 533
 534 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 535 (defun swiper-from-isearch ()
 536   "Invoke `swiper' from isearch."
 537   (interactive)
 538   (let ((query (if isearch-regexp
 539                    isearch-string
 540                  (regexp-quote isearch-string))))
 541     (isearch-exit)
 542     (swiper query)))
 543
 544 (defvar swiper-multi-buffers nil
 545   "Store the current list of buffers.")
 546
 547 (defvar swiper-multi-candidates nil
 548   "Store the list of candidates for `swiper-multi'.")
 549
 550 (defun swiper-multi-prompt ()
 551   (format "Buffers (%s): "
 552           (mapconcat #'identity swiper-multi-buffers ", ")))
 553
 554 (defun swiper-multi ()
 555   "Select one or more buffers.
 556 Run `swiper' for those buffers."
 557   (interactive)
 558   (setq swiper-multi-buffers nil)
 559   (ivy-read (swiper-multi-prompt)
 560             'internal-complete-buffer
 561             :action 'swiper-multi-action-1)
 562   (ivy-read "Swiper: " swiper-multi-candidates
 563             :action 'swiper-multi-action-2
 564             :unwind #'swiper--cleanup
 565             :caller 'swiper-multi))
 566
 567 (defun swiper-all ()
 568   "Run `swiper' for all opened buffers."
 569   (interactive)
 570   (ivy-read "Swiper: " (swiper--multi-candidates
 571                         (cl-remove-if-not
 572                          #'buffer-file-name
 573                          (buffer-list)))
 574             :action 'swiper-multi-action-2
 575             :unwind #'swiper--cleanup
 576             :caller 'swiper-multi))
 577
 578 (defun swiper--multi-candidates (buffers)
 579   (let* ((ww (window-width))
 580          (res nil)
 581          (column-2 (apply #'max
 582                           (mapcar
 583                            (lambda (b)
 584                              (length (buffer-name b)))
 585                            buffers)))
 586          (column-1 (- ww 4 column-2 1)))
 587     (dolist (buf buffers)
 588       (with-current-buffer buf
 589         (setq res
 590               (append
 591                (mapcar
 592                 (lambda (s)
 593                   (setq s (concat (ivy--truncate-string s column-1) " "))
 594                   (let ((len (length s)))
 595                     (put-text-property
 596                      (1- len) len 'display
 597                      (concat
 598                       (make-string
 599                        (- ww (string-width s) (length (buffer-name)) 3)
 600                        ?\ )
 601                       (buffer-name))
 602                      s)
 603                     s))
 604                 (swiper--candidates 4))
 605                res))
 606         nil))
 607     res))
 608
 609 (defun swiper-multi-action-1 (x)
 610   (if (member x swiper-multi-buffers)
 611       (progn
 612         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 613     (unless (equal x "")
 614       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 615   (let ((prompt (swiper-multi-prompt)))
 616     (setf (ivy-state-prompt ivy-last) prompt)
 617     (setq ivy--prompt (concat "%-4d " prompt)))
 618   (cond ((memq this-command '(ivy-done
 619                               ivy-alt-done
 620                               ivy-immediate-done))
 621          (setq swiper-multi-candidates
 622                (swiper--multi-candidates
 623                 (mapcar #'get-buffer swiper-multi-buffers))))
 624         ((eq this-command 'ivy-call)
 625          (delete-minibuffer-contents))))
 626
 627 (defun swiper-multi-action-2 (x)
 628   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 629     (with-ivy-window
 630       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 631         (switch-to-buffer (match-string 1 buf-space))
 632         (goto-char (point-min))
 633         (forward-line (1- (read (get-text-property 0 'display x))))
 634         (re-search-forward
 635          (ivy--regex ivy-text)
 636          (line-end-position) t)
 637         (unless (eq ivy-exit 'done)
 638           (swiper--cleanup)
 639           (swiper--add-overlays (ivy--regex ivy-text)))))))
 640
 641 (provide 'swiper)
 642
 643 ;;; swiper.el ends here