code.delx.au - gnu-emacs-elpa/blob - company-semantic.el

   1 ;;; company-semantic.el --- company-mode completion back-end using Semantic
   2
   3 ;; Copyright (C) 2009-2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'cl-lib)
  30
  31 (defvar semantic-idle-summary-function)
  32 (declare-function semantic-documentation-for-tag "semantic/doc" )
  33 (declare-function semantic-analyze-current-context "semantic/analyze")
  34 (declare-function semantic-analyze-possible-completions "semantic/complete")
  35 (declare-function semantic-analyze-find-tags-by-prefix "semantic/analyze/fcn")
  36 (declare-function semantic-tag-class "semantic/tag")
  37 (declare-function semantic-tag-name "semantic/tag")
  38 (declare-function semantic-tag-start "semantic/tag")
  39 (declare-function semantic-tag-buffer "semantic/tag")
  40 (declare-function semantic-active-p "semantic")
  41
  42 (defgroup company-semantic nil
  43   "Completion back-end using Semantic."
  44   :group 'company)
  45
  46 (defcustom company-semantic-metadata-function 'company-semantic-summary-and-doc
  47   "The function turning a semantic tag into doc information."
  48   :type 'function)
  49
  50 (defvar company-semantic-modes '(c-mode c++-mode jde-mode java-mode))
  51
  52 (defvar-local company-semantic--current-tags nil
  53   "Tags for the current context.")
  54
  55 (defun company-semantic-documentation-for-tag (tag)
  56   (when (semantic-tag-buffer tag)
  57     ;; When TAG's buffer is unknown, the function below raises an error.
  58     (semantic-documentation-for-tag tag)))
  59
  60 (defun company-semantic-doc-or-summary (tag)
  61   (or (company-semantic-documentation-for-tag tag)
  62       (and (require 'semantic-idle nil t)
  63            (require 'semantic/idle nil t)
  64            (funcall semantic-idle-summary-function tag nil t))))
  65
  66 (defun company-semantic-summary-and-doc (tag)
  67   (let ((doc (company-semantic-documentation-for-tag tag))
  68         (summary (funcall semantic-idle-summary-function tag nil t)))
  69     (and (stringp doc)
  70          (string-match "\n*\\(.*\\)$" doc)
  71          (setq doc (match-string 1 doc)))
  72     (concat summary
  73             (when doc
  74                   (if (< (+ (length doc) (length summary) 4) (window-width))
  75                       " -- "
  76                     "\n"))
  77             doc)))
  78
  79 (defun company-semantic-doc-buffer (tag)
  80   (let ((doc (company-semantic-documentation-for-tag tag)))
  81     (when doc
  82       (company-doc-buffer
  83        (concat (funcall semantic-idle-summary-function tag nil t)
  84                "\n"
  85                doc)))))
  86
  87 (defsubst company-semantic-completions (prefix)
  88   (ignore-errors
  89     (let ((completion-ignore-case nil)
  90           (context (semantic-analyze-current-context)))
  91       (setq company-semantic--current-tags
  92             (semantic-analyze-possible-completions context))
  93       (all-completions prefix company-semantic--current-tags))))
  94
  95 (defun company-semantic-completions-raw (prefix)
  96   (setq company-semantic--current-tags nil)
  97   (dolist (tag (semantic-analyze-find-tags-by-prefix prefix))
  98     (unless (eq (semantic-tag-class tag) 'include)
  99       (push tag company-semantic--current-tags)))
 100   (delete "" (mapcar 'semantic-tag-name company-semantic--current-tags)))
 101
 102 (defun company-semantic--pre-prefix-length (prefix-length)
 103   "Sum up the length of all chained symbols before POS.
 104 Symbols are chained by \".\" or \"->\"."
 105   (save-excursion
 106     (let ((pos (point)))
 107       (goto-char (- (point) prefix-length))
 108       (while (looking-back "->\\|\\.")
 109         (goto-char (match-beginning 0))
 110         (skip-syntax-backward "w_"))
 111       (- pos (point)))))
 112
 113 (defun company-semantic--grab ()
 114   "Grab the semantic prefix, but return everything before -> or . as length."
 115   (let ((symbol (company-grab-symbol)))
 116     (when symbol
 117       (cons symbol (company-semantic--pre-prefix-length (length symbol))))))
 118
 119 ;;;###autoload
 120 (defun company-semantic (command &optional arg &rest ignored)
 121   "`company-mode' completion back-end using CEDET Semantic."
 122   (interactive (list 'interactive))
 123   (cl-case command
 124     (interactive (company-begin-backend 'company-semantic))
 125     (prefix (and (featurep 'semantic)
 126                  (semantic-active-p)
 127                  (memq major-mode company-semantic-modes)
 128                  (not (company-in-string-or-comment))
 129                  (or (company-semantic--grab) 'stop)))
 130     (candidates (if (and (equal arg "")
 131                          (not (looking-back "->\\|\\.")))
 132                     (company-semantic-completions-raw arg)
 133                   (company-semantic-completions arg)))
 134     (meta (funcall company-semantic-metadata-function
 135                    (assoc arg company-semantic--current-tags)))
 136     (doc-buffer (company-semantic-doc-buffer
 137                  (assoc arg company-semantic--current-tags)))
 138     ;; Because "" is an empty context and doesn't return local variables.
 139     (no-cache (equal arg ""))
 140     (location (let ((tag (assoc arg company-semantic--current-tags)))
 141                 (when (buffer-live-p (semantic-tag-buffer tag))
 142                   (cons (semantic-tag-buffer tag)
 143                         (semantic-tag-start tag)))))))
 144
 145 (provide 'company-semantic)
 146 ;;; company-semantic.el ends here