code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (swiper--cleanup)
 109       (ivy-exit-with-action
 110        (lambda (_)
 111          (with-ivy-window
 112            (move-beginning-of-line 1)
 113            (perform-replace from to
 114                             t t nil)))))))
 115
 116 (defvar avy-background)
 117 (defvar avy-all-windows)
 118 (defvar avy-style)
 119 (defvar avy-keys)
 120 (declare-function avy--regex-candidates "ext:avy")
 121 (declare-function avy--process "ext:avy")
 122 (declare-function avy--overlay-post "ext:avy")
 123 (declare-function avy-action-goto "ext:avy")
 124 (declare-function avy--done "ext:avy")
 125 (declare-function avy--make-backgrounds "ext:avy")
 126 (declare-function avy-window-list "ext:avy")
 127 (declare-function avy-read "ext:avy")
 128 (declare-function avy-read-de-bruijn "ext:avy")
 129 (declare-function avy-tree "ext:avy")
 130 (declare-function avy-push-mark "ext:avy")
 131 (declare-function avy--remove-leading-chars "ext:avy")
 132
 133 ;;;###autoload
 134 (defun swiper-avy ()
 135   "Jump to one of the current swiper candidates."
 136   (interactive)
 137   (unless (string= ivy-text "")
 138     (let* ((avy-all-windows nil)
 139            (candidates (append
 140                         (with-ivy-window
 141                           (avy--regex-candidates
 142                            (ivy--regex ivy-text)))
 143                         (save-excursion
 144                           (save-restriction
 145                             (narrow-to-region (window-start) (window-end))
 146                             (goto-char (point-min))
 147                             (forward-line)
 148                             (let ((cands))
 149                               (while (< (point) (point-max))
 150                                 (push (cons (1+ (point))
 151                                             (selected-window))
 152                                       cands)
 153                                 (forward-line))
 154                               cands)))))
 155            (candidate (unwind-protect
 156                           (prog2
 157                               (avy--make-backgrounds
 158                                (append (avy-window-list)
 159                                        (list  (ivy-state-window ivy-last))))
 160                               (if (eq avy-style 'de-bruijn)
 161                                   (avy-read-de-bruijn
 162                                    candidates avy-keys)
 163                                 (avy-read (avy-tree candidates avy-keys)
 164                                           #'avy--overlay-post
 165                                           #'avy--remove-leading-chars))
 166                             (avy-push-mark))
 167                         (avy--done))))
 168       (if (window-minibuffer-p (cdr candidate))
 169           (progn
 170             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 171             (ivy--exhibit)
 172             (ivy-done)
 173             (ivy-call))
 174         (ivy-quit-and-run
 175          (avy-action-goto (caar candidate)))))))
 176
 177 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 178 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 179
 180 ;;;###autoload
 181 (defun swiper-mc ()
 182   (interactive)
 183   (unless (require 'multiple-cursors nil t)
 184     (error "multiple-cursors isn't installed"))
 185   (let ((cands (nreverse ivy--old-cands)))
 186     (unless (string= ivy-text "")
 187       (ivy-exit-with-action
 188        (lambda (_)
 189          (let (cand)
 190            (while (setq cand (pop cands))
 191              (swiper--action cand)
 192              (when cands
 193                (mc/create-fake-cursor-at-point))))
 194          (multiple-cursors-mode 1))))))
 195
 196 (defun swiper-recenter-top-bottom (&optional arg)
 197   "Call (`recenter-top-bottom' ARG)."
 198   (interactive "P")
 199   (with-ivy-window
 200     (recenter-top-bottom arg)))
 201
 202 (defvar swiper-font-lock-exclude
 203   '(package-menu-mode
 204     gnus-summary-mode
 205     gnus-article-mode
 206     gnus-group-mode
 207     emms-playlist-mode
 208     emms-stream-mode
 209     erc-mode
 210     org-agenda-mode
 211     dired-mode
 212     jabber-chat-mode
 213     elfeed-search-mode
 214     elfeed-show-mode
 215     fundamental-mode
 216     Man-mode
 217     woman-mode
 218     mu4e-view-mode
 219     mu4e-headers-mode
 220     help-mode
 221     debbugs-gnu-mode
 222     occur-mode
 223     occur-edit-mode
 224     bongo-mode
 225     bongo-library-mode
 226     bongo-playlist-mode
 227     eww-mode
 228     twittering-mode
 229     vc-dir-mode
 230     rcirc-mode
 231     sauron-mode
 232     w3m-mode)
 233   "List of major-modes that are incompatible with font-lock-ensure.")
 234
 235 (defun swiper-font-lock-ensure-p ()
 236   "Return non-nil if we should font-lock-ensure."
 237   (or (derived-mode-p 'magit-mode)
 238               (bound-and-true-p magit-blame-mode)
 239               (memq major-mode swiper-font-lock-exclude)))
 240
 241 (defun swiper-font-lock-ensure ()
 242   "Ensure the entired buffer is highlighted."
 243   (unless (swiper-font-lock-ensure-p)
 244     (unless (> (buffer-size) 100000)
 245       (if (fboundp 'font-lock-ensure)
 246           (font-lock-ensure)
 247         (with-no-warnings (font-lock-fontify-buffer))))))
 248
 249 (defvar swiper--format-spec ""
 250   "Store the current candidates format spec.")
 251
 252 (defvar swiper--width nil
 253   "Store the amount of digits needed for the longest line nubmer.")
 254
 255 (defvar swiper-use-visual-line nil
 256   "When non-nil, use `line-move' instead of `forward-line'.")
 257
 258 (declare-function outline-show-all "outline")
 259
 260 (defun swiper--candidates (&optional numbers-width)
 261   "Return a list of this buffer lines.
 262
 263 NUMBERS-WIDTH, when specified, is used for line numbers width
 264 spec, instead of calculating it as the log of the buffer line
 265 count."
 266   (if (and visual-line-mode
 267            ;; super-slow otherwise
 268            (< (buffer-size) 20000))
 269       (progn
 270         (when (eq major-mode 'org-mode)
 271           (require 'outline)
 272           (if (fboundp 'outline-show-all)
 273               (outline-show-all)
 274             (with-no-warnings
 275               (show-all))))
 276         (setq swiper-use-visual-line t))
 277     (setq swiper-use-visual-line nil))
 278   (let ((n-lines (count-lines (point-min) (point-max))))
 279     (unless (zerop n-lines)
 280       (setq swiper--width (or numbers-width
 281                               (1+ (floor (log n-lines 10)))))
 282       (setq swiper--format-spec
 283             (format "%%-%dd " swiper--width))
 284       (let ((line-number 0)
 285             (advancer (if swiper-use-visual-line
 286                           (lambda (arg) (line-move arg t))
 287                         #'forward-line))
 288             candidates)
 289         (save-excursion
 290           (goto-char (point-min))
 291           (swiper-font-lock-ensure)
 292           (while (< (point) (point-max))
 293             (let ((str (concat
 294                         " "
 295                         (replace-regexp-in-string
 296                          "\t" "    "
 297                          (if swiper-use-visual-line
 298                              (buffer-substring
 299                               (save-excursion
 300                                 (beginning-of-visual-line)
 301                                 (point))
 302                               (save-excursion
 303                                 (end-of-visual-line)
 304                                 (point)))
 305                            (buffer-substring
 306                             (point)
 307                             (line-end-position)))))))
 308               (when (eq major-mode 'twittering-mode)
 309                 (remove-text-properties 0 (length str) '(field) str))
 310               (put-text-property 0 1 'display
 311                                  (format swiper--format-spec
 312                                          (cl-incf line-number))
 313                                  str)
 314               (push str candidates))
 315             (funcall advancer 1))
 316           (nreverse candidates))))))
 317
 318 (defvar swiper--opoint 1
 319   "The point when `swiper' starts.")
 320
 321 ;;;###autoload
 322 (defun swiper (&optional initial-input)
 323   "`isearch' with an overview.
 324 When non-nil, INITIAL-INPUT is the initial search pattern."
 325   (interactive)
 326   (swiper--ivy initial-input))
 327
 328 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 329
 330 (defvar swiper--current-line nil)
 331 (defvar swiper--current-match-start nil)
 332
 333 (defun swiper--init ()
 334   "Perform initialization common to both completion methods."
 335   (setq swiper--current-line nil)
 336   (setq swiper--current-match-start nil)
 337   (setq swiper--opoint (point))
 338   (when (bound-and-true-p evil-jumper-mode)
 339     (evil-jumper--set-jump)))
 340
 341 (defun swiper--re-builder (str)
 342   "Transform STR into a swiper regex.
 343 This is the regex used in the minibuffer, since the candidates
 344 there have line numbers. In the buffer, `ivy--regex' should be used."
 345   (cond
 346     ((equal str "")
 347      "")
 348     ((equal str "^")
 349      (setq ivy--subexps 0)
 350      ".")
 351     ((string-match "^\\^" str)
 352      (setq ivy--old-re "")
 353      (let ((re (ivy--regex-plus (substring str 1))))
 354        (if (zerop ivy--subexps)
 355            (prog1 (format "^ ?\\(%s\\)" re)
 356              (setq ivy--subexps 1))
 357          (format "^ %s" re))))
 358     (t
 359      (ivy--regex-plus str))))
 360
 361 (defvar swiper-history nil
 362   "History for `swiper'.")
 363
 364 (defvar swiper-invocation-face nil
 365   "The face at the point of invocation of `swiper'.")
 366
 367 (defun swiper--ivy (&optional initial-input)
 368   "`isearch' with an overview using `ivy'.
 369 When non-nil, INITIAL-INPUT is the initial search pattern."
 370   (interactive)
 371   (swiper--init)
 372   (setq swiper-invocation-face
 373         (plist-get (text-properties-at (point)) 'face))
 374   (let ((candidates (swiper--candidates))
 375         (preselect
 376          (if swiper-use-visual-line
 377              (count-screen-lines
 378               (point-min)
 379               (save-excursion (beginning-of-visual-line) (point)))
 380            (1- (line-number-at-pos))))
 381         (minibuffer-allow-text-properties t)
 382         res)
 383     (unwind-protect
 384          (setq res
 385                (ivy-read
 386                 "Swiper: "
 387                 candidates
 388                 :initial-input initial-input
 389                 :keymap swiper-map
 390                 :preselect preselect
 391                 :require-match t
 392                 :update-fn #'swiper--update-input-ivy
 393                 :unwind #'swiper--cleanup
 394                 :action #'swiper--action
 395                 :re-builder #'swiper--re-builder
 396                 :history 'swiper-history
 397                 :caller 'swiper))
 398       (unless res
 399         (goto-char swiper--opoint)))))
 400
 401 (defun swiper-toggle-face-matching ()
 402   "Toggle matching only the candidates with `swiper-invocation-face'."
 403   (interactive)
 404   (setf (ivy-state-matcher ivy-last)
 405         (if (ivy-state-matcher ivy-last)
 406             nil
 407           #'swiper--face-matcher))
 408   (setq ivy--old-re nil))
 409
 410 (defun swiper--face-matcher (regexp candidates)
 411   "Return REGEXP-matching CANDIDATES.
 412 Matched candidates should have `swiper-invocation-face'."
 413   (cl-remove-if-not
 414    (lambda (x)
 415      (and
 416       (string-match regexp x)
 417       (let ((s (match-string 0 x))
 418             (i 0))
 419         (while (and (< i (length s))
 420                     (text-property-any
 421                      i (1+ i)
 422                      'face swiper-invocation-face
 423                      s))
 424           (cl-incf i))
 425         (eq i (length s)))))
 426    candidates))
 427
 428 (defun swiper--ensure-visible ()
 429   "Remove overlays hiding point."
 430   (let ((overlays (overlays-at (point)))
 431         ov expose)
 432     (while (setq ov (pop overlays))
 433       (if (and (invisible-p (overlay-get ov 'invisible))
 434                (setq expose (overlay-get ov 'isearch-open-invisible)))
 435           (funcall expose ov)))))
 436
 437 (defvar swiper--overlays nil
 438   "Store overlays.")
 439
 440 (defun swiper--cleanup ()
 441   "Clean up the overlays."
 442   (while swiper--overlays
 443     (delete-overlay (pop swiper--overlays)))
 444   (save-excursion
 445     (goto-char (point-min))
 446     (isearch-clean-overlays)))
 447
 448 (defun swiper--update-input-ivy ()
 449   "Called when `ivy' input is updated."
 450   (with-ivy-window
 451     (swiper--cleanup)
 452     (when (> (length ivy--current) 0)
 453       (let* ((re (funcall ivy--regex-function ivy-text))
 454              (re (if (stringp re) re (caar re)))
 455              (str (get-text-property 0 'display ivy--current))
 456              (num (if (string-match "^[0-9]+" str)
 457                       (string-to-number (match-string 0 str))
 458                     0)))
 459         (unless (eq this-command 'ivy-yank-word)
 460           (when (cl-plusp num)
 461             (unless (if swiper--current-line
 462                         (eq swiper--current-line num)
 463                       (eq (line-number-at-pos) num))
 464               (goto-char (point-min))
 465               (if swiper-use-visual-line
 466                   (line-move (1- num))
 467                 (forward-line (1- num))))
 468             (if (and (equal ivy-text "")
 469                      (>= swiper--opoint (line-beginning-position))
 470                      (<= swiper--opoint (line-end-position)))
 471                 (goto-char swiper--opoint)
 472               (if (eq swiper--current-line num)
 473                   (when swiper--current-match-start
 474                     (goto-char swiper--current-match-start))
 475                 (setq swiper--current-line num))
 476               (re-search-forward re (line-end-position) t)
 477               (setq swiper--current-match-start (match-beginning 0)))
 478             (isearch-range-invisible (line-beginning-position)
 479                                      (line-end-position))
 480             (unless (and (>= (point) (window-start))
 481                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 482               (recenter))))
 483         (swiper--add-overlays re)))))
 484
 485 (defun swiper--add-overlays (re &optional beg end wnd)
 486   "Add overlays for RE regexp in visible part of the current buffer.
 487 BEG and END, when specified, are the point bounds.
 488 WND, when specified is the window."
 489   (setq wnd (or wnd (ivy-state-window ivy-last)))
 490   (let ((ov (if visual-line-mode
 491                 (make-overlay
 492                  (save-excursion
 493                    (beginning-of-visual-line)
 494                    (point))
 495                  (save-excursion
 496                    (end-of-visual-line)
 497                    (point)))
 498               (make-overlay
 499                (line-beginning-position)
 500                (1+ (line-end-position))))))
 501     (overlay-put ov 'face 'swiper-line-face)
 502     (overlay-put ov 'window wnd)
 503     (push ov swiper--overlays)
 504     (let* ((wh (window-height))
 505            (beg (or beg (save-excursion
 506                           (forward-line (- wh))
 507                           (point))))
 508            (end (or end (save-excursion
 509                           (forward-line wh)
 510                           (point)))))
 511       (when (>= (length re) swiper-min-highlight)
 512         (save-excursion
 513           (goto-char beg)
 514           ;; RE can become an invalid regexp
 515           (while (and (ignore-errors (re-search-forward re end t))
 516                       (> (- (match-end 0) (match-beginning 0)) 0))
 517             (let ((i 0))
 518               (while (<= i ivy--subexps)
 519                 (when (match-beginning i)
 520                   (let ((overlay (make-overlay (match-beginning i)
 521                                                (match-end i)))
 522                         (face
 523                          (cond ((zerop ivy--subexps)
 524                                 (cadr swiper-faces))
 525                                ((zerop i)
 526                                 (car swiper-faces))
 527                                (t
 528                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 529                                      swiper-faces)))))
 530                     (push overlay swiper--overlays)
 531                     (overlay-put overlay 'face face)
 532                     (overlay-put overlay 'window wnd)
 533                     (overlay-put overlay 'priority i)))
 534                 (cl-incf i)))))))))
 535
 536 (defun swiper--action (x)
 537   "Goto line X."
 538   (if (null x)
 539       (user-error "No candidates")
 540     (with-ivy-window
 541       (unless (equal (current-buffer)
 542                      (ivy-state-buffer ivy-last))
 543         (switch-to-buffer (ivy-state-buffer ivy-last)))
 544       (goto-char (point-min))
 545       (funcall (if swiper-use-visual-line
 546                    #'line-move
 547                  #'forward-line)
 548                (1- (read (get-text-property 0 'display x))))
 549       (re-search-forward
 550        (ivy--regex ivy-text) (line-end-position) t)
 551       (swiper--ensure-visible)
 552       (when (/= (point) swiper--opoint)
 553         (unless (and transient-mark-mode mark-active)
 554           (when (eq ivy-exit 'done)
 555             (push-mark swiper--opoint t)
 556             (message "Mark saved where search started")))))))
 557
 558 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 559 (defun swiper-from-isearch ()
 560   "Invoke `swiper' from isearch."
 561   (interactive)
 562   (let ((query (if isearch-regexp
 563                    isearch-string
 564                  (regexp-quote isearch-string))))
 565     (isearch-exit)
 566     (swiper query)))
 567
 568 (defvar swiper-multi-buffers nil
 569   "Store the current list of buffers.")
 570
 571 (defvar swiper-multi-candidates nil
 572   "Store the list of candidates for `swiper-multi'.")
 573
 574 (defun swiper-multi-prompt ()
 575   (format "Buffers (%s): "
 576           (mapconcat #'identity swiper-multi-buffers ", ")))
 577
 578 (defun swiper-multi ()
 579   "Select one or more buffers.
 580 Run `swiper' for those buffers."
 581   (interactive)
 582   (setq swiper-multi-buffers nil)
 583   (ivy-read (swiper-multi-prompt)
 584             'internal-complete-buffer
 585             :action 'swiper-multi-action-1)
 586   (ivy-read "Swiper: " swiper-multi-candidates
 587             :action 'swiper-multi-action-2
 588             :unwind #'swiper--cleanup
 589             :caller 'swiper-multi))
 590
 591 (defun swiper-all ()
 592   "Run `swiper' for all opened buffers."
 593   (interactive)
 594   (ivy-read "Swiper: " (swiper--multi-candidates
 595                         (cl-remove-if-not
 596                          #'buffer-file-name
 597                          (buffer-list)))
 598             :action 'swiper-multi-action-2
 599             :unwind #'swiper--cleanup
 600             :caller 'swiper-multi))
 601
 602 (defun swiper--multi-candidates (buffers)
 603   (let* ((ww (window-width))
 604          (res nil)
 605          (column-2 (apply #'max
 606                           (mapcar
 607                            (lambda (b)
 608                              (length (buffer-name b)))
 609                            buffers)))
 610          (column-1 (- ww 4 column-2 1)))
 611     (dolist (buf buffers)
 612       (with-current-buffer buf
 613         (setq res
 614               (append
 615                (mapcar
 616                 (lambda (s)
 617                   (setq s (concat (ivy--truncate-string s column-1) " "))
 618                   (let ((len (length s)))
 619                     (put-text-property
 620                      (1- len) len 'display
 621                      (concat
 622                       (make-string
 623                        (- ww (string-width s) (length (buffer-name)) 3)
 624                        ?\ )
 625                       (buffer-name))
 626                      s)
 627                     s))
 628                 (swiper--candidates 4))
 629                res))
 630         nil))
 631     res))
 632
 633 (defun swiper-multi-action-1 (x)
 634   (if (member x swiper-multi-buffers)
 635       (progn
 636         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 637     (unless (equal x "")
 638       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 639   (let ((prompt (swiper-multi-prompt)))
 640     (setf (ivy-state-prompt ivy-last) prompt)
 641     (setq ivy--prompt (concat "%-4d " prompt)))
 642   (cond ((memq this-command '(ivy-done
 643                               ivy-alt-done
 644                               ivy-immediate-done))
 645          (setq swiper-multi-candidates
 646                (swiper--multi-candidates
 647                 (mapcar #'get-buffer swiper-multi-buffers))))
 648         ((eq this-command 'ivy-call)
 649          (delete-minibuffer-contents))))
 650
 651 (defun swiper-multi-action-2 (x)
 652   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 653     (with-ivy-window
 654       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 655         (switch-to-buffer (match-string 1 buf-space))
 656         (goto-char (point-min))
 657         (forward-line (1- (read (get-text-property 0 'display x))))
 658         (re-search-forward
 659          (ivy--regex ivy-text)
 660          (line-end-position) t)
 661         (unless (eq ivy-exit 'done)
 662           (swiper--cleanup)
 663           (swiper--add-overlays (ivy--regex ivy-text)))))))
 664
 665 (provide 'swiper)
 666
 667 ;;; swiper.el ends here