code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (swiper--cleanup)
 109       (ivy-exit-with-action
 110        (lambda (_)
 111          (with-ivy-window
 112            (move-beginning-of-line 1)
 113            (perform-replace from to
 114                             t t nil)))))))
 115
 116 (defvar avy-background)
 117 (defvar avy-all-windows)
 118 (defvar avy-style)
 119 (defvar avy-keys)
 120 (declare-function avy--regex-candidates "ext:avy")
 121 (declare-function avy--process "ext:avy")
 122 (declare-function avy--overlay-post "ext:avy")
 123 (declare-function avy-action-goto "ext:avy")
 124 (declare-function avy--done "ext:avy")
 125 (declare-function avy--make-backgrounds "ext:avy")
 126 (declare-function avy-window-list "ext:avy")
 127 (declare-function avy-read "ext:avy")
 128 (declare-function avy-read-de-bruijn "ext:avy")
 129 (declare-function avy-tree "ext:avy")
 130 (declare-function avy-push-mark "ext:avy")
 131 (declare-function avy--remove-leading-chars "ext:avy")
 132
 133 ;;;###autoload
 134 (defun swiper-avy ()
 135   "Jump to one of the current swiper candidates."
 136   (interactive)
 137   (unless (string= ivy-text "")
 138     (let* ((avy-all-windows nil)
 139            (candidates (append
 140                         (with-ivy-window
 141                           (avy--regex-candidates
 142                            (ivy--regex ivy-text)))
 143                         (save-excursion
 144                           (save-restriction
 145                             (narrow-to-region (window-start) (window-end))
 146                             (goto-char (point-min))
 147                             (forward-line)
 148                             (let ((cands))
 149                               (while (< (point) (point-max))
 150                                 (push (cons (1+ (point))
 151                                             (selected-window))
 152                                       cands)
 153                                 (forward-line))
 154                               cands)))))
 155            (candidate (unwind-protect
 156                            (prog2
 157                                (avy--make-backgrounds
 158                                 (append (avy-window-list)
 159                                         (list (ivy-state-window ivy-last))))
 160                                (if (eq avy-style 'de-bruijn)
 161                                    (avy-read-de-bruijn
 162                                     candidates avy-keys)
 163                                  (avy-read (avy-tree candidates avy-keys)
 164                                            #'avy--overlay-post
 165                                            #'avy--remove-leading-chars))
 166                              (avy-push-mark))
 167                         (avy--done))))
 168       (if (window-minibuffer-p (cdr candidate))
 169           (progn
 170             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 171             (ivy--exhibit)
 172             (ivy-done)
 173             (ivy-call))
 174         (ivy-quit-and-run
 175          (avy-action-goto (caar candidate)))))))
 176
 177 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 178 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 179
 180 ;;;###autoload
 181 (defun swiper-mc ()
 182   (interactive)
 183   (unless (require 'multiple-cursors nil t)
 184     (error "multiple-cursors isn't installed"))
 185   (let ((cands (nreverse ivy--old-cands)))
 186     (unless (string= ivy-text "")
 187       (ivy-exit-with-action
 188        (lambda (_)
 189          (let (cand)
 190            (while (setq cand (pop cands))
 191              (swiper--action cand)
 192              (when cands
 193                (mc/create-fake-cursor-at-point))))
 194          (multiple-cursors-mode 1))))))
 195
 196 (defun swiper-recenter-top-bottom (&optional arg)
 197   "Call (`recenter-top-bottom' ARG)."
 198   (interactive "P")
 199   (with-ivy-window
 200     (recenter-top-bottom arg)))
 201
 202 (defvar swiper-font-lock-exclude
 203   '(package-menu-mode
 204     gnus-summary-mode
 205     gnus-article-mode
 206     gnus-group-mode
 207     emms-playlist-mode
 208     emms-stream-mode
 209     erc-mode
 210     org-agenda-mode
 211     dired-mode
 212     jabber-chat-mode
 213     elfeed-search-mode
 214     elfeed-show-mode
 215     fundamental-mode
 216     Man-mode
 217     woman-mode
 218     mu4e-view-mode
 219     mu4e-headers-mode
 220     help-mode
 221     debbugs-gnu-mode
 222     occur-mode
 223     occur-edit-mode
 224     bongo-mode
 225     bongo-library-mode
 226     bongo-playlist-mode
 227     eww-mode
 228     twittering-mode
 229     vc-dir-mode
 230     rcirc-mode
 231     sauron-mode
 232     w3m-mode)
 233   "List of major-modes that are incompatible with font-lock-ensure.")
 234
 235 (defun swiper-font-lock-ensure-p ()
 236   "Return non-nil if we should font-lock-ensure."
 237   (or (derived-mode-p 'magit-mode)
 238               (bound-and-true-p magit-blame-mode)
 239               (memq major-mode swiper-font-lock-exclude)))
 240
 241 (defun swiper-font-lock-ensure ()
 242   "Ensure the entired buffer is highlighted."
 243   (unless (swiper-font-lock-ensure-p)
 244     (unless (> (buffer-size) 100000)
 245       (if (fboundp 'font-lock-ensure)
 246           (font-lock-ensure)
 247         (with-no-warnings (font-lock-fontify-buffer))))))
 248
 249 (defvar swiper--format-spec ""
 250   "Store the current candidates format spec.")
 251
 252 (defvar swiper--width nil
 253   "Store the amount of digits needed for the longest line nubmer.")
 254
 255 (defvar swiper-use-visual-line nil
 256   "When non-nil, use `line-move' instead of `forward-line'.")
 257
 258 (declare-function outline-show-all "outline")
 259
 260 (defun swiper--candidates (&optional numbers-width)
 261   "Return a list of this buffer lines.
 262
 263 NUMBERS-WIDTH, when specified, is used for line numbers width
 264 spec, instead of calculating it as the log of the buffer line
 265 count."
 266   (if (and visual-line-mode
 267            ;; super-slow otherwise
 268            (< (buffer-size) 20000))
 269       (progn
 270         (when (eq major-mode 'org-mode)
 271           (require 'outline)
 272           (if (fboundp 'outline-show-all)
 273               (outline-show-all)
 274             (with-no-warnings
 275               (show-all))))
 276         (setq swiper-use-visual-line t))
 277     (setq swiper-use-visual-line nil))
 278   (let ((n-lines (count-lines (point-min) (point-max))))
 279     (unless (zerop n-lines)
 280       (setq swiper--width (or numbers-width
 281                               (1+ (floor (log n-lines 10)))))
 282       (setq swiper--format-spec
 283             (format "%%-%dd " swiper--width))
 284       (let ((line-number 0)
 285             (advancer (if swiper-use-visual-line
 286                           (lambda (arg) (line-move arg t))
 287                         #'forward-line))
 288             candidates)
 289         (save-excursion
 290           (goto-char (point-min))
 291           (swiper-font-lock-ensure)
 292           (while (< (point) (point-max))
 293             (let ((str (concat
 294                         " "
 295                         (replace-regexp-in-string
 296                          "\t" "    "
 297                          (if swiper-use-visual-line
 298                              (buffer-substring
 299                               (save-excursion
 300                                 (beginning-of-visual-line)
 301                                 (point))
 302                               (save-excursion
 303                                 (end-of-visual-line)
 304                                 (point)))
 305                            (buffer-substring
 306                             (point)
 307                             (line-end-position)))))))
 308               (when (eq major-mode 'twittering-mode)
 309                 (remove-text-properties 0 (length str) '(field) str))
 310               (put-text-property 0 1 'display
 311                                  (format swiper--format-spec
 312                                          (cl-incf line-number))
 313                                  str)
 314               (push str candidates))
 315             (funcall advancer 1))
 316           (nreverse candidates))))))
 317
 318 (defvar swiper--opoint 1
 319   "The point when `swiper' starts.")
 320
 321 ;;;###autoload
 322 (defun swiper (&optional initial-input)
 323   "`isearch' with an overview.
 324 When non-nil, INITIAL-INPUT is the initial search pattern."
 325   (interactive)
 326   (swiper--ivy initial-input))
 327
 328 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 329
 330 (defvar swiper--current-line nil)
 331 (defvar swiper--current-match-start nil)
 332
 333 (defun swiper--init ()
 334   "Perform initialization common to both completion methods."
 335   (setq swiper--current-line nil)
 336   (setq swiper--current-match-start nil)
 337   (setq swiper--opoint (point))
 338   (when (bound-and-true-p evil-jumper-mode)
 339     (evil-jumper--set-jump)))
 340
 341 (defun swiper--re-builder (str)
 342   "Transform STR into a swiper regex.
 343 This is the regex used in the minibuffer, since the candidates
 344 there have line numbers. In the buffer, `ivy--regex' should be used."
 345   (cond
 346     ((equal str "")
 347      "")
 348     ((equal str "^")
 349      (setq ivy--subexps 0)
 350      ".")
 351     ((string-match "^\\^" str)
 352      (setq ivy--old-re "")
 353      (let ((re (ivy--regex-plus (substring str 1))))
 354        (if (zerop ivy--subexps)
 355            (prog1 (format "^ ?\\(%s\\)" re)
 356              (setq ivy--subexps 1))
 357          (format "^ %s" re))))
 358     (t
 359      (ivy--regex-plus str))))
 360
 361 (defvar swiper-history nil
 362   "History for `swiper'.")
 363
 364 (defvar swiper-invocation-face nil
 365   "The face at the point of invocation of `swiper'.")
 366
 367 (defun swiper--ivy (&optional initial-input)
 368   "`isearch' with an overview using `ivy'.
 369 When non-nil, INITIAL-INPUT is the initial search pattern."
 370   (interactive)
 371   (swiper--init)
 372   (setq swiper-invocation-face
 373         (plist-get (text-properties-at (point)) 'face))
 374   (let ((candidates (swiper--candidates))
 375         (preselect
 376          (if swiper-use-visual-line
 377              (count-screen-lines
 378               (point-min)
 379               (save-excursion (beginning-of-visual-line) (point)))
 380            (1- (line-number-at-pos))))
 381         (minibuffer-allow-text-properties t)
 382         res)
 383     (unwind-protect
 384          (and
 385           (setq res
 386                 (ivy-read
 387                  "Swiper: "
 388                  candidates
 389                  :initial-input initial-input
 390                  :keymap swiper-map
 391                  :preselect preselect
 392                  :require-match t
 393                  :update-fn #'swiper--update-input-ivy
 394                  :unwind #'swiper--cleanup
 395                  :action #'swiper--action
 396                  :re-builder #'swiper--re-builder
 397                  :history 'swiper-history
 398                  :caller 'swiper))
 399           (point))
 400       (unless res
 401         (goto-char swiper--opoint)))))
 402
 403 (defun swiper-toggle-face-matching ()
 404   "Toggle matching only the candidates with `swiper-invocation-face'."
 405   (interactive)
 406   (setf (ivy-state-matcher ivy-last)
 407         (if (ivy-state-matcher ivy-last)
 408             nil
 409           #'swiper--face-matcher))
 410   (setq ivy--old-re nil))
 411
 412 (defun swiper--face-matcher (regexp candidates)
 413   "Return REGEXP-matching CANDIDATES.
 414 Matched candidates should have `swiper-invocation-face'."
 415   (cl-remove-if-not
 416    (lambda (x)
 417      (and
 418       (string-match regexp x)
 419       (let ((s (match-string 0 x))
 420             (i 0))
 421         (while (and (< i (length s))
 422                     (text-property-any
 423                      i (1+ i)
 424                      'face swiper-invocation-face
 425                      s))
 426           (cl-incf i))
 427         (eq i (length s)))))
 428    candidates))
 429
 430 (defun swiper--ensure-visible ()
 431   "Remove overlays hiding point."
 432   (let ((overlays (overlays-at (point)))
 433         ov expose)
 434     (while (setq ov (pop overlays))
 435       (if (and (invisible-p (overlay-get ov 'invisible))
 436                (setq expose (overlay-get ov 'isearch-open-invisible)))
 437           (funcall expose ov)))))
 438
 439 (defvar swiper--overlays nil
 440   "Store overlays.")
 441
 442 (defun swiper--cleanup ()
 443   "Clean up the overlays."
 444   (while swiper--overlays
 445     (delete-overlay (pop swiper--overlays)))
 446   (save-excursion
 447     (goto-char (point-min))
 448     (isearch-clean-overlays)))
 449
 450 (defun swiper--update-input-ivy ()
 451   "Called when `ivy' input is updated."
 452   (with-ivy-window
 453     (swiper--cleanup)
 454     (when (> (length ivy--current) 0)
 455       (let* ((re (funcall ivy--regex-function ivy-text))
 456              (re (if (stringp re) re (caar re)))
 457              (str (get-text-property 0 'display ivy--current))
 458              (num (if (string-match "^[0-9]+" str)
 459                       (string-to-number (match-string 0 str))
 460                     0)))
 461         (unless (eq this-command 'ivy-yank-word)
 462           (when (cl-plusp num)
 463             (unless (if swiper--current-line
 464                         (eq swiper--current-line num)
 465                       (eq (line-number-at-pos) num))
 466               (goto-char (point-min))
 467               (if swiper-use-visual-line
 468                   (line-move (1- num))
 469                 (forward-line (1- num))))
 470             (if (and (equal ivy-text "")
 471                      (>= swiper--opoint (line-beginning-position))
 472                      (<= swiper--opoint (line-end-position)))
 473                 (goto-char swiper--opoint)
 474               (if (eq swiper--current-line num)
 475                   (when swiper--current-match-start
 476                     (goto-char swiper--current-match-start))
 477                 (setq swiper--current-line num))
 478               (re-search-forward re (line-end-position) t)
 479               (setq swiper--current-match-start (match-beginning 0)))
 480             (isearch-range-invisible (line-beginning-position)
 481                                      (line-end-position))
 482             (unless (and (>= (point) (window-start))
 483                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 484               (recenter))))
 485         (swiper--add-overlays re)))))
 486
 487 (defun swiper--add-overlays (re &optional beg end wnd)
 488   "Add overlays for RE regexp in visible part of the current buffer.
 489 BEG and END, when specified, are the point bounds.
 490 WND, when specified is the window."
 491   (setq wnd (or wnd (ivy-state-window ivy-last)))
 492   (let ((ov (if visual-line-mode
 493                 (make-overlay
 494                  (save-excursion
 495                    (beginning-of-visual-line)
 496                    (point))
 497                  (save-excursion
 498                    (end-of-visual-line)
 499                    (point)))
 500               (make-overlay
 501                (line-beginning-position)
 502                (1+ (line-end-position))))))
 503     (overlay-put ov 'face 'swiper-line-face)
 504     (overlay-put ov 'window wnd)
 505     (push ov swiper--overlays)
 506     (let* ((wh (window-height))
 507            (beg (or beg (save-excursion
 508                           (forward-line (- wh))
 509                           (point))))
 510            (end (or end (save-excursion
 511                           (forward-line wh)
 512                           (point)))))
 513       (when (>= (length re) swiper-min-highlight)
 514         (save-excursion
 515           (goto-char beg)
 516           ;; RE can become an invalid regexp
 517           (while (and (ignore-errors (re-search-forward re end t))
 518                       (> (- (match-end 0) (match-beginning 0)) 0))
 519             (let ((i 0))
 520               (while (<= i ivy--subexps)
 521                 (when (match-beginning i)
 522                   (let ((overlay (make-overlay (match-beginning i)
 523                                                (match-end i)))
 524                         (face
 525                          (cond ((zerop ivy--subexps)
 526                                 (cadr swiper-faces))
 527                                ((zerop i)
 528                                 (car swiper-faces))
 529                                (t
 530                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 531                                      swiper-faces)))))
 532                     (push overlay swiper--overlays)
 533                     (overlay-put overlay 'face face)
 534                     (overlay-put overlay 'window wnd)
 535                     (overlay-put overlay 'priority i)))
 536                 (cl-incf i)))))))))
 537
 538 (defun swiper--action (x)
 539   "Goto line X."
 540   (if (null x)
 541       (user-error "No candidates")
 542     (with-ivy-window
 543       (unless (equal (current-buffer)
 544                      (ivy-state-buffer ivy-last))
 545         (switch-to-buffer (ivy-state-buffer ivy-last)))
 546       (goto-char (point-min))
 547       (funcall (if swiper-use-visual-line
 548                    #'line-move
 549                  #'forward-line)
 550                (1- (read (get-text-property 0 'display x))))
 551       (re-search-forward
 552        (ivy--regex ivy-text) (line-end-position) t)
 553       (swiper--ensure-visible)
 554       (when (/= (point) swiper--opoint)
 555         (unless (and transient-mark-mode mark-active)
 556           (when (eq ivy-exit 'done)
 557             (push-mark swiper--opoint t)
 558             (message "Mark saved where search started"))))
 559       (add-to-history
 560        'regexp-search-ring
 561        (ivy--regex ivy-text)
 562        regexp-search-ring-max))))
 563
 564 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 565 (defun swiper-from-isearch ()
 566   "Invoke `swiper' from isearch."
 567   (interactive)
 568   (let ((query (if isearch-regexp
 569                    isearch-string
 570                  (regexp-quote isearch-string))))
 571     (isearch-exit)
 572     (swiper query)))
 573
 574 (defvar swiper-multi-buffers nil
 575   "Store the current list of buffers.")
 576
 577 (defvar swiper-multi-candidates nil
 578   "Store the list of candidates for `swiper-multi'.")
 579
 580 (defun swiper-multi-prompt ()
 581   (format "Buffers (%s): "
 582           (mapconcat #'identity swiper-multi-buffers ", ")))
 583
 584 (defun swiper-multi ()
 585   "Select one or more buffers.
 586 Run `swiper' for those buffers."
 587   (interactive)
 588   (setq swiper-multi-buffers nil)
 589   (ivy-read (swiper-multi-prompt)
 590             'internal-complete-buffer
 591             :action 'swiper-multi-action-1)
 592   (ivy-read "Swiper: " swiper-multi-candidates
 593             :action 'swiper-multi-action-2
 594             :unwind #'swiper--cleanup
 595             :caller 'swiper-multi))
 596
 597 (defun swiper-all ()
 598   "Run `swiper' for all opened buffers."
 599   (interactive)
 600   (ivy-read "Swiper: " (swiper--multi-candidates
 601                         (cl-remove-if-not
 602                          #'buffer-file-name
 603                          (buffer-list)))
 604             :action 'swiper-multi-action-2
 605             :unwind #'swiper--cleanup
 606             :caller 'swiper-multi))
 607
 608 (defun swiper--multi-candidates (buffers)
 609   (let* ((ww (window-width))
 610          (res nil)
 611          (column-2 (apply #'max
 612                           (mapcar
 613                            (lambda (b)
 614                              (length (buffer-name b)))
 615                            buffers)))
 616          (column-1 (- ww 4 column-2 1)))
 617     (dolist (buf buffers)
 618       (with-current-buffer buf
 619         (setq res
 620               (append
 621                (mapcar
 622                 (lambda (s)
 623                   (setq s (concat (ivy--truncate-string s column-1) " "))
 624                   (let ((len (length s)))
 625                     (put-text-property
 626                      (1- len) len 'display
 627                      (concat
 628                       (make-string
 629                        (- ww (string-width s) (length (buffer-name)) 3)
 630                        ?\ )
 631                       (buffer-name))
 632                      s)
 633                     s))
 634                 (swiper--candidates 4))
 635                res))
 636         nil))
 637     res))
 638
 639 (defun swiper-multi-action-1 (x)
 640   (if (member x swiper-multi-buffers)
 641       (progn
 642         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 643     (unless (equal x "")
 644       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 645   (let ((prompt (swiper-multi-prompt)))
 646     (setf (ivy-state-prompt ivy-last) prompt)
 647     (setq ivy--prompt (concat "%-4d " prompt)))
 648   (cond ((memq this-command '(ivy-done
 649                               ivy-alt-done
 650                               ivy-immediate-done))
 651          (setq swiper-multi-candidates
 652                (swiper--multi-candidates
 653                 (mapcar #'get-buffer swiper-multi-buffers))))
 654         ((eq this-command 'ivy-call)
 655          (delete-minibuffer-contents))))
 656
 657 (defun swiper-multi-action-2 (x)
 658   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 659     (with-ivy-window
 660       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 661         (switch-to-buffer (match-string 1 buf-space))
 662         (goto-char (point-min))
 663         (forward-line (1- (read (get-text-property 0 'display x))))
 664         (re-search-forward
 665          (ivy--regex ivy-text)
 666          (line-end-position) t)
 667         (unless (eq ivy-exit 'done)
 668           (swiper--cleanup)
 669           (swiper--add-overlays (ivy--regex ivy-text)))))))
 670
 671 (provide 'swiper)
 672
 673 ;;; swiper.el ends here