code.delx.au - gnu-emacs-elpa/blob - aggressive-indent.el

   1 ;;; aggressive-indent.el --- Minor mode to aggressively keep your code always indented
   2
   3 ;; Copyright (C) 2014 Artur Malabarba <bruce.connor.am@gmail.com>
   4
   5 ;; Author: Artur Malabarba <bruce.connor.am@gmail.com>
   6 ;; URL: http://github.com/Bruce-Connor/aggressive-indent-mode
   7 ;; Version: 0.3.1
   8 ;; Package-Requires: ((emacs "24.1") (names "0.5") (cl-lib "0.5"))
   9 ;; Keywords: indent lisp maint tools
  10 ;; Prefix: aggressive-indent
  11 ;; Separator: -
  12
  13 ;;; Commentary:
  14 ;;
  15 ;; `electric-indent-mode' is enough to keep your code nicely aligned when
  16 ;; all you do is type. However, once you start shifting blocks around,
  17 ;; transposing lines, or slurping and barfing sexps, indentation is bound
  18 ;; to go wrong.
  19 ;;
  20 ;; `aggressive-indent-mode' is a minor mode that keeps your code always
  21 ;; indented. It reindents after every command, making it more reliable
  22 ;; than `electric-indent-mode'.
  23 ;;
  24 ;; ### Instructions ###
  25 ;;
  26 ;; This package is available fom Melpa, you may install it by calling
  27 ;;
  28 ;;     M-x package-install RET aggressive-indent
  29 ;;
  30 ;; Then activate it with
  31 ;;
  32 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  33 ;;     (add-hook 'css-mode-hook #'aggressive-indent-mode)
  34 ;;
  35 ;; You can use this hook on any mode you want, `aggressive-indent' is not
  36 ;; exclusive to emacs-lisp code. In fact, if you want to turn it on for
  37 ;; every programming mode, you can do something like:
  38 ;;
  39 ;;     (global-aggressive-indent-mode 1)
  40 ;;     (add-to-list 'aggressive-indent-excluded-modes 'html-mode)
  41 ;;
  42 ;; ### Manual Installation ###
  43 ;;
  44 ;; If you don't want to install from Melpa, you can download it manually,
  45 ;; place it in your `load-path' and require it with
  46 ;;
  47 ;;     (require 'aggressive-indent)
  48
  49 ;;; Instructions:
  50 ;;
  51 ;; INSTALLATION
  52 ;;
  53 ;; This package is available fom Melpa, you may install it by calling
  54 ;; M-x package-install RET aggressive-indent.
  55 ;;
  56 ;; Then activate it with
  57 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  58 ;;
  59 ;; You can also use an equivalent hook for another mode,
  60 ;; `aggressive-indent' is not exclusive to emacs-lisp code.
  61 ;;
  62 ;; Alternatively, you can download it manually, place it in your
  63 ;; `load-path' and require it with
  64 ;;
  65 ;;     (require 'aggressive-indent)
  66
  67 ;;; License:
  68 ;;
  69 ;; This file is NOT part of GNU Emacs.
  70 ;;
  71 ;; This program is free software; you can redistribute it and/or
  72 ;; modify it under the terms of the GNU General Public License
  73 ;; as published by the Free Software Foundation; either version 2
  74 ;; of the License, or (at your option) any later version.
  75 ;;
  76 ;; This program is distributed in the hope that it will be useful,
  77 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  78 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  79 ;; GNU General Public License for more details.
  80 ;;
  81
  82 ;;; Change Log:
  83 ;; 0.3 - 2014/10/23 - Implement a smarter engine for non-lisp modes.
  84 ;; 0.2 - 2014/10/20 - Reactivate `electric-indent-mode'.
  85 ;; 0.2 - 2014/10/19 - Add variable `aggressive-indent-dont-indent-if', so the user can prevent indentation.
  86 ;; 0.1 - 2014/10/15 - Release.
  87 ;;; Code:
  88
  89 (require 'cl-lib)
  90 (require 'names)
  91
  92 ;;;###autoload
  93 (define-namespace aggressive-indent- :group indent
  94
  95 (defconst version "0.3.1" "Version of the aggressive-indent.el package.")
  96 (defun bug-report ()
  97   "Opens github issues page in a web browser. Please send any bugs you find.
  98 Please include your emacs and aggressive-indent versions."
  99   (interactive)
 100   (message "Your `aggressive-indent-version' is: %s, and your emacs version is: %s.
 101 Please include this in your report!"
 102            version emacs-version)
 103   (browse-url "https://github.com/Bruce-Connor/aggressive-indent-mode/issues/new"))
 104
 105 \f
 106 ;;; Start of actual Code:
 107 (defcustom excluded-modes
 108   '(text-mode
 109     tabulated-list-mode
 110     special-mode
 111     minibuffer-inactive-mode
 112     bibtex-mode
 113     erc-mode
 114     yaml-mode
 115     jabber-chat-mode)
 116   "Modes in which `aggressive-indent-mode' should not be activated.
 117 This variable is only used if `global-aggressive-indent-mode' is
 118 active. If the minor mode is turned on with the local command,
 119 `aggressive-indent-mode', this variable is ignored."
 120   :type '(repeat symbol)
 121   :package-version '(aggressive-indent . "0.2"))
 122
 123 (defcustom protected-commands '(undo undo-tree-undo undo-tree-redo)
 124   "Commands after which indentation will NOT be performed.
 125 Aggressive indentation could break things like `undo' by locking
 126 the user in a loop, so this variable is used to control which
 127 commands will NOT be followed by a re-indent."
 128   :type '(repeat symbol)
 129   :package-version '(aggressive-indent . "0.1"))
 130
 131 (defcustom comments-too nil
 132   "If non-nil, aggressively indent in comments as well."
 133   :type 'boolean
 134   :package-version '(aggressive-indent . "0.3"))
 135
 136 (defvar -internal-dont-indent-if
 137   '((memq this-command aggressive-indent-protected-commands)
 138     (region-active-p)
 139     buffer-read-only
 140     (null (buffer-modified-p))
 141     (string-match "\\`[[:blank:]]*\n?\\'" (thing-at-point 'line))
 142     (and (not aggressive-indent-comments-too)
 143          (aggressive-indent--in-comment-p)))
 144   "List of forms which prevent indentation when they evaluate to non-nil.
 145 This is for internal use only. For user customization, use
 146 `aggressive-indent-dont-indent-if' instead.")
 147
 148 (defcustom modes-to-prefer-defun '(emacs-lisp-mode lisp-mode scheme-mode)
 149   "List of major-modes in which indenting defun is preferred.
 150 Add here any major modes with very good definitions of
 151 `end-of-defun' and `beginning-of-defun', or modes which bug out
 152 if you have `after-change-functions' (such as paredit).
 153
 154 If current major mode is derived from one of these,
 155 `aggressive-indent-mode' will call
 156 `aggressive-indent-indent-defun' after every command. Otherwise,
 157 it will call `aggressive-indent-indent-region-and-on' after every
 158 buffer change."
 159   :type '(repeat symbol)
 160   :package-version '(aggressive-indent . "0.3"))
 161
 162 (eval-after-load 'yasnippet
 163   '(when (boundp 'yas--active-field-overlay)
 164      (add-to-list 'aggressive-indent--internal-dont-indent-if
 165                   '(and
 166                     (overlayp yas--active-field-overlay)
 167                     (overlay-end yas--active-field-overlay))
 168                   'append)))
 169 (eval-after-load 'company
 170   '(when (boundp 'company-candidates)
 171      (add-to-list 'aggressive-indent--internal-dont-indent-if
 172                   'company-candidates)))
 173 (eval-after-load 'auto-complete
 174   '(when (boundp 'ac-completing)
 175      (add-to-list 'aggressive-indent--internal-dont-indent-if
 176                   'ac-completing)))
 177
 178 (eval-after-load 'css-mode
 179   '(add-hook
 180     'css-mode-hook
 181     (lambda () (unless defun-prompt-regexp
 182             (setq-local defun-prompt-regexp "^[^[:blank:]].*")))))
 183
 184 (defcustom dont-indent-if '()
 185   "List of variables and functions to prevent aggressive indenting.
 186 This variable is a list where each element is a lisp form.
 187 As long as any one of these forms returns non-nil,
 188 aggressive-indent will not perform any indentation.
 189
 190 See `aggressive-indent--internal-dont-indent-if' for usage examples."
 191   :type '(repeat sexp)
 192   :group 'aggressive-indent
 193   :package-version '(aggressive-indent . "0.2"))
 194
 195 (defvar -error-message
 196   "One of the forms in `aggressive-indent-dont-indent-if' had the following error, I've disabled it until you fix it: %S"
 197   "Error message thrown by `aggressive-indent-dont-indent-if'.")
 198
 199 (defvar -has-errored nil
 200   "Keep track of whether `aggressive-indent-dont-indent-if' is throwing.
 201 This is used to prevent an infinite error loop on the user.")
 202
 203 (defun -run-user-hooks ()
 204   "Safely run forms in `aggressive-indent-dont-indent-if'.
 205 If any of them errors out, we only report it once until it stops
 206 erroring again."
 207   (and dont-indent-if
 208        (condition-case er
 209            (prog1 (eval (cons 'or dont-indent-if))
 210              (setq -has-errored nil))
 211          (error
 212           (unless -has-errored
 213             (setq -has-errored t)
 214             (message -error-message er))))))
 215
 216 (defmacro -do-softly (&rest body)
 217   "Execute body unobstrusively.
 218 This means: do nothing if mark is active (to avoid deactivaing
 219 it), or if buffer is not modified (to avoid creating accidental
 220 modifications), or if any of the forms in
 221 `aggressive-indent-dont-indent-if' evaluates to non-nil.
 222
 223 Also, never throw errors nor messages.
 224 Meant for use in functions which go in hooks."
 225   (declare (debug t))
 226   `(unless (or (run-hook-wrapped
 227                 'aggressive-indent--internal-dont-indent-if
 228                 #'eval)
 229                (aggressive-indent--run-user-hooks))
 230      (ignore-errors
 231        (cl-letf (((symbol-function 'message) #'ignore))
 232          ,@body))))
 233
 234 :autoload
 235 (defun indent-defun ()
 236   "Indent current defun.
 237 Throw an error if parentheses are unbalanced."
 238   (interactive)
 239   (let ((p (point-marker)))
 240     (set-marker-insertion-type p t)
 241     (indent-region
 242      (save-excursion (beginning-of-defun 1) (point))
 243      (save-excursion (end-of-defun 1) (point)))
 244     (goto-char p)))
 245
 246 (defun -softly-indent-defun ()
 247   "Indent current defun unobstrusively.
 248 Like `aggressive-indent-indent-defun', but wrapped in a
 249 `aggressive-indent--do-softly'."
 250   (unless (or (run-hook-wrapped
 251                'aggressive-indent--internal-dont-indent-if
 252                #'eval)
 253               (aggressive-indent--run-user-hooks))
 254     (ignore-errors
 255       (cl-letf (((symbol-function 'message) #'ignore))
 256         (indent-defun)))))
 257
 258 :autoload
 259 (defun indent-region-and-on (l r)
 260   "Indent region between L and R, and then some.
 261 Call `indent-region' between L and R, and then keep indenting
 262 until nothing more happens."
 263   (interactive "r")
 264   (let ((p (point-marker))
 265         was-begining-of-line)
 266     (set-marker-insertion-type p t)
 267     (goto-char r)
 268     (setq was-begining-of-line
 269           (= r (line-beginning-position)))
 270     ;; If L is at the end of a line, skip that line.
 271     (unless (= l r)
 272       (goto-char l)
 273       (when (= l (line-end-position))
 274         (cl-incf l)))
 275     ;; Indent the affected region.
 276     (unless (= l r) (indent-region l r))
 277     ;; `indent-region' doesn't do anything if R was the beginning of a line, so we indent manually there.
 278     (when was-begining-of-line
 279       (indent-according-to-mode))
 280     ;; And then we indent each following line until nothing happens.
 281     (forward-line 1)
 282     (while (and (null (eobp))
 283                 (/= (progn (skip-chars-forward "[:blank:]\n")
 284                            (point))
 285                     (progn (indent-according-to-mode)
 286                            (point))))
 287       (forward-line 1))
 288     (goto-char p)))
 289
 290 (defun -softly-indent-region-and-on (l r &rest _)
 291   "Indent current defun unobstrusively.
 292 Like `aggressive-indent-indent-region-and-on', but wrapped in a
 293 `aggressive-indent--do-softly'."
 294   (unless (or (run-hook-wrapped
 295                'aggressive-indent--internal-dont-indent-if
 296                #'eval)
 297               (aggressive-indent--run-user-hooks))
 298     (ignore-errors
 299       (cl-letf (((symbol-function 'message) #'ignore))
 300         (indent-region-and-on l r)))))
 301
 302 (defvar changed-list-right nil
 303   "List of right limit of regions changed in the last command loop.")
 304
 305 (defvar changed-list-left nil
 306   "List of left limit of regions changed in the last command loop.")
 307
 308 (defun -indent-if-changed ()
 309   "Indent any region that changed in the last command loop."
 310   (let ((inhibit-modification-hooks t))
 311     (when changed-list-left
 312       (-softly-indent-region-and-on
 313        (apply #'min changed-list-left)
 314        (apply #'max changed-list-right))
 315       (setq changed-list-left nil
 316             changed-list-right nil))))
 317
 318 (defun -keep-track-of-changes (l r &rest _)
 319   "Store the limits of each change that happens in the buffer."
 320   (push l changed-list-left)
 321   (push r changed-list-right))
 322
 323 (defun -in-comment-p ()
 324   "Return non-nil if point is inside a comment.
 325 Assumes that the syntax table is sufficient to find comments."
 326   (nth 4 (syntax-ppss)))
 327
 328 \f
 329 ;;; Minor modes
 330 :autoload
 331 (define-minor-mode mode nil nil " =>"
 332   '(("\C-c\C-q" . aggressive-indent-indent-defun))
 333   (if mode
 334       (if (and global-aggressive-indent-mode
 335                (or (cl-member-if #'derived-mode-p excluded-modes)
 336                    buffer-read-only))
 337           (mode -1)
 338         (when (fboundp 'electric-indent-local-mode)
 339           (electric-indent-local-mode 1))
 340         (if (cl-member-if #'derived-mode-p modes-to-prefer-defun)
 341             (add-hook 'post-command-hook #'-softly-indent-defun nil 'local)
 342           (add-hook 'after-change-functions #'-keep-track-of-changes nil 'local)
 343           (add-hook 'post-command-hook #'-indent-if-changed nil 'local)))
 344     ;; Clean the hooks
 345     (remove-hook 'after-change-functions #'-keep-track-of-changes 'local)
 346     (remove-hook 'post-command-hook #'-indent-if-changed 'local)
 347     (remove-hook 'post-command-hook #'-softly-indent-defun 'local)))
 348
 349 :autoload
 350 (define-globalized-minor-mode global-aggressive-indent-mode
 351   mode mode)
 352
 353 :autoload
 354 (defalias 'aggressive-indent-global-mode
 355   #'global-aggressive-indent-mode)
 356 )
 357
 358 (provide 'aggressive-indent)
 359 ;;; aggressive-indent.el ends here.