code.delx.au - gnu-emacs-elpa/blob - multishell.el

   1 ;;; multishell.el --- manage interaction with multiple local and remote shells
   2
   3 ;; Copyright (C) 1999-2016 Free Software Foundation, Inc. and Ken Manheimer
   4
   5 ;; Author: Ken Manheimer <ken.manheimer@gmail.com>
   6 ;; Version: 1.0.5
   7 ;; Created: 1999 -- first public availability
   8 ;; Keywords: processes
   9 ;; URL: https://github.com/kenmanheimer/EmacsUtils
  10 ;;
  11 ;;; Commentary:
  12 ;;
  13 ;; Easily use and navigate multiple shell buffers, including remote shells.
  14 ;; Fundamentally, multishell is the function `multishell-pop-to-shell' -
  15 ;; a la `pop-to-buffer' - plus a keybinding. Together, they enable you to:
  16 ;;
  17 ;; * Get to the input point from wherever you are in a shell buffer,
  18 ;; * ... or to a shell buffer if you're not currently in one.
  19 ;; * Use universal arguments to launch and choose among alternate shell buffers,
  20 ;; * ... and select which is default.
  21 ;; * Append a path to a new shell name to launch a shell in that directory,
  22 ;; * ... and use a path with Emacs tramp syntax to launch a remote shell.
  23 ;;
  24 ;; Customize-group `multishell` to select and activate a keybinding and set
  25 ;; various behaviors.
  26 ;;
  27 ;; See the multishell-pop-to-shell docstring for details.
  28 ;;
  29 ;;; Change Log:
  30 ;;
  31 ;; 2016-01-02 Ken Manheimer - working on this in public, but not yet released.
  32 ;;
  33 ;;; TODO:
  34 ;;
  35 ;; * Preserveable (savehist) history that associates names with paths
  36 ;;   - Using an association list between names and paths
  37 ;;   - Searched for search backwards/forwards on isearch-like M-r/M-s bindings
  38 ;;     - *Not* searched for regular completion
  39 ;;   - Editible
  40 ;;     - New shell prompts for confirmation
  41 ;;       - Including path from history, if any
  42 ;;       - which offers opportunity to edit association
  43 ;;     - New association overrides previous
  44 ;;   - History tracks buffer disposition
  45 ;;     - Track buffer name change using buffer-list-update-hook
  46 ;;     - Deleting buffer removes history entry!
  47 ;;   - Option to track last directory - multishell-remember-last-dir
  48 ;;     - Include note about tramp not tracking remote dirs well
  49 ;;       - use `M-x shell-resync-dirs'; I bind to M-return
  50 ;; * Customize activation of savehist
  51 ;;   - Customize entry has warning about activating savehist
  52 ;;   - Adds the name/path association list to savehist-additional-variables
  53 ;;   - Activates savehist, if inactive
  54
  55 ;;; Code:
  56
  57 (require 'comint)
  58 (require 'shell)
  59
  60 (defgroup multishell nil
  61   "Allout extension that highlights outline structure graphically.
  62
  63 Customize `allout-widgets-auto-activation' to activate allout-widgets
  64 with allout-mode."
  65   :group 'shell)
  66
  67 (defcustom multishell-command-key "\M- "
  68   "The key to use if `multishell-activate-command-key' is true.
  69
  70 You can instead manually bind `multishell-pop-to-shell` using emacs
  71 lisp, eg: (global-set-key \"\\M- \" 'multishell-pop-to-shell)."
  72   :type 'key-sequence
  73   :group 'multishell)
  74
  75 (defvar multishell--responsible-for-command-key nil
  76   "Multishell internal.")
  77 (defun multishell-activate-command-key-setter (symbol setting)
  78   "Implement `multishell-activate-command-key' choice."
  79   (set-default 'multishell-activate-command-key setting)
  80   (when (or setting multishell--responsible-for-command-key)
  81     (multishell-implement-command-key-choice (not setting))))
  82 (defun multishell-implement-command-key-choice (&optional unbind)
  83   "If settings dicate, implement binding of multishell command key.
  84
  85 If optional UNBIND is true, globally unbind the key.
  86
  87 * `multishell-activate-command-key' - Set this to get the binding or not.
  88 * `multishell-command-key' - The key to use for the binding, if appropriate."
  89   (cond (unbind
  90          (when (and (boundp 'multishell-command-key) multishell-command-key)
  91            (global-unset-key multishell-command-key)))
  92         ((not (and (boundp 'multishell-activate-command-key)
  93                    (boundp 'multishell-command-key)))
  94          nil)
  95         ((and multishell-activate-command-key multishell-command-key)
  96          (setq multishell--responsible-for-command-key t)
  97          (global-set-key multishell-command-key 'multishell-pop-to-shell))))
  98
  99 (defcustom multishell-activate-command-key nil
 100   "Set this to impose the `multishell-command-key' binding.
 101
 102 You can instead manually bind `multishell-pop-to-shell` using emacs
 103 lisp, eg: (global-set-key \"\\M- \" 'multishell-pop-to-shell)."
 104   :type 'boolean
 105   :set 'multishell-activate-command-key-setter
 106   :group 'multishell)
 107
 108 ;; Assert the customizations whenever the package is loaded:
 109 (with-eval-after-load "multishell"
 110   (multishell-implement-command-key-choice))
 111
 112 (defcustom multishell-pop-to-frame nil
 113   "*If non-nil, jump to a frame already showing the shell, if another is.
 114
 115 Otherwise, disregard already-open windows on the shell if they're
 116 in another frame, and open a new window on the shell in the
 117 current frame.
 118
 119 \(Use `pop-up-windows' to change multishell other-buffer vs
 120 current-buffer behavior.)"
 121   :type 'boolean
 122   :group 'multishell)
 123
 124 ;; (defcustom multishell-persist-shell-names nil
 125 ;;   "Remember shell name/path associations across sessions. Note well:
 126 ;; This will activate minibuffer history persistence, in general, if it's not
 127 ;; already active."
 128 ;;  :type 'boolean
 129 ;;  :set 'multishell-activate-persistence
 130 ;;  :group 'shell)
 131
 132 (defvar multishell-name-path-assoc nil
 133   "Assoc list from name to path")
 134
 135 (defvar multishell-primary-name "*shell*"
 136   "Shell name to use for un-modified multishell-pop-to-shell buffer target.")
 137 (defvar multishell-buffer-name-history nil
 138   "Distinct multishell-pop-to-shell completion history container.")
 139 (defvar multishell-names-to-paths nil
 140   "Multishell buffer name/path associations.")
 141 (defun multishell-register-buffer-name (name path)
 142   "Associate NAME with PATH in `multishell-names-to-path'.
 143
 144 Remove registration for NAME if PATH is nil (but not the empty string)."
 145   (if path
 146       (let* ((it (cons name path))
 147              (got (member it multishell-buffer-name_path-history)))
 148         (if got
 149             (setcdr it path)
 150           (setq multishell-buffer-name_path-history
 151                 (cons (cons name path) multishell-buffer-name_path-history))))
 152     (let ((it (assoc name multishell-buffer-name_path-history)))
 153       (if it
 154           (setq multishell-buffer-name_path-history
 155                 (delete it multishell-buffer-name_path-history))))))
 156
 157 (defun multishell-pop-to-shell (&optional arg)
 158   "Easily navigate to and within multiple shell buffers, local and remote.
 159
 160 Use universal arguments to launch and choose between alternate
 161 shell buffers and to select which is default.  Append a path to
 162 a new shell name to launch a shell in that directory, and use
 163 Emacs tramp syntax to launch a remote shell.
 164
 165 Customize-group `multishell' to set up a key binding and tweak behaviors.
 166
 167 ==== Basic operation:
 168
 169  - If the current buffer is shell-mode (or shell-mode derived)
 170    buffer then focus is moved to the process input point.
 171
 172    \(You can use a universal argument go to a different shell
 173    buffer when already in a buffer that has a process - see
 174    below.)
 175
 176  - If not in a shell buffer (or with universal argument), go to a
 177    window that is already showing the (a) shell buffer, if any.
 178
 179    In this case, the cursor is left in its prior position in the
 180    shell buffer. Repeating the command will then go to the
 181    process input point, per the first item in this list.
 182
 183    We respect `pop-up-windows', so you can adjust it to set the
 184    other-buffer/same-buffer behavior.
 185
 186  - Otherwise, start a new shell buffer, using the current
 187    directory as the working directory.
 188
 189 If a buffer with the resulting name exists and its shell process
 190 was disconnected or otherwise stopped, it's resumed.
 191
 192 ===== Universal arg to start and select between named shell buffers:
 193
 194 You can name alternate shell buffers to create or return to using
 195 single or doubled universal arguments:
 196
 197  - With a single universal argument, prompt for the buffer name
 198    to use (without the asterisks that shell mode will put around
 199    the name), defaulting to 'shell'.
 200
 201    Completion is available.
 202
 203    This combination makes it easy to start and switch between
 204    multiple shell buffers.
 205
 206  - A double universal argument will prompt for the name *and* set
 207    the default to that name, so the target shell becomes the
 208    primary.
 209
 210 ===== Select starting directory and remote host:
 211
 212 The shell buffer name you give to the prompt for a universal arg
 213 can include an appended path. That will be used for the startup
 214 directory. You can use tramp remote syntax to specify a remote
 215 shell. If there is an element after a final '/', that's used for
 216 the buffer name. Otherwise, the host, domain, or path is used.
 217
 218 For example:
 219
 220 * Use '/ssh:example.net:/' for a shell buffer on example.net named
 221   \"example.net\".
 222 * '\#ex/ssh:example.net|sudo:root@example.net:/' for a root shell on
 223   example.net named \"#ex\"."
 224
 225 ;; I'm leaving the following out of the docstring for now because just
 226 ;; saving the buffer names, and not the paths, yields sometimes unwanted
 227 ;; behavior.
 228
 229 ;; ===== Persisting your alternate shell buffer names and paths:
 230
 231 ;; You can use emacs builtin SaveHist to preserve your alternate
 232 ;; shell buffer names and paths across emacs sessions. To do so,
 233 ;; customize the `savehist' group, and:
 234
 235 ;; 1. Add `multishell-pop-to-shell-buffer-name-history' to Savehist Additional
 236 ;;    Variables.
 237 ;; 2. Activate Savehist Mode, if not already activated.
 238 ;; 3. Save.
 239
 240   (interactive "P")
 241
 242   (let* ((from-buffer (current-buffer))
 243          (from-buffer-is-shell (derived-mode-p 'shell-mode))
 244          (doublearg (equal arg '(16)))
 245          (target-name-and-path
 246           (multishell-derive-target-name-and-path
 247            (if arg
 248                (multishell-read-bare-shell-buffer-name
 249                 (format "Shell buffer name [%s]%s "
 250                         (substring-no-properties
 251                          multishell-primary-name
 252                          1 (- (length multishell-primary-name) 1))
 253                         (if doublearg " <==" ":"))
 254                 multishell-primary-name)
 255              multishell-primary-name)))
 256          (use-default-dir (cadr target-name-and-path))
 257          (target-shell-buffer-name (car target-name-and-path))
 258          (curr-buff-proc (get-buffer-process from-buffer))
 259          (target-buffer (if from-buffer-is-shell
 260                             from-buffer
 261                           (get-buffer target-shell-buffer-name)))
 262          inwin
 263          already-there)
 264
 265     (when doublearg
 266       (setq multishell-primary-name target-shell-buffer-name))
 267
 268     ;; Situate:
 269
 270     (cond
 271
 272      ((and (or curr-buff-proc from-buffer-is-shell)
 273            (not arg)
 274            (eq from-buffer target-buffer)
 275            (not (eq target-shell-buffer-name (buffer-name from-buffer))))
 276       ;; In a shell buffer, but not named - stay in buffer, but go to end.
 277       (setq already-there t))
 278
 279      ((string= (buffer-name) target-shell-buffer-name)
 280       ;; Already in the specified shell buffer:
 281       (setq already-there t))
 282
 283      ((or (not target-buffer)
 284           (not (setq inwin
 285                      (multishell-get-visible-window-for-buffer target-buffer))))
 286       ;; No preexisting shell buffer, or not in a visible window:
 287       (pop-to-buffer target-shell-buffer-name pop-up-windows))
 288
 289        ;; Buffer exists and already has a window - jump to it:
 290      (t (if (and multishell-pop-to-frame
 291                  inwin
 292                  (not (equal (window-frame (selected-window))
 293                              (window-frame inwin))))
 294             (select-frame-set-input-focus (window-frame inwin)))
 295         (if (not (string= (buffer-name (current-buffer))
 296                           target-shell-buffer-name))
 297             (pop-to-buffer target-shell-buffer-name t))))
 298
 299     ;; We're in the buffer. Activate:
 300
 301     (cond ((not (comint-check-proc (current-buffer)))
 302            (multishell-start-shell-in-buffer (buffer-name (current-buffer))
 303                                              use-default-dir))
 304           (use-default-dir
 305            (cd use-default-dir)))
 306
 307     ;; If the destination buffer has a stopped process, resume it:
 308     (let ((process (get-buffer-process (current-buffer))))
 309       (if (and process (equal 'stop (process-status process)))
 310           (continue-process process)))
 311     (when (or already-there
 312              (equal (current-buffer) from-buffer))
 313       (goto-char (point-max))
 314       (and (get-buffer-process from-buffer)
 315            (goto-char (process-mark (get-buffer-process from-buffer)))))))
 316
 317 (defun multishell-get-visible-window-for-buffer (buffer)
 318   "Return visible window containing buffer."
 319   (catch 'got-a-vis
 320     (walk-windows
 321      (function (lambda (win)
 322                  (if (and (eq (window-buffer win) buffer)
 323                           (equal (frame-parameter
 324                                   (selected-frame) 'display)
 325                                  (frame-parameter
 326                                   (window-frame win) 'display)))
 327                      (throw 'got-a-vis win))))
 328      nil 'visible)
 329     nil))
 330
 331 (defun multishell-read-bare-shell-buffer-name (prompt default)
 332   "PROMPT for shell buffer name, sans asterisks.
 333
 334 Return the supplied name bracketed with the asterisks, or specified DEFAULT
 335 on empty input."
 336   (let* ((candidates (append
 337                       (remq nil
 338                             (mapcar (lambda (buffer)
 339                                       (let ((name (buffer-name buffer)))
 340                                         (if (with-current-buffer buffer
 341                                               (derived-mode-p 'shell-mode))
 342                                             ;; Shell mode buffers.
 343                                             (if (> (length name) 2)
 344                                                 ;; Strip asterisks.
 345                                                 (substring name 1
 346                                                            (1- (length name)))
 347                                               name))))
 348                                     (buffer-list)))))
 349          (got (completing-read prompt
 350                                candidates ; COLLECTION
 351                                nil        ; PREDICATE
 352                                'confirm   ; REQUIRE-MATCH
 353                                nil        ; INITIAL-INPUT
 354                                'multishell-buffer-name-history ; HIST
 355                                )))
 356     (if (not (string= got "")) (multishell-bracket-asterisks got) default)))
 357 (defun multishell-derive-target-name-and-path (path-ish)
 358   "Give tramp-style PATH-ISH, determine target name and default directory.
 359
 360 The name is the part of the string before the initial '/' slash,
 361 if any. Otherwise, it's either the host-name, domain-name, final
 362 directory name, or local host name. The path is everything
 363 besides the string before the initial '/' slash.
 364
 365 Return them as a list (name dir), with dir nil if none given."
 366   (let (name (path "") dir)
 367     (cond ((string= path-ish "") (setq dir multishell-primary-name))
 368           ((string-match "^\\*\\([^/]*\\)\\(/.*/\\)\\(.*\\)\\*" path-ish)
 369            ;; We have a path, use it
 370            (let ((overt-name (match-string 1 path-ish))
 371                  (overt-path (match-string 2 path-ish))
 372                  (trailing-name (match-string 3 path-ish)))
 373              (if (string= overt-name "") (setq overt-name nil))
 374              (if (string= overt-path "") (setq overt-path nil))
 375              (if (string= trailing-name "") (setq trailing-name nil))
 376              (setq path (concat overt-path trailing-name))
 377              (setq name
 378                    (multishell-bracket-asterisks
 379                     (or overt-name
 380                         (if (file-remote-p path)
 381                             (let ((vec (tramp-dissect-file-name path)))
 382                               (or (tramp-file-name-host vec)
 383                                   (tramp-file-name-domain vec)
 384                                   (tramp-file-name-localname vec)
 385                                   trailing-name
 386                                   system-name))
 387                           (multishell-unbracket-asterisks
 388                            multishell-primary-name)))))))
 389           (t (setq name (multishell-bracket-asterisks path-ish))))
 390     (list name path)))
 391
 392 (defun multishell-bracket-asterisks (name)
 393   "Return a copy of name, ensuring it has an asterisk at the beginning and end."
 394   (if (not (string= (substring name 0 1) "*"))
 395       (setq name (concat "*" name)))
 396   (if (not (string= (substring name -1) "*"))
 397       (setq name (concat name "*")))
 398   name)
 399 (defun multishell-unbracket-asterisks (name)
 400   "Return a copy of name, removing asterisks, if any, at beginning and end."
 401   (if (string= (substring name 0 1) "*")
 402       (setq name (substring name 1)))
 403   (if (string= (substring name -1) "*")
 404       (setq name (substring name 0 -1)))
 405   name)
 406
 407 (defun multishell-start-shell-in-buffer (buffer-name path)
 408   "Ensure a shell is started, with name NAME and PATH."
 409   ;; We work around shell-mode's bracketing of the buffer name, and do
 410   ;; some tramp-mode hygiene for remote connections.
 411
 412   (let* ((buffer buffer-name)
 413          (prog (or explicit-shell-file-name
 414                    (getenv "ESHELL")
 415                    (getenv "SHELL")
 416                    "/bin/sh"))
 417          (name (file-name-nondirectory prog))
 418          (startfile (concat "~/.emacs_" name))
 419          (xargs-name (intern-soft (concat "explicit-" name "-args"))))
 420     (set-buffer buffer-name)
 421     (if (and path (not (string= path "")))
 422         (setq default-directory path))
 423     (when (and (file-remote-p default-directory)
 424                (derived-mode-p 'shell-mode)
 425                (not (comint-check-proc (current-buffer))))
 426       ;; We're returning to an already established but disconnected remote
 427       ;; shell, tidy it:
 428       (tramp-cleanup-connection
 429        (tramp-dissect-file-name default-directory 'noexpand)
 430        'keep-debug 'keep-password))
 431     ;; (cd default-directory) will reconnect a disconnected remote:
 432     (cd default-directory)
 433     (setq buffer (set-buffer (apply 'make-comint
 434                                     (multishell-unbracket-asterisks buffer-name)
 435                                     prog
 436                                     (if (file-exists-p startfile)
 437                                         startfile)
 438                                     (if (and xargs-name
 439                                              (boundp xargs-name))
 440                                         (symbol-value xargs-name)
 441                                       '("-i")))))
 442     (shell-mode)))
 443
 444 (provide 'multishell)
 445
 446 ;;; multishell.el ends here