code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.6.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     map)
  97   "Keymap for swiper.")
  98
  99 (defun swiper-query-replace ()
 100   "Start `query-replace' with string to replace from last search string."
 101   (interactive)
 102   (if (null (window-minibuffer-p))
 103       (user-error "Should only be called in the minibuffer through `swiper-map'")
 104     (let* ((enable-recursive-minibuffers t)
 105            (from (ivy--regex ivy-text))
 106            (to (query-replace-read-to from "Query replace" t)))
 107       (delete-minibuffer-contents)
 108       (ivy-set-action (lambda (_)
 109                         (with-ivy-window
 110                           (move-beginning-of-line 1)
 111                           (perform-replace from to
 112                                            t t nil))))
 113       (swiper--cleanup)
 114       (exit-minibuffer))))
 115
 116 (defvar avy-background)
 117 (defvar avy-all-windows)
 118 (defvar avy-style)
 119 (defvar avy-keys)
 120 (declare-function avy--regex-candidates "ext:avy")
 121 (declare-function avy--process "ext:avy")
 122 (declare-function avy--overlay-post "ext:avy")
 123 (declare-function avy-action-goto "ext:avy")
 124 (declare-function avy--done "ext:avy")
 125 (declare-function avy--make-backgrounds "ext:avy")
 126 (declare-function avy-window-list "ext:avy")
 127 (declare-function avy-read "ext:avy")
 128 (declare-function avy-read-de-bruijn "ext:avy")
 129 (declare-function avy-tree "ext:avy")
 130 (declare-function avy-push-mark "ext:avy")
 131 (declare-function avy--remove-leading-chars "ext:avy")
 132
 133 ;;;###autoload
 134 (defun swiper-avy ()
 135   "Jump to one of the current swiper candidates."
 136   (interactive)
 137   (unless (string= ivy-text "")
 138     (let* ((avy-all-windows nil)
 139            (candidates (append
 140                         (with-ivy-window
 141                           (avy--regex-candidates
 142                            (ivy--regex ivy-text)))
 143                         (save-excursion
 144                           (save-restriction
 145                             (narrow-to-region (window-start) (window-end))
 146                             (goto-char (point-min))
 147                             (forward-line)
 148                             (let ((cands))
 149                               (while (< (point) (point-max))
 150                                 (push (cons (1+ (point))
 151                                             (selected-window))
 152                                       cands)
 153                                 (forward-line))
 154                               cands)))))
 155            (candidate (unwind-protect
 156                           (prog2
 157                               (avy--make-backgrounds
 158                                (append (avy-window-list)
 159                                        (list  (ivy-state-window ivy-last))))
 160                               (if (eq avy-style 'de-bruijn)
 161                                   (avy-read-de-bruijn
 162                                    candidates avy-keys)
 163                                 (avy-read (avy-tree candidates avy-keys)
 164                                           #'avy--overlay-post
 165                                           #'avy--remove-leading-chars))
 166                             (avy-push-mark))
 167                         (avy--done))))
 168       (if (window-minibuffer-p (cdr candidate))
 169           (progn
 170             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 171             (ivy--exhibit)
 172             (ivy-done)
 173             (ivy-call))
 174         (ivy-quit-and-run
 175          (avy-action-goto (caar candidate)))))))
 176
 177 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 178 (declare-function mc/maybe-multiple-cursors-mode "ext:multiple-cursors-core")
 179
 180 ;;;###autoload
 181 (defun swiper-mc ()
 182   (interactive)
 183   (unless (require 'multiple-cursors nil t)
 184     (error "multiple-cursors isn't installed"))
 185   (let ((cands (nreverse ivy--old-cands)))
 186     (unless (string= ivy-text "")
 187       (ivy-set-action
 188        (lambda (_)
 189          (let (cand)
 190            (while (setq cand (pop cands))
 191              (swiper--action cand)
 192              (when cands
 193                (mc/create-fake-cursor-at-point))))
 194          (mc/maybe-multiple-cursors-mode)))
 195       (setq ivy-exit 'done)
 196       (exit-minibuffer))))
 197
 198 (defun swiper-recenter-top-bottom (&optional arg)
 199   "Call (`recenter-top-bottom' ARG)."
 200   (interactive "P")
 201   (with-ivy-window
 202     (recenter-top-bottom arg)))
 203
 204 (defun swiper-font-lock-ensure ()
 205   "Ensure the entired buffer is highlighted."
 206   (unless (or (derived-mode-p 'magit-mode)
 207               (bound-and-true-p magit-blame-mode)
 208               (memq major-mode '(package-menu-mode
 209                                  gnus-summary-mode
 210                                  gnus-article-mode
 211                                  gnus-group-mode
 212                                  emms-playlist-mode erc-mode
 213                                  org-agenda-mode
 214                                  dired-mode
 215                                  jabber-chat-mode
 216                                  elfeed-search-mode
 217                                  elfeed-show-mode
 218                                  fundamental-mode
 219                                  Man-mode
 220                                  woman-mode
 221                                  mu4e-view-mode
 222                                  mu4e-headers-mode
 223                                  help-mode
 224                                  w3m-mode)))
 225     (unless (> (buffer-size) 100000)
 226       (if (fboundp 'font-lock-ensure)
 227           (font-lock-ensure)
 228         (with-no-warnings (font-lock-fontify-buffer))))))
 229
 230 (defvar swiper--format-spec ""
 231   "Store the current candidates format spec.")
 232
 233 (defvar swiper--width nil
 234   "Store the amount of digits needed for the longest line nubmer.")
 235
 236 (defvar swiper-use-visual-line nil
 237   "When non-nil, use `line-move' instead of `forward-line'.")
 238
 239 (defun swiper--candidates ()
 240   "Return a list of this buffer lines."
 241   (setq swiper-use-visual-line
 242         (and (not (eq major-mode 'org-mode))
 243              visual-line-mode
 244              (< (buffer-size) 20000)))
 245   (let ((n-lines (count-lines (point-min) (point-max))))
 246     (unless (zerop n-lines)
 247       (setq swiper--width (1+ (floor (log n-lines 10))))
 248       (setq swiper--format-spec
 249             (format "%%-%dd " swiper--width))
 250       (let ((line-number 0)
 251             (advancer (if swiper-use-visual-line
 252                           (lambda (arg) (line-move arg t))
 253                         #'forward-line))
 254             candidates)
 255         (save-excursion
 256           (goto-char (point-min))
 257           (swiper-font-lock-ensure)
 258           (while (< (point) (point-max))
 259             (let ((str (concat " " (buffer-substring
 260                                     (point)
 261                                     (if swiper-use-visual-line
 262                                         (save-excursion
 263                                           (end-of-visual-line)
 264                                           (point))
 265                                       (line-end-position))))))
 266               (put-text-property 0 1 'display
 267                                  (format swiper--format-spec
 268                                          (cl-incf line-number))
 269                                  str)
 270               (push str candidates))
 271             (funcall advancer 1))
 272           (nreverse candidates))))))
 273
 274 (defvar swiper--opoint 1
 275   "The point when `swiper' starts.")
 276
 277 ;;;###autoload
 278 (defun swiper (&optional initial-input)
 279   "`isearch' with an overview.
 280 When non-nil, INITIAL-INPUT is the initial search pattern."
 281   (interactive)
 282   (swiper--ivy initial-input))
 283
 284 (defvar swiper--anchor nil
 285   "A line number to which the search should be anchored.")
 286
 287 (defvar swiper--len 0
 288   "The last length of input for which an anchoring was made.")
 289
 290 (defun swiper--init ()
 291   "Perform initialization common to both completion methods."
 292   (setq swiper--opoint (point))
 293   (setq swiper--len 0)
 294   (setq swiper--anchor (line-number-at-pos)))
 295
 296 (defun swiper--re-builder (str)
 297   "Transform STR into a swiper regex.
 298 This is the regex used in the minibuffer, since the candidates
 299 there have line numbers. In the buffer, `ivy--regex' should be used."
 300   (cond
 301     ((equal str "")
 302      "")
 303     ((equal str "^")
 304      (setq ivy--subexps 0)
 305      ".")
 306     ((string-match "^\\^" str)
 307      (setq ivy--old-re "")
 308      (let ((re (ivy--regex-plus (substring str 1))))
 309        (if (zerop ivy--subexps)
 310            (prog1 (format "^ ?\\(%s\\)" re)
 311              (setq ivy--subexps 1))
 312          (format "^ %s" re))))
 313     (t
 314      (ivy--regex-plus str))))
 315
 316 (defvar swiper-history nil
 317   "History for `swiper'.")
 318
 319 (defun swiper--ivy (&optional initial-input)
 320   "`isearch' with an overview using `ivy'.
 321 When non-nil, INITIAL-INPUT is the initial search pattern."
 322   (interactive)
 323   (swiper--init)
 324   (let ((candidates (swiper--candidates))
 325         (preselect (buffer-substring-no-properties
 326                     (line-beginning-position)
 327                     (line-end-position)))
 328         (minibuffer-allow-text-properties t))
 329     (unwind-protect
 330         (ivy-read
 331          "Swiper: "
 332          candidates
 333          :initial-input initial-input
 334          :keymap swiper-map
 335          :preselect preselect
 336          :require-match t
 337          :update-fn #'swiper--update-input-ivy
 338          :unwind #'swiper--cleanup
 339          :action #'swiper--action
 340          :re-builder #'swiper--re-builder
 341          :history 'swiper-history
 342          :caller 'swiper)
 343       (when (null ivy-exit)
 344         (goto-char swiper--opoint)))))
 345
 346 (defun swiper--ensure-visible ()
 347   "Remove overlays hiding point."
 348   (let ((overlays (overlays-at (point)))
 349         ov expose)
 350     (while (setq ov (pop overlays))
 351       (if (and (invisible-p (overlay-get ov 'invisible))
 352                (setq expose (overlay-get ov 'isearch-open-invisible)))
 353           (funcall expose ov)))))
 354
 355 (defvar swiper--overlays nil
 356   "Store overlays.")
 357
 358 (defun swiper--cleanup ()
 359   "Clean up the overlays."
 360   (while swiper--overlays
 361     (delete-overlay (pop swiper--overlays)))
 362   (save-excursion
 363     (goto-char (point-min))
 364     (isearch-clean-overlays)))
 365
 366 (defun swiper--update-input-ivy ()
 367   "Called when `ivy' input is updated."
 368   (with-ivy-window
 369     (swiper--cleanup)
 370     (when (> (length ivy--current) 0)
 371       (let* ((re (funcall ivy--regex-function ivy-text))
 372              (re (if (stringp re) re (caar re)))
 373              (str (get-text-property 0 'display ivy--current))
 374              (num (if (string-match "^[0-9]+" str)
 375                       (string-to-number (match-string 0 str))
 376                     0)))
 377         (goto-char (point-min))
 378         (when (cl-plusp num)
 379           (goto-char (point-min))
 380           (if swiper-use-visual-line
 381               (line-move (1- num))
 382             (forward-line (1- num)))
 383           (if (and (equal ivy-text "")
 384                    (>= swiper--opoint (line-beginning-position))
 385                    (<= swiper--opoint (line-end-position)))
 386               (goto-char swiper--opoint)
 387             (re-search-forward re (line-end-position) t))
 388           (isearch-range-invisible (line-beginning-position)
 389                                    (line-end-position))
 390           (unless (and (>= (point) (window-start))
 391                        (<= (point) (window-end (ivy-state-window ivy-last) t)))
 392             (recenter)))
 393         (swiper--add-overlays re)))))
 394
 395 (defun swiper--add-overlays (re &optional beg end)
 396   "Add overlays for RE regexp in visible part of the current buffer.
 397 BEG and END, when specified, are the point bounds."
 398   (let ((ov (if visual-line-mode
 399                 (make-overlay
 400                  (save-excursion
 401                    (beginning-of-visual-line)
 402                    (point))
 403                  (save-excursion
 404                    (end-of-visual-line)
 405                    (point)))
 406               (make-overlay
 407                (line-beginning-position)
 408                (1+ (line-end-position))))))
 409     (overlay-put ov 'face 'swiper-line-face)
 410     (overlay-put ov 'window (ivy-state-window ivy-last))
 411     (push ov swiper--overlays)
 412     (let* ((wh (window-height))
 413            (beg (or beg (save-excursion
 414                           (forward-line (- wh))
 415                           (point))))
 416            (end (or end (save-excursion
 417                           (forward-line wh)
 418                           (point)))))
 419       (when (>= (length re) swiper-min-highlight)
 420         (save-excursion
 421           (goto-char beg)
 422           ;; RE can become an invalid regexp
 423           (while (and (ignore-errors (re-search-forward re end t))
 424                       (> (- (match-end 0) (match-beginning 0)) 0))
 425             (let ((i 0))
 426               (while (<= i ivy--subexps)
 427                 (when (match-beginning i)
 428                   (let ((overlay (make-overlay (match-beginning i)
 429                                                (match-end i)))
 430                         (face
 431                          (cond ((zerop ivy--subexps)
 432                                 (cadr swiper-faces))
 433                                ((zerop i)
 434                                 (car swiper-faces))
 435                                (t
 436                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 437                                      swiper-faces)))))
 438                     (push overlay swiper--overlays)
 439                     (overlay-put overlay 'face face)
 440                     (overlay-put overlay 'window (ivy-state-window ivy-last))
 441                     (overlay-put overlay 'priority i)))
 442                 (cl-incf i)))))))))
 443
 444 (defun swiper--action (x)
 445   "Goto line X."
 446   (if (null x)
 447       (user-error "No candidates")
 448     (goto-char (point-min))
 449     (funcall (if swiper-use-visual-line
 450                  #'line-move
 451                #'forward-line)
 452              (1- (read (get-text-property 0 'display x))))
 453     (re-search-forward
 454      (ivy--regex ivy-text) (line-end-position) t)
 455     (swiper--ensure-visible)
 456     (when (/= (point) swiper--opoint)
 457       (unless (and transient-mark-mode mark-active)
 458         (push-mark swiper--opoint t)
 459         (message "Mark saved where search started")))))
 460
 461 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 462 (defun swiper-from-isearch ()
 463   "Invoke `swiper' from isearch."
 464   (interactive)
 465   (let ((query (if isearch-regexp
 466                    isearch-string
 467                  (regexp-quote isearch-string))))
 468     (isearch-exit)
 469     (swiper query)))
 470
 471 (defvar swiper-multi-buffers nil
 472   "Store the current list of buffers.")
 473
 474 (defvar swiper-multi-candidates nil
 475   "Store the list of candidates for `swiper-multi'.")
 476
 477 (defun swiper-multi-prompt ()
 478   (format "Buffers (%s): "
 479           (mapconcat #'identity swiper-multi-buffers ", ")))
 480
 481 (defun swiper-multi ()
 482   "Select one or more buffers.
 483 Run `swiper' for those buffers."
 484   (interactive)
 485   (setq swiper-multi-buffers nil)
 486   (setq swiper-multi-candidates nil)
 487   (ivy-read (swiper-multi-prompt)
 488             'internal-complete-buffer
 489             :action 'swiper-multi-action-1)
 490   (ivy-read "Swiper: " swiper-multi-candidates
 491             :action 'swiper-multi-action-2
 492             :unwind #'swiper--cleanup
 493             :caller 'swiper-multi))
 494
 495 (defun swiper-multi-action-1 (x)
 496   (if (member x swiper-multi-buffers)
 497       (progn
 498         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 499     (unless (equal x "")
 500       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 501   (let ((prompt (swiper-multi-prompt)))
 502     (setf (ivy-state-prompt ivy-last) prompt)
 503     (setq ivy--prompt (concat "%-4d " prompt)))
 504   (cond ((memq this-command '(ivy-done
 505                               ivy-alt-done
 506                               ivy-immediate-done))
 507          (let ((ww (window-width)))
 508            (dolist (buf swiper-multi-buffers)
 509              (with-current-buffer buf
 510                (setq swiper-multi-candidates
 511                      (append
 512                       (mapcar
 513                        (lambda (s)
 514                          (setq s (concat s " "))
 515                          (let ((len (length s)))
 516                            (put-text-property
 517                             (1- len) len 'display
 518                             (concat
 519                              (make-string
 520                               (max
 521                                (- ww
 522                                   (string-width s)
 523                                   (length (buffer-name))
 524                                   1)
 525                                0)
 526                               ?\ )
 527                              (buffer-name))
 528                             s)
 529                            s))
 530                        (swiper--candidates))
 531                       swiper-multi-candidates))))))
 532         ((eq this-command 'ivy-call)
 533          (delete-minibuffer-contents))))
 534
 535 (defun swiper-multi-action-2 (x)
 536   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 537     (with-ivy-window
 538       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 539         (switch-to-buffer (match-string 1 buf-space))
 540         (goto-char (point-min))
 541         (forward-line (1- (read x)))
 542         (re-search-forward
 543          (ivy--regex ivy-text)
 544          (line-end-position) t)
 545         (unless (eq ivy-exit 'done)
 546           (swiper--cleanup)
 547           (swiper--add-overlays (ivy--regex ivy-text)))))))
 548
 549 (provide 'swiper)
 550
 551 ;;; swiper.el ends here