code.delx.au - gnu-emacs-elpa/blob - packages/nameless/nameless.el

   1 ;;; nameless.el --- Hide package namespace in your emacs-lisp code  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; Keywords: convenience, lisp
   7 ;; Version: 0.3.1
   8 ;; Package-Requires: ((emacs "24.4"))
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Usage
  26 ;; ─────
  27 ;;
  28 ;;   To use this package add the following configuration to your Emacs init
  29 ;;   file.
  30 ;;
  31 ;;   ┌────
  32 ;;   │ (add-hook 'emacs-lisp-mode-hook #'nameless-mode)
  33 ;;   └────
  34 ;;
  35 ;;   You can configure a string to use instead of `:' by setting the
  36 ;;   `nameless-prefix', and the name of the face used is `nameless-face'.
  37 ;;
  38 ;;   While the mode is active, the `_' key inserts the package
  39 ;;   namespace if appropriate.
  40
  41 ;;; Code:
  42 (require 'lisp-mnt)
  43
  44 (defgroup nameless nil
  45   "Customization group for nameless."
  46   :group 'emacs)
  47
  48 (defcustom nameless-prefix ":"
  49   "Prefix displayed instead of package namespace."
  50   :type 'string)
  51
  52 (defcustom nameless-global-aliases '(("fl" . "font-lock"))
  53   "Alist from aliases to namespaces.
  54 This alist is used everywhere.  It is designed for namespaces you
  55 use commonly.  To apply aliases specific to a file, set the
  56 `nameless-aliases' variable with `add-file-local-variable'.
  57
  58 Each element of this list should have the form (ALIAS . NAMESPACE),
  59 both strings.  For example, if you set this variable to
  60           ((\"fl\" . \"font-lock\"))
  61 then expressions like `(font-lock-add-keywords nil kwds)' will
  62 displayed as `(fl/add-keywords nil kwds)' instead.
  63
  64 Furthermore typing `fl' followed by `\\[nameless-insert-name]' will
  65 automatically insert `font-lock-'."
  66   :type '(alist string string))
  67
  68 (defvar nameless-aliases nil
  69   "Alist from aliases to namespaces.
  70 This variable takes the same syntax and has the same effect as
  71 `nameless-global-aliases'.  Aliases set here take priority over
  72 those in `nameless-global-aliases'.
  73 This variable is designed to be used as a file-local or dir-local
  74 variable.")
  75
  76 (defface nameless-face
  77   '((t :inherit font-lock-type-face))
  78   "Face used on `nameless-prefix'")
  79
  80 (defcustom nameless-affect-indentation-and-filling 'outside-strings
  81   "If non-nil, code is indented and filled according to what you see.
  82 If nil, code is indented and filled according to its actual content.
  83 If the value is `outside-strings', behave like nil inside strings
  84 and behave like t otherwise.
  85
  86 After changing this variable, you must reenable `nameless-mode'
  87 for it to take effect."
  88   :type '(choice (const :tag "Always affect indentation" t)
  89                  (const :tag "Don't affect indentation" nil)
  90                  (const :tag "Only outside strings" 'outside-strings)))
  91
  92 \f
  93 ;;; Font-locking
  94 (defun nameless--make-composition (s)
  95   "Return a list that composes S if passed to `compose-region'."
  96   (cdr (apply #'append (mapcar (lambda (x) (list '(Br . Bl) x)) s))))
  97
  98 (defvar nameless-mode)
  99 (defun nameless--compose-as (display)
 100   "Compose the matched region and return a face spec."
 101   (when nameless-mode
 102     (let ((compose (save-match-data
 103                      (and nameless-affect-indentation-and-filling
 104                          (or (not (eq nameless-affect-indentation-and-filling 'outside-strings))
 105                              (not (nth 3 (syntax-ppss)))))))
 106           (dis (concat display nameless-prefix)))
 107       (when compose
 108         (compose-region (match-beginning 1)
 109                         (match-end 1)
 110                         (nameless--make-composition dis)))
 111       `(face nameless-face ,@(unless compose (list 'display dis))))))
 112
 113 (defvar-local nameless--font-lock-keywords nil)
 114
 115 (defun nameless--ensure ()
 116   (save-excursion
 117     (font-lock-fontify-region (point-min) (point-max))))
 118
 119 (defun nameless--remove-keywords ()
 120   "Remove font-lock keywords set by `nameless--add-keywords'."
 121   (font-lock-remove-keywords nil nameless--font-lock-keywords)
 122   (setq nameless--font-lock-keywords nil)
 123   (nameless--ensure))
 124
 125 (defun nameless--add-keywords (&rest r)
 126   "Add font-lock keywords displaying REGEXP as DISPLAY.
 127
 128 \(fn (regexp . display) [(regexp . display) ...])"
 129   (setq-local font-lock-extra-managed-props
 130               `(composition display ,@font-lock-extra-managed-props))
 131   (let ((kws (mapcar (lambda (x) `(,(nameless--name-regexp (cdr x)) 1 (nameless--compose-as ,(car x)) prepend)) r)))
 132     (setq nameless--font-lock-keywords kws)
 133     (font-lock-add-keywords nil kws t))
 134   (nameless--ensure))
 135
 136 \f
 137 ;;; Name and regexp
 138 (defvar-local nameless-current-name nil)
 139
 140 (defun nameless--in-arglist-p ()
 141   "Is point inside an arglist?"
 142   (save-excursion
 143     (ignore-errors
 144       (backward-up-list)
 145       (or (progn (forward-sexp -1)
 146                  (looking-at-p "[a-z-]lambda\\_>"))
 147           (progn (forward-sexp -1)
 148                  (looking-at-p "\\(cl-\\)?def\\(un\\|macro\\|inline\\)\\*?\\_>"))))))
 149
 150 (defun nameless-insert-name (&optional noerror)
 151   "Insert `nameless-current-name' or the alias at point.
 152 If point is immediately after an alias configured in
 153 `nameless-aliases' or `nameless-global-aliases', replace it with
 154 the full name for that alias.
 155 Otherwise, insert `nameless-current-name'.
 156
 157 If NOERROR is nil, signal an error if the alias at point is not
 158 configured, or if `nameless-current-name' is nil."
 159   (interactive)
 160   (if (string-match (rx (or (syntax symbol)
 161                             (syntax word)))
 162                     (string (char-before)))
 163       (let* ((r (point))
 164              (l (save-excursion
 165                   (forward-sexp -1)
 166                   (skip-chars-forward "^[:alnum:]")
 167                   (point)))
 168              (alias (buffer-substring l r))
 169              (full-name (when alias
 170                           (cdr (or (assoc alias nameless-aliases)
 171                                    (assoc alias nameless-global-aliases))))))
 172         (if full-name
 173             (progn (delete-region l r)
 174                    (insert full-name "-"))
 175           (unless noerror
 176             (user-error "No name for alias `%s', see `nameless-aliases'" alias))))
 177     (if nameless-current-name
 178         (progn (insert nameless-current-name "-")
 179                t)
 180       (unless noerror
 181         (user-error "No name for current buffer, see `nameless-current-name'")))))
 182
 183 (defun nameless-insert-name-or-self-insert (&optional self-insert)
 184   "Insert the name of current package, with a hyphen."
 185   (interactive "P")
 186   (if (or self-insert
 187           (not nameless-current-name)
 188           (eq (char-before) ?\\)
 189           (nameless--in-arglist-p))
 190       (call-interactively #'self-insert-command)
 191     (or (nameless-insert-name 'noerror)
 192         (call-interactively #'self-insert-command))))
 193
 194 (defun nameless--name-regexp (name)
 195   "Return a regexp of the current name."
 196   (concat "\\_<@?\\(" (regexp-quote name) "-\\)\\(\\s_\\|\\sw\\)"))
 197
 198 (defun nameless--filter-string (s)
 199   "Remove from string S any disply or composition properties.
 200 Return S."
 201   (let ((length (length s)))
 202     (remove-text-properties 0 length '(composition nil display nil) s)
 203     s))
 204
 205 \f
 206 ;;; Minor mode
 207 ;;;###autoload
 208 (define-minor-mode nameless-mode
 209   nil nil " :" '(("_" . nameless-insert-name-or-self-insert))
 210   (if nameless-mode
 211       (if (or nameless-current-name
 212               (ignore-errors (string-match "\\.el\\'" (lm-get-package-name))))
 213           (progn
 214             (unless nameless-current-name
 215               (setq nameless-current-name (replace-regexp-in-string "\\.[^.]*\\'" "" (lm-get-package-name))))
 216             (add-function :filter-return (local 'filter-buffer-substring-function)
 217                           #'nameless--filter-string)
 218             (apply #'nameless--add-keywords
 219                    `((nil . ,nameless-current-name)
 220                      ,@nameless-global-aliases
 221                      ,@nameless-aliases)))
 222         (nameless-mode -1))
 223     (remove-function (local 'filter-buffer-substring-function)
 224                      #'nameless--filter-string)
 225     (setq nameless-current-name nil)
 226     (nameless--remove-keywords)))
 227
 228 (provide 'nameless)
 229 ;;; nameless.el ends here