code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.6.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (delete-minibuffer-contents)
 109       (ivy-set-action (lambda (_)
 110                         (with-ivy-window
 111                           (move-beginning-of-line 1)
 112                           (perform-replace from to
 113                                            t t nil))))
 114       (swiper--cleanup)
 115       (exit-minibuffer))))
 116
 117 (defvar avy-background)
 118 (defvar avy-all-windows)
 119 (defvar avy-style)
 120 (defvar avy-keys)
 121 (declare-function avy--regex-candidates "ext:avy")
 122 (declare-function avy--process "ext:avy")
 123 (declare-function avy--overlay-post "ext:avy")
 124 (declare-function avy-action-goto "ext:avy")
 125 (declare-function avy--done "ext:avy")
 126 (declare-function avy--make-backgrounds "ext:avy")
 127 (declare-function avy-window-list "ext:avy")
 128 (declare-function avy-read "ext:avy")
 129 (declare-function avy-read-de-bruijn "ext:avy")
 130 (declare-function avy-tree "ext:avy")
 131 (declare-function avy-push-mark "ext:avy")
 132 (declare-function avy--remove-leading-chars "ext:avy")
 133
 134 ;;;###autoload
 135 (defun swiper-avy ()
 136   "Jump to one of the current swiper candidates."
 137   (interactive)
 138   (unless (string= ivy-text "")
 139     (let* ((avy-all-windows nil)
 140            (candidates (append
 141                         (with-ivy-window
 142                           (avy--regex-candidates
 143                            (ivy--regex ivy-text)))
 144                         (save-excursion
 145                           (save-restriction
 146                             (narrow-to-region (window-start) (window-end))
 147                             (goto-char (point-min))
 148                             (forward-line)
 149                             (let ((cands))
 150                               (while (< (point) (point-max))
 151                                 (push (cons (1+ (point))
 152                                             (selected-window))
 153                                       cands)
 154                                 (forward-line))
 155                               cands)))))
 156            (candidate (unwind-protect
 157                           (prog2
 158                               (avy--make-backgrounds
 159                                (append (avy-window-list)
 160                                        (list  (ivy-state-window ivy-last))))
 161                               (if (eq avy-style 'de-bruijn)
 162                                   (avy-read-de-bruijn
 163                                    candidates avy-keys)
 164                                 (avy-read (avy-tree candidates avy-keys)
 165                                           #'avy--overlay-post
 166                                           #'avy--remove-leading-chars))
 167                             (avy-push-mark))
 168                         (avy--done))))
 169       (if (window-minibuffer-p (cdr candidate))
 170           (progn
 171             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 172             (ivy--exhibit)
 173             (ivy-done)
 174             (ivy-call))
 175         (ivy-quit-and-run
 176          (avy-action-goto (caar candidate)))))))
 177
 178 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 179 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 180
 181 ;;;###autoload
 182 (defun swiper-mc ()
 183   (interactive)
 184   (unless (require 'multiple-cursors nil t)
 185     (error "multiple-cursors isn't installed"))
 186   (let ((cands (nreverse ivy--old-cands)))
 187     (unless (string= ivy-text "")
 188       (ivy-set-action
 189        (lambda (_)
 190          (let (cand)
 191            (while (setq cand (pop cands))
 192              (swiper--action cand)
 193              (when cands
 194                (mc/create-fake-cursor-at-point))))
 195          (multiple-cursors-mode 1)))
 196       (setq ivy-exit 'done)
 197       (exit-minibuffer))))
 198
 199 (defun swiper-recenter-top-bottom (&optional arg)
 200   "Call (`recenter-top-bottom' ARG)."
 201   (interactive "P")
 202   (with-ivy-window
 203     (recenter-top-bottom arg)))
 204
 205 (defun swiper-font-lock-ensure ()
 206   "Ensure the entired buffer is highlighted."
 207   (unless (or (derived-mode-p 'magit-mode)
 208               (bound-and-true-p magit-blame-mode)
 209               (memq major-mode '(package-menu-mode
 210                                  gnus-summary-mode
 211                                  gnus-article-mode
 212                                  gnus-group-mode
 213                                  emms-playlist-mode
 214                                  emms-stream-mode
 215                                  erc-mode
 216                                  org-agenda-mode
 217                                  dired-mode
 218                                  jabber-chat-mode
 219                                  elfeed-search-mode
 220                                  elfeed-show-mode
 221                                  fundamental-mode
 222                                  Man-mode
 223                                  woman-mode
 224                                  mu4e-view-mode
 225                                  mu4e-headers-mode
 226                                  help-mode
 227                                  debbugs-gnu-mode
 228                                  occur-mode
 229                                  occur-edit-mode
 230                                  bongo-mode
 231                                  eww-mode
 232                                  w3m-mode)))
 233     (unless (> (buffer-size) 100000)
 234       (if (fboundp 'font-lock-ensure)
 235           (font-lock-ensure)
 236         (with-no-warnings (font-lock-fontify-buffer))))))
 237
 238 (defvar swiper--format-spec ""
 239   "Store the current candidates format spec.")
 240
 241 (defvar swiper--width nil
 242   "Store the amount of digits needed for the longest line nubmer.")
 243
 244 (defvar swiper-use-visual-line nil
 245   "When non-nil, use `line-move' instead of `forward-line'.")
 246
 247 (defun swiper--candidates (&optional numbers-width)
 248   "Return a list of this buffer lines.
 249
 250 NUMBERS-WIDTH, when specified, is used for line numbers width
 251 spec, instead of calculating it as the log of the buffer line
 252 count."
 253   (setq swiper-use-visual-line
 254         (and (not (eq major-mode 'org-mode))
 255              visual-line-mode
 256              (< (buffer-size) 20000)))
 257   (let ((n-lines (count-lines (point-min) (point-max))))
 258     (unless (zerop n-lines)
 259       (setq swiper--width (or numbers-width
 260                               (1+ (floor (log n-lines 10)))))
 261       (setq swiper--format-spec
 262             (format "%%-%dd " swiper--width))
 263       (let ((line-number 0)
 264             (advancer (if swiper-use-visual-line
 265                           (lambda (arg) (line-move arg t))
 266                         #'forward-line))
 267             candidates)
 268         (save-excursion
 269           (goto-char (point-min))
 270           (swiper-font-lock-ensure)
 271           (while (< (point) (point-max))
 272             (let ((str (concat
 273                         " "
 274                         (replace-regexp-in-string
 275                          "\t" "    "
 276                          (buffer-substring
 277                           (point)
 278                           (if swiper-use-visual-line
 279                               (save-excursion
 280                                 (end-of-visual-line)
 281                                 (point))
 282                             (line-end-position)))))))
 283               (put-text-property 0 1 'display
 284                                  (format swiper--format-spec
 285                                          (cl-incf line-number))
 286                                  str)
 287               (push str candidates))
 288             (funcall advancer 1))
 289           (nreverse candidates))))))
 290
 291 (defvar swiper--opoint 1
 292   "The point when `swiper' starts.")
 293
 294 ;;;###autoload
 295 (defun swiper (&optional initial-input)
 296   "`isearch' with an overview.
 297 When non-nil, INITIAL-INPUT is the initial search pattern."
 298   (interactive)
 299   (swiper--ivy initial-input))
 300
 301 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 302
 303 (defun swiper--init ()
 304   "Perform initialization common to both completion methods."
 305   (setq swiper--opoint (point))
 306   (when (bound-and-true-p evil-jumper-mode)
 307     (evil-jumper--set-jump)))
 308
 309 (defun swiper--re-builder (str)
 310   "Transform STR into a swiper regex.
 311 This is the regex used in the minibuffer, since the candidates
 312 there have line numbers. In the buffer, `ivy--regex' should be used."
 313   (cond
 314     ((equal str "")
 315      "")
 316     ((equal str "^")
 317      (setq ivy--subexps 0)
 318      ".")
 319     ((string-match "^\\^" str)
 320      (setq ivy--old-re "")
 321      (let ((re (ivy--regex-plus (substring str 1))))
 322        (if (zerop ivy--subexps)
 323            (prog1 (format "^ ?\\(%s\\)" re)
 324              (setq ivy--subexps 1))
 325          (format "^ %s" re))))
 326     (t
 327      (ivy--regex-plus str))))
 328
 329 (defvar swiper-history nil
 330   "History for `swiper'.")
 331
 332 (defvar swiper-invocation-face nil
 333   "The face at the point of invocation of `swiper'.")
 334
 335 (defun swiper--ivy (&optional initial-input)
 336   "`isearch' with an overview using `ivy'.
 337 When non-nil, INITIAL-INPUT is the initial search pattern."
 338   (interactive)
 339   (swiper--init)
 340   (setq swiper-invocation-face
 341         (plist-get (text-properties-at (point)) 'face))
 342   (let ((candidates (swiper--candidates))
 343         (preselect
 344          (if (bound-and-true-p visual-line-mode)
 345              (concat " " (buffer-substring-no-properties
 346                           (line-beginning-position)
 347                           (line-end-position)))
 348            (1- (line-number-at-pos))))
 349         (minibuffer-allow-text-properties t))
 350     (unwind-protect
 351          (ivy-read
 352           "Swiper: "
 353           candidates
 354           :initial-input initial-input
 355           :keymap swiper-map
 356           :preselect preselect
 357           :require-match t
 358           :update-fn #'swiper--update-input-ivy
 359           :unwind #'swiper--cleanup
 360           :action #'swiper--action
 361           :re-builder #'swiper--re-builder
 362           :history 'swiper-history
 363           :caller 'swiper)
 364       (when (null ivy-exit)
 365         (goto-char swiper--opoint)))))
 366
 367 (defun swiper-toggle-face-matching ()
 368   "Toggle matching only the candidates with `swiper-invocation-face'."
 369   (interactive)
 370   (setf (ivy-state-matcher ivy-last)
 371         (if (ivy-state-matcher ivy-last)
 372             nil
 373           #'swiper--face-matcher))
 374   (setq ivy--old-re nil))
 375
 376 (defun swiper--face-matcher (regexp candidates)
 377   "Return REGEXP-matching CANDIDATES.
 378 Matched candidates should have `swiper-invocation-face'."
 379   (cl-remove-if-not
 380    (lambda (x)
 381      (and
 382       (string-match regexp x)
 383       (let ((s (match-string 0 x))
 384             (i 0))
 385         (while (and (< i (length s))
 386                     (text-property-any
 387                      i (1+ i)
 388                      'face swiper-invocation-face
 389                      s))
 390           (cl-incf i))
 391         (eq i (length s)))))
 392    candidates))
 393
 394 (defun swiper--ensure-visible ()
 395   "Remove overlays hiding point."
 396   (let ((overlays (overlays-at (point)))
 397         ov expose)
 398     (while (setq ov (pop overlays))
 399       (if (and (invisible-p (overlay-get ov 'invisible))
 400                (setq expose (overlay-get ov 'isearch-open-invisible)))
 401           (funcall expose ov)))))
 402
 403 (defvar swiper--overlays nil
 404   "Store overlays.")
 405
 406 (defun swiper--cleanup ()
 407   "Clean up the overlays."
 408   (while swiper--overlays
 409     (delete-overlay (pop swiper--overlays)))
 410   (save-excursion
 411     (goto-char (point-min))
 412     (isearch-clean-overlays)))
 413
 414 (defun swiper--update-input-ivy ()
 415   "Called when `ivy' input is updated."
 416   (with-ivy-window
 417     (swiper--cleanup)
 418     (when (> (length ivy--current) 0)
 419       (let* ((re (funcall ivy--regex-function ivy-text))
 420              (re (if (stringp re) re (caar re)))
 421              (str (get-text-property 0 'display ivy--current))
 422              (num (if (string-match "^[0-9]+" str)
 423                       (string-to-number (match-string 0 str))
 424                     0)))
 425         (goto-char (point-min))
 426         (when (cl-plusp num)
 427           (goto-char (point-min))
 428           (if swiper-use-visual-line
 429               (line-move (1- num))
 430             (forward-line (1- num)))
 431           (if (and (equal ivy-text "")
 432                    (>= swiper--opoint (line-beginning-position))
 433                    (<= swiper--opoint (line-end-position)))
 434               (goto-char swiper--opoint)
 435             (re-search-forward re (line-end-position) t))
 436           (isearch-range-invisible (line-beginning-position)
 437                                    (line-end-position))
 438           (unless (and (>= (point) (window-start))
 439                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 440             (recenter)))
 441         (swiper--add-overlays re)))))
 442
 443 (defun swiper--add-overlays (re &optional beg end wnd)
 444   "Add overlays for RE regexp in visible part of the current buffer.
 445 BEG and END, when specified, are the point bounds.
 446 WND, when specified is the window."
 447   (setq wnd (or wnd (ivy-state-window ivy-last)))
 448   (let ((ov (if visual-line-mode
 449                 (make-overlay
 450                  (save-excursion
 451                    (beginning-of-visual-line)
 452                    (point))
 453                  (save-excursion
 454                    (end-of-visual-line)
 455                    (point)))
 456               (make-overlay
 457                (line-beginning-position)
 458                (1+ (line-end-position))))))
 459     (overlay-put ov 'face 'swiper-line-face)
 460     (overlay-put ov 'window wnd)
 461     (push ov swiper--overlays)
 462     (let* ((wh (window-height))
 463            (beg (or beg (save-excursion
 464                           (forward-line (- wh))
 465                           (point))))
 466            (end (or end (save-excursion
 467                           (forward-line wh)
 468                           (point)))))
 469       (when (>= (length re) swiper-min-highlight)
 470         (save-excursion
 471           (goto-char beg)
 472           ;; RE can become an invalid regexp
 473           (while (and (ignore-errors (re-search-forward re end t))
 474                       (> (- (match-end 0) (match-beginning 0)) 0))
 475             (let ((i 0))
 476               (while (<= i ivy--subexps)
 477                 (when (match-beginning i)
 478                   (let ((overlay (make-overlay (match-beginning i)
 479                                                (match-end i)))
 480                         (face
 481                          (cond ((zerop ivy--subexps)
 482                                 (cadr swiper-faces))
 483                                ((zerop i)
 484                                 (car swiper-faces))
 485                                (t
 486                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 487                                      swiper-faces)))))
 488                     (push overlay swiper--overlays)
 489                     (overlay-put overlay 'face face)
 490                     (overlay-put overlay 'window wnd)
 491                     (overlay-put overlay 'priority i)))
 492                 (cl-incf i)))))))))
 493
 494 (defun swiper--action (x)
 495   "Goto line X."
 496   (if (null x)
 497       (user-error "No candidates")
 498     (with-ivy-window
 499       (unless (equal (current-buffer)
 500                      (ivy-state-buffer ivy-last))
 501         (switch-to-buffer (ivy-state-buffer ivy-last)))
 502       (goto-char (point-min))
 503       (funcall (if swiper-use-visual-line
 504                    #'line-move
 505                  #'forward-line)
 506                (1- (read (get-text-property 0 'display x))))
 507       (re-search-forward
 508        (ivy--regex ivy-text) (line-end-position) t)
 509       (swiper--ensure-visible)
 510       (when (/= (point) swiper--opoint)
 511         (unless (and transient-mark-mode mark-active)
 512           (push-mark swiper--opoint t)
 513           (message "Mark saved where search started"))))))
 514
 515 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 516 (defun swiper-from-isearch ()
 517   "Invoke `swiper' from isearch."
 518   (interactive)
 519   (let ((query (if isearch-regexp
 520                    isearch-string
 521                  (regexp-quote isearch-string))))
 522     (isearch-exit)
 523     (swiper query)))
 524
 525 (defvar swiper-multi-buffers nil
 526   "Store the current list of buffers.")
 527
 528 (defvar swiper-multi-candidates nil
 529   "Store the list of candidates for `swiper-multi'.")
 530
 531 (defun swiper-multi-prompt ()
 532   (format "Buffers (%s): "
 533           (mapconcat #'identity swiper-multi-buffers ", ")))
 534
 535 (defun swiper-multi ()
 536   "Select one or more buffers.
 537 Run `swiper' for those buffers."
 538   (interactive)
 539   (setq swiper-multi-buffers nil)
 540   (ivy-read (swiper-multi-prompt)
 541             'internal-complete-buffer
 542             :action 'swiper-multi-action-1)
 543   (ivy-read "Swiper: " swiper-multi-candidates
 544             :action 'swiper-multi-action-2
 545             :unwind #'swiper--cleanup
 546             :caller 'swiper-multi))
 547
 548 (defun swiper-all ()
 549   "Run `swiper' for all opened buffers."
 550   (interactive)
 551   (ivy-read "Swiper: " (swiper--multi-candidates
 552                         (cl-remove-if-not
 553                          #'buffer-file-name
 554                          (buffer-list)))
 555             :action 'swiper-multi-action-2
 556             :unwind #'swiper--cleanup
 557             :caller 'swiper-multi))
 558
 559 (defun swiper--multi-candidates (buffers)
 560   (let* ((ww (window-width))
 561          (res nil)
 562          (column-2 (apply #'max
 563                           (mapcar
 564                            (lambda (b)
 565                              (length (buffer-name b)))
 566                            buffers)))
 567          (column-1 (- ww 4 column-2 1)))
 568     (dolist (buf buffers)
 569       (with-current-buffer buf
 570         (setq res
 571               (append
 572                (mapcar
 573                 (lambda (s)
 574                   (setq s (concat (ivy--truncate-string s column-1) " "))
 575                   (let ((len (length s)))
 576                     (put-text-property
 577                      (1- len) len 'display
 578                      (concat
 579                       (make-string
 580                        (- ww (string-width s) (length (buffer-name)) 3)
 581                        ?\ )
 582                       (buffer-name))
 583                      s)
 584                     s))
 585                 (swiper--candidates 4))
 586                res))
 587         nil))
 588     res))
 589
 590 (defun swiper-multi-action-1 (x)
 591   (if (member x swiper-multi-buffers)
 592       (progn
 593         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 594     (unless (equal x "")
 595       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 596   (let ((prompt (swiper-multi-prompt)))
 597     (setf (ivy-state-prompt ivy-last) prompt)
 598     (setq ivy--prompt (concat "%-4d " prompt)))
 599   (cond ((memq this-command '(ivy-done
 600                               ivy-alt-done
 601                               ivy-immediate-done))
 602          (setq swiper-multi-candidates
 603                (swiper--multi-candidates
 604                 (mapcar #'get-buffer swiper-multi-buffers))))
 605         ((eq this-command 'ivy-call)
 606          (delete-minibuffer-contents))))
 607
 608 (defun swiper-multi-action-2 (x)
 609   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 610     (with-ivy-window
 611       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 612         (switch-to-buffer (match-string 1 buf-space))
 613         (goto-char (point-min))
 614         (forward-line (1- (read (get-text-property 0 'display x))))
 615         (re-search-forward
 616          (ivy--regex ivy-text)
 617          (line-end-position) t)
 618         (unless (eq ivy-exit 'done)
 619           (swiper--cleanup)
 620           (swiper--add-overlays (ivy--regex ivy-text)))))))
 621
 622 (provide 'swiper)
 623
 624 ;;; swiper.el ends here