code.delx.au - gnu-emacs-elpa/blob - company-dabbrev-code.el

   1 ;;; company-dabbrev-code.el --- a dabbrev-like company-mode back-end for code
   2 ;;
   3 ;; Copyright (C) 2009 Nikolaj Schumacher
   4 ;;
   5 ;; This file is part of company 0.3.1.
   6 ;;
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License
   9 ;; as published by the Free Software Foundation; either version 2
  10 ;; of the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (require 'company)
  21 (eval-when-compile (require 'cl))
  22
  23 (defcustom company-dabbrev-code-modes
  24   '(asm-mode batch-file-mode c++-mode c-mode cperl-mode csharp-mode css-mode
  25     emacs-lisp-mode erlang-mode espresso-mode f90-mode fortran-mode
  26     haskell-mode java-mode javascript-mode jde-mode js2-mode lisp-mode
  27     lua-mode objc-mode perl-mode php-mode python-mode ruby-mode scheme-mode
  28     shell-script-mode)
  29   "*Modes that use `company-dabbrev-code'.
  30 In all these modes `company-dabbrev-code' will complete only symbols, not text
  31 in comments or strings.  In other modes `company-dabbrev-code' will pass control
  32 to other back-ends \(e.g. `company-dabbrev'\).
  33 Value t means complete in all modes."
  34   :group 'company
  35   :type '(choice (repeat (symbol :tag "Major mode"))
  36                  (const tag "All modes" t)))
  37
  38 (defcustom company-dabbrev-code-other-buffers t
  39   "*Determines whether `company-dabbrev-code' should search other buffers.
  40 If t, search all buffers with the same major-mode.
  41 See also `company-dabbrev-code-time-limit'."
  42   :group 'company
  43   :type '(choice (const :tag "Off" nil)
  44                  (const :tag "Same major mode" t)))
  45
  46 (defcustom company-dabbrev-code-time-limit .5
  47   "*Determines how long `company-dabbrev-code' should look for matches."
  48   :group 'company
  49   :type '(choice (const :tag "Off" nil)
  50                  (number :tag "Seconds")))
  51
  52 (defmacro company-dabrev-code--time-limit-while (test start limit &rest body)
  53   (declare (indent 3) (debug t))
  54   `(let ((company-time-limit-while-counter 0))
  55      (catch 'done
  56        (while ,test
  57          ,@body
  58          (and ,limit
  59               (eq (incf company-time-limit-while-counter) 25)
  60               (setq company-time-limit-while-counter 0)
  61               (> (float-time (time-since ,start)) ,limit)
  62               (throw 'done 'company-time-out))))))
  63
  64 (defsubst company-dabbrev-code--make-regexp (prefix)
  65   (concat "\\_<" (if (equal prefix "")
  66                      "\\([a-zA-Z]\\|\\s_\\)"
  67                    (regexp-quote prefix))
  68           "\\(\\sw\\|\\s_\\)*\\_>"))
  69
  70 (defun company-dabbrev-code--buffer-symbols (regexp pos &optional symbols
  71                                              start limit)
  72   (save-excursion
  73     (let (match)
  74       (goto-char (if pos (1- pos) (point-min)))
  75       ;; search before pos
  76       (company-dabrev-code--time-limit-while (re-search-backward regexp nil t)
  77           start limit
  78         (setq match (match-string-no-properties 0))
  79         (if (company-in-string-or-comment)
  80             (re-search-backward "\\s<\\|\\s!\\|\\s\"\\|\\s|" nil t)
  81           (push match symbols)))
  82       (goto-char (or pos (point-min)))
  83       ;; search after pos
  84       (company-dabrev-code--time-limit-while (re-search-forward regexp nil t)
  85           start limit
  86         (setq match (match-string-no-properties 0))
  87         (if (company-in-string-or-comment)
  88             (re-search-forward "\\s>\\|\\s!\\|\\s\"" nil t)
  89           (push match symbols)))
  90       symbols)))
  91
  92 (defun company-dabbrev-code--symbols (regexp)
  93   (let* ((start (current-time))
  94          (limit company-dabbrev-code-time-limit)
  95          (symbols (company-dabbrev-code--buffer-symbols regexp (point) nil
  96                                                         start limit)))
  97     (when company-dabbrev-code-other-buffers
  98       (dolist (buffer (delq (current-buffer) (buffer-list)))
  99         (and (eq (buffer-local-value 'major-mode buffer) major-mode)
 100              (with-current-buffer buffer
 101                (setq symbols
 102                      (company-dabbrev-code--buffer-symbols regexp nil symbols
 103                                                            start limit))))
 104         (and limit
 105              (> (float-time (time-since start)) limit)
 106              (return))))
 107     symbols))
 108
 109 ;;;###autoload
 110 (defun company-dabbrev-code (command &optional arg &rest ignored)
 111   "A dabbrev-like `company-mode' back-end for code.
 112 The back-end looks for all symbols in the current buffer that aren't in
 113 comments or strings."
 114   (interactive (list 'interactive))
 115   (case command
 116     ('interactive (company-begin-backend 'company-dabbrev-code))
 117     ('prefix (and (or (eq t company-dabbrev-code-modes)
 118                       (apply 'derived-mode-p company-dabbrev-code-modes))
 119                   (not (company-in-string-or-comment))
 120                   (or (company-grab-symbol) 'stop)))
 121     ('candidates (let ((case-fold-search nil))
 122                    (company-dabbrev-code--symbols
 123                     (company-dabbrev-code--make-regexp arg))))
 124     ('duplicates t)))
 125
 126 (provide 'company-dabbrev-code)
 127 ;;; company-dabbrev-code.el ends here