code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (defface swiper-line-face
  65   '((t (:inherit highlight)))
  66   "Face for current `swiper' line.")
  67
  68 (defcustom swiper-faces '(swiper-match-face-1
  69                           swiper-match-face-2
  70                           swiper-match-face-3
  71                           swiper-match-face-4)
  72   "List of `swiper' faces for group matches."
  73   :group 'ivy-faces
  74   :type 'list)
  75
  76 (defcustom swiper-min-highlight 2
  77   "Only highlight matches for regexps at least this long."
  78   :type 'integer)
  79
  80 (defvar swiper-map
  81   (let ((map (make-sparse-keymap)))
  82     (define-key map (kbd "M-q") 'swiper-query-replace)
  83     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  84     (define-key map (kbd "C-'") 'swiper-avy)
  85     (define-key map (kbd "C-7") 'swiper-mc)
  86     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  87     map)
  88   "Keymap for swiper.")
  89
  90 (defun swiper-query-replace ()
  91   "Start `query-replace' with string to replace from last search string."
  92   (interactive)
  93   (if (null (window-minibuffer-p))
  94       (user-error "Should only be called in the minibuffer through `swiper-map'")
  95     (let* ((enable-recursive-minibuffers t)
  96            (from (ivy--regex ivy-text))
  97            (to (query-replace-read-to from "Query replace" t)))
  98       (swiper--cleanup)
  99       (ivy-exit-with-action
 100        (lambda (_)
 101          (with-ivy-window
 102            (move-beginning-of-line 1)
 103            (perform-replace from to
 104                             t t nil)))))))
 105
 106 (defvar avy-background)
 107 (defvar avy-all-windows)
 108 (defvar avy-style)
 109 (defvar avy-keys)
 110 (declare-function avy--regex-candidates "ext:avy")
 111 (declare-function avy--process "ext:avy")
 112 (declare-function avy--overlay-post "ext:avy")
 113 (declare-function avy-action-goto "ext:avy")
 114 (declare-function avy--done "ext:avy")
 115 (declare-function avy--make-backgrounds "ext:avy")
 116 (declare-function avy-window-list "ext:avy")
 117 (declare-function avy-read "ext:avy")
 118 (declare-function avy-read-de-bruijn "ext:avy")
 119 (declare-function avy-tree "ext:avy")
 120 (declare-function avy-push-mark "ext:avy")
 121 (declare-function avy--remove-leading-chars "ext:avy")
 122
 123 ;;;###autoload
 124 (defun swiper-avy ()
 125   "Jump to one of the current swiper candidates."
 126   (interactive)
 127   (unless (string= ivy-text "")
 128     (let* ((avy-all-windows nil)
 129            (candidates (append
 130                         (with-ivy-window
 131                           (avy--regex-candidates
 132                            (ivy--regex ivy-text)))
 133                         (save-excursion
 134                           (save-restriction
 135                             (narrow-to-region (window-start) (window-end))
 136                             (goto-char (point-min))
 137                             (forward-line)
 138                             (let ((cands))
 139                               (while (< (point) (point-max))
 140                                 (push (cons (1+ (point))
 141                                             (selected-window))
 142                                       cands)
 143                                 (forward-line))
 144                               cands)))))
 145            (candidate (unwind-protect
 146                            (prog2
 147                                (avy--make-backgrounds
 148                                 (append (avy-window-list)
 149                                         (list (ivy-state-window ivy-last))))
 150                                (if (eq avy-style 'de-bruijn)
 151                                    (avy-read-de-bruijn
 152                                     candidates avy-keys)
 153                                  (avy-read (avy-tree candidates avy-keys)
 154                                            #'avy--overlay-post
 155                                            #'avy--remove-leading-chars))
 156                              (avy-push-mark))
 157                         (avy--done))))
 158       (if (window-minibuffer-p (cdr candidate))
 159           (progn
 160             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 161             (ivy--exhibit)
 162             (ivy-done)
 163             (ivy-call))
 164         (ivy-quit-and-run
 165          (avy-action-goto (caar candidate)))))))
 166
 167 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 168 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 169
 170 ;;;###autoload
 171 (defun swiper-mc ()
 172   (interactive)
 173   (unless (require 'multiple-cursors nil t)
 174     (error "multiple-cursors isn't installed"))
 175   (let ((cands (nreverse ivy--old-cands)))
 176     (unless (string= ivy-text "")
 177       (ivy-exit-with-action
 178        (lambda (_)
 179          (let (cand)
 180            (while (setq cand (pop cands))
 181              (swiper--action cand)
 182              (when cands
 183                (mc/create-fake-cursor-at-point))))
 184          (multiple-cursors-mode 1))))))
 185
 186 (defun swiper-recenter-top-bottom (&optional arg)
 187   "Call (`recenter-top-bottom' ARG)."
 188   (interactive "P")
 189   (with-ivy-window
 190     (recenter-top-bottom arg)))
 191
 192 (defvar swiper-font-lock-exclude
 193   '(package-menu-mode
 194     gnus-summary-mode
 195     gnus-article-mode
 196     gnus-group-mode
 197     emms-playlist-mode
 198     emms-stream-mode
 199     erc-mode
 200     org-agenda-mode
 201     dired-mode
 202     jabber-chat-mode
 203     elfeed-search-mode
 204     elfeed-show-mode
 205     fundamental-mode
 206     Man-mode
 207     woman-mode
 208     mu4e-view-mode
 209     mu4e-headers-mode
 210     help-mode
 211     debbugs-gnu-mode
 212     occur-mode
 213     occur-edit-mode
 214     bongo-mode
 215     bongo-library-mode
 216     bongo-playlist-mode
 217     eww-mode
 218     twittering-mode
 219     vc-dir-mode
 220     rcirc-mode
 221     sauron-mode
 222     w3m-mode)
 223   "List of major-modes that are incompatible with font-lock-ensure.")
 224
 225 (defun swiper-font-lock-ensure-p ()
 226   "Return non-nil if we should font-lock-ensure."
 227   (or (derived-mode-p 'magit-mode)
 228               (bound-and-true-p magit-blame-mode)
 229               (memq major-mode swiper-font-lock-exclude)))
 230
 231 (defun swiper-font-lock-ensure ()
 232   "Ensure the entired buffer is highlighted."
 233   (unless (swiper-font-lock-ensure-p)
 234     (unless (or (> (buffer-size) 100000) (null font-lock-mode))
 235       (if (fboundp 'font-lock-ensure)
 236           (font-lock-ensure)
 237         (with-no-warnings (font-lock-fontify-buffer))))))
 238
 239 (defvar swiper--format-spec ""
 240   "Store the current candidates format spec.")
 241
 242 (defvar swiper--width nil
 243   "Store the number of digits needed for the longest line nubmer.")
 244
 245 (defvar swiper-use-visual-line nil
 246   "When non-nil, use `line-move' instead of `forward-line'.")
 247
 248 (declare-function outline-show-all "outline")
 249
 250 (defun swiper--candidates (&optional numbers-width)
 251   "Return a list of this buffer lines.
 252
 253 NUMBERS-WIDTH, when specified, is used for width spec of line
 254 numbers; replaces calculating the width from buffer line count."
 255   (if (and visual-line-mode
 256            ;; super-slow otherwise
 257            (< (buffer-size) 20000))
 258       (progn
 259         (when (eq major-mode 'org-mode)
 260           (require 'outline)
 261           (if (fboundp 'outline-show-all)
 262               (outline-show-all)
 263             (with-no-warnings
 264               (show-all))))
 265         (setq swiper-use-visual-line t))
 266     (setq swiper-use-visual-line nil))
 267   (let ((n-lines (count-lines (point-min) (point-max))))
 268     (unless (zerop n-lines)
 269       (setq swiper--width (or numbers-width
 270                               (1+ (floor (log n-lines 10)))))
 271       (setq swiper--format-spec
 272             (format "%%-%dd " swiper--width))
 273       (let ((line-number 0)
 274             (advancer (if swiper-use-visual-line
 275                           (lambda (arg) (line-move arg t))
 276                         #'forward-line))
 277             candidates)
 278         (save-excursion
 279           (goto-char (point-min))
 280           (swiper-font-lock-ensure)
 281           (while (< (point) (point-max))
 282             (let ((str (concat
 283                         " "
 284                         (replace-regexp-in-string
 285                          "\t" "    "
 286                          (if swiper-use-visual-line
 287                              (buffer-substring
 288                               (save-excursion
 289                                 (beginning-of-visual-line)
 290                                 (point))
 291                               (save-excursion
 292                                 (end-of-visual-line)
 293                                 (point)))
 294                            (buffer-substring
 295                             (point)
 296                             (line-end-position)))))))
 297               (when (eq major-mode 'twittering-mode)
 298                 (remove-text-properties 0 (length str) '(field) str))
 299               (put-text-property 0 1 'display
 300                                  (format swiper--format-spec
 301                                          (cl-incf line-number))
 302                                  str)
 303               (push str candidates))
 304             (funcall advancer 1))
 305           (nreverse candidates))))))
 306
 307 (defvar swiper--opoint 1
 308   "The point when `swiper' starts.")
 309
 310 ;;;###autoload
 311 (defun swiper (&optional initial-input)
 312   "`isearch' with an overview.
 313 When non-nil, INITIAL-INPUT is the initial search pattern."
 314   (interactive)
 315   (swiper--ivy (swiper--candidates) initial-input))
 316
 317 (declare-function string-trim-right "subr-x")
 318
 319 (defun swiper-occur (&optional revert)
 320   "Generate a custom occur buffer for `swiper'.
 321 When REVERT is non-nil, regenerate the current *ivy-occur* buffer."
 322   (let* ((buffer (ivy-state-buffer ivy-last))
 323          (fname (propertize
 324                  (with-ivy-window
 325                    (if (buffer-file-name buffer)
 326                        (file-name-nondirectory
 327                         (buffer-file-name buffer))
 328                      (buffer-name buffer)))
 329                  'face
 330                  'compilation-info))
 331          (cands (mapcar
 332                  (lambda (s)
 333                    (format "%s:%s:%s"
 334                            fname
 335                            (propertize
 336                             (string-trim-right
 337                              (get-text-property 0 'display s))
 338                             'face 'compilation-line-number)
 339                            (substring s 1)))
 340                  (if (null revert)
 341                      ivy--old-cands
 342                    (setq ivy--old-re nil)
 343                    (ivy--filter
 344                     (progn (string-match "\"\\(.*\\)\"" (buffer-name))
 345                            (match-string 1 (buffer-name)))
 346                     (with-current-buffer buffer
 347                       (swiper--candidates)))))))
 348     (unless (eq major-mode 'ivy-occur-grep-mode)
 349       (ivy-occur-grep-mode)
 350       (font-lock-mode -1))
 351     (insert (format "-*- mode:grep; default-directory: %S -*-\n\n\n"
 352                     default-directory))
 353     (insert (format "%d candidates:\n" (length cands)))
 354     (ivy--occur-insert-lines
 355      (mapcar
 356       (lambda (cand) (concat "./" cand))
 357       cands))
 358     (goto-char (point-min))
 359     (forward-line 4)))
 360
 361 (ivy-set-occur 'swiper 'swiper-occur)
 362
 363 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 364
 365 (defvar swiper--current-line nil)
 366 (defvar swiper--current-match-start nil)
 367
 368 (defun swiper--init ()
 369   "Perform initialization common to both completion methods."
 370   (setq swiper--current-line nil)
 371   (setq swiper--current-match-start nil)
 372   (setq swiper--opoint (point))
 373   (when (bound-and-true-p evil-jumper-mode)
 374     (evil-jumper--set-jump)))
 375
 376 (defun swiper--re-builder (str)
 377   "Transform STR into a swiper regex.
 378 This is the regex used in the minibuffer where candidates have
 379 line numbers. For the buffer, use `ivy--regex' instead."
 380   (replace-regexp-in-string
 381    "\t" "    "
 382    (cond
 383      ((equal str "")
 384       "")
 385      ((equal str "^")
 386       (setq ivy--subexps 0)
 387       ".")
 388      ((string-match "^\\^" str)
 389       (setq ivy--old-re "")
 390       (let ((re (ivy--regex-plus (substring str 1))))
 391         (if (zerop ivy--subexps)
 392             (prog1 (format "^ ?\\(%s\\)" re)
 393               (setq ivy--subexps 1))
 394           (format "^ %s" re))))
 395      (t
 396       (ivy--regex-plus str)))))
 397
 398 (defvar swiper-history nil
 399   "History for `swiper'.")
 400
 401 (defvar swiper-invocation-face nil
 402   "The face at the point of invocation of `swiper'.")
 403
 404 (defun swiper--ivy (candidates &optional initial-input)
 405   "Select one of CANDIDATES and move there.
 406 When non-nil, INITIAL-INPUT is the initial search pattern."
 407   (interactive)
 408   (swiper--init)
 409   (setq swiper-invocation-face
 410         (plist-get (text-properties-at (point)) 'face))
 411   (let ((preselect
 412          (if swiper-use-visual-line
 413              (count-screen-lines
 414               (point-min)
 415               (save-excursion (beginning-of-visual-line) (point)))
 416            (1- (line-number-at-pos))))
 417         (minibuffer-allow-text-properties t)
 418         res)
 419     (unwind-protect
 420          (and
 421           (setq res
 422                 (ivy-read
 423                  "Swiper: "
 424                  candidates
 425                  :initial-input initial-input
 426                  :keymap swiper-map
 427                  :preselect preselect
 428                  :require-match t
 429                  :update-fn #'swiper--update-input-ivy
 430                  :unwind #'swiper--cleanup
 431                  :action #'swiper--action
 432                  :re-builder #'swiper--re-builder
 433                  :history 'swiper-history
 434                  :caller 'swiper))
 435           (point))
 436       (unless res
 437         (goto-char swiper--opoint)))))
 438
 439 (defun swiper-toggle-face-matching ()
 440   "Toggle matching only the candidates with `swiper-invocation-face'."
 441   (interactive)
 442   (setf (ivy-state-matcher ivy-last)
 443         (if (ivy-state-matcher ivy-last)
 444             nil
 445           #'swiper--face-matcher))
 446   (setq ivy--old-re nil))
 447
 448 (defun swiper--face-matcher (regexp candidates)
 449   "Return REGEXP-matching CANDIDATES.
 450 Matched candidates should have `swiper-invocation-face'."
 451   (cl-remove-if-not
 452    (lambda (x)
 453      (and
 454       (string-match regexp x)
 455       (let ((s (match-string 0 x))
 456             (i 0))
 457         (while (and (< i (length s))
 458                     (text-property-any
 459                      i (1+ i)
 460                      'face swiper-invocation-face
 461                      s))
 462           (cl-incf i))
 463         (eq i (length s)))))
 464    candidates))
 465
 466 (defun swiper--ensure-visible ()
 467   "Remove overlays hiding point."
 468   (let ((overlays (overlays-at (1- (point))))
 469         ov expose)
 470     (while (setq ov (pop overlays))
 471       (if (and (invisible-p (overlay-get ov 'invisible))
 472                (setq expose (overlay-get ov 'isearch-open-invisible)))
 473           (funcall expose ov)))))
 474
 475 (defvar swiper--overlays nil
 476   "Store overlays.")
 477
 478 (defun swiper--cleanup ()
 479   "Clean up the overlays."
 480   (while swiper--overlays
 481     (delete-overlay (pop swiper--overlays)))
 482   (save-excursion
 483     (goto-char (point-min))
 484     (isearch-clean-overlays)))
 485
 486 (defun swiper--update-input-ivy ()
 487   "Called when `ivy' input is updated."
 488   (with-ivy-window
 489     (swiper--cleanup)
 490     (when (> (length ivy--current) 0)
 491       (let* ((re (replace-regexp-in-string
 492                   "    " "\t"
 493                   (funcall ivy--regex-function ivy-text)))
 494              (re (if (stringp re) re (caar re)))
 495              (str (get-text-property 0 'display ivy--current))
 496              (num (if (string-match "^[0-9]+" str)
 497                       (string-to-number (match-string 0 str))
 498                     0)))
 499         (unless (eq this-command 'ivy-yank-word)
 500           (when (cl-plusp num)
 501             (unless (if swiper--current-line
 502                         (eq swiper--current-line num)
 503                       (eq (line-number-at-pos) num))
 504               (goto-char (point-min))
 505               (if swiper-use-visual-line
 506                   (line-move (1- num))
 507                 (forward-line (1- num))))
 508             (if (and (equal ivy-text "")
 509                      (>= swiper--opoint (line-beginning-position))
 510                      (<= swiper--opoint (line-end-position)))
 511                 (goto-char swiper--opoint)
 512               (if (eq swiper--current-line num)
 513                   (when swiper--current-match-start
 514                     (goto-char swiper--current-match-start))
 515                 (setq swiper--current-line num))
 516               (when (re-search-forward re (line-end-position) t)
 517                 (setq swiper--current-match-start (match-beginning 0))))
 518             (isearch-range-invisible (line-beginning-position)
 519                                      (line-end-position))
 520             (unless (and (>= (point) (window-start))
 521                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 522               (recenter))))
 523         (swiper--add-overlays re)))))
 524
 525 (defun swiper--add-overlays (re &optional beg end wnd)
 526   "Add overlays for RE regexp in visible part of the current buffer.
 527 BEG and END, when specified, are the point bounds.
 528 WND, when specified is the window."
 529   (setq wnd (or wnd (ivy-state-window ivy-last)))
 530   (let ((ov (if visual-line-mode
 531                 (make-overlay
 532                  (save-excursion
 533                    (beginning-of-visual-line)
 534                    (point))
 535                  (save-excursion
 536                    (end-of-visual-line)
 537                    (point)))
 538               (make-overlay
 539                (line-beginning-position)
 540                (1+ (line-end-position))))))
 541     (overlay-put ov 'face 'swiper-line-face)
 542     (overlay-put ov 'window wnd)
 543     (push ov swiper--overlays)
 544     (let* ((wh (window-height))
 545            (beg (or beg (save-excursion
 546                           (forward-line (- wh))
 547                           (point))))
 548            (end (or end (save-excursion
 549                           (forward-line wh)
 550                           (point)))))
 551       (when (>= (length re) swiper-min-highlight)
 552         (save-excursion
 553           (goto-char beg)
 554           ;; RE can become an invalid regexp
 555           (while (and (ignore-errors (re-search-forward re end t))
 556                       (> (- (match-end 0) (match-beginning 0)) 0))
 557             (let ((i 0))
 558               (while (<= i ivy--subexps)
 559                 (when (match-beginning i)
 560                   (let ((overlay (make-overlay (match-beginning i)
 561                                                (match-end i)))
 562                         (face
 563                          (cond ((zerop ivy--subexps)
 564                                 (cadr swiper-faces))
 565                                ((zerop i)
 566                                 (car swiper-faces))
 567                                (t
 568                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 569                                      swiper-faces)))))
 570                     (push overlay swiper--overlays)
 571                     (overlay-put overlay 'face face)
 572                     (overlay-put overlay 'window wnd)
 573                     (overlay-put overlay 'priority i)))
 574                 (cl-incf i)))))))))
 575
 576 (defun swiper--action (x)
 577   "Goto line X."
 578   (let ((ln (1- (read (or (get-text-property 0 'display x)
 579                           (and (string-match ":\\([0-9]+\\):.*\\'" x)
 580                                (match-string-no-properties 1 x))))))
 581         (re (ivy--regex ivy-text)))
 582     (if (null x)
 583         (user-error "No candidates")
 584       (with-ivy-window
 585         (unless (equal (current-buffer)
 586                        (ivy-state-buffer ivy-last))
 587           (switch-to-buffer (ivy-state-buffer ivy-last)))
 588         (goto-char (point-min))
 589         (funcall (if swiper-use-visual-line
 590                      #'line-move
 591                    #'forward-line)
 592                  ln)
 593         (re-search-forward re (line-end-position) t)
 594         (swiper--ensure-visible)
 595         (when (/= (point) swiper--opoint)
 596           (unless (and transient-mark-mode mark-active)
 597             (when (eq ivy-exit 'done)
 598               (push-mark swiper--opoint t)
 599               (message "Mark saved where search started"))))
 600         (add-to-history
 601          'regexp-search-ring
 602          re
 603          regexp-search-ring-max)))))
 604
 605 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 606 (defun swiper-from-isearch ()
 607   "Invoke `swiper' from isearch."
 608   (interactive)
 609   (let ((query (if isearch-regexp
 610                    isearch-string
 611                  (regexp-quote isearch-string))))
 612     (isearch-exit)
 613     (swiper query)))
 614
 615 (defvar swiper-multi-buffers nil
 616   "Store the current list of buffers.")
 617
 618 (defvar swiper-multi-candidates nil
 619   "Store the list of candidates for `swiper-multi'.")
 620
 621 (defun swiper-multi-prompt ()
 622   (format "Buffers (%s): "
 623           (mapconcat #'identity swiper-multi-buffers ", ")))
 624
 625 (defun swiper-multi ()
 626   "Select one or more buffers.
 627 Run `swiper' for those buffers."
 628   (interactive)
 629   (setq swiper-multi-buffers nil)
 630   (ivy-read (swiper-multi-prompt)
 631             'internal-complete-buffer
 632             :action 'swiper-multi-action-1)
 633   (ivy-read "Swiper: " swiper-multi-candidates
 634             :action 'swiper-multi-action-2
 635             :unwind #'swiper--cleanup
 636             :caller 'swiper-multi))
 637
 638 (defun swiper-all ()
 639   "Run `swiper' for all opened buffers."
 640   (interactive)
 641   (ivy-read "Swiper: " (swiper--multi-candidates
 642                         (cl-remove-if-not
 643                          #'buffer-file-name
 644                          (buffer-list)))
 645             :action 'swiper-multi-action-2
 646             :unwind #'swiper--cleanup
 647             :update-fn (lambda ()
 648                          (swiper-multi-action-2 ivy--current))
 649             :caller 'swiper-multi))
 650
 651 (defun swiper--multi-candidates (buffers)
 652   (let* ((ww (window-width))
 653          (res nil)
 654          (column-2 (apply #'max
 655                           (mapcar
 656                            (lambda (b)
 657                              (length (buffer-name b)))
 658                            buffers)))
 659          (column-1 (- ww 4 column-2 1)))
 660     (dolist (buf buffers)
 661       (with-current-buffer buf
 662         (setq res
 663               (append
 664                (mapcar
 665                 (lambda (s)
 666                   (setq s (concat (ivy--truncate-string s column-1) " "))
 667                   (let ((len (length s)))
 668                     (put-text-property
 669                      (1- len) len 'display
 670                      (concat
 671                       (make-string
 672                        (- ww (string-width s) (length (buffer-name)) 3)
 673                        ?\ )
 674                       (buffer-name))
 675                      s)
 676                     s))
 677                 (swiper--candidates 4))
 678                res))
 679         nil))
 680     res))
 681
 682 (defun swiper-multi-action-1 (x)
 683   (if (member x swiper-multi-buffers)
 684       (progn
 685         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 686     (unless (equal x "")
 687       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 688   (let ((prompt (swiper-multi-prompt)))
 689     (setf (ivy-state-prompt ivy-last) prompt)
 690     (setq ivy--prompt (concat "%-4d " prompt)))
 691   (cond ((memq this-command '(ivy-done
 692                               ivy-alt-done
 693                               ivy-immediate-done))
 694          (setq swiper-multi-candidates
 695                (swiper--multi-candidates
 696                 (mapcar #'get-buffer swiper-multi-buffers))))
 697         ((eq this-command 'ivy-call)
 698          (delete-minibuffer-contents))))
 699
 700 (defun swiper-multi-action-2 (x)
 701   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 702     (with-ivy-window
 703       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 704         (switch-to-buffer (match-string 1 buf-space))
 705         (goto-char (point-min))
 706         (forward-line (1- (read (get-text-property 0 'display x))))
 707         (re-search-forward
 708          (ivy--regex ivy-text)
 709          (line-end-position) t)
 710         (unless (eq ivy-exit 'done)
 711           (swiper--cleanup)
 712           (swiper--add-overlays (ivy--regex ivy-text)))))))
 713
 714 (provide 'swiper)
 715
 716 ;;; swiper.el ends here