code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.6.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (delete-minibuffer-contents)
 109       (ivy-set-action (lambda (_)
 110                         (with-ivy-window
 111                           (move-beginning-of-line 1)
 112                           (perform-replace from to
 113                                            t t nil))))
 114       (swiper--cleanup)
 115       (exit-minibuffer))))
 116
 117 (defvar avy-background)
 118 (defvar avy-all-windows)
 119 (defvar avy-style)
 120 (defvar avy-keys)
 121 (declare-function avy--regex-candidates "ext:avy")
 122 (declare-function avy--process "ext:avy")
 123 (declare-function avy--overlay-post "ext:avy")
 124 (declare-function avy-action-goto "ext:avy")
 125 (declare-function avy--done "ext:avy")
 126 (declare-function avy--make-backgrounds "ext:avy")
 127 (declare-function avy-window-list "ext:avy")
 128 (declare-function avy-read "ext:avy")
 129 (declare-function avy-read-de-bruijn "ext:avy")
 130 (declare-function avy-tree "ext:avy")
 131 (declare-function avy-push-mark "ext:avy")
 132 (declare-function avy--remove-leading-chars "ext:avy")
 133
 134 ;;;###autoload
 135 (defun swiper-avy ()
 136   "Jump to one of the current swiper candidates."
 137   (interactive)
 138   (unless (string= ivy-text "")
 139     (let* ((avy-all-windows nil)
 140            (candidates (append
 141                         (with-ivy-window
 142                           (avy--regex-candidates
 143                            (ivy--regex ivy-text)))
 144                         (save-excursion
 145                           (save-restriction
 146                             (narrow-to-region (window-start) (window-end))
 147                             (goto-char (point-min))
 148                             (forward-line)
 149                             (let ((cands))
 150                               (while (< (point) (point-max))
 151                                 (push (cons (1+ (point))
 152                                             (selected-window))
 153                                       cands)
 154                                 (forward-line))
 155                               cands)))))
 156            (candidate (unwind-protect
 157                           (prog2
 158                               (avy--make-backgrounds
 159                                (append (avy-window-list)
 160                                        (list  (ivy-state-window ivy-last))))
 161                               (if (eq avy-style 'de-bruijn)
 162                                   (avy-read-de-bruijn
 163                                    candidates avy-keys)
 164                                 (avy-read (avy-tree candidates avy-keys)
 165                                           #'avy--overlay-post
 166                                           #'avy--remove-leading-chars))
 167                             (avy-push-mark))
 168                         (avy--done))))
 169       (if (window-minibuffer-p (cdr candidate))
 170           (progn
 171             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 172             (ivy--exhibit)
 173             (ivy-done)
 174             (ivy-call))
 175         (ivy-quit-and-run
 176          (avy-action-goto (caar candidate)))))))
 177
 178 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 179 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 180
 181 ;;;###autoload
 182 (defun swiper-mc ()
 183   (interactive)
 184   (unless (require 'multiple-cursors nil t)
 185     (error "multiple-cursors isn't installed"))
 186   (let ((cands (nreverse ivy--old-cands)))
 187     (unless (string= ivy-text "")
 188       (ivy-set-action
 189        (lambda (_)
 190          (let (cand)
 191            (while (setq cand (pop cands))
 192              (swiper--action cand)
 193              (when cands
 194                (mc/create-fake-cursor-at-point))))
 195          (multiple-cursors-mode 1)))
 196       (setq ivy-exit 'done)
 197       (exit-minibuffer))))
 198
 199 (defun swiper-recenter-top-bottom (&optional arg)
 200   "Call (`recenter-top-bottom' ARG)."
 201   (interactive "P")
 202   (with-ivy-window
 203     (recenter-top-bottom arg)))
 204
 205 (defun swiper-font-lock-ensure ()
 206   "Ensure the entired buffer is highlighted."
 207   (unless (or (derived-mode-p 'magit-mode)
 208               (bound-and-true-p magit-blame-mode)
 209               (memq major-mode '(package-menu-mode
 210                                  gnus-summary-mode
 211                                  gnus-article-mode
 212                                  gnus-group-mode
 213                                  emms-playlist-mode
 214                                  emms-stream-mode
 215                                  erc-mode
 216                                  org-agenda-mode
 217                                  dired-mode
 218                                  jabber-chat-mode
 219                                  elfeed-search-mode
 220                                  elfeed-show-mode
 221                                  fundamental-mode
 222                                  Man-mode
 223                                  woman-mode
 224                                  mu4e-view-mode
 225                                  mu4e-headers-mode
 226                                  help-mode
 227                                  debbugs-gnu-mode
 228                                  occur-mode
 229                                  occur-edit-mode
 230                                  bongo-mode
 231                                  eww-mode
 232                                  w3m-mode)))
 233     (unless (> (buffer-size) 100000)
 234       (if (fboundp 'font-lock-ensure)
 235           (font-lock-ensure)
 236         (with-no-warnings (font-lock-fontify-buffer))))))
 237
 238 (defvar swiper--format-spec ""
 239   "Store the current candidates format spec.")
 240
 241 (defvar swiper--width nil
 242   "Store the amount of digits needed for the longest line nubmer.")
 243
 244 (defvar swiper-use-visual-line nil
 245   "When non-nil, use `line-move' instead of `forward-line'.")
 246
 247 (defun swiper--candidates ()
 248   "Return a list of this buffer lines."
 249   (setq swiper-use-visual-line
 250         (and (not (eq major-mode 'org-mode))
 251              visual-line-mode
 252              (< (buffer-size) 20000)))
 253   (let ((n-lines (count-lines (point-min) (point-max))))
 254     (unless (zerop n-lines)
 255       (setq swiper--width (1+ (floor (log n-lines 10))))
 256       (setq swiper--format-spec
 257             (format "%%-%dd " swiper--width))
 258       (let ((line-number 0)
 259             (advancer (if swiper-use-visual-line
 260                           (lambda (arg) (line-move arg t))
 261                         #'forward-line))
 262             candidates)
 263         (save-excursion
 264           (goto-char (point-min))
 265           (swiper-font-lock-ensure)
 266           (while (< (point) (point-max))
 267             (let ((str (concat
 268                         " "
 269                         (replace-regexp-in-string
 270                          "\t" "    "
 271                          (buffer-substring
 272                           (point)
 273                           (if swiper-use-visual-line
 274                               (save-excursion
 275                                 (end-of-visual-line)
 276                                 (point))
 277                             (line-end-position)))))))
 278               (put-text-property 0 1 'display
 279                                  (format swiper--format-spec
 280                                          (cl-incf line-number))
 281                                  str)
 282               (push str candidates))
 283             (funcall advancer 1))
 284           (nreverse candidates))))))
 285
 286 (defvar swiper--opoint 1
 287   "The point when `swiper' starts.")
 288
 289 ;;;###autoload
 290 (defun swiper (&optional initial-input)
 291   "`isearch' with an overview.
 292 When non-nil, INITIAL-INPUT is the initial search pattern."
 293   (interactive)
 294   (swiper--ivy initial-input))
 295
 296 (defvar swiper--anchor nil
 297   "A line number to which the search should be anchored.")
 298
 299 (defvar swiper--len 0
 300   "The last length of input for which an anchoring was made.")
 301
 302 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 303
 304 (defun swiper--init ()
 305   "Perform initialization common to both completion methods."
 306   (setq swiper--opoint (point))
 307   (setq swiper--len 0)
 308   (setq swiper--anchor (line-number-at-pos))
 309   (when (bound-and-true-p evil-jumper-mode)
 310     (evil-jumper--set-jump)))
 311
 312 (defun swiper--re-builder (str)
 313   "Transform STR into a swiper regex.
 314 This is the regex used in the minibuffer, since the candidates
 315 there have line numbers. In the buffer, `ivy--regex' should be used."
 316   (cond
 317     ((equal str "")
 318      "")
 319     ((equal str "^")
 320      (setq ivy--subexps 0)
 321      ".")
 322     ((string-match "^\\^" str)
 323      (setq ivy--old-re "")
 324      (let ((re (ivy--regex-plus (substring str 1))))
 325        (if (zerop ivy--subexps)
 326            (prog1 (format "^ ?\\(%s\\)" re)
 327              (setq ivy--subexps 1))
 328          (format "^ %s" re))))
 329     (t
 330      (ivy--regex-plus str))))
 331
 332 (defvar swiper-history nil
 333   "History for `swiper'.")
 334
 335 (defvar swiper-invocation-face nil
 336   "The face at the point of invocation of `swiper'.")
 337
 338 (defun swiper--ivy (&optional initial-input)
 339   "`isearch' with an overview using `ivy'.
 340 When non-nil, INITIAL-INPUT is the initial search pattern."
 341   (interactive)
 342   (swiper--init)
 343   (setq swiper-invocation-face
 344         (plist-get (text-properties-at (point)) 'face))
 345   (let ((candidates (swiper--candidates))
 346         (preselect (buffer-substring-no-properties
 347                     (line-beginning-position)
 348                     (line-end-position)))
 349         (minibuffer-allow-text-properties t))
 350     (unwind-protect
 351         (ivy-read
 352          "Swiper: "
 353          candidates
 354          :initial-input initial-input
 355          :keymap swiper-map
 356          :preselect preselect
 357          :require-match t
 358          :update-fn #'swiper--update-input-ivy
 359          :unwind #'swiper--cleanup
 360          :action #'swiper--action
 361          :re-builder #'swiper--re-builder
 362          :history 'swiper-history
 363          :caller 'swiper)
 364       (when (null ivy-exit)
 365         (goto-char swiper--opoint)))))
 366
 367 (defun swiper-toggle-face-matching ()
 368   "Toggle matching only the candidates with `swiper-invocation-face'."
 369   (interactive)
 370   (setf (ivy-state-matcher ivy-last)
 371         (if (ivy-state-matcher ivy-last)
 372             nil
 373           #'swiper--face-matcher))
 374   (setq ivy--old-re nil))
 375
 376 (defun swiper--face-matcher (regexp candidates)
 377   "Return REGEXP-matching CANDIDATES.
 378 Matched candidates should have `swiper-invocation-face'."
 379   (cl-remove-if-not
 380    (lambda (x)
 381      (and
 382       (string-match regexp x)
 383       (let ((s (match-string 0 x))
 384             (i 0))
 385         (while (and (< i (length s))
 386                     (text-property-any
 387                      i (1+ i)
 388                      'face swiper-invocation-face
 389                      s))
 390           (cl-incf i))
 391         (eq i (length s)))))
 392    candidates))
 393
 394 (defun swiper--ensure-visible ()
 395   "Remove overlays hiding point."
 396   (let ((overlays (overlays-at (point)))
 397         ov expose)
 398     (while (setq ov (pop overlays))
 399       (if (and (invisible-p (overlay-get ov 'invisible))
 400                (setq expose (overlay-get ov 'isearch-open-invisible)))
 401           (funcall expose ov)))))
 402
 403 (defvar swiper--overlays nil
 404   "Store overlays.")
 405
 406 (defun swiper--cleanup ()
 407   "Clean up the overlays."
 408   (while swiper--overlays
 409     (delete-overlay (pop swiper--overlays)))
 410   (save-excursion
 411     (goto-char (point-min))
 412     (isearch-clean-overlays)))
 413
 414 (defun swiper--update-input-ivy ()
 415   "Called when `ivy' input is updated."
 416   (with-ivy-window
 417     (swiper--cleanup)
 418     (when (> (length ivy--current) 0)
 419       (let* ((re (funcall ivy--regex-function ivy-text))
 420              (re (if (stringp re) re (caar re)))
 421              (str (get-text-property 0 'display ivy--current))
 422              (num (if (string-match "^[0-9]+" str)
 423                       (string-to-number (match-string 0 str))
 424                     0)))
 425         (goto-char (point-min))
 426         (when (cl-plusp num)
 427           (goto-char (point-min))
 428           (if swiper-use-visual-line
 429               (line-move (1- num))
 430             (forward-line (1- num)))
 431           (if (and (equal ivy-text "")
 432                    (>= swiper--opoint (line-beginning-position))
 433                    (<= swiper--opoint (line-end-position)))
 434               (goto-char swiper--opoint)
 435             (re-search-forward re (line-end-position) t))
 436           (isearch-range-invisible (line-beginning-position)
 437                                    (line-end-position))
 438           (unless (and (>= (point) (window-start))
 439                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 440             (recenter)))
 441         (swiper--add-overlays re)))))
 442
 443 (defun swiper--add-overlays (re &optional beg end wnd)
 444   "Add overlays for RE regexp in visible part of the current buffer.
 445 BEG and END, when specified, are the point bounds.
 446 WND, when specified is the window."
 447   (setq wnd (or wnd (ivy-state-window ivy-last)))
 448   (let ((ov (if visual-line-mode
 449                 (make-overlay
 450                  (save-excursion
 451                    (beginning-of-visual-line)
 452                    (point))
 453                  (save-excursion
 454                    (end-of-visual-line)
 455                    (point)))
 456               (make-overlay
 457                (line-beginning-position)
 458                (1+ (line-end-position))))))
 459     (overlay-put ov 'face 'swiper-line-face)
 460     (overlay-put ov 'window wnd)
 461     (push ov swiper--overlays)
 462     (let* ((wh (window-height))
 463            (beg (or beg (save-excursion
 464                           (forward-line (- wh))
 465                           (point))))
 466            (end (or end (save-excursion
 467                           (forward-line wh)
 468                           (point)))))
 469       (when (>= (length re) swiper-min-highlight)
 470         (save-excursion
 471           (goto-char beg)
 472           ;; RE can become an invalid regexp
 473           (while (and (ignore-errors (re-search-forward re end t))
 474                       (> (- (match-end 0) (match-beginning 0)) 0))
 475             (let ((i 0))
 476               (while (<= i ivy--subexps)
 477                 (when (match-beginning i)
 478                   (let ((overlay (make-overlay (match-beginning i)
 479                                                (match-end i)))
 480                         (face
 481                          (cond ((zerop ivy--subexps)
 482                                 (cadr swiper-faces))
 483                                ((zerop i)
 484                                 (car swiper-faces))
 485                                (t
 486                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 487                                      swiper-faces)))))
 488                     (push overlay swiper--overlays)
 489                     (overlay-put overlay 'face face)
 490                     (overlay-put overlay 'window wnd)
 491                     (overlay-put overlay 'priority i)))
 492                 (cl-incf i)))))))))
 493
 494 (defun swiper--action (x)
 495   "Goto line X."
 496   (if (null x)
 497       (user-error "No candidates")
 498     (with-ivy-window
 499       (unless (equal (current-buffer)
 500                      (ivy-state-buffer ivy-last))
 501         (switch-to-buffer (ivy-state-buffer ivy-last)))
 502       (goto-char (point-min))
 503       (funcall (if swiper-use-visual-line
 504                    #'line-move
 505                  #'forward-line)
 506                (1- (read (get-text-property 0 'display x))))
 507       (re-search-forward
 508        (ivy--regex ivy-text) (line-end-position) t)
 509       (swiper--ensure-visible)
 510       (when (/= (point) swiper--opoint)
 511         (unless (and transient-mark-mode mark-active)
 512           (push-mark swiper--opoint t)
 513           (message "Mark saved where search started"))))))
 514
 515 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 516 (defun swiper-from-isearch ()
 517   "Invoke `swiper' from isearch."
 518   (interactive)
 519   (let ((query (if isearch-regexp
 520                    isearch-string
 521                  (regexp-quote isearch-string))))
 522     (isearch-exit)
 523     (swiper query)))
 524
 525 (defvar swiper-multi-buffers nil
 526   "Store the current list of buffers.")
 527
 528 (defvar swiper-multi-candidates nil
 529   "Store the list of candidates for `swiper-multi'.")
 530
 531 (defun swiper-multi-prompt ()
 532   (format "Buffers (%s): "
 533           (mapconcat #'identity swiper-multi-buffers ", ")))
 534
 535 (defun swiper-multi ()
 536   "Select one or more buffers.
 537 Run `swiper' for those buffers."
 538   (interactive)
 539   (setq swiper-multi-buffers nil)
 540   (setq swiper-multi-candidates nil)
 541   (ivy-read (swiper-multi-prompt)
 542             'internal-complete-buffer
 543             :action 'swiper-multi-action-1)
 544   (ivy-read "Swiper: " swiper-multi-candidates
 545             :action 'swiper-multi-action-2
 546             :unwind #'swiper--cleanup
 547             :caller 'swiper-multi))
 548
 549 (defun swiper-multi-action-1 (x)
 550   (if (member x swiper-multi-buffers)
 551       (progn
 552         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 553     (unless (equal x "")
 554       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 555   (let ((prompt (swiper-multi-prompt)))
 556     (setf (ivy-state-prompt ivy-last) prompt)
 557     (setq ivy--prompt (concat "%-4d " prompt)))
 558   (cond ((memq this-command '(ivy-done
 559                               ivy-alt-done
 560                               ivy-immediate-done))
 561          (let ((ww (window-width)))
 562            (dolist (buf swiper-multi-buffers)
 563              (with-current-buffer buf
 564                (setq swiper-multi-candidates
 565                      (append
 566                       (mapcar
 567                        (lambda (s)
 568                          (setq s (concat s " "))
 569                          (let ((len (length s)))
 570                            (put-text-property
 571                             (1- len) len 'display
 572                             (concat
 573                              (make-string
 574                               (max
 575                                (- ww
 576                                   (string-width s)
 577                                   (length (buffer-name))
 578                                   1)
 579                                0)
 580                               ?\ )
 581                              (buffer-name))
 582                             s)
 583                            s))
 584                        (swiper--candidates))
 585                       swiper-multi-candidates))))))
 586         ((eq this-command 'ivy-call)
 587          (delete-minibuffer-contents))))
 588
 589 (defun swiper-multi-action-2 (x)
 590   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 591     (with-ivy-window
 592       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 593         (switch-to-buffer (match-string 1 buf-space))
 594         (goto-char (point-min))
 595         (forward-line (1- (read x)))
 596         (re-search-forward
 597          (ivy--regex ivy-text)
 598          (line-end-position) t)
 599         (unless (eq ivy-exit 'done)
 600           (swiper--cleanup)
 601           (swiper--add-overlays (ivy--regex ivy-text)))))))
 602
 603 (provide 'swiper)
 604
 605 ;;; swiper.el ends here