code.delx.au - gnu-emacs-elpa/blob - packages/multishell/multishell-list.el

   1 ;;; multishell-list.el --- tabulated-list-mode for multishell shell buffers
   2
   3 ;; Copyright (C) 2016 Free Software Foundation, Inc. and Ken Manheimer
   4
   5 ;; Author: Ken Manheimer <ken.manheimer@gmail.com>
   6 ;; Version: 1.1.2
   7 ;; Created: 2016 -- first public availability
   8 ;; Keywords: processes
   9 ;; URL: https://github.com/kenmanheimer/EmacsMultishell
  10
  11 ;; See multishell.el for commentary, change log, etc.
  12
  13 (require 'tabulated-list)
  14
  15 (defun multishell-list-open-pop ()
  16   "Pop to current entry's shell, and refresh the listing buffer."
  17   (interactive)
  18   (let ((list-buffer (current-buffer)))
  19     (multishell-pop-to-shell nil (tabulated-list-get-id))
  20     (with-current-buffer list-buffer
  21       (revert-buffer))))
  22 (defun multishell-list-open-as-default ()
  23   "Pop to current entry's shell, and set as the default shell."
  24   (interactive)
  25   (let ((list-buffer (current-buffer)))
  26     (message "%s <==" (multishell-name-from-entry (tabulated-list-get-id)))
  27     (multishell-pop-to-shell '(16) (tabulated-list-get-id))
  28     (with-current-buffer list-buffer
  29       (revert-buffer))))
  30 (defun multishell-list-open-here ()
  31   "Switch to current entry's shell buffer."
  32   (interactive)
  33   (let ((list-buffer (current-buffer)))
  34     (multishell-pop-to-shell nil (tabulated-list-get-id) 'here)
  35     (with-current-buffer list-buffer
  36       ;; In case they use switch-to-buffer or whatever to return.
  37       (revert-buffer))))
  38
  39 (defun multishell-list-delete ()
  40   "Remove current shell entry, and prompt for buffer-removal if present.
  41
  42 \(We depend on intrinsic confirmation prompts for active buffers,
  43 supplemented by our own when buffer is inactive.)"
  44   (interactive)
  45   (let* ((entry (tabulated-list-get-id))
  46          (name (multishell-name-from-entry entry))
  47          (name-bracketed (multishell-bracket name))
  48          (buffer (get-buffer name-bracketed)))
  49     (when (multishell-delete-history-name name)
  50       (and buffer
  51            ;; If the process is live, let shell-mode get confirmation:
  52            (or (comint-check-proc (current-buffer))
  53                (y-or-n-p (format "Kill buffer %s? " name-bracketed)))
  54            (kill-buffer name-bracketed)))
  55     (tabulated-list-delete-entry)))
  56
  57 (defun multishell-list-edit-entry ()
  58   "Edit the value of current shell entry."
  59   (interactive)
  60   (let* ((where (save-excursion (beginning-of-line) (point)))
  61          (entry (tabulated-list-get-id))
  62          (name (multishell-name-from-entry entry))
  63          (revised (multishell-read-unbracketed-entry
  64                    (format "Edit shell spec for %s: " name)
  65                    entry
  66                    'no-record))
  67          (revised-name (multishell-name-from-entry revised))
  68          buffer)
  69     (when (not (string= revised entry))
  70       (multishell-replace-entry entry revised)
  71       (when (and (not (string= name revised-name))
  72                  (setq buffer (get-buffer (multishell-bracket name))))
  73         (with-current-buffer buffer
  74           (rename-buffer (multishell-bracket revised-name))))
  75       (revert-buffer)
  76       (goto-char where))))
  77
  78 (defun multishell-list-placeholder (value default)
  79   "Return VALUE if non-empty string, else DEFAULT."
  80   (if (or (not value) (string= value ""))
  81       default
  82     value))
  83 (defconst multishell-list-active-buffer-flag "+")
  84 (defconst multishell-list-inactive-buffer-flag ".")
  85 (defconst multishell-list-absent-buffer-flag "x")
  86
  87 (defun multishell-list-entries ()
  88   "Generate multishell name/path entries list for tabulated-list."
  89   (let ((recency 0))
  90     (mapcar #'(lambda (entry)
  91                 (setq recency (1+ recency))
  92                 (let* ((splat (multishell-split-entry entry))
  93                        (name (car splat))
  94                        (buffer (and name
  95                                     (get-buffer
  96                                      (multishell-bracket name))))
  97                        (status (cond ((not buffer)
  98                                       multishell-list-absent-buffer-flag)
  99                                      ((comint-check-proc buffer)
 100                                       multishell-list-active-buffer-flag)
 101                                      (t multishell-list-inactive-buffer-flag)))
 102                        (rest (cadr splat))
 103                        (path (or (file-remote-p rest 'localname)
 104                                  rest))
 105                        (hops (and (file-remote-p rest 'localname)
 106                                   (substring
 107                                    rest 0 (- (length rest) (length path))))))
 108                   (when (not name)
 109                     (setq name (multishell-name-from-entry entry)))
 110                   (list entry
 111                         (vector (format "%d" recency)
 112                                 status
 113                                 name
 114                                 (multishell-list-placeholder hops "-")
 115                                 (multishell-list-placeholder path "~")))))
 116             (multishell-all-entries))))
 117
 118 (defun compare-strings-as-numbers (a b)
 119   (let ((a (aref (cadr a) 0))
 120         (b (aref (cadr b) 0)))
 121     (> (string-to-number a) (string-to-number b))))
 122
 123 (defvar multishell-list-mode-map
 124   (let ((map (make-sparse-keymap)))
 125     (define-key map (kbd "d") 'multishell-list-delete)
 126     (define-key map (kbd "\C-k") 'multishell-list-delete)
 127     (define-key map (kbd "k") 'multishell-list-delete)
 128     (define-key map (kbd "e") 'multishell-list-edit-entry)
 129     (define-key map (kbd "o") 'multishell-list-open-pop)
 130     (define-key map (kbd " ") 'multishell-list-open-pop)
 131     (define-key map (kbd "O") 'multishell-list-open-as-default)
 132     (define-key map (kbd "RET") 'multishell-list-open-here)
 133     map))
 134 (define-derived-mode multishell-list-mode
 135     tabulated-list-mode "Shells"
 136   "Major mode for listing current and historically registered shells.
 137 \\{multishell-list-mode-map\}"
 138   (setq tabulated-list-format
 139         [;; (name width sort '(:right-align nil :pad-right nil))
 140          ("#" 0 compare-strings-as-numbers :pad-right 1)
 141          ("! " 1 t :pad-right 1)
 142          ("Name" 15 t)
 143          ("Hops" 30 t)
 144          ("Path" 30 t)]
 145         tabulated-list-sort-key '("#" . t)
 146         tabulated-list-entries #'multishell-list-entries)
 147   (tabulated-list-init-header))
 148
 149 ;;;###autoload
 150 (defun multishell-list ()
 151   "Edit your current and historic list of shell buffers.
 152
 153 Hit ? for a list of commands.
 154
 155 You can get to this shell listing manager by
 156 recursively invoking \\[multishell-pop-to-shell] at either of the
 157 `multishell-pop-to-shell' universal argument prompts."
 158   (interactive)
 159   (let ((buffer (get-buffer-create "*Shells*")))
 160     (pop-to-buffer buffer)
 161     (multishell-list-mode)
 162     (tabulated-list-print)))
 163
 164 (provide 'multishell-list)
 165 (require 'multishell)
 166
 167 ;;; multishell-list.el ends here