code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (swiper--cleanup)
 109       (ivy-exit-with-action
 110        (lambda (_)
 111          (with-ivy-window
 112            (move-beginning-of-line 1)
 113            (perform-replace from to
 114                             t t nil)))))))
 115
 116 (defvar avy-background)
 117 (defvar avy-all-windows)
 118 (defvar avy-style)
 119 (defvar avy-keys)
 120 (declare-function avy--regex-candidates "ext:avy")
 121 (declare-function avy--process "ext:avy")
 122 (declare-function avy--overlay-post "ext:avy")
 123 (declare-function avy-action-goto "ext:avy")
 124 (declare-function avy--done "ext:avy")
 125 (declare-function avy--make-backgrounds "ext:avy")
 126 (declare-function avy-window-list "ext:avy")
 127 (declare-function avy-read "ext:avy")
 128 (declare-function avy-read-de-bruijn "ext:avy")
 129 (declare-function avy-tree "ext:avy")
 130 (declare-function avy-push-mark "ext:avy")
 131 (declare-function avy--remove-leading-chars "ext:avy")
 132
 133 ;;;###autoload
 134 (defun swiper-avy ()
 135   "Jump to one of the current swiper candidates."
 136   (interactive)
 137   (unless (string= ivy-text "")
 138     (let* ((avy-all-windows nil)
 139            (candidates (append
 140                         (with-ivy-window
 141                           (avy--regex-candidates
 142                            (ivy--regex ivy-text)))
 143                         (save-excursion
 144                           (save-restriction
 145                             (narrow-to-region (window-start) (window-end))
 146                             (goto-char (point-min))
 147                             (forward-line)
 148                             (let ((cands))
 149                               (while (< (point) (point-max))
 150                                 (push (cons (1+ (point))
 151                                             (selected-window))
 152                                       cands)
 153                                 (forward-line))
 154                               cands)))))
 155            (candidate (unwind-protect
 156                            (prog2
 157                                (avy--make-backgrounds
 158                                 (append (avy-window-list)
 159                                         (list (ivy-state-window ivy-last))))
 160                                (if (eq avy-style 'de-bruijn)
 161                                    (avy-read-de-bruijn
 162                                     candidates avy-keys)
 163                                  (avy-read (avy-tree candidates avy-keys)
 164                                            #'avy--overlay-post
 165                                            #'avy--remove-leading-chars))
 166                              (avy-push-mark))
 167                         (avy--done))))
 168       (if (window-minibuffer-p (cdr candidate))
 169           (progn
 170             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 171             (ivy--exhibit)
 172             (ivy-done)
 173             (ivy-call))
 174         (ivy-quit-and-run
 175          (avy-action-goto (caar candidate)))))))
 176
 177 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 178 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 179
 180 ;;;###autoload
 181 (defun swiper-mc ()
 182   (interactive)
 183   (unless (require 'multiple-cursors nil t)
 184     (error "multiple-cursors isn't installed"))
 185   (let ((cands (nreverse ivy--old-cands)))
 186     (unless (string= ivy-text "")
 187       (ivy-exit-with-action
 188        (lambda (_)
 189          (let (cand)
 190            (while (setq cand (pop cands))
 191              (swiper--action cand)
 192              (when cands
 193                (mc/create-fake-cursor-at-point))))
 194          (multiple-cursors-mode 1))))))
 195
 196 (defun swiper-recenter-top-bottom (&optional arg)
 197   "Call (`recenter-top-bottom' ARG)."
 198   (interactive "P")
 199   (with-ivy-window
 200     (recenter-top-bottom arg)))
 201
 202 (defvar swiper-font-lock-exclude
 203   '(package-menu-mode
 204     gnus-summary-mode
 205     gnus-article-mode
 206     gnus-group-mode
 207     emms-playlist-mode
 208     emms-stream-mode
 209     erc-mode
 210     org-agenda-mode
 211     dired-mode
 212     jabber-chat-mode
 213     elfeed-search-mode
 214     elfeed-show-mode
 215     fundamental-mode
 216     Man-mode
 217     woman-mode
 218     mu4e-view-mode
 219     mu4e-headers-mode
 220     help-mode
 221     debbugs-gnu-mode
 222     occur-mode
 223     occur-edit-mode
 224     bongo-mode
 225     bongo-library-mode
 226     bongo-playlist-mode
 227     eww-mode
 228     twittering-mode
 229     vc-dir-mode
 230     rcirc-mode
 231     sauron-mode
 232     w3m-mode)
 233   "List of major-modes that are incompatible with font-lock-ensure.")
 234
 235 (defun swiper-font-lock-ensure-p ()
 236   "Return non-nil if we should font-lock-ensure."
 237   (or (derived-mode-p 'magit-mode)
 238               (bound-and-true-p magit-blame-mode)
 239               (memq major-mode swiper-font-lock-exclude)))
 240
 241 (defun swiper-font-lock-ensure ()
 242   "Ensure the entired buffer is highlighted."
 243   (unless (swiper-font-lock-ensure-p)
 244     (unless (> (buffer-size) 100000)
 245       (if (fboundp 'font-lock-ensure)
 246           (font-lock-ensure)
 247         (with-no-warnings (font-lock-fontify-buffer))))))
 248
 249 (defvar swiper--format-spec ""
 250   "Store the current candidates format spec.")
 251
 252 (defvar swiper--width nil
 253   "Store the amount of digits needed for the longest line nubmer.")
 254
 255 (defvar swiper-use-visual-line nil
 256   "When non-nil, use `line-move' instead of `forward-line'.")
 257
 258 (declare-function outline-show-all "outline")
 259
 260 (defun swiper--candidates (&optional numbers-width)
 261   "Return a list of this buffer lines.
 262
 263 NUMBERS-WIDTH, when specified, is used for line numbers width
 264 spec, instead of calculating it as the log of the buffer line
 265 count."
 266   (if (and visual-line-mode
 267            ;; super-slow otherwise
 268            (< (buffer-size) 20000))
 269       (progn
 270         (when (eq major-mode 'org-mode)
 271           (require 'outline)
 272           (if (fboundp 'outline-show-all)
 273               (outline-show-all)
 274             (with-no-warnings
 275               (show-all))))
 276         (setq swiper-use-visual-line t))
 277     (setq swiper-use-visual-line nil))
 278   (let ((n-lines (count-lines (point-min) (point-max))))
 279     (unless (zerop n-lines)
 280       (setq swiper--width (or numbers-width
 281                               (1+ (floor (log n-lines 10)))))
 282       (setq swiper--format-spec
 283             (format "%%-%dd " swiper--width))
 284       (let ((line-number 0)
 285             (advancer (if swiper-use-visual-line
 286                           (lambda (arg) (line-move arg t))
 287                         #'forward-line))
 288             candidates)
 289         (save-excursion
 290           (goto-char (point-min))
 291           (swiper-font-lock-ensure)
 292           (while (< (point) (point-max))
 293             (let ((str (concat
 294                         " "
 295                         (replace-regexp-in-string
 296                          "\t" "    "
 297                          (if swiper-use-visual-line
 298                              (buffer-substring
 299                               (save-excursion
 300                                 (beginning-of-visual-line)
 301                                 (point))
 302                               (save-excursion
 303                                 (end-of-visual-line)
 304                                 (point)))
 305                            (buffer-substring
 306                             (point)
 307                             (line-end-position)))))))
 308               (when (eq major-mode 'twittering-mode)
 309                 (remove-text-properties 0 (length str) '(field) str))
 310               (put-text-property 0 1 'display
 311                                  (format swiper--format-spec
 312                                          (cl-incf line-number))
 313                                  str)
 314               (push str candidates))
 315             (funcall advancer 1))
 316           (nreverse candidates))))))
 317
 318 (defvar swiper--opoint 1
 319   "The point when `swiper' starts.")
 320
 321 ;;;###autoload
 322 (defun swiper (&optional initial-input)
 323   "`isearch' with an overview.
 324 When non-nil, INITIAL-INPUT is the initial search pattern."
 325   (interactive)
 326   (swiper--ivy initial-input))
 327
 328 (defun swiper-occur ()
 329   "Generate a custom occur buffer for `swiper'."
 330   (ivy-occur-grep-mode)
 331   (font-lock-mode -1)
 332   (let* ((fname (propertize
 333                  (with-ivy-window
 334                    (file-name-nondirectory
 335                     (buffer-file-name)))
 336                  'face
 337                  'compilation-info))
 338          (cands (mapcar
 339                  (lambda (s)
 340                    (format "%s:%s:%s"
 341                            fname
 342                            (propertize
 343                             (string-trim-right
 344                              (get-text-property 0 'display s))
 345                             'face 'compilation-line-number)
 346                            (substring s 1)))
 347                  ivy--old-cands)))
 348     (insert (format "-*- mode:grep; default-directory: %S -*-\n\n\n"
 349                     default-directory))
 350     (insert (format "%d candidates:\n" (length cands)))
 351     (ivy--occur-insert-lines
 352      (mapcar
 353       (lambda (cand) (concat "./" cand))
 354       cands))))
 355
 356 (ivy-set-occur 'swiper 'swiper-occur)
 357
 358 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 359
 360 (defvar swiper--current-line nil)
 361 (defvar swiper--current-match-start nil)
 362
 363 (defun swiper--init ()
 364   "Perform initialization common to both completion methods."
 365   (setq swiper--current-line nil)
 366   (setq swiper--current-match-start nil)
 367   (setq swiper--opoint (point))
 368   (when (bound-and-true-p evil-jumper-mode)
 369     (evil-jumper--set-jump)))
 370
 371 (defun swiper--re-builder (str)
 372   "Transform STR into a swiper regex.
 373 This is the regex used in the minibuffer, since the candidates
 374 there have line numbers. In the buffer, `ivy--regex' should be used."
 375   (cond
 376     ((equal str "")
 377      "")
 378     ((equal str "^")
 379      (setq ivy--subexps 0)
 380      ".")
 381     ((string-match "^\\^" str)
 382      (setq ivy--old-re "")
 383      (let ((re (ivy--regex-plus (substring str 1))))
 384        (if (zerop ivy--subexps)
 385            (prog1 (format "^ ?\\(%s\\)" re)
 386              (setq ivy--subexps 1))
 387          (format "^ %s" re))))
 388     (t
 389      (ivy--regex-plus str))))
 390
 391 (defvar swiper-history nil
 392   "History for `swiper'.")
 393
 394 (defvar swiper-invocation-face nil
 395   "The face at the point of invocation of `swiper'.")
 396
 397 (defun swiper--ivy (&optional initial-input)
 398   "`isearch' with an overview using `ivy'.
 399 When non-nil, INITIAL-INPUT is the initial search pattern."
 400   (interactive)
 401   (swiper--init)
 402   (setq swiper-invocation-face
 403         (plist-get (text-properties-at (point)) 'face))
 404   (let ((candidates (swiper--candidates))
 405         (preselect
 406          (if swiper-use-visual-line
 407              (count-screen-lines
 408               (point-min)
 409               (save-excursion (beginning-of-visual-line) (point)))
 410            (1- (line-number-at-pos))))
 411         (minibuffer-allow-text-properties t)
 412         res)
 413     (unwind-protect
 414          (and
 415           (setq res
 416                 (ivy-read
 417                  "Swiper: "
 418                  candidates
 419                  :initial-input initial-input
 420                  :keymap swiper-map
 421                  :preselect preselect
 422                  :require-match t
 423                  :update-fn #'swiper--update-input-ivy
 424                  :unwind #'swiper--cleanup
 425                  :action #'swiper--action
 426                  :re-builder #'swiper--re-builder
 427                  :history 'swiper-history
 428                  :caller 'swiper))
 429           (point))
 430       (unless res
 431         (goto-char swiper--opoint)))))
 432
 433 (defun swiper-toggle-face-matching ()
 434   "Toggle matching only the candidates with `swiper-invocation-face'."
 435   (interactive)
 436   (setf (ivy-state-matcher ivy-last)
 437         (if (ivy-state-matcher ivy-last)
 438             nil
 439           #'swiper--face-matcher))
 440   (setq ivy--old-re nil))
 441
 442 (defun swiper--face-matcher (regexp candidates)
 443   "Return REGEXP-matching CANDIDATES.
 444 Matched candidates should have `swiper-invocation-face'."
 445   (cl-remove-if-not
 446    (lambda (x)
 447      (and
 448       (string-match regexp x)
 449       (let ((s (match-string 0 x))
 450             (i 0))
 451         (while (and (< i (length s))
 452                     (text-property-any
 453                      i (1+ i)
 454                      'face swiper-invocation-face
 455                      s))
 456           (cl-incf i))
 457         (eq i (length s)))))
 458    candidates))
 459
 460 (defun swiper--ensure-visible ()
 461   "Remove overlays hiding point."
 462   (let ((overlays (overlays-at (point)))
 463         ov expose)
 464     (while (setq ov (pop overlays))
 465       (if (and (invisible-p (overlay-get ov 'invisible))
 466                (setq expose (overlay-get ov 'isearch-open-invisible)))
 467           (funcall expose ov)))))
 468
 469 (defvar swiper--overlays nil
 470   "Store overlays.")
 471
 472 (defun swiper--cleanup ()
 473   "Clean up the overlays."
 474   (while swiper--overlays
 475     (delete-overlay (pop swiper--overlays)))
 476   (save-excursion
 477     (goto-char (point-min))
 478     (isearch-clean-overlays)))
 479
 480 (defun swiper--update-input-ivy ()
 481   "Called when `ivy' input is updated."
 482   (with-ivy-window
 483     (swiper--cleanup)
 484     (when (> (length ivy--current) 0)
 485       (let* ((re (funcall ivy--regex-function ivy-text))
 486              (re (if (stringp re) re (caar re)))
 487              (str (get-text-property 0 'display ivy--current))
 488              (num (if (string-match "^[0-9]+" str)
 489                       (string-to-number (match-string 0 str))
 490                     0)))
 491         (unless (eq this-command 'ivy-yank-word)
 492           (when (cl-plusp num)
 493             (unless (if swiper--current-line
 494                         (eq swiper--current-line num)
 495                       (eq (line-number-at-pos) num))
 496               (goto-char (point-min))
 497               (if swiper-use-visual-line
 498                   (line-move (1- num))
 499                 (forward-line (1- num))))
 500             (if (and (equal ivy-text "")
 501                      (>= swiper--opoint (line-beginning-position))
 502                      (<= swiper--opoint (line-end-position)))
 503                 (goto-char swiper--opoint)
 504               (if (eq swiper--current-line num)
 505                   (when swiper--current-match-start
 506                     (goto-char swiper--current-match-start))
 507                 (setq swiper--current-line num))
 508               (when (re-search-forward re (line-end-position) t)
 509                 (setq swiper--current-match-start (match-beginning 0))))
 510             (isearch-range-invisible (line-beginning-position)
 511                                      (line-end-position))
 512             (unless (and (>= (point) (window-start))
 513                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 514               (recenter))))
 515         (swiper--add-overlays re)))))
 516
 517 (defun swiper--add-overlays (re &optional beg end wnd)
 518   "Add overlays for RE regexp in visible part of the current buffer.
 519 BEG and END, when specified, are the point bounds.
 520 WND, when specified is the window."
 521   (setq wnd (or wnd (ivy-state-window ivy-last)))
 522   (let ((ov (if visual-line-mode
 523                 (make-overlay
 524                  (save-excursion
 525                    (beginning-of-visual-line)
 526                    (point))
 527                  (save-excursion
 528                    (end-of-visual-line)
 529                    (point)))
 530               (make-overlay
 531                (line-beginning-position)
 532                (1+ (line-end-position))))))
 533     (overlay-put ov 'face 'swiper-line-face)
 534     (overlay-put ov 'window wnd)
 535     (push ov swiper--overlays)
 536     (let* ((wh (window-height))
 537            (beg (or beg (save-excursion
 538                           (forward-line (- wh))
 539                           (point))))
 540            (end (or end (save-excursion
 541                           (forward-line wh)
 542                           (point)))))
 543       (when (>= (length re) swiper-min-highlight)
 544         (save-excursion
 545           (goto-char beg)
 546           ;; RE can become an invalid regexp
 547           (while (and (ignore-errors (re-search-forward re end t))
 548                       (> (- (match-end 0) (match-beginning 0)) 0))
 549             (let ((i 0))
 550               (while (<= i ivy--subexps)
 551                 (when (match-beginning i)
 552                   (let ((overlay (make-overlay (match-beginning i)
 553                                                (match-end i)))
 554                         (face
 555                          (cond ((zerop ivy--subexps)
 556                                 (cadr swiper-faces))
 557                                ((zerop i)
 558                                 (car swiper-faces))
 559                                (t
 560                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 561                                      swiper-faces)))))
 562                     (push overlay swiper--overlays)
 563                     (overlay-put overlay 'face face)
 564                     (overlay-put overlay 'window wnd)
 565                     (overlay-put overlay 'priority i)))
 566                 (cl-incf i)))))))))
 567
 568 (defun swiper--action (x)
 569   "Goto line X."
 570   (let ((ln (1- (read (if (memq this-command '(ivy-occur-press))
 571                           (when (string-match ":\\([0-9]+\\):.*\\'" x)
 572                             (match-string-no-properties 1 x))
 573                         (get-text-property 0 'display x)))))
 574         (re (ivy--regex ivy-text)))
 575     (if (null x)
 576         (user-error "No candidates")
 577       (with-ivy-window
 578         (unless (equal (current-buffer)
 579                        (ivy-state-buffer ivy-last))
 580           (switch-to-buffer (ivy-state-buffer ivy-last)))
 581         (goto-char (point-min))
 582         (funcall (if swiper-use-visual-line
 583                      #'line-move
 584                    #'forward-line)
 585                  ln)
 586         (re-search-forward re (line-end-position) t)
 587         (swiper--ensure-visible)
 588         (when (/= (point) swiper--opoint)
 589           (unless (and transient-mark-mode mark-active)
 590             (when (eq ivy-exit 'done)
 591               (push-mark swiper--opoint t)
 592               (message "Mark saved where search started"))))
 593         (add-to-history
 594          'regexp-search-ring
 595          re
 596          regexp-search-ring-max)))))
 597
 598 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 599 (defun swiper-from-isearch ()
 600   "Invoke `swiper' from isearch."
 601   (interactive)
 602   (let ((query (if isearch-regexp
 603                    isearch-string
 604                  (regexp-quote isearch-string))))
 605     (isearch-exit)
 606     (swiper query)))
 607
 608 (defvar swiper-multi-buffers nil
 609   "Store the current list of buffers.")
 610
 611 (defvar swiper-multi-candidates nil
 612   "Store the list of candidates for `swiper-multi'.")
 613
 614 (defun swiper-multi-prompt ()
 615   (format "Buffers (%s): "
 616           (mapconcat #'identity swiper-multi-buffers ", ")))
 617
 618 (defun swiper-multi ()
 619   "Select one or more buffers.
 620 Run `swiper' for those buffers."
 621   (interactive)
 622   (setq swiper-multi-buffers nil)
 623   (ivy-read (swiper-multi-prompt)
 624             'internal-complete-buffer
 625             :action 'swiper-multi-action-1)
 626   (ivy-read "Swiper: " swiper-multi-candidates
 627             :action 'swiper-multi-action-2
 628             :unwind #'swiper--cleanup
 629             :caller 'swiper-multi))
 630
 631 (defun swiper-all ()
 632   "Run `swiper' for all opened buffers."
 633   (interactive)
 634   (ivy-read "Swiper: " (swiper--multi-candidates
 635                         (cl-remove-if-not
 636                          #'buffer-file-name
 637                          (buffer-list)))
 638             :action 'swiper-multi-action-2
 639             :unwind #'swiper--cleanup
 640             :caller 'swiper-multi))
 641
 642 (defun swiper--multi-candidates (buffers)
 643   (let* ((ww (window-width))
 644          (res nil)
 645          (column-2 (apply #'max
 646                           (mapcar
 647                            (lambda (b)
 648                              (length (buffer-name b)))
 649                            buffers)))
 650          (column-1 (- ww 4 column-2 1)))
 651     (dolist (buf buffers)
 652       (with-current-buffer buf
 653         (setq res
 654               (append
 655                (mapcar
 656                 (lambda (s)
 657                   (setq s (concat (ivy--truncate-string s column-1) " "))
 658                   (let ((len (length s)))
 659                     (put-text-property
 660                      (1- len) len 'display
 661                      (concat
 662                       (make-string
 663                        (- ww (string-width s) (length (buffer-name)) 3)
 664                        ?\ )
 665                       (buffer-name))
 666                      s)
 667                     s))
 668                 (swiper--candidates 4))
 669                res))
 670         nil))
 671     res))
 672
 673 (defun swiper-multi-action-1 (x)
 674   (if (member x swiper-multi-buffers)
 675       (progn
 676         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 677     (unless (equal x "")
 678       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 679   (let ((prompt (swiper-multi-prompt)))
 680     (setf (ivy-state-prompt ivy-last) prompt)
 681     (setq ivy--prompt (concat "%-4d " prompt)))
 682   (cond ((memq this-command '(ivy-done
 683                               ivy-alt-done
 684                               ivy-immediate-done))
 685          (setq swiper-multi-candidates
 686                (swiper--multi-candidates
 687                 (mapcar #'get-buffer swiper-multi-buffers))))
 688         ((eq this-command 'ivy-call)
 689          (delete-minibuffer-contents))))
 690
 691 (defun swiper-multi-action-2 (x)
 692   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 693     (with-ivy-window
 694       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 695         (switch-to-buffer (match-string 1 buf-space))
 696         (goto-char (point-min))
 697         (forward-line (1- (read (get-text-property 0 'display x))))
 698         (re-search-forward
 699          (ivy--regex ivy-text)
 700          (line-end-position) t)
 701         (unless (eq ivy-exit 'done)
 702           (swiper--cleanup)
 703           (swiper--add-overlays (ivy--regex ivy-text)))))))
 704
 705 (provide 'swiper)
 706
 707 ;;; swiper.el ends here